lisp/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements globally unique identifiers for Org-mode entries.
  29 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  30 ;; are provided that create and retrieve such identifiers, and that find
  31 ;; entries based on the identifier.
  32
  33 ;; Identifiers consist of a prefix (default "Org" given by the variable
  34 ;; `org-id-prefix') and a unique part that can be created by a number
  35 ;; of different methods, see the variable `org-id-method'.
  36 ;; Org has a builtin method that uses a compact encoding of the creation
  37 ;; time of the ID, with microsecond accuracy.  This virtually
  38 ;; guarantees globally unique identifiers, even if several people are
  39 ;; creating IDs at the same time in files that will eventually be used
  40 ;; together.
  41 ;;
  42 ;; By default Org uses UUIDs as global unique identifiers.
  43 ;;
  44 ;; This file defines the following API:
  45 ;;
  46 ;; org-id-get-create
  47 ;;        Create an ID for the entry at point if it does not yet have one.
  48 ;;        Returns the ID (old or new).  This function can be used
  49 ;;        interactively, with prefix argument the creation of a new ID is
  50 ;;        forced, even if there was an old one.
  51 ;;
  52 ;; org-id-get
  53 ;;        Get the ID property of an entry.  Using appropriate arguments
  54 ;;        to the function, it can also create the ID for this entry.
  55 ;;
  56 ;; org-id-goto
  57 ;;        Command to go to a specific ID, this command can be used
  58 ;;        interactively.
  59 ;;
  60 ;; org-id-get-with-outline-path-completion
  61 ;;        Retrieve the ID of an entry, using outline path completion.
  62 ;;        This function can work for multiple files.
  63 ;;
  64 ;; org-id-get-with-outline-drilling
  65 ;;        Retrieve the ID of an entry, using outline path completion.
  66 ;;        This function only works for the current file.
  67 ;;
  68 ;; org-id-find
  69 ;;        Find the location of an entry with specific id.
  70 ;;
  71
  72 ;;; Code:
  73
  74 (require 'org)
  75
  76 (declare-function message-make-fqdn "message" ())
  77
  78 ;;; Customization
  79
  80 (defgroup org-id nil
  81   "Options concerning global entry identifiers in Org-mode."
  82   :tag "Org ID"
  83   :group 'org)
  84
  85 (defcustom org-id-uuid-program "uuidgen"
  86   "The uuidgen program."
  87   :group 'org-id
  88   :type 'string)
  89
  90 (defcustom org-id-method 'uuid
  91   "The method that should be used to create new IDs.
  92
  93 An ID will consist of the optional prefix specified in `org-id-prefix',
  94 and a unique part created by the method this variable specifies.
  95
  96 Allowed values are:
  97
  98 org        Org's own internal method, using an encoding of the current time to
  99            microsecond accuracy, and optionally the current domain of the
 100            computer.  See the variable `org-id-include-domain'.
 101
 102 uuid       Create random (version 4) UUIDs.  If the program defined in
 103            `org-id-uuid-program' is available it is used to create the ID.
 104            Otherwise an internal functions is used."
 105   :group 'org-id
 106   :type '(choice
 107           (const :tag "Org's internal method" org)
 108           (const :tag "external: uuidgen" uuid)))
 109
 110 (defcustom org-id-prefix nil
 111   "The prefix for IDs.
 112
 113 This may be a string, or it can be nil to indicate that no prefix is required.
 114 When a string, the string should have no space characters as IDs are expected
 115 to have no space characters in them."
 116   :group 'org-id
 117   :type '(choice
 118           (const :tag "No prefix")
 119           (string :tag "Prefix")))
 120
 121 (defcustom org-id-include-domain nil
 122   "Non-nil means add the domain name to new IDs.
 123 This ensures global uniqueness of IDs, and is also suggested by
 124 RFC 2445 in combination with RFC 822.  This is only relevant if
 125 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 126 be added.
 127 The default is to not use this because we have no really good way to get
 128 the true domain, and Org entries will normally not be shared with enough
 129 people to make this necessary."
 130   :group 'org-id
 131   :type 'boolean)
 132
 133 (defcustom org-id-track-globally t
 134   "Non-nil means track IDs through files, so that links work globally.
 135 This work by maintaining a hash table for IDs and writing this table
 136 to disk when exiting Emacs.  Because of this, it works best if you use
 137 a single Emacs process, not many.
 138
 139 When nil, IDs are not tracked.  Links to IDs will still work within
 140 a buffer, but not if the entry is located in another file.
 141 IDs can still be used if the entry with the id is in the same file as
 142 the link."
 143   :group 'org-id
 144   :type 'boolean)
 145
 146 (defcustom org-id-locations-file (convert-standard-filename
 147                                   "~/.emacs.d/.org-id-locations")
 148   "The file for remembering in which file an ID was defined.
 149 This variable is only relevant when `org-id-track-globally' is set."
 150   :group 'org-id
 151   :type 'file)
 152
 153 (defvar org-id-locations nil
 154   "List of files with IDs in those files.
 155 Depending on `org-id-use-hash' this can also be a hash table mapping IDs
 156 to files.")
 157
 158 (defvar org-id-files nil
 159   "List of files that contain IDs.")
 160
 161 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 162   "Files to be searched for IDs, besides the agenda files.
 163 When Org reparses files to remake the list of files and IDs it is tracking,
 164 it will normally scan the agenda files, the archives related to agenda files,
 165 any files that are listed as ID containing in the current register, and
 166 any Org-mode files currently visited by Emacs.
 167 You can list additional files here.
 168 This variable is only relevant when `org-id-track-globally' is set."
 169   :group 'org-id
 170   :type
 171   '(choice
 172     (symbol :tag "Variable")
 173     (repeat :tag "List of files"
 174             (file))))
 175
 176 (defcustom org-id-search-archives t
 177   "Non-nil means search also the archive files of agenda files for entries.
 178 This is a possibility to reduce overhead, but it means that entries moved
 179 to the archives can no longer be found by ID.
 180 This variable is only relevant when `org-id-track-globally' is set."
 181   :group 'org-id
 182   :type 'boolean)
 183
 184 ;;; The API functions
 185
 186 ;;;###autoload
 187 (defun org-id-get-create (&optional force)
 188   "Create an ID for the current entry and return it.
 189 If the entry already has an ID, just return it.
 190 With optional argument FORCE, force the creation of a new ID."
 191   (interactive "P")
 192   (when force
 193     (org-entry-put (point) "ID" nil))
 194   (org-id-get (point) 'create))
 195
 196 ;;;###autoload
 197 (defun org-id-copy ()
 198   "Copy the ID of the entry at point to the kill ring.
 199 Create an ID if necessary."
 200   (interactive)
 201   (org-kill-new (org-id-get nil 'create)))
 202
 203 ;;;###autoload
 204 (defun org-id-get (&optional pom create prefix)
 205   "Get the ID property of the entry at point-or-marker POM.
 206 If POM is nil, refer to the entry at point.
 207 If the entry does not have an ID, the function returns nil.
 208 However, when CREATE is non nil, create an ID if none is present already.
 209 PREFIX will be passed through to `org-id-new'.
 210 In any case, the ID of the entry is returned."
 211   (org-with-point-at pom
 212     (let ((id (org-entry-get nil "ID")))
 213       (cond
 214        ((and id (stringp id) (string-match "\\S-" id))
 215         id)
 216        (create
 217         (setq id (org-id-new prefix))
 218         (org-entry-put pom "ID" id)
 219         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 220         id)
 221        (t nil)))))
 222
 223 ;;;###autoload
 224 (defun org-id-get-with-outline-path-completion (&optional targets)
 225   "Use outline-path-completion to retrieve the ID of an entry.
 226 TARGETS may be a setting for `org-refile-targets' to define the eligible
 227 headlines.  When omitted, all headlines in all agenda files are
 228 eligible.
 229 It returns the ID of the entry.  If necessary, the ID is created."
 230   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 231          (org-refile-use-outline-path
 232           (if (caar org-refile-targets) 'file t))
 233          (org-refile-target-verify-function nil)
 234          (spos (org-refile-get-location "Entry"))
 235          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 236                                      (get-file-buffer (nth 1 spos))))))
 237     (prog1 (org-id-get pom 'create)
 238       (move-marker pom nil))))
 239
 240 ;;;###autoload
 241 (defun org-id-get-with-outline-drilling (&optional targets)
 242   "Use an outline-cycling interface to retrieve the ID of an entry.
 243 This only finds entries in the current buffer, using `org-get-location'.
 244 It returns the ID of the entry.  If necessary, the ID is created."
 245   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 246          (pom (and spos (move-marker (make-marker) (car spos)))))
 247     (prog1 (org-id-get pom 'create)
 248       (move-marker pom nil))))
 249
 250 ;;;###autoload
 251 (defun org-id-goto (id)
 252   "Switch to the buffer containing the entry with id ID.
 253 Move the cursor to that entry in that buffer."
 254   (interactive "sID: ")
 255   (let ((m (org-id-find id 'marker)))
 256     (unless m
 257       (error "Cannot find entry with ID \"%s\"" id))
 258     (switch-to-buffer (marker-buffer m))
 259     (goto-char m)
 260     (move-marker m nil)
 261     (org-show-context)))
 262
 263 ;;;###autoload
 264 (defun org-id-find (id &optional markerp)
 265   "Return the location of the entry with the id ID.
 266 The return value is a cons cell (file-name . position), or nil
 267 if there is no entry with that ID.
 268 With optional argument MARKERP, return the position as a new marker."
 269   (cond
 270    ((symbolp id) (setq id (symbol-name id)))
 271    ((numberp id) (setq id (number-to-string id))))
 272   (let ((file (org-id-find-id-file id))
 273         org-agenda-new-buffers where)
 274     (when file
 275       (setq where (org-id-find-id-in-file id file markerp)))
 276     (unless where
 277       (org-id-update-id-locations)
 278       (setq file (org-id-find-id-file id))
 279       (when file
 280         (setq where (org-id-find-id-in-file id file markerp))))
 281     where))
 282
 283 ;;; Internal functions
 284
 285 ;; Creating new IDs
 286
 287 (defun org-id-new (&optional prefix)
 288   "Create a new globally unique ID.
 289
 290 An ID consists of two parts separated by a colon:
 291 - a prefix
 292 - a unique part that will be created according to `org-id-method'.
 293
 294 PREFIX can specify the prefix, the default is given by the variable
 295 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 296 prefix even if `org-id-prefix' specifies one.
 297
 298 So a typical ID could look like \"Org:4nd91V40HI\"."
 299   (let* ((prefix (if (eq prefix 'none)
 300                      ""
 301                    (concat (or prefix org-id-prefix) ":")))
 302          unique)
 303     (if (equal prefix ":") (setq prefix ""))
 304     (cond
 305      ((memq org-id-method '(uuidgen uuid))
 306       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 307       (unless (org-uuidgen-p unique)
 308         (setq unique (org-id-uuid))))
 309      ((eq org-id-method 'org)
 310       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 311              (postfix (if org-id-include-domain
 312                           (progn
 313                             (require 'message)
 314                             (concat "@" (message-make-fqdn))))))
 315         (setq unique (concat etime postfix))))
 316      (t (error "Invalid `org-id-method'")))
 317     (concat prefix unique)))
 318
 319 (defun org-id-uuid ()
 320   "Return string with random (version 4) UUID."
 321   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 322                           (random t)
 323                           (current-time)
 324                           (user-uid)
 325                           (emacs-pid)
 326                           (user-full-name)
 327                           user-mail-address
 328                           (recent-keys)))))
 329     (format "%s-%s-4%s-%s%s-%s"
 330             (substring rnd 0 8)
 331             (substring rnd 8 12)
 332             (substring rnd 13 16)
 333             (format "%x"
 334                     (logior
 335                      #b10000000
 336                      (logand
 337                       #b10111111
 338                       (string-to-number
 339                        (substring rnd 16 18) 16))))
 340             (substring rnd 18 20)
 341             (substring rnd 20 32))))
 342
 343 (defun org-id-reverse-string (s)
 344   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 345
 346 (defun org-id-int-to-b36-one-digit (i)
 347   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 348   (cond
 349    ((< i 10) (+ ?0 i))
 350    ((< i 36) (+ ?a i -10))
 351    (t (error "Larger that 35"))))
 352
 353 (defun org-id-b36-to-int-one-digit (i)
 354   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 355 The input I may be a character, or a single-letter string."
 356   (and (stringp i) (setq i (string-to-char i)))
 357   (cond
 358    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 359    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 360    (t (error "Invalid b36 letter"))))
 361
 362 (defun org-id-int-to-b36 (i &optional length)
 363   "Convert an integer to a base-36 number represented as a string."
 364   (let ((s ""))
 365     (while (> i 0)
 366       (setq s (concat (char-to-string
 367                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 368             i (/ i 36)))
 369     (setq length (max 1 (or length 1)))
 370     (if (< (length s) length)
 371         (setq s (concat (make-string (- length (length s)) ?0) s)))
 372     s))
 373
 374 (defun org-id-b36-to-int (s)
 375   "Convert a base-36 string into the corresponding integer."
 376   (let ((r 0))
 377     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 378           s)
 379     r))
 380
 381 (defun org-id-time-to-b36 (&optional time)
 382   "Encode TIME as a 10-digit string.
 383 This string holds the time to micro-second accuracy, and can be decoded
 384 using `org-id-decode'."
 385   (setq time (or time (current-time)))
 386   (concat (org-id-int-to-b36 (nth 0 time) 4)
 387           (org-id-int-to-b36 (nth 1 time) 4)
 388           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 389
 390 (defun org-id-decode (id)
 391   "Split ID into the prefix and the time value that was used to create it.
 392 The return value is (prefix . time) where PREFIX is nil or a string,
 393 and time is the usual three-integer representation of time."
 394   (let (prefix time parts)
 395     (setq parts (org-split-string id ":"))
 396     (if (= 2 (length parts))
 397         (setq prefix (car parts) time (nth 1 parts))
 398       (setq prefix nil time (nth 0 parts)))
 399     (setq time (org-id-reverse-string time))
 400     (setq time (list (org-id-b36-to-int (substring time 0 4))
 401                      (org-id-b36-to-int (substring time 4 8))
 402                      (org-id-b36-to-int (substring time 8 12))))
 403     (cons prefix time)))
 404
 405 ;; Storing ID locations (files)
 406
 407 (defun org-id-update-id-locations (&optional files)
 408   "Scan relevant files for IDs.
 409 Store the relation between files and corresponding IDs.
 410 This will scan all agenda files, all associated archives, and all
 411 files currently mentioned in `org-id-locations'.
 412 When FILES is given, scan these files instead.
 413 When CHECK is given, prepare detailed information about duplicate IDs."
 414   (interactive)
 415   (if (not org-id-track-globally)
 416       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 417     (let* ((org-id-search-archives
 418             (or org-id-search-archives
 419                 (and (symbolp org-id-extra-files)
 420                      (symbol-value org-id-extra-files)
 421                      (member 'agenda-archives org-id-extra-files))))
 422            (files
 423             (or files
 424                 (append
 425                  ;; Agenda files and all associated archives
 426                  (org-agenda-files t org-id-search-archives)
 427                  ;; Explicit extra files
 428                  (if (symbolp org-id-extra-files)
 429                      (symbol-value org-id-extra-files)
 430                    org-id-extra-files)
 431               ;; Files associated with live org-mode buffers
 432                  (delq nil
 433                        (mapcar (lambda (b)
 434                                  (with-current-buffer b
 435                                    (and (org-mode-p) (buffer-file-name))))
 436                                (buffer-list)))
 437                  ;; All files known to have IDs
 438                  org-id-files)))
 439            org-agenda-new-buffers
 440            file nfiles tfile ids reg found id seen (ndup 0))
 441       (when (member 'agenda-archives files)
 442         (setq files (delq 'agenda-archives (copy-sequence files))))
 443       (setq nfiles (length files))
 444       (while (setq file (pop files))
 445         (message "Finding ID locations (%d/%d files): %s"
 446                  (- nfiles (length files)) nfiles file)
 447         (setq tfile (file-truename file))
 448         (when (and (file-exists-p file) (not (member tfile seen)))
 449           (push tfile seen)
 450           (setq ids nil)
 451           (with-current-buffer (org-get-agenda-file-buffer file)
 452             (save-excursion
 453               (save-restriction
 454                 (widen)
 455                 (goto-char (point-min))
 456                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 457                                           nil t)
 458                   (setq id (org-match-string-no-properties 1))
 459                   (if (member id found)
 460                       (progn
 461                         (message "Duplicate ID \"%s\", also in file %s"
 462                                  id (or (car (delq
 463                                               nil
 464                                               (mapcar
 465                                                (lambda (x)
 466                                                  (if (member id (cdr x))
 467                                                      (car x)))
 468                                                reg)))
 469                                         (buffer-file-name)))
 470                         (when (= ndup 0)
 471                           (ding)
 472                           (sit-for 2))
 473                         (setq ndup (1+ ndup)))
 474                     (push id found)
 475                     (push id ids)))
 476                 (push (cons (abbreviate-file-name file) ids) reg))))))
 477       (org-release-buffers org-agenda-new-buffers)
 478       (setq org-agenda-new-buffers nil)
 479       (setq org-id-locations reg)
 480       (setq org-id-files (mapcar 'car org-id-locations))
 481       (org-id-locations-save) ;; this function can also handle the alist form
 482       ;; now convert to a hash
 483       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 484       (if (> ndup 0)
 485           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 486         (message "%d unique files scanned for IDs" (length org-id-files)))
 487       org-id-locations)))
 488
 489 (defun org-id-locations-save ()
 490   "Save `org-id-locations' in `org-id-locations-file'."
 491   (when (and org-id-track-globally org-id-locations)
 492     (let ((out (if (hash-table-p org-id-locations)
 493                    (org-id-hash-to-alist org-id-locations)
 494                  org-id-locations)))
 495       (with-temp-file org-id-locations-file
 496         (print out (current-buffer))))))
 497
 498 (defun org-id-locations-load ()
 499   "Read the data from `org-id-locations-file'."
 500   (setq org-id-locations nil)
 501   (when org-id-track-globally
 502     (with-temp-buffer
 503       (condition-case nil
 504           (progn
 505             (insert-file-contents-literally org-id-locations-file)
 506             (goto-char (point-min))
 507             (setq org-id-locations (read (current-buffer))))
 508         (error
 509          (message "Could not read org-id-values from %s. Setting it to nil."
 510                   org-id-locations-file))))
 511     (setq org-id-files (mapcar 'car org-id-locations))
 512     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 513
 514 (defun org-id-add-location (id file)
 515   "Add the ID with location FILE to the database of ID locations."
 516   ;; Only if global tracking is on, and when the buffer has a file
 517   (when (and org-id-track-globally id file)
 518     (unless org-id-locations (org-id-locations-load))
 519     (puthash id (abbreviate-file-name file) org-id-locations)
 520     (add-to-list 'org-id-files (abbreviate-file-name file))))
 521
 522 (unless noninteractive
 523   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 524
 525 (defun org-id-hash-to-alist (hash)
 526   "Turn an org-id hash into an alist, so that it can be written to a file."
 527   (let (res x)
 528     (maphash
 529      (lambda (k v)
 530        (if (setq x (member v res))
 531            (setcdr x (cons k (cdr x)))
 532          (push (list v k) res)))
 533      hash)
 534     res))
 535
 536 (defun org-id-alist-to-hash (list)
 537   "Turn an org-id location list into a hash table."
 538   (let ((res (make-hash-table
 539               :test 'equal
 540               :size (apply '+ (mapcar 'length list))))
 541         f)
 542     (mapc
 543      (lambda (x)
 544        (setq f (car x))
 545        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 546      list)
 547     res))
 548
 549 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 550   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 551   (when org-id-track-globally
 552     (save-match-data
 553       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 554       (when (bufferp buffer-or-file)
 555         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 556                                  buffer-or-file))
 557         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 558       (when buffer-or-file
 559         (let ((fname (abbreviate-file-name buffer-or-file))
 560               (s 0))
 561           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 562             (setq s (match-end 0))
 563             (org-id-add-location (match-string 1 txt) fname)))))))
 564
 565 ;; Finding entries with specified id
 566
 567 ;;;###autoload
 568 (defun org-id-find-id-file (id)
 569   "Query the id database for the file in which this ID is located."
 570   (unless org-id-locations (org-id-locations-load))
 571   (or (and org-id-locations
 572            (hash-table-p org-id-locations)
 573            (gethash id org-id-locations))
 574       ;; ball back on current buffer
 575       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 576                             (current-buffer)))))
 577
 578 (defun org-id-find-id-in-file (id file &optional markerp)
 579   "Return the position of the entry ID in FILE.
 580 If that files does not exist, or if it does not contain this ID,
 581 return nil.
 582 The position is returned as a cons cell (file-name . position).  With
 583 optional argument MARKERP, return the position as a new marker."
 584   (let (org-agenda-new-buffers buf pos)
 585     (cond
 586      ((not file) nil)
 587      ((not (file-exists-p file)) nil)
 588      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 589           (setq pos (org-find-entry-with-id id))
 590           (when pos
 591             (if markerp
 592                 (move-marker (make-marker) pos buf)
 593               (cons file pos))))))))
 594
 595 ;; id link type
 596
 597 ;; Calling the following function is hard-coded into `org-store-link',
 598 ;; so we do have to add it to `org-store-link-functions'.
 599
 600 ;;;###autoload
 601 (defun org-id-store-link ()
 602   "Store a link to the current entry, using its ID."
 603   (interactive)
 604   (when (and (buffer-file-name (buffer-base-buffer)) (org-mode-p))
 605     (let* ((link (org-make-link "id:" (org-id-get-create)))
 606            (case-fold-search nil)
 607            (desc (save-excursion
 608                    (org-back-to-heading t)
 609                    (or (and (looking-at org-complex-heading-regexp)
 610                             (if (match-end 4)
 611                                 (match-string 4)
 612                               (match-string 0)))
 613                        link))))
 614       (org-store-link-props :link link :description desc :type "id")
 615       link)))
 616
 617 (defun org-id-open (id)
 618   "Go to the entry with id ID."
 619   (org-mark-ring-push)
 620   (let ((m (org-id-find id 'marker))
 621         cmd)
 622     (unless m
 623       (error "Cannot find entry with ID \"%s\"" id))
 624     ;; Use a buffer-switching command in analogy to finding files
 625     (setq cmd
 626           (or
 627            (cdr
 628             (assq
 629              (cdr (assq 'file org-link-frame-setup))
 630              '((find-file . switch-to-buffer)
 631                (find-file-other-window . switch-to-buffer-other-window)
 632                (find-file-other-frame . switch-to-buffer-other-frame))))
 633            'switch-to-buffer-other-window))
 634     (if (not (equal (current-buffer) (marker-buffer m)))
 635         (funcall cmd (marker-buffer m)))
 636     (goto-char m)
 637     (move-marker m nil)
 638     (org-show-context)))
 639
 640 (org-add-link-type "id" 'org-id-open)
 641
 642 (provide 'org-id)
 643
 644 ;;; org-id.el ends here
 645
 646 ;; arch-tag: e5abaca4-e16f-4b25-832a-540cfb63a712
 647
 648