lisp/ob-ocaml.el

   1 ;;; ob-ocaml.el --- org-babel functions for ocaml evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 0.01
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating ocaml source code.  This one will
  28 ;; be sort of tricky because ocaml programs must be compiled before
  29 ;; they can be run, but ocaml code can also be run through an
  30 ;; interactive interpreter.
  31 ;;
  32 ;; For now lets only allow evaluation using the ocaml interpreter.
  33
  34 ;;; Requirements:
  35
  36 ;; - tuareg-mode :: http://www-rocq.inria.fr/~acohen/tuareg/
  37
  38 ;;; Code:
  39 (require 'ob)
  40 (require 'ob-comint)
  41 (require 'comint)
  42 (eval-when-compile (require 'cl))
  43
  44 (declare-function tuareg-run-caml "ext:tuareg" ())
  45 (declare-function tuareg-interactive-send-input "ext:tuareg" ())
  46
  47 (add-to-list 'org-babel-tangle-lang-exts '("ocaml" . "ml"))
  48
  49 (defvar org-babel-default-header-args:ocaml '())
  50
  51 (defvar org-babel-ocaml-eoe-indicator "\"org-babel-ocaml-eoe\";;")
  52 (defvar org-babel-ocaml-eoe-output "org-babel-ocaml-eoe")
  53
  54 (defun org-babel-expand-body:ocaml (body params &optional processed-params)
  55   "Expand BODY according to PARAMS, return the expanded body."
  56   (let ((vars (nth 1 (or processed-params (org-babel-process-params params)))))
  57     (concat
  58      (mapconcat
  59       (lambda (pair) (format "let %s = %s;;" (car pair)
  60                         (org-babel-ocaml-elisp-to-ocaml (cdr pair))))
  61       vars "\n") "\n" body "\n")))
  62
  63 (defun org-babel-execute:ocaml (body params)
  64   "Execute a block of Ocaml code with Babel."
  65   (let* ((processed-params (org-babel-process-params params))
  66          (vars (nth 1 processed-params))
  67          (full-body (org-babel-expand-body:ocaml body params processed-params))
  68          (session (org-babel-prep-session:ocaml
  69                    (cdr (assoc :session params)) params))
  70          (raw (org-babel-comint-with-output
  71                   (session org-babel-ocaml-eoe-output t full-body)
  72                 (insert
  73                  (concat
  74                   (org-babel-chomp full-body)"\n"org-babel-ocaml-eoe-indicator))
  75                 (tuareg-interactive-send-input)))
  76          (clean
  77           (car (let ((re (regexp-quote org-babel-ocaml-eoe-output)) out)
  78                  (delq nil (mapcar (lambda (line)
  79                                      (if out
  80                                          (progn (setq out nil) line)
  81                                        (when (string-match re line)
  82                                          (progn (setq out t) nil))))
  83                                  (mapcar #'org-babel-trim (reverse raw))))))))
  84     (org-babel-reassemble-table
  85      (org-babel-ocaml-parse-output (org-babel-trim clean))
  86      (org-babel-pick-name
  87       (nth 4 processed-params) (cdr (assoc :colnames params)))
  88      (org-babel-pick-name
  89       (nth 5 processed-params) (cdr (assoc :rownames params))))))
  90
  91 (defvar tuareg-interactive-buffer-name)
  92 (defun org-babel-prep-session:ocaml (session params)
  93   "Prepare SESSION according to the header arguments in PARAMS."
  94   (require 'tuareg)
  95   (let ((tuareg-interactive-buffer-name (if (and (not (string= session "none"))
  96                                                  (not (string= session "default"))
  97                                                  (stringp session))
  98                                             session
  99                                           tuareg-interactive-buffer-name)))
 100     (save-window-excursion (tuareg-run-caml)
 101                            (get-buffer tuareg-interactive-buffer-name))))
 102
 103 (defun org-babel-ocaml-elisp-to-ocaml (val)
 104   "Return a string of ocaml code which evaluates to VAL."
 105   (if (listp val)
 106       (concat "[|" (mapconcat #'org-babel-ocaml-elisp-to-ocaml val "; ") "|]")
 107     (format "%S" val)))
 108
 109 (defun org-babel-ocaml-parse-output (output)
 110   "Parse OUTPUT.
 111 OUTPUT is string output from an ocaml process."
 112   (let ((regexp "%s = \\(.+\\)$"))
 113     (cond
 114      ((string-match (format regexp "string") output)
 115       (org-babel-read (match-string 1 output)))
 116      ((or (string-match (format regexp "int") output)
 117           (string-match (format regexp "float") output))
 118       (string-to-number (match-string 1 output)))
 119      ((string-match (format regexp "list") output)
 120       (org-babel-ocaml-read-list (match-string 1 output)))
 121      ((string-match (format regexp "array") output)
 122       (org-babel-ocaml-read-array (match-string 1 output)))
 123      (t (message "don't recognize type of %s" output) output))))
 124
 125 (defun org-babel-ocaml-read-list (results)
 126   "Convert RESULTS into an elisp table or string.
 127 If the results look like a table, then convert them into an
 128 Emacs-lisp table, otherwise return the results as a string."
 129   (org-babel-read
 130    (if (and (stringp results) (string-match "^\\[.+\\]$" results))
 131        (org-babel-read
 132         (replace-regexp-in-string
 133          "\\[" "(" (replace-regexp-in-string
 134                     "\\]" ")" (replace-regexp-in-string
 135                                "; " " " (replace-regexp-in-string
 136                                          "'" "\"" results)))))
 137      results)))
 138
 139 (defun org-babel-ocaml-read-array (results)
 140   "Convert RESULTS into an elisp table or string.
 141 If the results look like a table, then convert them into an
 142 Emacs-lisp table, otherwise return the results as a string."
 143   (org-babel-read
 144    (if (and (stringp results) (string-match "^\\[.+\\]$" results))
 145        (org-babel-read
 146         (concat
 147          "'" (replace-regexp-in-string
 148               "\\[|" "(" (replace-regexp-in-string
 149                           "|\\]" ")" (replace-regexp-in-string
 150                                       "; " " " (replace-regexp-in-string
 151                                                 "'" "\"" results))))))
 152      results)))
 153
 154 (provide 'ob-ocaml)
 155
 156 ;; arch-tag: 2e815f4d-365e-4d69-b1df-dd17fdd7b7b7
 157
 158 ;;; ob-ocaml.el ends here