lisp/org-wl.el

   1 ;;; org-wl.el --- Support for links to Wanderlust messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Tokuya Kameshima <kames at fa2 dot so-net dot ne dot jp>
   7 ;;         David Maus <dmaus at ictsoc dot de>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 6.36trans
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to Wanderlust messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37
  38 (defgroup org-wl nil
  39  "Options concerning the Wanderlust link."
  40  :tag "Org Startup"
  41  :group 'org-link)
  42
  43 (defcustom org-wl-link-to-refile-destination t
  44   "Create a link to the refile destination if the message is marked as refile."
  45   :group 'org-wl
  46   :type 'boolean)
  47
  48 (defcustom org-wl-link-remove-filter nil
  49   "Remove filter condition if message is filter folder."
  50   :group 'org-wl
  51   :type 'boolean)
  52
  53 (defcustom org-wl-shimbun-prefer-web-links nil
  54   "If non-nil create web links for shimbun messages."
  55   :group 'org-wl
  56   :type 'boolean)
  57
  58 (defcustom org-wl-nntp-prefer-web-links nil
  59   "If non-nil create web links for nntp messages.
  60 When folder name contains string \"gmane\" link to gmane,
  61 googlegroups otherwise."
  62   :type 'boolean
  63   :group 'org-wl)
  64
  65 (defcustom org-wl-disable-folder-check t
  66   "Disable check for new messages when open a link."
  67   :type 'boolean
  68   :group 'org-wl)
  69
  70 (defcustom org-wl-namazu-default-index nil
  71   "Default namazu search index."
  72   :type 'directory
  73   :group 'org-wl)
  74
  75 ;; Declare external functions and variables
  76 (declare-function elmo-folder-exists-p "ext:elmo" (folder) t)
  77 (declare-function elmo-message-entity-field "ext:elmo-msgdb"
  78                   (entity field &optional type))
  79 (declare-function elmo-message-field "ext:elmo"
  80                   (folder number field &optional type) t)
  81 (declare-function elmo-msgdb-overview-get-entity "ext:elmo" (id msgdb) t)
  82 ;; Backward compatibility to old version of wl
  83 (declare-function wl "ext:wl" () t)
  84 (declare-function wl-summary-buffer-msgdb "ext:wl-folder" () t)
  85 (declare-function wl-summary-jump-to-msg-by-message-id "ext:wl-summary"
  86                   (&optional id))
  87 (declare-function wl-summary-line-from "ext:wl-summary" ())
  88 (declare-function wl-summary-line-subject "ext:wl-summary" ())
  89 (declare-function wl-summary-message-number "ext:wl-summary" ())
  90 (declare-function wl-summary-redisplay "ext:wl-summary" (&optional arg))
  91 (declare-function wl-summary-registered-temp-mark "ext:wl-action" (number))
  92 (declare-function wl-folder-goto-folder-subr "ext:wl-folder"
  93                   (&optional folder sticky))
  94 (declare-function wl-folder-get-petname "ext:wl-folder" (name))
  95 (declare-function wl-folder-get-entity-from-buffer "ext:wl-folder"
  96                   (&optional getid))
  97 (declare-function wl-folder-buffer-group-p "ext:wl-folder")
  98 (defvar wl-init)
  99 (defvar wl-summary-buffer-elmo-folder)
 100 (defvar wl-summary-buffer-folder-name)
 101 (defvar wl-folder-group-regexp)
 102
 103 (defconst org-wl-folder-types
 104   '(("%" . imap) ("-" . nntp) ("+" . mh) ("=" . spool)
 105     ("$" . archive) ("&" . pop) ("@" . shimbun) ("[" . search)
 106     ("*" . multi) ("/" . filter) ("|" . pipe) ("'" . internal))
 107   "List of folder indicators. See Wanderlust manual, section 3.")
 108
 109 ;; Install the link type
 110 (org-add-link-type "wl" 'org-wl-open)
 111 (add-hook 'org-store-link-functions 'org-wl-store-link)
 112
 113 ;; Implementation
 114
 115 (defun org-wl-folder-type (folder)
 116   "Return symbol that indicicates the type of FOLDER.
 117 FOLDER is the wanderlust folder name. The first character of the
 118 folder name determines the the folder type."
 119   (let* ((indicator (substring folder 0 1))
 120          (type (cdr (assoc indicator org-wl-folder-types))))
 121     ;; maybe access or file folder
 122     (when (not type)
 123       (setq type
 124             (cond
 125              ((and (>= (length folder) 5)
 126                    (string= (substring folder 0 5) "file:"))
 127               'file)
 128              ((and (>= (length folder) 7)
 129                    (string= (substring folder 0 7) "access:"))
 130               'access)
 131              (t
 132               nil))))
 133     type))
 134
 135 (defun org-wl-message-field (field entity)
 136   "Return content of FIELD in ENTITY.
 137 FIELD is a symbol of a rfc822 message header field.
 138 ENTITY is a message entity."
 139   (let ((content (elmo-message-entity-field entity field)))
 140     (if (listp content) (car content) content)))
 141
 142 (defun org-wl-store-link ()
 143   "Store a link to a WL message or folder."
 144   (cond
 145    ((memq major-mode '(wl-summary-mode mime-view-mode))
 146     (org-wl-store-link-message))
 147    ((eq major-mode 'wl-folder-mode)
 148     (org-wl-store-link-folder))
 149    (t
 150     nil)))
 151
 152 (defun org-wl-store-link-folder ()
 153   "Store a link to a WL folder."
 154   (let* ((folder (wl-folder-get-entity-from-buffer))
 155          (petname (wl-folder-get-petname folder))
 156          (link (org-make-link "wl:" folder)))
 157     (save-excursion
 158       (beginning-of-line)
 159       (unless (and (wl-folder-buffer-group-p)
 160                    (looking-at wl-folder-group-regexp))
 161         (org-store-link-props :type "wl" :description petname
 162                               :link link)
 163         link))))
 164
 165 (defun org-wl-store-link-message ()
 166   "Store a link to a WL message."
 167   (save-excursion
 168     (let ((buf (if (eq major-mode 'wl-summary-mode)
 169                    (current-buffer)
 170                  (and (boundp 'wl-message-buffer-cur-summary-buffer)
 171                       wl-message-buffer-cur-summary-buffer))))
 172       (when buf
 173         (with-current-buffer buf
 174           (let* ((msgnum (wl-summary-message-number))
 175                  (mark-info (wl-summary-registered-temp-mark msgnum))
 176                  (folder-name
 177                   (if (and org-wl-link-to-refile-destination
 178                            mark-info
 179                            (equal (nth 1 mark-info) "o")) ; marked as refile
 180                       (nth 2 mark-info)
 181                     wl-summary-buffer-folder-name))
 182                  (folder-type (org-wl-folder-type folder-name))
 183                  (wl-message-entity
 184                   (if (fboundp 'elmo-message-entity)
 185                       (elmo-message-entity
 186                        wl-summary-buffer-elmo-folder msgnum)
 187                     (elmo-msgdb-overview-get-entity
 188                      msgnum (wl-summary-buffer-msgdb))))
 189                  (message-id
 190                   (org-wl-message-field 'message-id wl-message-entity))
 191                  (from (org-wl-message-field 'from wl-message-entity))
 192                  (to (org-wl-message-field 'to wl-message-entity))
 193                  (xref (org-wl-message-field 'xref wl-message-entity))
 194                  (subject (org-wl-message-field 'subject wl-message-entity))
 195                  desc link)
 196
 197             ;; remove text properties of subject string to avoid possible bug
 198             ;; when formatting the subject
 199             ;; (Emacs bug #5306, fixed)
 200             (set-text-properties 0 (length subject) nil subject)
 201
 202             ;; maybe remove filter condition
 203             (when (and (eq folder-type 'filter) org-wl-link-remove-filter)
 204               (while (eq (org-wl-folder-type folder-name) 'filter)
 205                 (setq folder-name
 206                       (replace-regexp-in-string "^/[^/]+/" "" folder-name))))
 207
 208             ;; maybe create http link
 209             (cond
 210              ((and (eq folder-type 'shimbun)
 211                    org-wl-shimbun-prefer-web-links xref)
 212               (org-store-link-props :type "http" :link xref :description subject
 213                                     :from from :to to :message-id message-id
 214                                     :subject subject))
 215              ((and (eq folder-type 'nntp) org-wl-nntp-prefer-web-links)
 216               (setq link
 217                     (format
 218                      (if (string-match "gmane\\." folder-name)
 219                          "http://mid.gmane.org/%s"
 220                        "http://groups.google.com/groups/search?as_umsgid=%s")
 221                      (org-fixup-message-id-for-http message-id)))
 222               (org-store-link-props :type "http" :link link :description subject
 223                                     :from from :to to :message-id message-id
 224                                     :subject subject))
 225              (t
 226               (org-store-link-props :type "wl" :from from :to to
 227                                     :subject subject :message-id message-id)
 228               (setq message-id (org-remove-angle-brackets message-id))
 229               (setq desc (org-email-link-description))
 230               (setq link (org-make-link "wl:" folder-name "#" message-id))
 231               (org-add-link-props :link link :description desc)))
 232             (or link xref)))))))
 233
 234 (defun org-wl-open (path)
 235   "Follow the WL message link specified by PATH.
 236 When called with one prefix, open message in namazu search folder
 237 with `org-wl-namazu-default-index' as search index.  When called
 238 with two prefixes or `org-wl-namazu-default-index' is nil, ask
 239 for namazu index."
 240   (require 'wl)
 241   (let ((wl-auto-check-folder-name
 242          (if org-wl-disable-folder-check
 243              'none
 244            wl-auto-check-folder-name)))
 245     (unless wl-init (wl))
 246     ;; XXX: The imap-uw's MH folder names start with "%#".
 247     (if (not (string-match "\\`\\(\\(?:%#\\)?[^#]+\\)\\(#\\(.*\\)\\)?" path))
 248         (error "Error in Wanderlust link"))
 249     (let ((folder (match-string 1 path))
 250           (article (match-string 3 path)))
 251       ;; maybe open message in namazu search folder
 252       (when current-prefix-arg
 253         (setq folder (concat "[" article "]"
 254                              (if (and (equal current-prefix-arg '(4))
 255                                       org-wl-namazu-default-index)
 256                                  org-wl-namazu-default-index
 257                                (read-directory-name "Namazu index: ")))))
 258       (if (not (elmo-folder-exists-p (org-no-warnings
 259                                       (wl-folder-get-elmo-folder folder))))
 260           (error "No such folder: %s" folder))
 261       (let ((old-buf (current-buffer))
 262             (old-point (point-marker)))
 263         (wl-folder-goto-folder-subr folder)
 264         (with-current-buffer old-buf
 265           ;; XXX: `wl-folder-goto-folder-subr' moves point to the
 266           ;; beginning of the current line.  So, restore the point
 267           ;; in the old buffer.
 268           (goto-char old-point))
 269         (and article (wl-summary-jump-to-msg-by-message-id (org-add-angle-brackets
 270                                                             article))
 271              (wl-summary-redisplay))))))
 272
 273 (provide 'org-wl)
 274
 275 ;; arch-tag: 29b75a0f-ef2e-430b-8abc-acff75bde54a
 276
 277 ;;; org-wl.el ends here