lisp/org-gnus.el

   1 ;;; org-gnus.el --- Support for links to Gnus groups and messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;;         Tassilo Horn <tassilo at member dot fsf dot org>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 6.36trans
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to Gnus groups and messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37 (eval-when-compile (require 'gnus-sum))
  38
  39 ;; Declare external functions and variables
  40 (declare-function message-fetch-field "message" (header &optional not-all))
  41 (declare-function message-narrow-to-head-1 "message" nil)
  42 ;; The following line suppresses a compiler warning stemming from gnus-sum.el
  43 (declare-function gnus-summary-last-subject "gnus-sum" nil)
  44
  45 ;; Customization variables
  46
  47 (when (fboundp 'defvaralias)
  48   (defvaralias 'org-usenet-links-prefer-google 'org-gnus-prefer-web-links))
  49
  50 (defcustom org-gnus-prefer-web-links nil
  51   "If non-nil, `org-store-link' creates web links to Google groups or Gmane.
  52 When nil, Gnus will be used for such links.
  53 Using a prefix arg to the command \\[org-store-link] (`org-store-link')
  54 negates this setting for the duration of the command."
  55   :group 'org-link-store
  56   :type 'boolean)
  57
  58
  59 ;; Install the link type
  60 (org-add-link-type "gnus" 'org-gnus-open)
  61 (add-hook 'org-store-link-functions 'org-gnus-store-link)
  62
  63 ;; Implementation
  64
  65 (defun org-gnus-group-link (group)
  66   "Create a link to the Gnus group GROUP.
  67 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  68 non-nil, create a link to groups.google.com or gmane.org.
  69 Otherwise create a link to the group inside Gnus.
  70
  71 If `org-store-link' was called with a prefix arg the meaning of
  72 `org-gnus-prefer-web-links' is reversed."
  73   (let ((unprefixed-group (replace-regexp-in-string "^[^:]+:" "" group)))
  74     (if (and (string-match "^nntp" group) ;; Only for nntp groups
  75              (org-xor current-prefix-arg
  76                       org-gnus-prefer-web-links))
  77         (org-make-link (if (string-match "gmane" unprefixed-group)
  78                            "http://news.gmane.org/"
  79                          "http://groups.google.com/group/")
  80                        unprefixed-group)
  81       (org-make-link "gnus:" group))))
  82
  83 (defun org-gnus-article-link (group newsgroups message-id x-no-archive)
  84   "Create a link to a Gnus article.
  85 The article is specified by its MESSAGE-ID.  Additional
  86 parameters are the Gnus GROUP, the NEWSGROUPS the article was
  87 posted to and the X-NO-ARCHIVE header value of that article.
  88
  89 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  90 non-nil, create a link to groups.google.com or gmane.org.
  91 Otherwise create a link to the article inside Gnus.
  92
  93 If `org-store-link' was called with a prefix arg the meaning of
  94 `org-gnus-prefer-web-links' is reversed."
  95   (if (and (org-xor current-prefix-arg org-gnus-prefer-web-links)
  96            newsgroups     ;; Make web links only for nntp groups
  97            (not x-no-archive)) ;; and if X-No-Archive isn't set.
  98       (format (if (string-match "gmane\\." newsgroups)
  99                   "http://mid.gmane.org/%s"
 100                 "http://groups.google.com/groups/search?as_umsgid=%s")
 101               (org-fixup-message-id-for-http message-id))
 102     (org-make-link "gnus:" group "#" message-id)))
 103
 104 (defun org-gnus-store-link ()
 105   "Store a link to a Gnus folder or message."
 106   (cond
 107    ((eq major-mode 'gnus-group-mode)
 108     (let* ((group (cond ((fboundp 'gnus-group-group-name) ; depending on Gnus
 109                          (gnus-group-group-name))         ; version
 110                         ((fboundp 'gnus-group-name)
 111                          (gnus-group-name))
 112                         (t "???")))
 113            desc link)
 114       (when group
 115         (org-store-link-props :type "gnus" :group group)
 116         (setq desc (org-gnus-group-link group)
 117               link desc)
 118         (org-add-link-props :link link :description desc)
 119         link)))
 120
 121    ((memq major-mode '(gnus-summary-mode gnus-article-mode))
 122     (let* ((group gnus-newsgroup-name)
 123            (header (with-current-buffer gnus-summary-buffer
 124                      (gnus-summary-article-header)))
 125            (from (mail-header-from header))
 126            (message-id (org-remove-angle-brackets (mail-header-id header)))
 127            (date (mail-header-date header))
 128            (subject (copy-sequence (mail-header-subject header)))
 129            (to (cdr (assq 'To (mail-header-extra header))))
 130            newsgroups x-no-archive desc link)
 131       ;; Remove text properties of subject string to avoid Emacs bug
 132       ;; #3506
 133       (set-text-properties 0 (length subject) nil subject)
 134
 135       ;; Fetching an article is an expensive operation; newsgroup and
 136       ;; x-no-archive are only needed for web links.
 137       (when (org-xor current-prefix-arg org-gnus-prefer-web-links)
 138         ;; Make sure the original article buffer is up-to-date
 139         (save-window-excursion (gnus-summary-select-article))
 140         (setq to (or to (gnus-fetch-original-field "To"))
 141               newsgroups (gnus-fetch-original-field "Newsgroups")
 142               x-no-archive (gnus-fetch-original-field "x-no-archive")))
 143       (org-store-link-props :type "gnus" :from from :subject subject
 144                             :message-id message-id :group group :to to)
 145       (setq desc (org-email-link-description)
 146             link (org-gnus-article-link
 147                   group newsgroups message-id x-no-archive))
 148       (org-add-link-props :link link :description desc)
 149       link))))
 150
 151 (defun org-gnus-open (path)
 152   "Follow the Gnus message or folder link specified by PATH."
 153   (let (group article)
 154     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
 155         (error "Error in Gnus link"))
 156     (setq group (match-string 1 path)
 157           article (match-string 3 path))
 158     (when group
 159       (setq group (org-substring-no-properties group)))
 160     (when article
 161       (setq article (org-substring-no-properties article)))
 162     (org-gnus-follow-link group article)))
 163
 164 (defun org-gnus-follow-link (&optional group article)
 165   "Follow a Gnus link to GROUP and ARTICLE."
 166   (require 'gnus)
 167   (funcall (cdr (assq 'gnus org-link-frame-setup)))
 168   (if gnus-other-frame-object (select-frame gnus-other-frame-object))
 169   (when group
 170     (setq group (org-substring-no-properties group)))
 171   (when article
 172     (setq article (org-substring-no-properties article)))
 173   (cond ((and group article)
 174          (gnus-activate-group group t)
 175          (condition-case nil
 176              (let ((backend (car (gnus-find-method-for-group group))))
 177                (cond
 178                 ((eq backend 'nndoc)
 179                  (if (gnus-group-read-group t nil group)
 180                      (gnus-summary-goto-article article nil t)
 181                    (message "Couldn't follow gnus link.  %s"
 182                             "The summary couldn't be opened.")))
 183                 (t
 184                  (let ((articles 1)
 185                        group-opened)
 186                    (while (and (not group-opened)
 187                                ;; stop on integer overflows
 188                                (> articles 0))
 189                      (setq group-opened (gnus-group-read-group
 190                                          articles nil group)
 191                            articles (if (< articles 16)
 192                                         (1+ articles)
 193                                       (* articles 2))))
 194                    (if group-opened
 195                        (gnus-summary-goto-article article nil t)
 196                      (message "Couldn't follow gnus link.  %s"
 197                               "The summary couldn't be opened."))))))
 198            (quit (message "Couldn't follow gnus link.  %s"
 199                           "The linked group is empty."))))
 200         (group (gnus-group-jump-to-group group))))
 201
 202 (defun org-gnus-no-new-news ()
 203   "Like `M-x gnus' but doesn't check for new news."
 204   (if (not (gnus-alive-p)) (gnus)))
 205
 206 (provide 'org-gnus)
 207
 208 ;; arch-tag: 512e0840-58fa-45b3-b456-71e10fa2376d
 209
 210 ;;; org-gnus.el ends here