lisp/ob-exp.el

   1 ;;; ob-exp.el --- Exportation of org-babel source blocks
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;      Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (require 'ob-core)
  27 (require 'org-src)
  28 (eval-when-compile
  29   (require 'cl))
  30
  31 (defvar org-babel-lob-one-liner-regexp)
  32 (defvar org-babel-ref-split-regexp)
  33 (defvar org-list-forbidden-blocks)
  34
  35 (declare-function org-babel-lob-get-info "ob-lob" ())
  36 (declare-function org-babel-eval-wipe-error-buffer "ob-eval" ())
  37 (declare-function org-between-regexps-p "org"
  38                   (start-re end-re &optional lim-up lim-down))
  39 (declare-function org-get-indentation "org" (&optional line))
  40 (declare-function org-heading-components "org" ())
  41 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  42 (declare-function org-in-block-p "org" (names))
  43 (declare-function org-in-verbatim-emphasis "org" ())
  44 (declare-function org-link-search "org" (s &optional type avoid-pos stealth))
  45 (declare-function org-fill-template "org" (template alist))
  46 (declare-function org-split-string "org" (string &optional separators))
  47 (declare-function org-element-at-point "org-element" ())
  48 (declare-function org-element-context "org-element" ())
  49 (declare-function org-element-property "org-element" (property element))
  50 (declare-function org-element-type "org-element" (element))
  51 (declare-function org-escape-code-in-string "org-src" (s))
  52
  53 (defcustom org-export-babel-evaluate t
  54   "Switch controlling code evaluation during export.
  55 When set to nil no code will be evaluated as part of the export
  56 process.  When set to 'inline-only, only inline code blocks will
  57 be executed."
  58   :group 'org-babel
  59   :version "24.1"
  60   :type '(choice (const :tag "Never" nil)
  61                  (const :tag "Only inline code" inline-only)
  62                  (const :tag "Always" t)))
  63 (put 'org-export-babel-evaluate 'safe-local-variable (lambda (x) (eq x nil)))
  64
  65 (defvar org-link-search-inhibit-query)
  66 (defmacro org-babel-exp-in-export-file (lang &rest body)
  67   (declare (indent 1))
  68   `(let* ((lang-headers (intern (concat "org-babel-default-header-args:" ,lang)))
  69           (heading (nth 4 (ignore-errors (org-heading-components))))
  70           (export-buffer (current-buffer))
  71           results)
  72      (when org-babel-exp-reference-buffer
  73        ;; Resolve parameters in the original file so that headline and
  74        ;; file-wide parameters are included, attempt to go to the same
  75        ;; heading in the original file
  76        (set-buffer org-babel-exp-reference-buffer)
  77        (save-restriction
  78          (when heading
  79            (condition-case nil
  80                (let ((org-link-search-inhibit-query t))
  81                  (org-link-search heading))
  82              (error (when heading
  83                       (goto-char (point-min))
  84                       (re-search-forward (regexp-quote heading) nil t)))))
  85          (setq results ,@body))
  86        (set-buffer export-buffer)
  87        results)))
  88 (def-edebug-spec org-babel-exp-in-export-file (form body))
  89
  90 (defun org-babel-exp-src-block (&rest headers)
  91   "Process source block for export.
  92 Depending on the 'export' headers argument, replace the source
  93 code block like this:
  94
  95 both ---- display the code and the results
  96
  97 code ---- the default, display the code inside the block but do
  98           not process
  99
 100 results - just like none only the block is run on export ensuring
 101           that it's results are present in the org-mode buffer
 102
 103 none ---- do not display either code or results upon export
 104
 105 Assume point is at the beginning of block's starting line."
 106   (interactive)
 107   (save-excursion
 108     (let* ((info (org-babel-get-src-block-info 'light))
 109            (line (org-current-line))
 110            (lang (nth 0 info))
 111            (raw-params (nth 2 info)) hash)
 112       ;; bail if we couldn't get any info from the block
 113       (unless noninteractive
 114         (message "org-babel-exp process %s at line %d..." lang line))
 115       (when info
 116         ;; if we're actually going to need the parameters
 117         (when (member (cdr (assoc :exports (nth 2 info))) '("both" "results"))
 118           (org-babel-exp-in-export-file lang
 119             (setf (nth 2 info)
 120                   (org-babel-process-params
 121                    (apply #'org-babel-merge-params
 122                           org-babel-default-header-args
 123                           (if (boundp lang-headers) (eval lang-headers) nil)
 124                           (append (org-babel-params-from-properties lang)
 125                                   (list raw-params))))))
 126           (setf hash (org-babel-sha1-hash info)))
 127         (org-babel-exp-do-export info 'block hash)))))
 128
 129 (defcustom org-babel-exp-call-line-template
 130   ""
 131   "Template used to export call lines.
 132 This template may be customized to include the call line name
 133 with any export markup.  The template is filled out using
 134 `org-fill-template', and the following %keys may be used.
 135
 136  line --- call line
 137
 138 An example value would be \"\\n: call: %line\" to export the call line
 139 wrapped in a verbatim environment.
 140
 141 Note: the results are inserted separately after the contents of
 142 this template."
 143   :group 'org-babel
 144   :type 'string)
 145
 146 (defvar org-babel-default-lob-header-args)
 147 (defun org-babel-exp-process-buffer (reference-buffer)
 148   "Execute all Babel blocks in current buffer.
 149 REFERENCE-BUFFER is the buffer containing a pristine copy of the
 150 buffer being processed.  It is used to properly resolve
 151 references in source blocks, as modifications in current buffer
 152 may make them unreachable."
 153   (interactive)
 154   (save-window-excursion
 155     (save-excursion
 156       (let ((case-fold-search t)
 157             (org-babel-exp-reference-buffer reference-buffer)
 158             (regexp (concat org-babel-inline-src-block-regexp "\\|"
 159                             org-babel-lob-one-liner-regexp "\\|"
 160                             "^[ \t]*#\\+BEGIN_SRC")))
 161         (goto-char (point-min))
 162         (while (re-search-forward regexp nil t)
 163           (unless (save-match-data (org-in-commented-heading-p))
 164             (let* ((element (save-excursion
 165                               ;; If match is inline, point is at its
 166                               ;; end.  Move backward so
 167                               ;; `org-element-context' can get the
 168                               ;; object, not the following one.
 169                               (backward-char)
 170                               (save-match-data (org-element-context))))
 171                    (type (org-element-type element))
 172                    (begin (copy-marker (org-element-property :begin element)))
 173                    (end (copy-marker
 174                          (save-excursion
 175                            (goto-char (org-element-property :end element))
 176                            (skip-chars-backward " \r\t\n")
 177                            (point)))))
 178               (case type
 179                 (inline-src-block
 180                  (let* ((info (org-babel-parse-inline-src-block-match))
 181                         (params (nth 2 info)))
 182                    (setf (nth 1 info)
 183                          (if (and (cdr (assoc :noweb params))
 184                                   (string= "yes" (cdr (assoc :noweb params))))
 185                              (org-babel-expand-noweb-references
 186                               info org-babel-exp-reference-buffer)
 187                            (nth 1 info)))
 188                    (goto-char begin)
 189                    (let ((replacement (org-babel-exp-do-export info 'inline)))
 190                      (if (equal replacement "")
 191                          ;; Replacement code is empty: remove inline
 192                          ;; source block, including extra white space
 193                          ;; that might have been created when
 194                          ;; inserting results.
 195                          (delete-region begin
 196                                         (progn (goto-char end)
 197                                                (skip-chars-forward " \t")
 198                                                (point)))
 199                        ;; Otherwise: remove inline src block but
 200                        ;; preserve following white spaces.  Then
 201                        ;; insert value.
 202                        (delete-region begin end)
 203                        (insert replacement)))))
 204                 ((babel-call inline-babel-call)
 205                  (let* ((lob-info (org-babel-lob-get-info))
 206                         (results
 207                          (org-babel-exp-do-export
 208                           (list "emacs-lisp" "results"
 209                                 (apply #'org-babel-merge-params
 210                                        org-babel-default-header-args
 211                                        org-babel-default-lob-header-args
 212                                        (append
 213                                         (org-babel-params-from-properties)
 214                                         (list
 215                                          (org-babel-parse-header-arguments
 216                                           (org-no-properties
 217                                            (concat
 218                                             ":var results="
 219                                             (mapconcat 'identity
 220                                                        (butlast lob-info 2)
 221                                                        " ")))))))
 222                                 "" (nth 3 lob-info) (nth 2 lob-info))
 223                           'lob))
 224                         (rep (org-fill-template
 225                               org-babel-exp-call-line-template
 226                               `(("line"  . ,(nth 0 lob-info))))))
 227                    ;; If replacement is empty, completely remove the
 228                    ;; object/element, including any extra white space
 229                    ;; that might have been created when including
 230                    ;; results.
 231                    (if (equal rep "")
 232                        (delete-region
 233                         begin
 234                         (progn (goto-char end)
 235                                (if (not (eq type 'babel-call))
 236                                    (progn (skip-chars-forward " \t") (point))
 237                                  (skip-chars-forward " \r\t\n")
 238                                  (line-beginning-position))))
 239                      ;; Otherwise, preserve following white
 240                      ;; spaces/newlines and then, insert replacement
 241                      ;; string.
 242                      (goto-char begin)
 243                      (delete-region begin end)
 244                      (insert rep))))
 245                 (src-block
 246                  (let* ((match-start (copy-marker (match-beginning 0)))
 247                         (ind (org-get-indentation))
 248                         (headers
 249                          (cons
 250                           (org-element-property :language element)
 251                           (let ((params (org-element-property :parameters
 252                                                               element)))
 253                             (and params (org-split-string params "[ \t]+"))))))
 254                    ;; Take care of matched block: compute replacement
 255                    ;; string.  In particular, a nil REPLACEMENT means
 256                    ;; the block should be left as-is while an empty
 257                    ;; string should remove the block.
 258                    (let ((replacement
 259                           (progn (goto-char match-start)
 260                                  (org-babel-exp-src-block headers))))
 261                      (cond ((not replacement) (goto-char end))
 262                            ((equal replacement "")
 263                             (goto-char end)
 264                             (skip-chars-forward " \r\t\n")
 265                             (beginning-of-line)
 266                             (delete-region begin (point)))
 267                            (t
 268                             (goto-char match-start)
 269                             (delete-region (point)
 270                                            (save-excursion (goto-char end)
 271                                                            (line-end-position)))
 272                             (insert replacement)
 273                             (if (or org-src-preserve-indentation
 274                                     (org-element-property :preserve-indent
 275                                                           element))
 276                                 ;; Indent only the code block markers.
 277                                 (save-excursion (skip-chars-backward " \r\t\n")
 278                                                 (indent-line-to ind)
 279                                                 (goto-char match-start)
 280                                                 (indent-line-to ind))
 281                               ;; Indent everything.
 282                               (indent-rigidly match-start (point) ind)))))
 283                    (set-marker match-start nil))))
 284               (set-marker begin nil)
 285               (set-marker end nil))))))))
 286
 287 (defun org-babel-in-example-or-verbatim ()
 288   "Return true if point is in example or verbatim code.
 289 Example and verbatim code include escaped portions of
 290 an org-mode buffer code that should be treated as normal
 291 org-mode text."
 292   (or (save-match-data
 293         (save-excursion
 294           (goto-char (point-at-bol))
 295           (looking-at "[ \t]*:[ \t]")))
 296       (org-in-verbatim-emphasis)
 297       (org-in-block-p org-list-forbidden-blocks)
 298       (org-between-regexps-p "^[ \t]*#\\+begin_src" "^[ \t]*#\\+end_src")))
 299
 300 (defun org-babel-exp-do-export (info type &optional hash)
 301   "Return a string with the exported content of a code block.
 302 The function respects the value of the :exports header argument."
 303   (let ((silently (lambda () (let ((session (cdr (assoc :session (nth 2 info)))))
 304                                (when (not (and session (equal "none" session)))
 305                                  (org-babel-exp-results info type 'silent)))))
 306         (clean (lambda () (unless (eq type 'inline) (org-babel-remove-result info)))))
 307     (case (intern (or (cdr (assoc :exports (nth 2 info))) "code"))
 308       ('none (funcall silently) (funcall clean) "")
 309       ('code (funcall silently) (funcall clean) (org-babel-exp-code info))
 310       ('results (org-babel-exp-results info type nil hash) "")
 311       ('both (org-babel-exp-results info type nil hash)
 312              (org-babel-exp-code info)))))
 313
 314 (defcustom org-babel-exp-code-template
 315   "#+BEGIN_SRC %lang%switches%flags\n%body\n#+END_SRC"
 316   "Template used to export the body of code blocks.
 317 This template may be customized to include additional information
 318 such as the code block name, or the values of particular header
 319 arguments.  The template is filled out using `org-fill-template',
 320 and the following %keys may be used.
 321
 322  lang ------ the language of the code block
 323  name ------ the name of the code block
 324  body ------ the body of the code block
 325  switches -- the switches associated to the code block
 326  flags ----- the flags passed to the code block
 327
 328 In addition to the keys mentioned above, every header argument
 329 defined for the code block may be used as a key and will be
 330 replaced with its value."
 331   :group 'org-babel
 332   :type 'string)
 333
 334 (defun org-babel-exp-code (info)
 335   "Return the original code block formatted for export."
 336   (setf (nth 1 info)
 337         (if (string= "strip-export" (cdr (assoc :noweb (nth 2 info))))
 338             (replace-regexp-in-string
 339              (org-babel-noweb-wrap) "" (nth 1 info))
 340           (if (org-babel-noweb-p (nth 2 info) :export)
 341               (org-babel-expand-noweb-references
 342                info org-babel-exp-reference-buffer)
 343             (nth 1 info))))
 344   (org-fill-template
 345    org-babel-exp-code-template
 346    `(("lang"  . ,(nth 0 info))
 347      ("body"  . ,(org-escape-code-in-string (nth 1 info)))
 348      ("switches" . ,(let ((f (nth 3 info)))
 349                       (and (org-string-nw-p f) (concat " " f))))
 350      ("flags" . ,(let ((f (assq :flags (nth 2 info))))
 351                    (and f (concat " " (cdr f)))))
 352      ,@(mapcar (lambda (pair)
 353                  (cons (substring (symbol-name (car pair)) 1)
 354                        (format "%S" (cdr pair))))
 355                (nth 2 info))
 356      ("name"  . ,(or (nth 4 info) "")))))
 357
 358 (defun org-babel-exp-results (info type &optional silent hash)
 359   "Evaluate and return the results of the current code block for export.
 360 Results are prepared in a manner suitable for export by org-mode.
 361 This function is called by `org-babel-exp-do-export'.  The code
 362 block will be evaluated.  Optional argument SILENT can be used to
 363 inhibit insertion of results into the buffer."
 364   (when (and (or (eq org-export-babel-evaluate t)
 365                  (and (eq type 'inline)
 366                       (eq org-export-babel-evaluate 'inline-only)))
 367              (not (and hash (equal hash (org-babel-current-result-hash)))))
 368     (let ((lang (nth 0 info))
 369           (body (if (org-babel-noweb-p (nth 2 info) :eval)
 370                     (org-babel-expand-noweb-references
 371                      info org-babel-exp-reference-buffer)
 372                   (nth 1 info)))
 373           (info (copy-sequence info))
 374           (org-babel-current-src-block-location (point-marker)))
 375       ;; skip code blocks which we can't evaluate
 376       (when (fboundp (intern (concat "org-babel-execute:" lang)))
 377         (org-babel-eval-wipe-error-buffer)
 378         (prog1 nil
 379           (setf (nth 1 info) body)
 380           (setf (nth 2 info)
 381                 (org-babel-exp-in-export-file lang
 382                   (org-babel-process-params
 383                    (org-babel-merge-params
 384                     (nth 2 info)
 385                     `((:results . ,(if silent "silent" "replace")))))))
 386           (cond
 387            ((equal type 'block)
 388             (org-babel-execute-src-block nil info))
 389            ((equal type 'inline)
 390             ;; position the point on the inline source block allowing
 391             ;; `org-babel-insert-result' to check that the block is
 392             ;; inline
 393             (re-search-backward "[ \f\t\n\r\v]" nil t)
 394             (re-search-forward org-babel-inline-src-block-regexp nil t)
 395             (re-search-backward "src_" nil t)
 396             (org-babel-execute-src-block nil info))
 397            ((equal type 'lob)
 398             (save-excursion
 399               (re-search-backward org-babel-lob-one-liner-regexp nil t)
 400               (let (org-confirm-babel-evaluate)
 401                 (org-babel-execute-src-block nil info))))))))))
 402
 403
 404 (provide 'ob-exp)
 405
 406 ;;; ob-exp.el ends here