lisp/ob-C.el

   1 ;;; ob-C.el --- org-babel functions for C and similar languages
   2
   3 ;; Copyright (C) 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 0.01
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating C code.
  28 ;;
  29 ;; very limited implementation:
  30 ;; - currently only support :results output
  31 ;; - not much in the way of error feedback
  32
  33 ;;; Code:
  34 (require 'ob)
  35 (require 'ob-eval)
  36 (require 'org)
  37 (require 'cc-mode)
  38
  39 (declare-function org-entry-get "org"
  40                   (pom property &optional inherit literal-nil))
  41
  42 (add-to-list 'org-babel-tangle-lang-exts '("c++" . "cpp"))
  43
  44 (defvar org-babel-default-header-args:C '())
  45
  46 (defvar org-babel-C-compiler "gcc"
  47   "Command used to compile a C source code file into an
  48   executable.")
  49
  50 (defvar org-babel-c++-compiler "g++"
  51   "Command used to compile a c++ source code file into an
  52   executable.")
  53
  54 (defvar org-babel-c-variant nil
  55   "Internal variable used to hold which type of C (e.g. C or C++)
  56 is currently being evaluated.")
  57
  58 (defun org-babel-execute:cpp (body params)
  59   "Execute BODY according to PARAMS.  This function calls
  60 `org-babel-execute:C'."
  61   (org-babel-execute:C body params))
  62
  63 (defun org-babel-execute:c++ (body params)
  64     "Execute a block of C++ code with org-babel.  This function is
  65 called by `org-babel-execute-src-block'."
  66   (let ((org-babel-c-variant 'cpp)) (org-babel-C-execute body params)))
  67
  68 (defun org-babel-expand-body:c++ (body params &optional processed-params)
  69   "Expand a block of C++ code with org-babel according to it's
  70 header arguments (calls `org-babel-C-expand')."
  71   (let ((org-babel-c-variant 'cpp)) (org-babel-C-expand body params processed-params)))
  72
  73 (defun org-babel-execute:C (body params)
  74   "Execute a block of C code with org-babel.  This function is
  75 called by `org-babel-execute-src-block'."
  76   (let ((org-babel-c-variant 'c)) (org-babel-C-execute body params)))
  77
  78 (defun org-babel-expand-body:c (body params &optional processed-params)
  79   "Expand a block of C code with org-babel according to it's
  80 header arguments (calls `org-babel-C-expand')."
  81   (let ((org-babel-c-variant 'c)) (org-babel-C-expand body params processed-params)))
  82
  83 (defun org-babel-C-execute (body params)
  84   "This function should only be called by `org-babel-execute:C'
  85 or `org-babel-execute:c++'."
  86   (message "executing C source code block")
  87   (let* ((processed-params (org-babel-process-params params))
  88          (tmp-src-file (make-temp-file "org-babel-C-src" nil
  89                                        (cond
  90                                         ((equal org-babel-c-variant 'c) ".c")
  91                                         ((equal org-babel-c-variant 'cpp) ".cpp"))))
  92          (tmp-bin-file (make-temp-file "org-babel-C-bin"))
  93          (tmp-out-file (make-temp-file "org-babel-C-out"))
  94          (cmdline (cdr (assoc :cmdline params)))
  95          (flags (cdr (assoc :flags params)))
  96          (full-body (org-babel-C-expand body params))
  97          (compile
  98           (progn
  99             (with-temp-file tmp-src-file (insert full-body))
 100             (org-babel-eval
 101              (format "%s -o %s %s %s"
 102                      (cond
 103                       ((equal org-babel-c-variant 'c) org-babel-C-compiler)
 104                       ((equal org-babel-c-variant 'cpp) org-babel-c++-compiler))
 105                      tmp-bin-file
 106                      (mapconcat 'identity
 107                                 (if (listp flags) flags (list flags)) " ")
 108                      tmp-src-file) ""))))
 109     (org-babel-reassemble-table
 110      (org-babel-read
 111       (org-babel-trim
 112        (org-babel-eval
 113         (concat tmp-bin-file (if cmdline (concat " " cmdline) "")) "")))
 114      (org-babel-pick-name
 115       (nth 4 processed-params) (cdr (assoc :colnames params)))
 116      (org-babel-pick-name
 117       (nth 5 processed-params) (cdr (assoc :rownames params))))))
 118
 119
 120 (defun org-babel-C-expand (body params &optional processed-params)
 121   "Expand a block of C or C++ code with org-babel according to
 122 it's header arguments."
 123   (let ((vars (nth 1 (or processed-params
 124                           (org-babel-process-params params))))
 125         (main-p (not (string= (cdr (assoc :main params)) "no")))
 126         (includes (or (cdr (assoc :includes params))
 127                       (org-babel-read (org-entry-get nil "includes" t))))
 128         (defines (org-babel-read
 129                   (or (cdr (assoc :defines params))
 130                       (org-babel-read (org-entry-get nil "defines" t))))))
 131     (mapconcat 'identity
 132                (list
 133                 ;; includes
 134                 (mapconcat
 135                  (lambda (inc) (format "#include %s" inc))
 136                  (if (listp includes) includes (list includes)) "\n")
 137                 ;; defines
 138                 (mapconcat
 139                  (lambda (inc) (format "#define %s" inc))
 140                  (if (listp defines) defines (list defines)) "\n")
 141                 ;; variables
 142                 (mapconcat 'org-babel-C-var-to-C vars "\n")
 143                 ;; body
 144                 (if main-p
 145                     (org-babel-C-ensure-main-wrap body)
 146                   body) "\n") "\n")))
 147
 148 (defun org-babel-C-ensure-main-wrap (body)
 149   "Wrap body in a \"main\" function call if none exists."
 150   (if (string-match "^[ \t]*[intvod]+[ \t]*main[ \t]*(.*)" body)
 151       body
 152     (format "int main() {\n%s\n}\n" body)))
 153
 154 (defun org-babel-prep-session:C (session params)
 155   "This function does nothing as C is a compiled language with no
 156 support for sessions"
 157   (error "C is a compiled languages -- no support for sessions"))
 158
 159 (defun org-babel-load-session:C (session body params)
 160   "This function does nothing as C is a compiled language with no
 161 support for sessions"
 162   (error "C is a compiled languages -- no support for sessions"))
 163
 164 ;; helper functions
 165
 166 (defun org-babel-C-var-to-C (pair)
 167   "Convert an elisp val into a string of C code specifying a var
 168 of the same value."
 169   ;; TODO list support
 170   (let ((var (car pair))
 171         (val (cdr pair)))
 172     (when (symbolp val)
 173       (setq val (symbol-name val))
 174       (when (= (length val) 1)
 175         (setq val (string-to-char val))))
 176     (cond
 177      ((integerp val)
 178       (format "int %S = %S;" var val))
 179      ((floatp val)
 180       (format "double %S = %S;" var val))
 181      ((or (characterp val))
 182       (format "char %S = '%S';" var val))
 183      ((stringp val)
 184       (format "char %S[%d] = \"%s\";"
 185               var (+ 1 (length val)) val))
 186      (t
 187       (format "u32 %S = %S;" var val)))))
 188
 189
 190 (provide 'ob-C)
 191
 192 ;; arch-tag: 8f49e462-54e3-417b-9a8d-423864893b37
 193
 194 ;;; ob-C.el ends here