lisp/ob-lob.el

   1 ;;; ob-lob.el --- functions supporting the Library of Babel
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.01trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; See the online documentation for more information
  28 ;;
  29 ;;   http://orgmode.org/worg/org-contrib/babel/
  30
  31 ;;; Code:
  32 (require 'ob)
  33 (require 'ob-table)
  34
  35 (defvar org-babel-library-of-babel nil
  36   "Library of source-code blocks.
  37 This is an association list.  Populate the library by adding
  38 files to `org-babel-lob-files'.")
  39
  40 (defcustom org-babel-lob-files '()
  41   "Files used to populate the `org-babel-library-of-babel'.
  42 To add files to this list use the `org-babel-lob-ingest' command."
  43   :group 'org-babel
  44   :type 'list)
  45
  46 ;;;###autoload
  47 (defun org-babel-lob-ingest (&optional file)
  48   "Add all source-blocks defined in FILE to `org-babel-library-of-babel'."
  49   (interactive "f")
  50   (org-babel-map-src-blocks file
  51     (let* ((info (org-babel-get-src-block-info))
  52            (source-name (intern (nth 4 info))))
  53       (when source-name
  54         (setq org-babel-library-of-babel
  55               (cons (cons source-name info)
  56                     (assq-delete-all source-name org-babel-library-of-babel)))))))
  57
  58 (defconst org-babel-lob-call-aliases '("lob" "call")
  59   "Aliases to call a source block function.
  60 If you change the value of this variable then your files may
  61   become unusable by other org-babel users, and vice versa.")
  62
  63 (defconst org-babel-lob-one-liner-regexp
  64   (concat
  65    "^\\([ \t]*\\)#\\+\\(?:"
  66    (mapconcat #'regexp-quote org-babel-lob-call-aliases "\\|")
  67    "\\):[ \t]+\\([^\(\)\n]+\\)\(\\([^\n]*\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\([^\n]*\\)")
  68   "Regexp to match calls to predefined source block functions.")
  69
  70 ;; functions for executing lob one-liners
  71 ;;;###autoload
  72 (defun org-babel-lob-execute-maybe ()
  73   "Execute a Library of Babel source block, if appropriate.
  74 Detect if this is context for a Library Of Babel source block and
  75 if so then run the appropriate source block from the Library."
  76   (interactive)
  77   (let ((info (org-babel-lob-get-info)))
  78     (if (nth 0 info) (progn (org-babel-lob-execute info) t) nil)))
  79
  80 ;;;###autoload
  81 (defun org-babel-lob-get-info ()
  82   "Return a Library of Babel function call as a string."
  83   (let ((case-fold-search t))
  84     (save-excursion
  85       (beginning-of-line 1)
  86       (if (looking-at org-babel-lob-one-liner-regexp)
  87           (append
  88            (mapcar #'org-babel-clean-text-properties
  89                    (list
  90                     (format "%s(%s)%s"
  91                             (match-string 2) (match-string 3) (match-string 4))
  92                     (match-string 5)))
  93            (list (length (match-string 1))))))))
  94
  95 (defun org-babel-lob-execute (info)
  96   "Execute the lob call specified by INFO."
  97   (let ((params (org-babel-merge-params
  98                  org-babel-default-header-args
  99                  (org-babel-params-from-buffer)
 100                  (org-babel-params-from-properties)
 101                  (org-babel-parse-header-arguments
 102                   (org-babel-clean-text-properties
 103                    (concat ":var results="
 104                            (mapconcat #'identity (butlast info) " ")))))))
 105     (org-babel-execute-src-block
 106      nil (list "emacs-lisp" "results" params nil nil (nth 2 info)))))
 107
 108 (provide 'ob-lob)
 109
 110 ;; arch-tag: ce0712c9-2147-4019-ba3f-42341b8b474b
 111
 112 ;;; ob-lob.el ends here