lisp/ob-latex.el

   1 ;;; ob-latex.el --- org-babel functions for latex "evaluation"
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating LaTeX source code.
  27 ;;
  28 ;; Currently on evaluation this returns raw LaTeX code, unless a :file
  29 ;; header argument is given in which case small png or pdf files will
  30 ;; be created directly form the latex source code.
  31
  32 ;;; Code:
  33 (require 'ob)
  34
  35 (declare-function org-create-formula-image "org" (string tofile options buffer))
  36 (declare-function org-splice-latex-header "org"
  37                   (tpl def-pkg pkg snippets-p &optional extra))
  38 (declare-function org-latex-guess-inputenc "ox-latex" (header))
  39 (declare-function org-latex-compile "ox-latex" (file))
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("latex" . "tex"))
  43
  44 (defvar org-format-latex-header)          ; From org.el
  45 (defvar org-format-latex-options)         ; From org.el
  46 (defvar org-latex-default-packages-alist) ; From org.el
  47 (defvar org-latex-packages-alist)         ; From org.el
  48
  49 (defvar org-babel-default-header-args:latex
  50   '((:results . "latex") (:exports . "results"))
  51   "Default arguments to use when evaluating a LaTeX source block.")
  52
  53 (defconst org-babel-header-args:latex
  54   '((border       . :any)
  55     (fit          . :any)
  56     (iminoptions  . :any)
  57     (imoutoptions . :any)
  58     (packages     . :any)
  59     (pdfheight    . :any)
  60     (pdfpng       . :any)
  61     (pdfwidth     . :any))
  62   "LaTeX-specific header arguments.")
  63
  64 (defcustom org-babel-latex-htlatex "htlatex"
  65   "The htlatex command to enable conversion of latex to SVG or HTML."
  66   :group 'org-babel
  67   :type 'string)
  68
  69 (defcustom org-babel-latex-htlatex-packages
  70   '("[usenames]{color}" "{tikz}" "{color}" "{listings}" "{amsmath}")
  71   "Packages to use for htlatex export."
  72   :group 'org-babel
  73   :type '(repeat (string)))
  74
  75 (defun org-babel-expand-body:latex (body params)
  76   "Expand BODY according to PARAMS, return the expanded body."
  77   (mapc (lambda (pair) ;; replace variables
  78           (setq body
  79                 (replace-regexp-in-string
  80                  (regexp-quote (format "%S" (car pair)))
  81                  (if (stringp (cdr pair))
  82                      (cdr pair) (format "%S" (cdr pair)))
  83                  body))) (mapcar #'cdr (org-babel-get-header params :var)))
  84   (org-babel-trim body))
  85
  86 (defun org-babel-execute:latex (body params)
  87   "Execute a block of Latex code with Babel.
  88 This function is called by `org-babel-execute-src-block'."
  89   (setq body (org-babel-expand-body:latex body params))
  90   (if (cdr (assoc :file params))
  91       (let* ((out-file (cdr (assoc :file params)))
  92              (tex-file (org-babel-temp-file "latex-" ".tex"))
  93              (border (cdr (assoc :border params)))
  94              (imagemagick (cdr (assoc :imagemagick params)))
  95              (im-in-options (cdr (assoc :iminoptions params)))
  96              (im-out-options (cdr (assoc :imoutoptions params)))
  97              (pdfpng (cdr (assoc :pdfpng params)))
  98              (fit (or (cdr (assoc :fit params)) border))
  99              (height (and fit (cdr (assoc :pdfheight params))))
 100              (width (and fit (cdr (assoc :pdfwidth params))))
 101              (headers (cdr (assoc :headers params)))
 102              (in-buffer (not (string= "no" (cdr (assoc :buffer params)))))
 103              (org-latex-packages-alist
 104               (append (cdr (assoc :packages params)) org-latex-packages-alist)))
 105         (cond
 106          ((and (string-match "\\.png$" out-file) (not imagemagick))
 107           (org-create-formula-image
 108            body out-file org-format-latex-options in-buffer))
 109          ((string-match "\\.tikz$" out-file)
 110           (when (file-exists-p out-file) (delete-file out-file))
 111           (with-temp-file out-file
 112             (insert body)))
 113          ((and (or (string-match "\\.svg$" out-file)
 114                    (string-match "\\.html$" out-file))
 115                (executable-find org-babel-latex-htlatex))
 116           ;; TODO: this is a very different way of generating the
 117           ;; frame latex document than in the pdf case.  Ideally, both
 118           ;; would be unified.  This would prevent bugs creeping in
 119           ;; such as the one fixed on Aug 16 2014 whereby :headers was
 120           ;; not included in the SVG/HTML case.
 121           (with-temp-file tex-file
 122             (insert (concat
 123                      "\\documentclass[preview]{standalone}
 124 \\def\\pgfsysdriver{pgfsys-tex4ht.def}
 125 "
 126                      (mapconcat (lambda (pkg)
 127                                   (concat "\\usepackage" pkg))
 128                                 org-babel-latex-htlatex-packages
 129                                 "\n")
 130                      (if headers
 131                          (concat "\n"
 132                                  (if (listp headers)
 133                                      (mapconcat #'identity headers "\n")
 134                                    headers) "\n")
 135                        "")
 136                      "\\begin{document}"
 137                      body
 138                      "\\end{document}")))
 139           (when (file-exists-p out-file) (delete-file out-file))
 140           (let ((default-directory (file-name-directory tex-file)))
 141             (shell-command (format "%s %s" org-babel-latex-htlatex tex-file)))
 142           (cond
 143            ((file-exists-p (concat (file-name-sans-extension tex-file) "-1.svg"))
 144             (if (string-match "\\.svg$" out-file)
 145                 (progn
 146                   (shell-command "pwd")
 147                   (shell-command (format "mv %s %s"
 148                                          (concat (file-name-sans-extension tex-file) "-1.svg")
 149                                          out-file)))
 150               (error "SVG file produced but HTML file requested")))
 151            ((file-exists-p (concat (file-name-sans-extension tex-file) ".html"))
 152             (if (string-match "\\.html$" out-file)
 153                 (shell-command "mv %s %s"
 154                                (concat (file-name-sans-extension tex-file)
 155                                        ".html")
 156                                out-file)
 157               (error "HTML file produced but SVG file requested")))))
 158          ((or (string-match "\\.pdf$" out-file) imagemagick)
 159           (with-temp-file tex-file
 160             (require 'ox-latex)
 161             (insert
 162              (org-latex-guess-inputenc
 163               (org-splice-latex-header
 164                org-format-latex-header
 165                (delq
 166                 nil
 167                 (mapcar
 168                  (lambda (el)
 169                    (unless (and (listp el) (string= "hyperref" (cadr el)))
 170                      el))
 171                  org-latex-default-packages-alist))
 172                org-latex-packages-alist
 173                nil))
 174              (if fit "\n\\usepackage[active, tightpage]{preview}\n" "")
 175              (if border (format "\\setlength{\\PreviewBorder}{%s}" border) "")
 176              (if height (concat "\n" (format "\\pdfpageheight %s" height)) "")
 177              (if width  (concat "\n" (format "\\pdfpagewidth %s" width))   "")
 178              (if headers
 179                  (concat "\n"
 180                          (if (listp headers)
 181                              (mapconcat #'identity headers "\n")
 182                            headers) "\n")
 183                "")
 184              (if fit
 185                  (concat "\n\\begin{document}\n\\begin{preview}\n" body
 186                          "\n\\end{preview}\n\\end{document}\n")
 187                (concat "\n\\begin{document}\n" body "\n\\end{document}\n"))))
 188           (when (file-exists-p out-file) (delete-file out-file))
 189           (let ((transient-pdf-file (org-babel-latex-tex-to-pdf tex-file)))
 190             (cond
 191              ((string-match "\\.pdf$" out-file)
 192               (rename-file transient-pdf-file out-file))
 193              (imagemagick
 194               (org-babel-latex-convert-pdf
 195                transient-pdf-file out-file im-in-options im-out-options)
 196               (when (file-exists-p transient-pdf-file)
 197                 (delete-file transient-pdf-file))))))
 198          ((string-match "\\.\\([^\\.]+\\)$" out-file)
 199           (error "Can not create %s files, please specify a .png or .pdf file or try the :imagemagick header argument"
 200                  (match-string 1 out-file))))
 201         nil) ;; signal that output has already been written to file
 202     body))
 203
 204 (defun org-babel-latex-convert-pdf (pdffile out-file im-in-options im-out-options)
 205   "Generate a file from a pdf file using imagemagick."
 206   (let ((cmd (concat "convert " im-in-options " " pdffile " "
 207                      im-out-options " " out-file)))
 208     (message (concat "Converting pdffile file " cmd  "..."))
 209     (shell-command cmd)))
 210
 211 (defun org-babel-latex-tex-to-pdf (file)
 212   "Generate a pdf file according to the contents FILE."
 213   (require 'ox-latex)
 214   (org-latex-compile file))
 215
 216 (defun org-babel-prep-session:latex (session params)
 217   "Return an error because LaTeX doesn't support sessions."
 218   (error "LaTeX does not support sessions"))
 219
 220
 221 (provide 'ob-latex)
 222 ;;; ob-latex.el ends here