lisp/ob-sqlite.el

   1 ;;; ob-sqlite.el --- org-babel functions for sqlite database interaction
   2
   3 ;; Copyright (C) 2010  Free Software Foundation
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.01trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating sqlite source code.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32
  33 (declare-function org-fill-template "org" (template alist))
  34 (declare-function org-table-convert-region "org-table"
  35                   (beg0 end0 &optional separator))
  36 (declare-function orgtbl-to-csv "org-table" (TABLE PARAMS))
  37
  38 (defvar org-babel-default-header-args:sqlite '())
  39
  40 (defvar org-babel-header-arg-names:sqlite
  41   '(db header echo bail csv column html line list separator nullvalue)
  42   "Sqlite specific header args.")
  43
  44 (defun org-babel-expand-body:sqlite (body params &optional processed-params)
  45   (org-babel-sqlite-expand-vars
  46    body (or (nth 1 processed-params) (org-babel-ref-variables params))))
  47
  48 (defvar org-babel-sqlite3-command "sqlite3")
  49
  50 (defun org-babel-execute:sqlite (body params)
  51   "Execute a block of Sqlite code with Babel.
  52 This function is called by `org-babel-execute-src-block'."
  53   (let ((result-params (split-string (or (cdr (assoc :results params)) "")))
  54         (vars (org-babel-ref-variables params))
  55         (db (cdr (assoc :db params)))
  56         (separator (cdr (assoc :separator params)))
  57         (nullvalue (cdr (assoc :nullvalue params)))
  58         (headers-p (equal "yes" (cdr (assoc :colnames params))))
  59         (others (delq nil (mapcar
  60                            (lambda (arg) (car (assoc arg params)))
  61                            (list :header :echo :bail :column
  62                                  :csv :html :line :list))))
  63         exit-code)
  64     (unless db (error "ob-sqlite: can't evaluate without a database."))
  65     (with-temp-buffer
  66       (insert
  67        (shell-command-to-string
  68         (org-fill-template
  69          "%cmd -init %body %header %separator %nullvalue %others %csv %db "
  70          (list
  71           (cons "body" ((lambda (sql-file)
  72                           (with-temp-file sql-file
  73                             (insert (org-babel-expand-body:sqlite
  74                                      body nil (list nil vars))))
  75                           sql-file)
  76                         (make-temp-file "ob-sqlite-sql")))
  77           (cons "cmd" org-babel-sqlite3-command)
  78           (cons "header" (if headers-p "-header" "-noheader"))
  79           (cons "separator"
  80                 (if separator (format "-separator %s" separator) ""))
  81           (cons "nullvalue"
  82                 (if nullvalue (format "-nullvalue %s" nullvalue) ""))
  83           (cons "others"
  84                 (mapconcat
  85                  (lambda (arg) (format "-%s" (substring (symbol-name arg) 1)))
  86                  others " "))
  87           ;; for easy table parsing, default header type should be -csv
  88           (cons "csv" (if (or (member :csv others) (member :column others)
  89                               (member :line others) (member :list others)
  90                               (member :html others) separator)
  91                           ""
  92                         "-csv"))
  93           (cons "db " db)))))
  94       (if (or (member "scalar" result-params)
  95               (member "html" result-params)
  96               (member "code" result-params)
  97               (equal (point-min) (point-max)))
  98           (buffer-string)
  99         (org-table-convert-region (point-min) (point-max))
 100         (org-babel-sqlite-table-or-scalar
 101          (org-babel-sqlite-offset-colnames
 102           (org-table-to-lisp) headers-p))))))
 103
 104 (defun org-babel-sqlite-expand-vars (body vars)
 105   "Expand the variables held in VARS in BODY."
 106   (mapc
 107    (lambda (pair)
 108      (setq body
 109            (replace-regexp-in-string
 110             (format "\$%s" (car pair))
 111             ((lambda (val)
 112                (if (listp val)
 113                    ((lambda (data-file)
 114                       (with-temp-file data-file
 115                         (insert (orgtbl-to-csv
 116                                  val '(:fmt (lambda (el) (if (stringp el)
 117                                                         el
 118                                                       (format "%S" el)))))))
 119                       data-file)
 120                     (make-temp-file "ob-sqlite-data"))
 121                  (if (stringp val) val (format "%S" val))))
 122              (cdr pair))
 123             body)))
 124    vars)
 125   body)
 126
 127 (defun org-babel-sqlite-table-or-scalar (result)
 128   "If RESULT looks like a trivial table, then unwrap it."
 129   (if (and (equal 1 (length result))
 130            (equal 1 (length (car result))))
 131       (org-babel-read (caar result))
 132     (mapcar (lambda (row)
 133               (if (equal 'hline row)
 134                   'hline
 135                 (mapcar #'org-babel-read row))) result)))
 136
 137 (defun org-babel-sqlite-offset-colnames (table headers-p)
 138   "If HEADERS-P is non-nil then offset the first row as column names."
 139   (if headers-p
 140       (cons (car table) (cons 'hline (cdr table)))
 141     table))
 142
 143 (defun org-babel-prep-session:sqlite (session params)
 144   "Raise an error because support for sqlite sessions isn't implemented.
 145 Prepare SESSION according to the header arguments specified in PARAMS."
 146   (error "sqlite sessions not yet implemented"))
 147
 148 (provide 'ob-sqlite)
 149
 150 ;; arch-tag: 5c03d7f2-0f72-48b8-bbd1-35aafea248ac
 151
 152 ;;; ob-sqlite.el ends here