lisp/org-icalendar.el

   1 ;;; org-icalendar.el --- iCalendar export for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 7.5
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (require 'org-exp)
  32
  33 (eval-when-compile
  34   (require 'cl))
  35
  36 (declare-function org-bbdb-anniv-export-ical "org-bbdb" nil)
  37
  38 (defgroup org-export-icalendar nil
  39   "Options specific for iCalendar export of Org-mode files."
  40   :tag "Org Export iCalendar"
  41   :group 'org-export)
  42
  43 (defcustom org-combined-agenda-icalendar-file "~/org.ics"
  44   "The file name for the iCalendar file covering all agenda files.
  45 This file is created with the command \\[org-export-icalendar-all-agenda-files].
  46 The file name should be absolute, the file will be overwritten without warning."
  47   :group 'org-export-icalendar
  48   :type 'file)
  49
  50 (defcustom org-icalendar-alarm-time 0
  51   "Number of minutes for triggering an alarm for exported timed events.
  52 A zero value (the default) turns off the definition of an alarm trigger
  53 for timed events.  If non-zero, alarms are created.
  54
  55 - a single alarm per entry is defined
  56 - The alarm will go off N minutes before the event
  57 - only a DISPLAY action is defined."
  58   :group 'org-export-icalendar
  59   :type 'integer)
  60
  61 (defcustom org-icalendar-combined-name "OrgMode"
  62   "Calendar name for the combined iCalendar representing all agenda files."
  63   :group 'org-export-icalendar
  64   :type 'string)
  65
  66 (defcustom org-icalendar-combined-description nil
  67   "Calendar description for the combined iCalendar (all agenda files)."
  68   :group 'org-export-icalendar
  69   :type 'string)
  70
  71 (defcustom org-icalendar-use-plain-timestamp t
  72   "Non-nil means make an event from every plain time stamp."
  73   :group 'org-export-icalendar
  74   :type 'boolean)
  75
  76 (defcustom org-icalendar-honor-noexport-tag nil
  77   "Non-nil means don't export entries with a tag in `org-export-exclude-tags'."
  78   :group 'org-export-icalendar
  79   :type 'boolean)
  80
  81 (defcustom org-icalendar-use-deadline '(event-if-not-todo todo-due)
  82   "Contexts where iCalendar export should use a deadline time stamp.
  83 This is a list with several symbols in it.  Valid symbol are:
  84
  85 event-if-todo       Deadlines in TODO entries become calendar events.
  86 event-if-not-todo   Deadlines in non-TODO entries become calendar events.
  87 todo-due            Use deadlines in TODO entries as due-dates"
  88   :group 'org-export-icalendar
  89   :type '(set :greedy t
  90               (const :tag "Deadlines in non-TODO entries become events"
  91                      event-if-not-todo)
  92               (const :tag "Deadline in TODO entries become events"
  93                      event-if-todo)
  94               (const :tag "Deadlines in TODO entries become due-dates"
  95                      todo-due)))
  96
  97 (defcustom org-icalendar-use-scheduled '(todo-start)
  98   "Contexts where iCalendar export should use a scheduling time stamp.
  99 This is a list with several symbols in it.  Valid symbol are:
 100
 101 event-if-todo       Scheduling time stamps in TODO entries become an event.
 102 event-if-not-todo   Scheduling time stamps in non-TODO entries become an event.
 103 todo-start          Scheduling time stamps in TODO entries become start date.
 104                     Some calendar applications show TODO entries only after
 105                     that date."
 106   :group 'org-export-icalendar
 107   :type '(set :greedy t
 108               (const :tag
 109                      "SCHEDULED timestamps in non-TODO entries become events"
 110                      event-if-not-todo)
 111               (const :tag "SCHEDULED timestamps in TODO entries become events"
 112                      event-if-todo)
 113               (const :tag "SCHEDULED in TODO entries become start date"
 114                      todo-start)))
 115
 116 (defcustom org-icalendar-categories '(local-tags category)
 117   "Items that should be entered into the categories field.
 118 This is a list of symbols, the following are valid:
 119
 120 category    The Org-mode category of the current file or tree
 121 todo-state  The todo state, if any
 122 local-tags  The tags, defined in the current line
 123 all-tags    All tags, including inherited ones."
 124   :group 'org-export-icalendar
 125   :type '(repeat
 126           (choice
 127            (const :tag "The file or tree category" category)
 128            (const :tag "The TODO state" todo-state)
 129            (const :tag "Tags defined in current line" local-tags)
 130            (const :tag "All tags, including inherited ones" all-tags))))
 131
 132 (defcustom org-icalendar-include-todo nil
 133   "Non-nil means export to iCalendar files should also cover TODO items.
 134 Valid values are:
 135 nil         don't include any TODO items
 136 t           include all TODO items that are not in a DONE state
 137 unblocked   include all TODO items that are not blocked
 138 all         include both done and not done items."
 139   :group 'org-export-icalendar
 140   :type '(choice
 141           (const :tag "None" nil)
 142           (const :tag "Unfinished" t)
 143           (const :tag "Unblocked" unblocked)
 144           (const :tag "All" all)))
 145
 146 (defvar org-icalendar-verify-function nil
 147   "Function to verify entries for iCalendar export.
 148 This can be set to a function that will be called at each entry that
 149 is considered for export to iCalendar.  When the function returns nil,
 150 the entry will be skipped.  When it returns a non-nil value, the entry
 151 will be considered for export.
 152 This is used internally when an agenda buffer is exported to an ics file,
 153 to make sure that only entries currently listed in the agenda will end
 154 up in the ics file.  But for normal iCalendar export, you can use this
 155 for whatever you need.")
 156
 157 (defcustom org-icalendar-include-bbdb-anniversaries nil
 158   "Non-nil means a combined iCalendar files should include anniversaries.
 159 The anniversaries are define in the BBDB database."
 160   :group 'org-export-icalendar
 161   :type 'boolean)
 162
 163 (defcustom org-icalendar-include-sexps t
 164   "Non-nil means export to iCalendar files should also cover sexp entries.
 165 These are entries like in the diary, but directly in an Org-mode file."
 166   :group 'org-export-icalendar
 167   :type 'boolean)
 168
 169 (defcustom org-icalendar-include-body 100
 170   "Amount of text below headline to be included in iCalendar export.
 171 This is a number of characters that should maximally be included.
 172 Properties, scheduling and clocking lines will always be removed.
 173 The text will be inserted into the DESCRIPTION field."
 174   :group 'org-export-icalendar
 175   :type '(choice
 176           (const :tag "Nothing" nil)
 177           (const :tag "Everything" t)
 178           (integer :tag "Max characters")))
 179
 180 (defcustom org-icalendar-store-UID nil
 181   "Non-nil means store any created UIDs in properties.
 182 The iCalendar standard requires that all entries have a unique identifier.
 183 Org will create these identifiers as needed.  When this variable is non-nil,
 184 the created UIDs will be stored in the ID property of the entry.  Then the
 185 next time this entry is exported, it will be exported with the same UID,
 186 superseding the previous form of it.  This is essential for
 187 synchronization services.
 188 This variable is not turned on by default because we want to avoid creating
 189 a property drawer in every entry if people are only playing with this feature,
 190 or if they are only using it locally."
 191   :group 'org-export-icalendar
 192   :type 'boolean)
 193
 194 (defcustom org-icalendar-timezone (getenv "TZ")
 195   "The time zone string for iCalendar export.
 196 When nil of the empty string, use the abbreviation retrieved from Emacs."
 197   :group 'org-export-icalendar
 198   :type '(choice
 199           (const :tag "Unspecified" nil)
 200           (string :tag "Time zone")))
 201
 202 ;; Backward compatibility with previous variable
 203 (defvar org-icalendar-use-UTC-date-time nil)
 204 (defcustom org-icalendar-date-time-format
 205   (if org-icalendar-use-UTC-date-time
 206       ":%Y%m%dT%H%M%SZ"
 207     ":%Y%m%dT%H%M%S")
 208   "Format-string for exporting icalendar DATE-TIME.
 209 See `format-time-string' for a full documentation.  The only
 210 difference is that `org-icalendar-timezone' is used for %Z.
 211
 212 Interesting value are:
 213  - \":%Y%m%dT%H%M%S\" for local time
 214  - \";TZID=%Z:%Y%m%dT%H%M%S\" for local time with explicit timezone
 215  - \":%Y%m%dT%H%M%SZ\" for time expressed in Universal Time"
 216
 217   :group 'org-export-icalendar
 218   :type '(choice
 219           (const :tag "Local time" ":%Y%m%dT%H%M%S")
 220           (const :tag "Explicit local time" ";TZID=%Z:%Y%m%dT%H%M%S")
 221           (const :tag "Universal time" ":%Y%m%dT%H%M%SZ")
 222           (string :tag "Explicit format")))
 223
 224 (defun org-icalendar-use-UTC-date-timep ()
 225   (char-equal (elt org-icalendar-date-time-format
 226                    (1- (length org-icalendar-date-time-format))) ?Z))
 227
 228 ;;; iCalendar export
 229
 230 ;;;###autoload
 231 (defun org-export-icalendar-this-file ()
 232   "Export current file as an iCalendar file.
 233 The iCalendar file will be located in the same directory as the Org-mode
 234 file, but with extension `.ics'."
 235   (interactive)
 236   (org-export-icalendar nil buffer-file-name))
 237
 238 ;;;###autoload
 239 (defun org-export-icalendar-all-agenda-files ()
 240   "Export all files in the variable `org-agenda-files' to iCalendar .ics files.
 241 Each iCalendar file will be located in the same directory as the Org-mode
 242 file, but with extension `.ics'."
 243   (interactive)
 244   (apply 'org-export-icalendar nil (org-agenda-files t)))
 245
 246 ;;;###autoload
 247 (defun org-export-icalendar-combine-agenda-files ()
 248   "Export all files in `org-agenda-files' to a single combined iCalendar file.
 249 The file is stored under the name `org-combined-agenda-icalendar-file'."
 250   (interactive)
 251   (apply 'org-export-icalendar t (org-agenda-files t)))
 252
 253 (defun org-export-icalendar (combine &rest files)
 254   "Create iCalendar files for all elements of FILES.
 255 If COMBINE is non-nil, combine all calendar entries into a single large
 256 file and store it under the name `org-combined-agenda-icalendar-file'."
 257   (save-excursion
 258     (org-prepare-agenda-buffers files)
 259     (let* ((dir (org-export-directory
 260                  :ical (list :publishing-directory
 261                              org-export-publishing-directory)))
 262            file ical-file ical-buffer category started org-agenda-new-buffers)
 263       (and (get-buffer "*ical-tmp*") (kill-buffer "*ical-tmp*"))
 264       (when combine
 265         (setq ical-file
 266               (if (file-name-absolute-p org-combined-agenda-icalendar-file)
 267                   org-combined-agenda-icalendar-file
 268                 (expand-file-name org-combined-agenda-icalendar-file dir))
 269               ical-buffer (org-get-agenda-file-buffer ical-file))
 270         (set-buffer ical-buffer) (erase-buffer))
 271       (while (setq file (pop files))
 272         (catch 'nextfile
 273           (org-check-agenda-file file)
 274           (set-buffer (org-get-agenda-file-buffer file))
 275           (unless combine
 276             (setq ical-file (concat (file-name-as-directory dir)
 277                                     (file-name-sans-extension
 278                                      (file-name-nondirectory buffer-file-name))
 279                                     ".ics"))
 280             (setq ical-buffer (org-get-agenda-file-buffer ical-file))
 281             (with-current-buffer ical-buffer (erase-buffer)))
 282           (setq category (or org-category
 283                              (file-name-sans-extension
 284                               (file-name-nondirectory buffer-file-name))))
 285           (if (symbolp category) (setq category (symbol-name category)))
 286           (let ((standard-output ical-buffer))
 287             (if combine
 288                 (and (not started) (setq started t)
 289                      (org-start-icalendar-file org-icalendar-combined-name))
 290               (org-start-icalendar-file category))
 291             (org-print-icalendar-entries combine)
 292             (when (or (and combine (not files)) (not combine))
 293               (when (and combine org-icalendar-include-bbdb-anniversaries)
 294                 (require 'org-bbdb)
 295                 (org-bbdb-anniv-export-ical))
 296               (org-finish-icalendar-file)
 297               (set-buffer ical-buffer)
 298               (run-hooks 'org-before-save-iCalendar-file-hook)
 299               (save-buffer)
 300               (run-hooks 'org-after-save-iCalendar-file-hook)
 301               (and (boundp 'org-wait) (numberp org-wait) (sit-for org-wait))
 302               ))))
 303       (org-release-buffers org-agenda-new-buffers))))
 304
 305 (defvar org-before-save-iCalendar-file-hook nil
 306   "Hook run before  an iCalendar file has been saved.
 307 This can be used to modify the result of the export.")
 308
 309 (defvar org-after-save-iCalendar-file-hook nil
 310   "Hook run after an iCalendar file has been saved.
 311 The iCalendar buffer is still current when this hook is run.
 312 A good way to use this is to tell a desktop calendar application to re-read
 313 the iCalendar file.")
 314
 315 (defvar org-agenda-default-appointment-duration) ; defined in org-agenda.el
 316 (defun org-print-icalendar-entries (&optional combine)
 317   "Print iCalendar entries for the current Org-mode file to `standard-output'.
 318 When COMBINE is non nil, add the category to each line."
 319   (require 'org-agenda)
 320   (let ((re1 (concat org-ts-regexp "\\|<%%([^>\n]+>"))
 321         (re2 (concat "--?-?\\(" org-ts-regexp "\\)"))
 322         (dts (org-ical-ts-to-string
 323               (format-time-string (cdr org-time-stamp-formats) (current-time))
 324               "DTSTART"))
 325         hd ts ts2 state status (inc t) pos b sexp rrule
 326         scheduledp deadlinep todo prefix due start tags
 327         tmp pri categories location summary desc uid alarm
 328         (sexp-buffer (get-buffer-create "*ical-tmp*")))
 329     (org-refresh-category-properties)
 330     (save-excursion
 331       (goto-char (point-min))
 332       (while (re-search-forward re1 nil t)
 333         (catch :skip
 334           (org-agenda-skip)
 335           (when org-icalendar-verify-function
 336             (unless (save-match-data (funcall org-icalendar-verify-function))
 337               (outline-next-heading)
 338               (backward-char 1)
 339               (throw :skip nil)))
 340           (setq pos (match-beginning 0)
 341                 ts (match-string 0)
 342                 tags (org-get-tags-at)
 343                 inc t
 344                 hd (condition-case nil
 345                        (org-icalendar-cleanup-string
 346                         (org-get-heading t))
 347                      (error (throw :skip nil)))
 348                 summary (org-icalendar-cleanup-string
 349                          (org-entry-get nil "SUMMARY"))
 350                 desc (org-icalendar-cleanup-string
 351                       (or (org-entry-get nil "DESCRIPTION")
 352                           (and org-icalendar-include-body (org-get-entry)))
 353                       t org-icalendar-include-body)
 354                 location (org-icalendar-cleanup-string
 355                           (org-entry-get nil "LOCATION" 'selective))
 356                 uid (if org-icalendar-store-UID
 357                         (org-id-get-create)
 358                       (or (org-id-get) (org-id-new)))
 359                 categories (org-export-get-categories)
 360                 alarm ""
 361                 deadlinep nil scheduledp nil)
 362           (if (looking-at re2)
 363               (progn
 364                 (goto-char (match-end 0))
 365                 (setq ts2 (match-string 1)
 366                       inc (not (string-match "[0-9]\\{1,2\\}:[0-9][0-9]" ts2))))
 367             (setq tmp (buffer-substring (max (point-min)
 368                                              (- pos org-ds-keyword-length))
 369                                         pos)
 370                   ts2 (if (string-match "[0-9]\\{1,2\\}:[0-9][0-9]-\\([0-9]\\{1,2\\}:[0-9][0-9]\\)" ts)
 371                           (progn
 372                             (setq inc nil)
 373                             (replace-match "\\1" t nil ts))
 374                         ts)
 375                   deadlinep (string-match org-deadline-regexp tmp)
 376                   scheduledp (string-match org-scheduled-regexp tmp)
 377                   todo (org-get-todo-state)
 378                   ;; donep (org-entry-is-done-p)
 379                   ))
 380           (when (and (not org-icalendar-use-plain-timestamp)
 381                      (not deadlinep) (not scheduledp))
 382             (throw :skip t))
 383           ;; don't export entries with a :noexport: tag
 384           (when (and org-icalendar-honor-noexport-tag
 385                      (delq nil (mapcar (lambda(x)
 386                                          (member x org-export-exclude-tags)) tags)))
 387             (throw :skip t))
 388           (when (and
 389                  deadlinep
 390                  (if todo
 391                      (not (memq 'event-if-todo org-icalendar-use-deadline))
 392                    (not (memq 'event-if-not-todo org-icalendar-use-deadline))))
 393             (throw :skip t))
 394           (when (and
 395                  scheduledp
 396                  (if todo
 397                      (not (memq 'event-if-todo org-icalendar-use-scheduled))
 398                    (not (memq 'event-if-not-todo org-icalendar-use-scheduled))))
 399             (throw :skip t))
 400           (setq prefix (if deadlinep "DL-" (if scheduledp "SC-" "TS-")))
 401           (if (or (string-match org-tr-regexp hd)
 402                   (string-match org-ts-regexp hd))
 403               (setq hd (replace-match "" t t hd)))
 404           (if (string-match "\\+\\([0-9]+\\)\\([dwmy]\\)>" ts)
 405               (setq rrule
 406                     (concat "\nRRULE:FREQ="
 407                             (cdr (assoc
 408                                   (match-string 2 ts)
 409                                   '(("d" . "DAILY")("w" . "WEEKLY")
 410                                     ("m" . "MONTHLY")("y" . "YEARLY"))))
 411                             ";INTERVAL=" (match-string 1 ts)))
 412             (setq rrule ""))
 413           (setq summary (or summary hd))
 414           ;; create an alarm entry if the entry is timed.  this is not very general in that:
 415           ;; (a) only one alarm per entry is defined,
 416           ;; (b) only minutes are allowed for the trigger period ahead of the start time, and
 417           ;; (c) only a DISPLAY action is defined.
 418           ;; [ESF]
 419           (let ((t1 (ignore-errors (org-parse-time-string ts 'nodefault))))
 420             (if (and (> org-icalendar-alarm-time 0)
 421                      (car t1) (nth 1 t1) (nth 2 t1))
 422                 (setq alarm (format "\nBEGIN:VALARM\nACTION:DISPLAY\nDESCRIPTION:%s\nTRIGGER:-P0D0H%dM0S\nEND:VALARM" summary org-icalendar-alarm-time))
 423               (setq alarm ""))
 424             )
 425           (if (string-match org-bracket-link-regexp summary)
 426               (setq summary
 427                     (replace-match (if (match-end 3)
 428                                        (match-string 3 summary)
 429                                      (match-string 1 summary))
 430                                    t t summary)))
 431           (if deadlinep (setq summary (concat "DL: " summary)))
 432           (if scheduledp (setq summary (concat "S: " summary)))
 433           (if (string-match "\\`<%%" ts)
 434               (with-current-buffer sexp-buffer
 435                 (insert (substring ts 1 -1) " " summary "\n"))
 436             (princ (format "BEGIN:VEVENT
 437 UID: %s
 438 %s
 439 %s%s
 440 SUMMARY:%s%s%s
 441 CATEGORIES:%s%s
 442 END:VEVENT\n"
 443                            (concat prefix uid)
 444                            (org-ical-ts-to-string ts "DTSTART")
 445                            (org-ical-ts-to-string ts2 "DTEND" inc)
 446                            rrule summary
 447                            (if (and desc (string-match "\\S-" desc))
 448                                (concat "\nDESCRIPTION: " desc) "")
 449                            (if (and location (string-match "\\S-" location))
 450                                (concat "\nLOCATION: " location) "")
 451                            categories
 452                            alarm)))))
 453       (when (and org-icalendar-include-sexps
 454                  (condition-case nil (require 'icalendar) (error nil))
 455                  (fboundp 'icalendar-export-region))
 456         ;; Get all the literal sexps
 457         (goto-char (point-min))
 458         (while (re-search-forward "^&?%%(" nil t)
 459           (catch :skip
 460             (org-agenda-skip)
 461             (when org-icalendar-verify-function
 462               (unless (save-match-data (funcall org-icalendar-verify-function))
 463                 (outline-next-heading)
 464                 (backward-char 1)
 465                 (throw :skip nil)))
 466             (setq b (match-beginning 0))
 467             (goto-char (1- (match-end 0)))
 468             (forward-sexp 1)
 469             (end-of-line 1)
 470             (setq sexp (buffer-substring b (point)))
 471             (with-current-buffer sexp-buffer
 472               (insert sexp "\n"))))
 473         (princ (org-diary-to-ical-string sexp-buffer))
 474         (kill-buffer sexp-buffer))
 475
 476       (when org-icalendar-include-todo
 477         (setq prefix "TODO-")
 478         (goto-char (point-min))
 479         (while (re-search-forward org-complex-heading-regexp nil t)
 480           (catch :skip
 481             (org-agenda-skip)
 482             (when org-icalendar-verify-function
 483               (unless (save-match-data
 484                         (funcall org-icalendar-verify-function))
 485                 (outline-next-heading)
 486                 (backward-char 1)
 487                 (throw :skip nil)))
 488             (setq state (match-string 2))
 489             (setq status (if (member state org-done-keywords)
 490                              "COMPLETED" "NEEDS-ACTION"))
 491             (when (and state
 492                        (cond
 493                         ;; check if the state is one we should use
 494                         ((eq org-icalendar-include-todo 'all)
 495                          ;; all should be included
 496                          t)
 497                         ((eq org-icalendar-include-todo 'unblocked)
 498                          ;; only undone entries that are not blocked
 499                          (and (member state org-not-done-keywords)
 500                               (or (not org-blocker-hook)
 501                                   (save-match-data
 502                                     (run-hook-with-args-until-failure
 503                                      'org-blocker-hook
 504                                      (list :type 'todo-state-change
 505                                            :position (point-at-bol)
 506                                            :from 'todo
 507                                            :to 'done))))))
 508                         ((eq org-icalendar-include-todo t)
 509                          ;; include everything that is not done
 510                          (member state org-not-done-keywords))))
 511               (setq hd (match-string 4)
 512                     summary (org-icalendar-cleanup-string
 513                              (org-entry-get nil "SUMMARY"))
 514                     desc (org-icalendar-cleanup-string
 515                           (or (org-entry-get nil "DESCRIPTION")
 516                               (and org-icalendar-include-body (org-get-entry)))
 517                           t org-icalendar-include-body)
 518                     location (org-icalendar-cleanup-string
 519                               (org-entry-get nil "LOCATION" 'selective))
 520                     due (and (member 'todo-due org-icalendar-use-deadline)
 521                              (org-entry-get nil "DEADLINE"))
 522                     start (and (member 'todo-start org-icalendar-use-scheduled)
 523                              (org-entry-get nil "SCHEDULED"))
 524                     categories (org-export-get-categories)
 525                     uid (if org-icalendar-store-UID
 526                             (org-id-get-create)
 527                           (or (org-id-get) (org-id-new))))
 528               (and due (setq due (org-ical-ts-to-string due "DUE")))
 529               (and start (setq start (org-ical-ts-to-string start "DTSTART")))
 530
 531               (if (string-match org-bracket-link-regexp hd)
 532                   (setq hd (replace-match (if (match-end 3) (match-string 3 hd)
 533                                             (match-string 1 hd))
 534                                           t t hd)))
 535               (if (string-match org-priority-regexp hd)
 536                   (setq pri (string-to-char (match-string 2 hd))
 537                         hd (concat (substring hd 0 (match-beginning 1))
 538                                    (substring hd (match-end 1))))
 539                 (setq pri org-default-priority))
 540               (setq pri (floor (- 9 (* 8. (/ (float (- org-lowest-priority pri))
 541                                              (- org-lowest-priority org-highest-priority))))))
 542
 543               (princ (format "BEGIN:VTODO
 544 UID: %s
 545 %s
 546 SUMMARY:%s%s%s%s
 547 CATEGORIES:%s
 548 SEQUENCE:1
 549 PRIORITY:%d
 550 STATUS:%s
 551 END:VTODO\n"
 552                              (concat prefix uid)
 553                              (or start dts)
 554                              (or summary hd)
 555                              (if (and location (string-match "\\S-" location))
 556                                  (concat "\nLOCATION: " location) "")
 557                              (if (and desc (string-match "\\S-" desc))
 558                                  (concat "\nDESCRIPTION: " desc) "")
 559                              (if due (concat "\n" due) "")
 560                              categories
 561                              pri status)))))))))
 562
 563 (defun org-export-get-categories ()
 564   "Get categories according to `org-icalendar-categories'."
 565   (let ((cs org-icalendar-categories) c rtn tmp)
 566     (while (setq c (pop cs))
 567       (cond
 568        ((eq c 'category) (push (org-get-category) rtn))
 569        ((eq c 'todo-state)
 570         (setq tmp (org-get-todo-state))
 571         (and tmp (push tmp rtn)))
 572        ((eq c 'local-tags)
 573         (setq rtn (append (nreverse (org-get-local-tags-at (point))) rtn)))
 574        ((eq c 'all-tags)
 575         (setq rtn (append (nreverse (org-get-tags-at (point))) rtn)))))
 576     (mapconcat 'identity (nreverse rtn) ",")))
 577
 578 (defun org-icalendar-cleanup-string (s &optional is-body maxlength)
 579   "Take out stuff and quote what needs to be quoted.
 580 When IS-BODY is non-nil, assume that this is the body of an item, clean up
 581 whitespace, newlines, drawers, and timestamps, and cut it down to MAXLENGTH
 582 characters."
 583   (if (not s)
 584       nil
 585     (if is-body
 586       (let ((re (concat "\\(" org-drawer-regexp "\\)[^\000]*?:END:.*\n?"))
 587             (re2 (concat "^[ \t]*" org-keyword-time-regexp ".*\n?")))
 588         (while (string-match re s) (setq s (replace-match "" t t s)))
 589         (while (string-match re2 s) (setq s (replace-match "" t t s))))
 590       (setq s (replace-regexp-in-string "[[:space:]]+" " " s)))
 591     (let ((start 0))
 592       (while (string-match "\\([,;]\\)" s start)
 593         (setq start (+ (match-beginning 0) 2)
 594               s (replace-match "\\\\\\1" nil nil s))))
 595     (setq s (org-trim s))
 596     (when is-body
 597       (while (string-match "[ \t]*\n[ \t]*" s)
 598         (setq s (replace-match "\\n" t t s))))
 599     (if is-body
 600         (if maxlength
 601             (if (and (numberp maxlength)
 602                      (> (length s) maxlength))
 603                 (setq s (substring s 0 maxlength)))))
 604     s))
 605
 606 (defun org-icalendar-cleanup-string-rfc2455 (s &optional is-body maxlength)
 607   "Take out stuff and quote what needs to be quoted.
 608 When IS-BODY is non-nil, assume that this is the body of an item, clean up
 609 whitespace, newlines, drawers, and timestamps, and cut it down to MAXLENGTH
 610 characters.
 611 This seems to be more like RFC 2455, but it causes problems, so it is
 612 not used right now."
 613   (if (not s)
 614       nil
 615     (if is-body
 616         (let ((re (concat "\\(" org-drawer-regexp "\\)[^\000]*?:END:.*\n?"))
 617               (re2 (concat "^[ \t]*" org-keyword-time-regexp ".*\n?")))
 618           (while (string-match re s) (setq s (replace-match "" t t s)))
 619           (while (string-match re2 s) (setq s (replace-match "" t t s)))
 620           (setq s (org-trim s))
 621           (while (string-match "[ \t]*\n[ \t]*" s)
 622             (setq s (replace-match "\\n" t t s)))
 623           (if maxlength
 624               (if (and (numberp maxlength)
 625                        (> (length s) maxlength))
 626                   (setq s (substring s 0 maxlength)))))
 627       (setq s (org-trim s)))
 628     (while (string-match "\"" s) (setq s (replace-match "''" t t s)))
 629     (when (string-match "[;,:]" s) (setq s (concat "\"" s "\"")))
 630     s))
 631
 632 (defun org-start-icalendar-file (name)
 633   "Start an iCalendar file by inserting the header."
 634   (let ((user user-full-name)
 635         (name (or name "unknown"))
 636         (timezone (if (> (length org-icalendar-timezone) 0)
 637                       org-icalendar-timezone
 638                     (cadr (current-time-zone))))
 639         (description org-icalendar-combined-description))
 640     (princ
 641      (format "BEGIN:VCALENDAR
 642 VERSION:2.0
 643 X-WR-CALNAME:%s
 644 PRODID:-//%s//Emacs with Org-mode//EN
 645 X-WR-TIMEZONE:%s
 646 X-WR-CALDESC:%s
 647 CALSCALE:GREGORIAN\n" name user timezone description))))
 648
 649 (defun org-finish-icalendar-file ()
 650   "Finish an iCalendar file by inserting the END statement."
 651   (princ "END:VCALENDAR\n"))
 652
 653 (defun org-ical-ts-to-string (s keyword &optional inc)
 654   "Take a time string S and convert it to iCalendar format.
 655 KEYWORD is added in front, to make a complete line like DTSTART....
 656 When INC is non-nil, increase the hour by two (if time string contains
 657 a time), or the day by one (if it does not contain a time)."
 658   (let ((t1 (ignore-errors (org-parse-time-string s 'nodefault)))
 659         t2 fmt have-time time)
 660     (if (not t1)
 661         ""
 662       (if (and (car t1) (nth 1 t1) (nth 2 t1))
 663           (setq t2 t1 have-time t)
 664         (setq t2 (org-parse-time-string s)))
 665       (let ((s (car t2))   (mi (nth 1 t2)) (h (nth 2 t2))
 666             (d (nth 3 t2)) (m  (nth 4 t2)) (y (nth 5 t2)))
 667         (when inc
 668           (if have-time
 669               (if org-agenda-default-appointment-duration
 670                   (setq mi (+ org-agenda-default-appointment-duration mi))
 671                 (setq h (+ 2 h)))
 672             (setq d (1+ d))))
 673         (setq time (encode-time s mi h d m y)))
 674       (setq fmt (if have-time
 675                     (replace-regexp-in-string "%Z"
 676                                               org-icalendar-timezone
 677                                               org-icalendar-date-time-format)
 678                     ";VALUE=DATE:%Y%m%d"))
 679       (concat keyword (format-time-string fmt time
 680                                           (and (org-icalendar-use-UTC-date-timep)
 681                                                have-time))))))
 682
 683 (provide 'org-icalendar)
 684
 685 ;; arch-tag: 2dee2b6e-9211-4aee-8a47-a3c7e5bc30cf
 686 ;;; org-icalendar.el ends here