lisp/ob-C.el

   1 ;;; ob-C.el --- org-babel functions for C and similar languages
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.01trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating C code.
  28 ;;
  29 ;; very limited implementation:
  30 ;; - currently only support :results output
  31 ;; - not much in the way of error feedback
  32
  33 ;;; Code:
  34 (require 'ob)
  35 (require 'ob-eval)
  36 (require 'org)
  37 (require 'cc-mode)
  38
  39 (declare-function org-entry-get "org"
  40                   (pom property &optional inherit literal-nil))
  41
  42 (add-to-list 'org-babel-tangle-lang-exts '("c++" . "cpp"))
  43
  44 (defvar org-babel-default-header-args:C '())
  45
  46 (defvar org-babel-C-compiler "gcc"
  47   "Command used to compile a C source code file into an
  48   executable.")
  49
  50 (defvar org-babel-c++-compiler "g++"
  51   "Command used to compile a c++ source code file into an
  52   executable.")
  53
  54 (defvar org-babel-c-variant nil
  55   "Internal variable used to hold which type of C (e.g. C or C++)
  56 is currently being evaluated.")
  57
  58 (defun org-babel-execute:cpp (body params)
  59   "Execute BODY according to PARAMS.  This function calls
  60 `org-babel-execute:C'."
  61   (org-babel-execute:C body params))
  62
  63 (defun org-babel-execute:c++ (body params)
  64     "Execute a block of C++ code with org-babel.  This function is
  65 called by `org-babel-execute-src-block'."
  66   (let ((org-babel-c-variant 'cpp)) (org-babel-C-execute body params)))
  67
  68 (defun org-babel-expand-body:c++ (body params &optional processed-params)
  69   "Expand a block of C++ code with org-babel according to it's
  70 header arguments (calls `org-babel-C-expand')."
  71   (let ((org-babel-c-variant 'cpp)) (org-babel-C-expand body params processed-params)))
  72
  73 (defun org-babel-execute:C (body params)
  74   "Execute a block of C code with org-babel.  This function is
  75 called by `org-babel-execute-src-block'."
  76   (let ((org-babel-c-variant 'c)) (org-babel-C-execute body params)))
  77
  78 (defun org-babel-expand-body:c (body params &optional processed-params)
  79   "Expand a block of C code with org-babel according to it's
  80 header arguments (calls `org-babel-C-expand')."
  81   (let ((org-babel-c-variant 'c)) (org-babel-C-expand body params processed-params)))
  82
  83 (defun org-babel-C-execute (body params)
  84   "This function should only be called by `org-babel-execute:C'
  85 or `org-babel-execute:c++'."
  86   (let* ((processed-params (org-babel-process-params params))
  87          (tmp-src-file (make-temp-file "org-babel-C-src" nil
  88                                        (cond
  89                                         ((equal org-babel-c-variant 'c) ".c")
  90                                         ((equal org-babel-c-variant 'cpp) ".cpp"))))
  91          (tmp-bin-file (make-temp-file "org-babel-C-bin"))
  92          (tmp-out-file (make-temp-file "org-babel-C-out"))
  93          (cmdline (cdr (assoc :cmdline params)))
  94          (flags (cdr (assoc :flags params)))
  95          (full-body (org-babel-C-expand body params))
  96          (compile
  97           (progn
  98             (with-temp-file tmp-src-file (insert full-body))
  99             (org-babel-eval
 100              (format "%s -o %s %s %s"
 101                      (cond
 102                       ((equal org-babel-c-variant 'c) org-babel-C-compiler)
 103                       ((equal org-babel-c-variant 'cpp) org-babel-c++-compiler))
 104                      tmp-bin-file
 105                      (mapconcat 'identity
 106                                 (if (listp flags) flags (list flags)) " ")
 107                      tmp-src-file) ""))))
 108     ((lambda (results)
 109        (org-babel-reassemble-table
 110         (if (member "vector" (nth 2 processed-params))
 111             (let ((tmp-file (make-temp-file "ob-c")))
 112               (with-temp-file tmp-file (insert results))
 113               (org-babel-import-elisp-from-file tmp-file))
 114           (org-babel-read results))
 115         (org-babel-pick-name
 116          (nth 4 processed-params) (cdr (assoc :colnames params)))
 117         (org-babel-pick-name
 118          (nth 5 processed-params) (cdr (assoc :rownames params)))))
 119      (org-babel-trim
 120        (org-babel-eval
 121         (concat tmp-bin-file (if cmdline (concat " " cmdline) "")) "")))))
 122
 123 (defun org-babel-C-expand (body params &optional processed-params)
 124   "Expand a block of C or C++ code with org-babel according to
 125 it's header arguments."
 126   (let ((vars (nth 1 (or processed-params
 127                           (org-babel-process-params params))))
 128         (main-p (not (string= (cdr (assoc :main params)) "no")))
 129         (includes (or (cdr (assoc :includes params))
 130                       (org-babel-read (org-entry-get nil "includes" t))))
 131         (defines (org-babel-read
 132                   (or (cdr (assoc :defines params))
 133                       (org-babel-read (org-entry-get nil "defines" t))))))
 134     (org-babel-trim
 135      (mapconcat 'identity
 136                 (list
 137                  ;; includes
 138                  (mapconcat
 139                   (lambda (inc) (format "#include %s" inc))
 140                   (if (listp includes) includes (list includes)) "\n")
 141                  ;; defines
 142                  (mapconcat
 143                   (lambda (inc) (format "#define %s" inc))
 144                   (if (listp defines) defines (list defines)) "\n")
 145                  ;; variables
 146                  (mapconcat 'org-babel-C-var-to-C vars "\n")
 147                  ;; body
 148                  (if main-p
 149                      (org-babel-C-ensure-main-wrap body)
 150                    body) "\n") "\n"))))
 151
 152 (defun org-babel-C-ensure-main-wrap (body)
 153   "Wrap body in a \"main\" function call if none exists."
 154   (if (string-match "^[ \t]*[intvod]+[ \t]*main[ \t]*(.*)" body)
 155       body
 156     (format "int main() {\n%s\n}\n" body)))
 157
 158 (defun org-babel-prep-session:C (session params)
 159   "This function does nothing as C is a compiled language with no
 160 support for sessions"
 161   (error "C is a compiled languages -- no support for sessions"))
 162
 163 (defun org-babel-load-session:C (session body params)
 164   "This function does nothing as C is a compiled language with no
 165 support for sessions"
 166   (error "C is a compiled languages -- no support for sessions"))
 167
 168 ;; helper functions
 169
 170 (defun org-babel-C-var-to-C (pair)
 171   "Convert an elisp val into a string of C code specifying a var
 172 of the same value."
 173   ;; TODO list support
 174   (let ((var (car pair))
 175         (val (cdr pair)))
 176     (when (symbolp val)
 177       (setq val (symbol-name val))
 178       (when (= (length val) 1)
 179         (setq val (string-to-char val))))
 180     (cond
 181      ((integerp val)
 182       (format "int %S = %S;" var val))
 183      ((floatp val)
 184       (format "double %S = %S;" var val))
 185      ((or (characterp val))
 186       (format "char %S = '%S';" var val))
 187      ((stringp val)
 188       (format "char %S[%d] = \"%s\";"
 189               var (+ 1 (length val)) val))
 190      (t
 191       (format "u32 %S = %S;" var val)))))
 192
 193
 194 (provide 'ob-C)
 195
 196 ;; arch-tag: 8f49e462-54e3-417b-9a8d-423864893b37
 197
 198 ;;; ob-C.el ends here