lisp/ob-awk.el

   1 ;;; ob-awk.el --- org-babel functions for awk evaluation
   2
   3 ;; Copyright (C) 2011-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Babel's awk can use special header argument:
  27 ;;
  28 ;; - :in-file takes a path to a file of data to be processed by awk
  29 ;;
  30 ;; - :stdin takes an Org-mode data or code block reference, the value
  31 ;;          of which will be passed to the awk process through STDIN
  32
  33 ;;; Code:
  34 (require 'ob)
  35 (require 'org-compat)
  36 (eval-when-compile (require 'cl))
  37
  38 (declare-function org-babel-ref-resolve "ob-ref" (ref))
  39 (declare-function orgtbl-to-generic "org-table" (table params))
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("awk" . "awk"))
  43
  44 (defvar org-babel-awk-command "awk"
  45   "Name of the awk executable command.")
  46
  47 (defun org-babel-expand-body:awk (body params)
  48   "Expand BODY according to PARAMS, return the expanded body."
  49   (dolist (pair (mapcar #'cdr (org-babel-get-header params :var)))
  50     (setf body (replace-regexp-in-string
  51                 (regexp-quote (format "$%s" (car pair))) (cdr pair) body)))
  52   body)
  53
  54 (defun org-babel-execute:awk (body params)
  55   "Execute a block of Awk code with org-babel.  This function is
  56 called by `org-babel-execute-src-block'"
  57   (message "executing Awk source code block")
  58   (let* ((result-params (cdr (assoc :result-params params)))
  59          (cmd-line (cdr (assoc :cmd-line params)))
  60          (in-file (cdr (assoc :in-file params)))
  61          (full-body (org-babel-expand-body:awk body params))
  62          (code-file ((lambda (file) (with-temp-file file (insert full-body)) file)
  63                      (org-babel-temp-file "awk-")))
  64          (stdin ((lambda (stdin)
  65                    (when stdin
  66                      (let ((tmp (org-babel-temp-file "awk-stdin-"))
  67                            (res (org-babel-ref-resolve stdin)))
  68                        (with-temp-file tmp
  69                          (insert (org-babel-awk-var-to-awk res)))
  70                        tmp)))
  71                  (cdr (assoc :stdin params))))
  72          (cmd (mapconcat #'identity (remove nil (list org-babel-awk-command
  73                                                       "-f" code-file
  74                                                       cmd-line
  75                                                       in-file))
  76                          " ")))
  77     (org-babel-reassemble-table
  78      ((lambda (results)
  79         (when results
  80           (org-babel-result-cond result-params
  81             results
  82             (let ((tmp (org-babel-temp-file "awk-results-")))
  83               (with-temp-file tmp (insert results))
  84               (org-babel-import-elisp-from-file tmp)))))
  85       (cond
  86        (stdin (with-temp-buffer
  87                 (call-process-shell-command cmd stdin (current-buffer))
  88                 (buffer-string)))
  89        (t (org-babel-eval cmd ""))))
  90      (org-babel-pick-name
  91       (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  92      (org-babel-pick-name
  93       (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))
  94
  95 (defun org-babel-awk-var-to-awk (var &optional sep)
  96   "Return a printed value of VAR suitable for parsing with awk."
  97   (let ((echo-var (lambda (v) (if (stringp v) v (format "%S" v)))))
  98     (cond
  99      ((and (listp var) (listp (car var)))
 100       (orgtbl-to-generic var  (list :sep (or sep "\t") :fmt echo-var)))
 101      ((listp var)
 102       (mapconcat echo-var var "\n"))
 103      (t (funcall echo-var var)))))
 104
 105 (defun org-babel-awk-table-or-string (results)
 106   "If the results look like a table, then convert them into an
 107 Emacs-lisp table, otherwise return the results as a string."
 108   (org-babel-script-escape results))
 109
 110 (provide 'ob-awk)
 111
 112
 113
 114 ;;; ob-awk.el ends here