lisp/org-gnus.el

   1 ;;; org-gnus.el --- Support for links to Gnus groups and messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;;         Tassilo Horn <tassilo at member dot fsf dot org>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;; Version: 7.01trans
  11 ;;
  12 ;; This file is part of GNU Emacs.
  13 ;;
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29
  30 ;; This file implements links to Gnus groups and messages from within Org-mode.
  31 ;; Org-mode loads this module by default - if this is not what you want,
  32 ;; configure the variable `org-modules'.
  33
  34 ;;; Code:
  35
  36 (require 'org)
  37 (eval-when-compile (require 'gnus-sum))
  38
  39 ;; Declare external functions and variables
  40 (declare-function message-fetch-field "message" (header &optional not-all))
  41 (declare-function message-narrow-to-head-1 "message" nil)
  42 (declare-function nnimap-group-overview-filename "nnimap" (group server))
  43 ;; The following line suppresses a compiler warning stemming from gnus-sum.el
  44 (declare-function gnus-summary-last-subject "gnus-sum" nil)
  45 ;; Customization variables
  46
  47 (when (fboundp 'defvaralias)
  48   (defvaralias 'org-usenet-links-prefer-google 'org-gnus-prefer-web-links))
  49
  50 (defcustom org-gnus-prefer-web-links nil
  51   "If non-nil, `org-store-link' creates web links to Google groups or Gmane.
  52 When nil, Gnus will be used for such links.
  53 Using a prefix arg to the command \\[org-store-link] (`org-store-link')
  54 negates this setting for the duration of the command."
  55   :group 'org-link-store
  56   :type 'boolean)
  57
  58 (defcustom org-gnus-nnimap-query-article-no-from-file t
  59   "If non-nil, `org-gnus-follow-link' will try to translate
  60 Message-Ids to article numbers by querying the .overview file.
  61 Normally, this translation is done by querying the IMAP server,
  62 which is usually very fast.  Unfortunately, some (maybe badly
  63 configured) IMAP servers don't support this operation quickly.
  64 So if following a link to a Gnus article takes ages, try setting
  65 this variable to `t'."
  66   :group 'org-link-store
  67   :type 'boolean)
  68
  69
  70 ;; Install the link type
  71 (org-add-link-type "gnus" 'org-gnus-open)
  72 (add-hook 'org-store-link-functions 'org-gnus-store-link)
  73
  74 ;; Implementation
  75
  76 (defun org-gnus-nnimap-cached-article-number (group server message-id)
  77   "Return cached article number (uid) of message in GROUP on SERVER.
  78 MESSAGE-ID is the message-id header field that identifies the
  79 message.  If the uid is not cached, return nil."
  80   (with-temp-buffer
  81     (let ((nov (nnimap-group-overview-filename group server)))
  82       (when (file-exists-p nov)
  83         (mm-insert-file-contents nov)
  84         (set-buffer-modified-p nil)
  85         (goto-char (point-min))
  86         (catch 'found
  87           (while (search-forward message-id nil t)
  88             (let ((hdr (split-string (thing-at-point 'line) "\t")))
  89               (if (string= (nth 4 hdr) message-id)
  90                   (throw 'found (nth 0 hdr))))))))))
  91
  92 (defun org-gnus-group-link (group)
  93   "Create a link to the Gnus group GROUP.
  94 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
  95 non-nil, create a link to groups.google.com or gmane.org.
  96 Otherwise create a link to the group inside Gnus.
  97
  98 If `org-store-link' was called with a prefix arg the meaning of
  99 `org-gnus-prefer-web-links' is reversed."
 100   (let ((unprefixed-group (replace-regexp-in-string "^[^:]+:" "" group)))
 101     (if (and (string-match "^nntp" group) ;; Only for nntp groups
 102              (org-xor current-prefix-arg
 103                       org-gnus-prefer-web-links))
 104         (org-make-link (if (string-match "gmane" unprefixed-group)
 105                            "http://news.gmane.org/"
 106                          "http://groups.google.com/group/")
 107                        unprefixed-group)
 108       (org-make-link "gnus:" group))))
 109
 110 (defun org-gnus-article-link (group newsgroups message-id x-no-archive)
 111   "Create a link to a Gnus article.
 112 The article is specified by its MESSAGE-ID.  Additional
 113 parameters are the Gnus GROUP, the NEWSGROUPS the article was
 114 posted to and the X-NO-ARCHIVE header value of that article.
 115
 116 If GROUP is a newsgroup and `org-gnus-prefer-web-links' is
 117 non-nil, create a link to groups.google.com or gmane.org.
 118 Otherwise create a link to the article inside Gnus.
 119
 120 If `org-store-link' was called with a prefix arg the meaning of
 121 `org-gnus-prefer-web-links' is reversed."
 122   (if (and (org-xor current-prefix-arg org-gnus-prefer-web-links)
 123            newsgroups     ;; Make web links only for nntp groups
 124            (not x-no-archive)) ;; and if X-No-Archive isn't set.
 125       (format (if (string-match "gmane\\." newsgroups)
 126                   "http://mid.gmane.org/%s"
 127                 "http://groups.google.com/groups/search?as_umsgid=%s")
 128               (org-fixup-message-id-for-http message-id))
 129     (org-make-link "gnus:" group "#" message-id)))
 130
 131 (defun org-gnus-store-link ()
 132   "Store a link to a Gnus folder or message."
 133   (cond
 134    ((eq major-mode 'gnus-group-mode)
 135     (let* ((group (cond ((fboundp 'gnus-group-group-name) ; depending on Gnus
 136                          (gnus-group-group-name))         ; version
 137                         ((fboundp 'gnus-group-name)
 138                          (gnus-group-name))
 139                         (t "???")))
 140            desc link)
 141       (when group
 142         (org-store-link-props :type "gnus" :group group)
 143         (setq desc (org-gnus-group-link group)
 144               link desc)
 145         (org-add-link-props :link link :description desc)
 146         link)))
 147
 148    ((memq major-mode '(gnus-summary-mode gnus-article-mode))
 149     (let* ((group gnus-newsgroup-name)
 150            (header (with-current-buffer gnus-summary-buffer
 151                      (gnus-summary-article-header)))
 152            (from (mail-header-from header))
 153            (message-id (org-remove-angle-brackets (mail-header-id header)))
 154            (date (mail-header-date header))
 155            (subject (copy-sequence (mail-header-subject header)))
 156            (to (cdr (assq 'To (mail-header-extra header))))
 157            newsgroups x-no-archive desc link)
 158       ;; Remove text properties of subject string to avoid Emacs bug
 159       ;; #3506
 160       (set-text-properties 0 (length subject) nil subject)
 161
 162       ;; Fetching an article is an expensive operation; newsgroup and
 163       ;; x-no-archive are only needed for web links.
 164       (when (org-xor current-prefix-arg org-gnus-prefer-web-links)
 165         ;; Make sure the original article buffer is up-to-date
 166         (save-window-excursion (gnus-summary-select-article))
 167         (setq to (or to (gnus-fetch-original-field "To"))
 168               newsgroups (gnus-fetch-original-field "Newsgroups")
 169               x-no-archive (gnus-fetch-original-field "x-no-archive")))
 170       (org-store-link-props :type "gnus" :from from :subject subject
 171                             :message-id message-id :group group :to to)
 172       (setq desc (org-email-link-description)
 173             link (org-gnus-article-link
 174                   group newsgroups message-id x-no-archive))
 175       (org-add-link-props :link link :description desc)
 176       link))))
 177
 178 (defun org-gnus-open (path)
 179   "Follow the Gnus message or folder link specified by PATH."
 180   (let (group article)
 181     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
 182         (error "Error in Gnus link"))
 183     (setq group (match-string 1 path)
 184           article (match-string 3 path))
 185     (when group
 186       (setq group (org-substring-no-properties group)))
 187     (when article
 188       (setq article (org-substring-no-properties article)))
 189     (org-gnus-follow-link group article)))
 190
 191 (defun org-gnus-follow-link (&optional group article)
 192   "Follow a Gnus link to GROUP and ARTICLE."
 193   (require 'gnus)
 194   (funcall (cdr (assq 'gnus org-link-frame-setup)))
 195   (if gnus-other-frame-object (select-frame gnus-other-frame-object))
 196   (when group
 197     (setq group (org-substring-no-properties group)))
 198   (when article
 199     (setq article (org-substring-no-properties article)))
 200   (cond ((and group article)
 201          (gnus-activate-group group t)
 202          (condition-case nil
 203              (let* ((method (gnus-find-method-for-group group))
 204                     (backend (car method))
 205                     (server (cadr method)))
 206                (cond
 207                 ((eq backend 'nndoc)
 208                  (if (gnus-group-read-group t nil group)
 209                      (gnus-summary-goto-article article nil t)
 210                    (message "Couldn't follow gnus link.  %s"
 211                             "The summary couldn't be opened.")))
 212                 (t
 213                  (let ((articles 1)
 214                        group-opened)
 215                    (when (and (eq backend 'nnimap)
 216                               org-gnus-nnimap-query-article-no-from-file)
 217                      (setq article
 218                            (or (org-gnus-nnimap-cached-article-number
 219                                 (nth 1 (split-string group ":"))
 220                                 server (concat "<" article ">")) article)))
 221                    (while (and (not group-opened)
 222                                ;; stop on integer overflows
 223                                (> articles 0))
 224                      (setq group-opened (gnus-group-read-group
 225                                          articles nil group)
 226                            articles (if (< articles 16)
 227                                         (1+ articles)
 228                                       (* articles 2))))
 229                    (if group-opened
 230                        (gnus-summary-goto-article article nil t)
 231                      (message "Couldn't follow gnus link.  %s"
 232                               "The summary couldn't be opened."))))))
 233            (quit (message "Couldn't follow gnus link.  %s"
 234                           "The linked group is empty."))))
 235         (group (gnus-group-jump-to-group group))))
 236
 237 (defun org-gnus-no-new-news ()
 238   "Like `M-x gnus' but doesn't check for new news."
 239   (if (not (gnus-alive-p)) (gnus)))
 240
 241 (provide 'org-gnus)
 242
 243 ;; arch-tag: 512e0840-58fa-45b3-b456-71e10fa2376d
 244
 245 ;;; org-gnus.el ends here