lisp/org-crypt.el

   1 ;;; org-crypt.el --- Public key encryption for org-mode entries
   2
   3 ;; Copyright (C) 2007, 2009-2012  Free Software Foundation, Inc.
   4
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-crypt.el
   7 ;; Keywords: org-mode
   8 ;; Author: John Wiegley <johnw@gnu.org>
   9 ;; Maintainer: Peter Jones <pjones@pmade.com>
  10 ;; Description: Adds public key encryption to org-mode buffers
  11 ;; URL: http://www.newartisans.com/software/emacs.html
  12 ;; Compatibility: Emacs22
  13
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;; Commentary:
  30
  31 ;; Right now this is just a set of functions to play with.  It depends
  32 ;; on the epg library.  Here's how you would use it:
  33 ;;
  34 ;; 1. To mark an entry for encryption, tag the heading with "crypt".
  35 ;;    You can change the tag to any complex tag matching string by
  36 ;;    setting the `org-crypt-tag-matcher' variable.
  37 ;;
  38 ;; 2. Set the encryption key to use in the `org-crypt-key' variable,
  39 ;;    or use `M-x org-set-property' to set the property CRYPTKEY to
  40 ;;    any address in your public keyring.  The text of the entry (but
  41 ;;    not its properties or headline) will be encrypted for this user.
  42 ;;    For them to read it, the corresponding secret key must be
  43 ;;    located in the secret key ring of the account where you try to
  44 ;;    decrypt it.  This makes it possible to leave secure notes that
  45 ;;    only the intended recipient can read in a shared-org-mode-files
  46 ;;    scenario.
  47 ;;    If the key is not set, org-crypt will default to symmetric encryption.
  48 ;;
  49 ;; 3. To later decrypt an entry, use `org-decrypt-entries' or
  50 ;;    `org-decrypt-entry'.  It might be useful to bind this to a key,
  51 ;;    like C-c C-/.  I hope that in the future, C-c C-r can be might
  52 ;;    overloaded to also decrypt an entry if it's encrypted, since
  53 ;;    that fits nicely with the meaning of "reveal".
  54 ;;
  55 ;; 4. To automatically encrypt all necessary entries when saving a
  56 ;;    file, call `org-crypt-use-before-save-magic' after loading
  57 ;;    org-crypt.el.
  58
  59 ;;; Thanks:
  60
  61 ;; - Carsten Dominik
  62 ;; - Vitaly Ostanin
  63
  64 (require 'org)
  65
  66 ;;; Code:
  67
  68 (declare-function epg-decrypt-string "epg" (context cipher))
  69 (declare-function epg-list-keys "epg" (context &optional name mode))
  70 (declare-function epg-make-context "epg"
  71                   (&optional protocol armor textmode include-certs
  72                              cipher-algorithm digest-algorithm
  73                              compress-algorithm))
  74 (declare-function epg-encrypt-string "epg"
  75                   (context plain recipients &optional sign always-trust))
  76
  77 (defgroup org-crypt nil
  78   "Org Crypt"
  79   :tag "Org Crypt"
  80   :group 'org)
  81
  82 (defcustom org-crypt-tag-matcher "crypt"
  83   "The tag matcher used to find headings whose contents should be encrypted.
  84
  85 See the \"Match syntax\" section of the org manual for more details."
  86   :type 'string
  87   :group 'org-crypt)
  88
  89 (defcustom org-crypt-key ""
  90   "The default key to use when encrypting the contents of a heading.
  91
  92 This setting can also be overridden in the CRYPTKEY property."
  93   :type 'string
  94   :group 'org-crypt)
  95
  96 (defcustom org-crypt-disable-auto-save 'ask
  97   "What org-decrypt should do if `auto-save-mode' is enabled.
  98
  99 t        : Disable auto-save-mode for the current buffer
 100            prior to decrypting an entry.
 101
 102 nil      : Leave auto-save-mode enabled.
 103            This may cause data to be written to disk unencrypted!
 104
 105 'ask     : Ask user whether or not to disable auto-save-mode
 106            for the current buffer.
 107
 108 'encrypt : Leave auto-save-mode enabled for the current buffer,
 109            but automatically re-encrypt all decrypted entries
 110            *before* auto-saving.
 111            NOTE: This only works for entries which have a tag
 112            that matches `org-crypt-tag-matcher'."
 113   :group 'org-crypt
 114   :version "24.1"
 115   :type '(choice (const :tag "Always"  t)
 116                  (const :tag "Never"   nil)
 117                  (const :tag "Ask"     ask)
 118                  (const :tag "Encrypt" encrypt)))
 119
 120 (defun org-crypt-check-auto-save ()
 121   "Check whether auto-save-mode is enabled for the current buffer.
 122
 123 `auto-save-mode' may cause leakage when decrypting entries, so
 124 check whether it's enabled, and decide what to do about it.
 125
 126 See `org-crypt-disable-auto-save'."
 127   (when buffer-auto-save-file-name
 128     (cond
 129      ((or
 130        (eq org-crypt-disable-auto-save t)
 131        (and
 132         (eq org-crypt-disable-auto-save 'ask)
 133         (y-or-n-p "org-decrypt: auto-save-mode may cause leakage. Disable it for current buffer? ")))
 134       (message (concat "org-decrypt: Disabling auto-save-mode for " (or (buffer-file-name) (current-buffer))))
 135       ; The argument to auto-save-mode has to be "-1", since
 136       ; giving a "nil" argument toggles instead of disabling.
 137       (auto-save-mode -1))
 138      ((eq org-crypt-disable-auto-save nil)
 139       (message "org-decrypt: Decrypting entry with auto-save-mode enabled. This may cause leakage."))
 140      ((eq org-crypt-disable-auto-save 'encrypt)
 141       (message "org-decrypt: Enabling re-encryption on auto-save.")
 142       (add-hook 'auto-save-hook
 143                 (lambda ()
 144                   (message "org-crypt: Re-encrypting all decrypted entries due to auto-save.")
 145                   (org-encrypt-entries))
 146                 nil t))
 147      (t nil))))
 148
 149 (defun org-crypt-key-for-heading ()
 150   "Return the encryption key for the current heading."
 151   (save-excursion
 152     (org-back-to-heading t)
 153     (or (org-entry-get nil "CRYPTKEY" 'selective)
 154         org-crypt-key
 155         (and (boundp 'epa-file-encrypt-to) epa-file-encrypt-to)
 156         (message "No crypt key set, using symmetric encryption."))))
 157
 158 (defun org-encrypt-string (str crypt-key)
 159   "Return STR encrypted with CRYPT-KEY."
 160   ;; Text and key have to be identical, otherwise we re-crypt.
 161   (if (and (string= crypt-key (get-text-property 0 'org-crypt-key str))
 162            (string= (sha1 str) (get-text-property 0 'org-crypt-checksum str)))
 163       (get-text-property 0 'org-crypt-text str)
 164     (let ((epg-context (epg-make-context nil t t)))
 165       (epg-encrypt-string epg-context str (epg-list-keys epg-context crypt-key)))))
 166
 167 (defun org-encrypt-entry ()
 168   "Encrypt the content of the current headline."
 169   (interactive)
 170   (require 'epg)
 171   (save-excursion
 172     (org-back-to-heading t)
 173     (let ((start-heading (point)))
 174       (forward-line)
 175       (when (not (looking-at "-----BEGIN PGP MESSAGE-----"))
 176         (let ((folded (outline-invisible-p))
 177               (epg-context (epg-make-context nil t t))
 178               (crypt-key (org-crypt-key-for-heading))
 179               (beg (point))
 180               end encrypted-text)
 181           (goto-char start-heading)
 182           (org-end-of-subtree t t)
 183           (org-back-over-empty-lines)
 184           (setq end (point)
 185                 encrypted-text
 186                 (org-encrypt-string (buffer-substring beg end) crypt-key))
 187           (delete-region beg end)
 188           (insert encrypted-text)
 189           (when folded
 190             (goto-char start-heading)
 191             (hide-subtree))
 192           nil)))))
 193
 194 (defun org-decrypt-entry ()
 195   "Decrypt the content of the current headline."
 196   (interactive)
 197   (require 'epg)
 198   (unless (org-before-first-heading-p)
 199     (save-excursion
 200       (org-back-to-heading t)
 201       (let ((heading-point (point))
 202             (heading-was-invisible-p
 203              (save-excursion
 204                (outline-end-of-heading)
 205                (outline-invisible-p))))
 206         (forward-line)
 207         (when (looking-at "-----BEGIN PGP MESSAGE-----")
 208           (org-crypt-check-auto-save)
 209           (let* ((end (save-excursion
 210                         (search-forward "-----END PGP MESSAGE-----")
 211                         (forward-line)
 212                         (point)))
 213                  (epg-context (epg-make-context nil t t))
 214                  (encrypted-text (buffer-substring-no-properties (point) end))
 215                  (decrypted-text
 216                   (decode-coding-string
 217                    (epg-decrypt-string
 218                     epg-context
 219                     encrypted-text)
 220                    'utf-8)))
 221             ;; Delete region starting just before point, because the
 222             ;; outline property starts at the \n of the heading.
 223             (delete-region (1- (point)) end)
 224             ;; Store a checksum of the decrypted and the encrypted
 225             ;; text value. This allow to reuse the same encrypted text
 226             ;; if the text does not change, and therefore avoid a
 227             ;; re-encryption process.
 228             (insert "\n" (propertize decrypted-text
 229                                      'org-crypt-checksum (sha1 decrypted-text)
 230                                      'org-crypt-key (org-crypt-key-for-heading)
 231                                      'org-crypt-text encrypted-text))
 232             (when heading-was-invisible-p
 233               (goto-char heading-point)
 234               (org-flag-subtree t))
 235             nil))))))
 236
 237 (defun org-encrypt-entries ()
 238   "Encrypt all top-level entries in the current buffer."
 239   (interactive)
 240   (org-scan-tags
 241    'org-encrypt-entry
 242    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 243
 244 (defun org-decrypt-entries ()
 245   "Decrypt all entries in the current buffer."
 246   (interactive)
 247   (org-scan-tags
 248    'org-decrypt-entry
 249    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 250
 251 (defun org-crypt-use-before-save-magic ()
 252   "Add a hook to automatically encrypt entries before a file is saved to disk."
 253   (add-hook
 254    'org-mode-hook
 255    (lambda () (add-hook 'before-save-hook 'org-encrypt-entries nil t))))
 256
 257 (add-hook 'org-reveal-start-hook 'org-decrypt-entry)
 258
 259 (provide 'org-crypt)
 260
 261 ;;; org-crypt.el ends here