lisp/org-capture.el

   1 ;;; org-capture.el --- Fast note taking in Org-mode
   2
   3 ;; Copyright (C) 2010-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains an alternative implementation of the functionality
  28 ;; that used to be provided by org-remember.el.  The implementation is more
  29 ;; streamlined, can produce more target types (e.g. plain list items or
  30 ;; table lines).  Also, it does not use a temporary buffer for editing
  31 ;; the captured entry - instead it uses an indirect buffer that visits
  32 ;; the new entry already in the target buffer (this was an idea by Samuel
  33 ;; Wales).  John Wiegley's excellent `remember.el' is not needed anymore
  34 ;; for this implementation, even though we borrow heavily from its ideas.
  35
  36 ;; This implementation heavily draws on ideas by James TD Smith and
  37 ;; Samuel Wales, and, of cause, uses John Wiegley's remember.el as inspiration.
  38
  39 ;;; TODO
  40
  41 ;; - find a clever way to not always insert an annotation maybe a
  42 ;;   predicate function that can check for conditions for %a to be
  43 ;;   used.  This could be one of the properties.
  44
  45 ;; - Should there be plist members that arrange for properties to be
  46 ;;   asked for, like James proposed in his RFC?
  47
  48 ;;; Code:
  49
  50 (eval-when-compile
  51   (require 'cl))
  52 (require 'org)
  53
  54 (declare-function org-datetree-find-date-create "org-datetree"
  55                   (date &optional keep-restriction))
  56 (declare-function org-table-get-specials "org-table" ())
  57 (declare-function org-table-goto-line "org-table" (N))
  58 (declare-function org-pop-to-buffer-same-window "org-compat"
  59                   (&optional buffer-or-name norecord label))
  60 (declare-function org-at-encrypted-entry-p "org-crypt" ())
  61 (declare-function org-encrypt-entry "org-crypt" ())
  62 (declare-function org-decrypt-entry "org-crypt" ())
  63
  64 (defvar org-remember-default-headline)
  65 (defvar org-remember-templates)
  66 (defvar org-table-hlines)
  67 (defvar dired-buffers)
  68
  69 (defvar org-capture-clock-was-started nil
  70   "Internal flag, noting if the clock was started.")
  71
  72 (defvar org-capture-last-stored-marker (make-marker)
  73   "Marker pointing to the entry most recently stored with `org-capture'.")
  74
  75 ;; The following variable is scoped dynamically by org-protocol
  76 ;; to indicate that the link properties have already been stored
  77 (defvar org-capture-link-is-already-stored nil)
  78
  79 (defgroup org-capture nil
  80   "Options concerning capturing new entries."
  81   :tag "Org Capture"
  82   :group 'org)
  83
  84 (defcustom org-capture-templates nil
  85   "Templates for the creation of new entries.
  86
  87 Each entry is a list with the following items:
  88
  89 keys         The keys that will select the template, as a string, characters
  90              only, for example \"a\" for a template to be selected with a
  91              single key, or \"bt\" for selection with two keys.  When using
  92              several keys, keys using the same prefix key must be together
  93              in the list and preceded by a 2-element entry explaining the
  94              prefix key, for example
  95
  96                      (\"b\" \"Templates for marking stuff to buy\")
  97
  98              The \"C\" key is used by default for quick access to the
  99              customization of the template variable.  But if you want to use
 100              that key for a template, you can.
 101
 102 description  A short string describing the template, will be shown during
 103              selection.
 104
 105 type         The type of entry.  Valid types are:
 106                entry       an Org-mode node, with a headline.  Will be
 107                            filed as the child of the target entry or as
 108                            a top-level entry.
 109                item        a plain list item, will be placed in the
 110                            first plain list at the target
 111                            location.
 112                checkitem   a checkbox item.  This differs from the
 113                            plain list item only is so far as it uses a
 114                            different default template.
 115                table-line  a new line in the first table at target location.
 116                plain       text to be inserted as it is.
 117
 118 target       Specification of where the captured item should be placed.
 119              In Org-mode files, targets usually define a node.  Entries will
 120              become children of this node, other types will be added to the
 121              table or list in the body of this node.
 122
 123              Most target specifications contain a file name.  If that file
 124              name is the empty string, it defaults to `org-default-notes-file'.
 125              A file can also be given as a variable, function, or Emacs Lisp
 126              form.
 127
 128              Valid values are:
 129
 130              (file \"path/to/file\")
 131                  Text will be placed at the beginning or end of that file
 132
 133              (id \"id of existing org entry\")
 134                  File as child of this entry, or in the body of the entry
 135
 136              (file+headline \"path/to/file\" \"node headline\")
 137                  Fast configuration if the target heading is unique in the file
 138
 139              (file+olp \"path/to/file\" \"Level 1 heading\" \"Level 2\" ...)
 140                  For non-unique headings, the full path is safer
 141
 142              (file+regexp  \"path/to/file\" \"regexp to find location\")
 143                  File to the entry matching regexp
 144
 145              (file+datetree \"path/to/file\")
 146                  Will create a heading in a date tree for today's date
 147
 148              (file+datetree+prompt \"path/to/file\")
 149                  Will create a heading in a date tree, prompts for date
 150
 151              (file+function \"path/to/file\" function-finding-location)
 152                  A function to find the right location in the file
 153
 154              (clock)
 155                 File to the entry that is currently being clocked
 156
 157              (function function-finding-location)
 158                 Most general way, write your own function to find both
 159                 file and location
 160
 161 template     The template for creating the capture item.  If you leave this
 162              empty, an appropriate default template will be used.  See below
 163              for more details.  Instead of a string, this may also be one of
 164
 165                  (file \"/path/to/template-file\")
 166                  (function function-returning-the-template)
 167
 168              in order to get a template from a file, or dynamically
 169              from a function.
 170
 171 The rest of the entry is a property list of additional options.  Recognized
 172 properties are:
 173
 174  :prepend            Normally newly captured information will be appended at
 175                      the target location (last child, last table line,
 176                      last list item...).  Setting this property will
 177                      change that.
 178
 179  :immediate-finish   When set, do not offer to edit the information, just
 180                      file it away immediately.  This makes sense if the
 181                      template only needs information that can be added
 182                      automatically.
 183
 184  :jump-to-captured   When set, jump to the captured entry when finished.
 185
 186  :empty-lines        Set this to the number of lines the should be inserted
 187                      before and after the new item.  Default 0, only common
 188                      other value is 1.
 189
 190  :empty-lines-before Set this to the number of lines the should be inserted
 191                      before the new item.  Overrides :empty-lines for the
 192                      number lines inserted before.
 193
 194  :empty-lines-after  Set this to the number of lines the should be inserted
 195                      after the new item.  Overrides :empty-lines for the
 196                      number of lines inserted after.
 197
 198  :clock-in           Start the clock in this item.
 199
 200  :clock-keep         Keep the clock running when filing the captured entry.
 201
 202  :clock-resume       Start the interrupted clock when finishing the capture.
 203                      Note that :clock-keep has precedence over :clock-resume.
 204                      When setting both to `t', the current clock will run and
 205                      the previous one will not be resumed.
 206
 207  :unnarrowed         Do not narrow the target buffer, simply show the
 208                      full buffer.  Default is to narrow it so that you
 209                      only see the new stuff.
 210
 211  :table-line-pos     Specification of the location in the table where the
 212                      new line should be inserted.  It should be a string like
 213                      \"II-3\", meaning that the new line should become the
 214                      third line before the second horizontal separator line.
 215
 216  :kill-buffer        If the target file was not yet visited by a buffer when
 217                      capture was invoked, kill the buffer again after capture
 218                      is finalized.
 219
 220 The template defines the text to be inserted.  Often this is an
 221 org-mode entry (so the first line should start with a star) that
 222 will be filed as a child of the target headline.  It can also be
 223 freely formatted text.  Furthermore, the following %-escapes will
 224 be replaced with content and expanded in this order:
 225
 226   %[pathname] Insert the contents of the file given by `pathname'.
 227   %(sexp)     Evaluate elisp `(sexp)' and replace it with the results.
 228               For convenience, %:keyword (see below) placeholders within
 229               the expression will be expanded prior to this.
 230   %<...>      The result of format-time-string on the ... format specification.
 231   %t          Time stamp, date only.
 232   %T          Time stamp with date and time.
 233   %u, %U      Like the above, but inactive time stamps.
 234   %i          Initial content, copied from the active region.  If %i is
 235               indented, the entire inserted text will be indented as well.
 236   %a          Annotation, normally the link created with `org-store-link'.
 237   %A          Like %a, but prompt for the description part.
 238   %l          Like %a, but only insert the literal link.
 239   %c          Current kill ring head.
 240   %x          Content of the X clipboard.
 241   %k          Title of currently clocked task.
 242   %K          Link to currently clocked task.
 243   %n          User name (taken from the variable `user-full-name').
 244   %f          File visited by current buffer when org-capture was called.
 245   %F          Full path of the file or directory visited by current buffer.
 246   %:keyword   Specific information for certain link types, see below.
 247   %^g         Prompt for tags, with completion on tags in target file.
 248   %^G         Prompt for tags, with completion on all tags in all agenda files.
 249   %^t         Like %t, but prompt for date.  Similarly %^T, %^u, %^U.
 250               You may define a prompt like: %^{Please specify birthday}t
 251   %^C         Interactive selection of which kill or clip to use.
 252   %^L         Like %^C, but insert as link.
 253   %^{prop}p   Prompt the user for a value for property `prop'.
 254   %^{prompt}  Prompt the user for a string and replace this sequence with it.
 255               A default value and a completion table ca be specified like this:
 256               %^{prompt|default|completion2|completion3|...}.
 257   %?          After completing the template, position cursor here.
 258   %\\n         Insert the text entered at the nth %^{prompt}, where `n' is
 259               a number, starting from 1.
 260
 261 Apart from these general escapes, you can access information specific to
 262 the link type that is created.  For example, calling `org-capture' in emails
 263 or in Gnus will record the author and the subject of the message, which you
 264 can access with \"%:from\" and \"%:subject\", respectively.  Here is a
 265 complete list of what is recorded for each link type.
 266
 267 Link type               |  Available information
 268 ------------------------+------------------------------------------------------
 269 bbdb                    |  %:type %:name %:company
 270 vm, wl, mh, mew, rmail, |  %:type %:subject %:message-id
 271 gnus                    |  %:from %:fromname %:fromaddress
 272                         |  %:to   %:toname   %:toaddress
 273                         |  %:fromto (either \"to NAME\" or \"from NAME\")
 274                         |  %:date %:date-timestamp (as active timestamp)
 275                         |  %:date-timestamp-inactive (as inactive timestamp)
 276 gnus                    |  %:group, for messages also all email fields
 277 w3, w3m                 |  %:type %:url
 278 info                    |  %:type %:file %:node
 279 calendar                |  %:type %:date"
 280   :group 'org-capture
 281   :version "24.1"
 282   :type
 283   '(repeat
 284     (choice :value ("" "" entry (file "~/org/notes.org") "")
 285             (list :tag "Multikey description"
 286                   (string :tag "Keys       ")
 287                   (string :tag "Description"))
 288             (list :tag "Template entry"
 289                   (string :tag "Keys           ")
 290                   (string :tag "Description    ")
 291                   (choice :tag "Capture Type   " :value entry
 292                           (const :tag "Org entry" entry)
 293                           (const :tag "Plain list item" item)
 294                           (const :tag "Checkbox item" checkitem)
 295                           (const :tag "Plain text" plain)
 296                           (const :tag "Table line" table-line))
 297                   (choice :tag "Target location"
 298                           (list :tag "File"
 299                                 (const :format "" file)
 300                                 (file :tag "  File"))
 301                           (list :tag "ID"
 302                                 (const :format "" id)
 303                                 (string :tag "  ID"))
 304                           (list :tag "File & Headline"
 305                                 (const :format "" file+headline)
 306                                 (file   :tag "  File    ")
 307                                 (string :tag "  Headline"))
 308                           (list :tag "File & Outline path"
 309                                 (const :format "" file+olp)
 310                                 (file   :tag "  File    ")
 311                                 (repeat :tag "Outline path" :inline t
 312                                         (string :tag "Headline")))
 313                           (list :tag "File & Regexp"
 314                                 (const :format "" file+regexp)
 315                                 (file   :tag "  File  ")
 316                                 (regexp :tag "  Regexp"))
 317                           (list :tag "File & Date tree"
 318                                 (const :format "" file+datetree)
 319                                 (file :tag "  File"))
 320                           (list :tag "File & Date tree, prompt for date"
 321                                 (const :format "" file+datetree+prompt)
 322                                 (file :tag "  File"))
 323                           (list :tag "File & function"
 324                                 (const :format "" file+function)
 325                                 (file :tag "  File    ")
 326                                 (sexp :tag "  Function"))
 327                           (list :tag "Current clocking task"
 328                                 (const :format "" clock))
 329                           (list :tag "Function"
 330                                 (const :format "" function)
 331                                 (sexp :tag "  Function")))
 332                   (choice :tag "Template"
 333                           (string)
 334                           (list :tag "File"
 335                                 (const :format "" file)
 336                                 (file :tag "Template file"))
 337                           (list :tag "Function"
 338                                 (const :format "" function)
 339                                 (function :tag "Template function")))
 340                   (plist :inline t
 341                          ;; Give the most common options as checkboxes
 342                          :options (((const :format "%v " :prepend) (const t))
 343                                    ((const :format "%v " :immediate-finish) (const t))
 344                                    ((const :format "%v " :jump-to-captured) (const t))
 345                                    ((const :format "%v " :empty-lines) (const 1))
 346                                    ((const :format "%v " :empty-lines-before) (const 1))
 347                                    ((const :format "%v " :empty-lines-after) (const 1))
 348                                    ((const :format "%v " :clock-in) (const t))
 349                                    ((const :format "%v " :clock-keep) (const t))
 350                                    ((const :format "%v " :clock-resume) (const t))
 351                                    ((const :format "%v " :unnarrowed) (const t))
 352                                    ((const :format "%v " :table-line-pos) (const t))
 353                                    ((const :format "%v " :kill-buffer) (const t))))))))
 354
 355 (defcustom org-capture-before-finalize-hook nil
 356   "Hook that is run right before a capture process is finalized.
 357 The capture buffer is still current when this hook runs and it is
 358 widened to the entire buffer."
 359   :group 'org-capture
 360   :version "24.1"
 361   :type 'hook)
 362
 363 (defcustom org-capture-after-finalize-hook nil
 364   "Hook that is run right after a capture process is finalized.
 365 Suitable for window cleanup."
 366   :group 'org-capture
 367   :version "24.1"
 368   :type 'hook)
 369
 370 (defcustom org-capture-prepare-finalize-hook nil
 371   "Hook that is run before the finalization starts.
 372 The capture buffer is current and still narrowed."
 373   :group 'org-capture
 374   :version "24.1"
 375   :type 'hook)
 376
 377 (defcustom org-capture-bookmark t
 378   "When non-nil, add a bookmark pointing at the last stored
 379 position when capturing."
 380   :group 'org-capture
 381   :version "24.3"
 382   :type 'boolean)
 383
 384 ;;; The property list for keeping information about the capture process
 385
 386 (defvar org-capture-plist nil
 387   "Plist for the current capture process, global, to avoid having to pass it.")
 388
 389 (defvar org-capture-current-plist nil
 390   "Local variable holding the plist in a capture buffer.
 391 This is used to store the plist for use when finishing a capture process
 392 because another such process might have changed the global variable by then.
 393
 394 Each time a new capture buffer has been set up, the global `org-capture-plist'
 395 is copied to this variable, which is local in the indirect buffer.")
 396
 397 (defvar org-capture-clock-keep nil
 398   "Local variable to store the value of the :clock-keep parameter.
 399 This is needed in case org-capture-finalize is called interactively.")
 400
 401 (defun org-capture-put (&rest stuff)
 402   "Add properties to the capture property list `org-capture-plist'."
 403   (while stuff
 404     (setq org-capture-plist (plist-put org-capture-plist
 405                                        (pop stuff) (pop stuff)))))
 406 (defun org-capture-get (prop &optional local)
 407   "Get properties from the capture property list `org-capture-plist'.
 408 When LOCAL is set, use the local variable `org-capture-current-plist',
 409 this is necessary after initialization of the capture process,
 410 to avoid conflicts with other active capture processes."
 411   (plist-get (if local org-capture-current-plist org-capture-plist) prop))
 412
 413 (defun org-capture-member (prop &optional local)
 414   "Is PROP a property in `org-capture-plist'.
 415 When LOCAL is set, use the local variable `org-capture-current-plist',
 416 this is necessary after initialization of the capture process,
 417 to avoid conflicts with other active capture processes."
 418   (plist-get (if local org-capture-current-plist org-capture-plist) prop))
 419
 420 ;;; The minor mode
 421
 422 (defvar org-capture-mode-map (make-sparse-keymap)
 423   "Keymap for `org-capture-mode', a minor mode.
 424 Use this map to set additional keybindings for when Org-mode is used
 425 for a capture buffer.")
 426
 427 (defvar org-capture-mode-hook nil
 428   "Hook for the minor `org-capture-mode'.")
 429
 430 (define-minor-mode org-capture-mode
 431   "Minor mode for special key bindings in a capture buffer.
 432
 433 Turning on this mode runs the normal hook `org-capture-mode-hook'."
 434   nil " Rem" org-capture-mode-map
 435   (org-set-local
 436    'header-line-format
 437    "Capture buffer.  Finish `C-c C-c', refile `C-c C-w', abort `C-c C-k'."))
 438 (define-key org-capture-mode-map "\C-c\C-c" 'org-capture-finalize)
 439 (define-key org-capture-mode-map "\C-c\C-k" 'org-capture-kill)
 440 (define-key org-capture-mode-map "\C-c\C-w" 'org-capture-refile)
 441
 442 ;;; The main commands
 443
 444 (defvar org-capture-initial nil)
 445 (defvar org-capture-entry nil)
 446
 447 ;;;###autoload
 448 (defun org-capture-string (string &optional keys)
 449   "Capture STRING with the template selected by KEYS."
 450   (interactive "sInitial text: \n")
 451   (let ((org-capture-initial string)
 452         (org-capture-entry (org-capture-select-template keys)))
 453     (org-capture)))
 454
 455 (defcustom org-capture-templates-contexts nil
 456   "Alist of capture templates and valid contexts.
 457
 458 For example, if you have a capture template \"c\" and you want
 459 this template to be accessible only from `message-mode' buffers,
 460 use this:
 461
 462    '((\"c\" ((in-mode . \"message-mode\"))))
 463
 464 Here are the available contexts definitions:
 465
 466       in-file: command displayed only in matching files
 467       in-mode: command displayed only in matching modes
 468   not-in-file: command not displayed in matching files
 469   not-in-mode: command not displayed in matching modes
 470     in-buffer: command displayed only in matching buffers
 471 not-in-buffer: command not displayed in matching buffers
 472    [function]: a custom function taking no argument
 473
 474 If you define several checks, the agenda command will be
 475 accessible if there is at least one valid check.
 476
 477 You can also bind a key to another agenda custom command
 478 depending on contextual rules.
 479
 480     '((\"c\" \"d\" ((in-mode . \"message-mode\"))))
 481
 482 Here it means: in `message-mode buffers', use \"c\" as the
 483 key for the capture template otherwise associated with \"d\".
 484 \(The template originally associated with \"d\" is not displayed
 485 to avoid duplicates.)"
 486   :version "24.3"
 487   :group 'org-capture
 488   :type '(repeat (list :tag "Rule"
 489                        (string :tag "        Capture key")
 490                        (string :tag "Replace by template")
 491                        (repeat :tag "Available when"
 492                               (choice
 493                                (cons :tag "Condition"
 494                                      (choice
 495                                       (const :tag "In file" in-file)
 496                                       (const :tag "Not in file" not-in-file)
 497                                       (const :tag "In buffer" in-buffer)
 498                                       (const :tag "Not in buffer" not-in-buffer)
 499                                       (const :tag "In mode" in-mode)
 500                                       (const :tag "Not in mode" not-in-mode))
 501                                      (regexp))
 502                                (function :tag "Custom function"))))))
 503
 504 (defcustom org-capture-use-agenda-date nil
 505   "Non-nil means use the date at point when capturing from agendas.
 506 When nil, you can still capture using the date at point with \\[org-agenda-capture]."
 507   :group 'org-capture
 508   :version "24.3"
 509   :type 'boolean)
 510
 511 ;;;###autoload
 512 (defun org-capture (&optional goto keys)
 513   "Capture something.
 514 \\<org-capture-mode-map>
 515 This will let you select a template from `org-capture-templates', and then
 516 file the newly captured information.  The text is immediately inserted
 517 at the target location, and an indirect buffer is shown where you can
 518 edit it.  Pressing \\[org-capture-finalize] brings you back to the previous state
 519 of Emacs, so that you can continue your work.
 520
 521 When called interactively with a \\[universal-argument] prefix argument GOTO, don't capture
 522 anything, just go to the file/headline where the selected template
 523 stores its notes.  With a double prefix argument \
 524 \\[universal-argument] \\[universal-argument], go to the last note
 525 stored.
 526
 527 When called with a `C-0' (zero) prefix, insert a template at point.
 528
 529 ELisp programs can set KEYS to a string associated with a template
 530 in `org-capture-templates'.  In this case, interactive selection
 531 will be bypassed.
 532
 533 If `org-capture-use-agenda-date' is non-nil, capturing from the
 534 agenda will use the date at point as the default date.  Then, a
 535 `C-1' prefix will tell the capture process to use the HH:MM time
 536 of the day at point (if any) or the current HH:MM time."
 537   (interactive "P")
 538   (when (and org-capture-use-agenda-date
 539              (eq major-mode 'org-agenda-mode))
 540     (setq org-overriding-default-time
 541           (org-get-cursor-date (equal goto 1))))
 542   (cond
 543    ((equal goto '(4)) (org-capture-goto-target))
 544    ((equal goto '(16)) (org-capture-goto-last-stored))
 545    (t
 546     ;; FIXME: Are these needed?
 547     (let* ((orig-buf (current-buffer))
 548            (annotation (if (and (boundp 'org-capture-link-is-already-stored)
 549                                 org-capture-link-is-already-stored)
 550                            (plist-get org-store-link-plist :annotation)
 551                          (ignore-errors (org-store-link nil))))
 552            (entry (or org-capture-entry (org-capture-select-template keys)))
 553            initial)
 554       (setq initial (or org-capture-initial
 555                         (and (org-region-active-p)
 556                              (buffer-substring (point) (mark)))))
 557       (when (stringp initial)
 558         (remove-text-properties 0 (length initial) '(read-only t) initial))
 559       (when (stringp annotation)
 560         (remove-text-properties 0 (length annotation)
 561                                 '(read-only t) annotation))
 562       (cond
 563        ((equal entry "C")
 564         (customize-variable 'org-capture-templates))
 565        ((equal entry "q")
 566         (error "Abort"))
 567        (t
 568         (org-capture-set-plist entry)
 569         (org-capture-get-template)
 570         (org-capture-put :original-buffer orig-buf
 571                          :original-file (or (buffer-file-name orig-buf)
 572                                             (and (featurep 'dired)
 573                                                  (car (rassq orig-buf
 574                                                              dired-buffers))))
 575                          :original-file-nondirectory
 576                          (and (buffer-file-name orig-buf)
 577                               (file-name-nondirectory
 578                                (buffer-file-name orig-buf)))
 579                          :annotation annotation
 580                          :initial initial
 581                          :return-to-wconf (current-window-configuration)
 582                          :default-time
 583                          (or org-overriding-default-time
 584                              (org-current-time)))
 585         (org-capture-set-target-location)
 586         (condition-case error
 587             (org-capture-put :template (org-capture-fill-template))
 588           ((error quit)
 589            (if (get-buffer "*Capture*") (kill-buffer "*Capture*"))
 590            (error "Capture abort: %s" error)))
 591
 592         (setq org-capture-clock-keep (org-capture-get :clock-keep))
 593         (if (equal goto 0)
 594             ;;insert at point
 595             (org-capture-insert-template-here)
 596           (condition-case error
 597               (org-capture-place-template
 598                (equal (car (org-capture-get :target)) 'function))
 599             ((error quit)
 600              (if (and (buffer-base-buffer (current-buffer))
 601                       (string-match "\\`CAPTURE-" (buffer-name)))
 602                  (kill-buffer (current-buffer)))
 603              (set-window-configuration (org-capture-get :return-to-wconf))
 604              (error "Capture template `%s': %s"
 605                     (org-capture-get :key)
 606                     (nth 1 error))))
 607           (if (and (derived-mode-p 'org-mode)
 608                    (org-capture-get :clock-in))
 609               (condition-case nil
 610                   (progn
 611                     (if (org-clock-is-active)
 612                         (org-capture-put :interrupted-clock
 613                                          (copy-marker org-clock-marker)))
 614                     (org-clock-in)
 615                     (org-set-local 'org-capture-clock-was-started t))
 616                 (error
 617                  "Could not start the clock in this capture buffer")))
 618           (if (org-capture-get :immediate-finish)
 619               (org-capture-finalize)))))))))
 620
 621 (defun org-capture-get-template ()
 622   "Get the template from a file or a function if necessary."
 623   (let ((txt (org-capture-get :template)) file)
 624     (cond
 625      ((and (listp txt) (eq (car txt) 'file))
 626       (if (file-exists-p
 627            (setq file (expand-file-name (nth 1 txt) org-directory)))
 628           (setq txt (org-file-contents file))
 629         (setq txt (format "* Template file %s not found" (nth 1 txt)))))
 630      ((and (listp txt) (eq (car txt) 'function))
 631       (if (fboundp (nth 1 txt))
 632           (setq txt (funcall (nth 1 txt)))
 633         (setq txt (format "* Template function %s not found" (nth 1 txt)))))
 634      ((not txt) (setq txt ""))
 635      ((stringp txt))
 636      (t (setq txt "* Invalid capture template")))
 637     (org-capture-put :template txt)))
 638
 639 (defun org-capture-finalize (&optional stay-with-capture)
 640   "Finalize the capture process.
 641 With prefix argument STAY-WITH-CAPTURE, jump to the location of the
 642 captured item after finalizing."
 643   (interactive "P")
 644   (when (org-capture-get :jump-to-captured)
 645     (setq stay-with-capture t))
 646   (unless (and org-capture-mode
 647                (buffer-base-buffer (current-buffer)))
 648     (error "This does not seem to be a capture buffer for Org-mode"))
 649
 650   (run-hooks 'org-capture-prepare-finalize-hook)
 651
 652   ;; Did we start the clock in this capture buffer?
 653   (when (and org-capture-clock-was-started
 654              org-clock-marker (marker-buffer org-clock-marker)
 655              (equal (marker-buffer org-clock-marker) (buffer-base-buffer))
 656              (> org-clock-marker (point-min))
 657              (< org-clock-marker (point-max)))
 658     ;; Looks like the clock we started is still running.  Clock out.
 659     (when (not org-capture-clock-keep) (let (org-log-note-clock-out) (org-clock-out)))
 660     (when (and (not org-capture-clock-keep)
 661                (org-capture-get :clock-resume 'local)
 662                (markerp (org-capture-get :interrupted-clock 'local))
 663                (buffer-live-p (marker-buffer
 664                                (org-capture-get :interrupted-clock 'local))))
 665       (let ((clock-in-task (org-capture-get :interrupted-clock 'local)))
 666         (org-with-point-at clock-in-task
 667           (org-clock-in)))
 668       (message "Interrupted clock has been resumed")))
 669
 670   (let ((beg (point-min))
 671         (end (point-max))
 672         (abort-note nil))
 673     ;; Store the size of the capture buffer
 674     (org-capture-put :captured-entry-size (- (point-max) (point-min)))
 675     (widen)
 676     ;; Store the insertion point in the target buffer
 677     (org-capture-put :insertion-point (point))
 678
 679     (if org-note-abort
 680         (let ((m1 (org-capture-get :begin-marker 'local))
 681               (m2 (org-capture-get :end-marker 'local)))
 682           (if (and m1 m2 (= m1 beg) (= m2 end))
 683               (progn
 684                 (setq m2 (if (cdr (assoc 'heading org-blank-before-new-entry))
 685                              m2 (1+ m2))
 686                       m2 (if (< (point-max) m2) (point-max) m2))
 687                 (setq abort-note 'clean)
 688                 (kill-region m1 m2))
 689             (setq abort-note 'dirty)))
 690
 691       ;; Make sure that the empty lines after are correct
 692       (when (and (> (point-max) end) ; indeed, the buffer was still narrowed
 693                  (member (org-capture-get :type 'local)
 694                          '(entry item checkitem plain)))
 695         (save-excursion
 696           (goto-char end)
 697           (or (bolp) (newline))
 698           (org-capture-empty-lines-after
 699            (or (org-capture-get :empty-lines-after 'local)
 700                (org-capture-get :empty-lines 'local) 0))))
 701       ;; Postprocessing:  Update Statistics cookies, do the sorting
 702       (when (derived-mode-p 'org-mode)
 703         (save-excursion
 704           (when (ignore-errors (org-back-to-heading))
 705             (org-update-parent-todo-statistics)
 706             (org-update-checkbox-count)))
 707         ;; FIXME Here we should do the sorting
 708         ;; If we have added a table line, maybe recompute?
 709         (when (and (eq (org-capture-get :type 'local) 'table-line)
 710                    (org-at-table-p))
 711           (if (org-table-get-stored-formulas)
 712               (org-table-recalculate 'all) ;; FIXME: Should we iterate???
 713             (org-table-align))))
 714       ;; Store this place as the last one where we stored something
 715       ;; Do the marking in the base buffer, so that it makes sense after
 716       ;; the indirect buffer has been killed.
 717       (when org-capture-bookmark
 718         (org-capture-bookmark-last-stored-position))
 719
 720       ;; Run the hook
 721       (run-hooks 'org-capture-before-finalize-hook))
 722
 723     (when (org-capture-get :decrypted)
 724       (save-excursion
 725         (goto-char (org-capture-get :decrypted))
 726         (org-encrypt-entry)))
 727
 728     ;; Kill the indirect buffer
 729     (save-buffer)
 730     (let ((return-wconf (org-capture-get :return-to-wconf 'local))
 731           (new-buffer (org-capture-get :new-buffer 'local))
 732           (kill-buffer (org-capture-get :kill-buffer 'local))
 733           (base-buffer (buffer-base-buffer (current-buffer))))
 734
 735       ;; Kill the indirect buffer
 736       (kill-buffer (current-buffer))
 737
 738       ;; Narrow back the target buffer to its previous state
 739       (with-current-buffer (org-capture-get :buffer)
 740         (let ((reg (org-capture-get :initial-target-region))
 741               (pos (org-capture-get :initial-target-position))
 742               (ipt (org-capture-get :insertion-point))
 743               (size (org-capture-get :captured-entry-size)))
 744           (if (not reg)
 745               (widen)
 746             (cond ((< ipt (car reg))
 747                    ;; insertion point is before the narrowed region
 748                    (narrow-to-region (+ size (car reg)) (+ size (cdr reg))))
 749                   ((> ipt (cdr reg))
 750                    ;; insertion point is after the narrowed region
 751                    (narrow-to-region (car reg) (cdr reg)))
 752                   (t
 753                    ;; insertion point is within the narrowed region
 754                    (narrow-to-region (car reg) (+ size (cdr reg)))))
 755             ;; now place back the point at its original position
 756             (if (< ipt (car reg))
 757                 (goto-char (+ size pos))
 758               (goto-char (if (< ipt pos) (+ size pos) pos))))))
 759
 760       ;; Kill the target buffer if that is desired
 761       (when (and base-buffer new-buffer kill-buffer)
 762         (with-current-buffer base-buffer (save-buffer))
 763         (kill-buffer base-buffer))
 764
 765       ;; Restore the window configuration before capture
 766       (set-window-configuration return-wconf))
 767
 768     (run-hooks 'org-capture-after-finalize-hook)
 769     ;; Special cases
 770     (cond
 771      (abort-note
 772       (cond
 773        ((equal abort-note 'clean)
 774         (message "Capture process aborted and target buffer cleaned up"))
 775        ((equal abort-note 'dirty)
 776         (error "Capture process aborted, but target buffer could not be cleaned up correctly"))))
 777      (stay-with-capture
 778       (org-capture-goto-last-stored)))
 779     ;; Return if we did store something
 780     (not abort-note)))
 781
 782 (defun org-capture-refile ()
 783   "Finalize the current capture and then refile the entry.
 784 Refiling is done from the base buffer, because the indirect buffer is then
 785 already gone.  Any prefix argument will be passed to the refile command."
 786   (interactive)
 787   (unless (eq (org-capture-get :type 'local) 'entry)
 788     (error
 789      "Refiling from a capture buffer makes only sense for `entry'-type templates"))
 790   (let ((pos (point))
 791         (base (buffer-base-buffer (current-buffer)))
 792         (org-refile-for-capture t))
 793     (save-window-excursion
 794       (with-current-buffer (or base (current-buffer))
 795         (save-excursion
 796           (save-restriction
 797             (widen)
 798             (goto-char pos)
 799             (call-interactively 'org-refile)))))
 800     (org-capture-finalize)))
 801
 802 (defun org-capture-kill ()
 803   "Abort the current capture process."
 804   (interactive)
 805   ;; FIXME: This does not do the right thing, we need to remove the
 806   ;; new stuff by hand it is easy: undo, then kill the buffer
 807   (let ((org-note-abort t)
 808         (org-capture-before-finalize-hook nil))
 809     (org-capture-finalize)))
 810
 811 (defun org-capture-goto-last-stored ()
 812   "Go to the location where the last capture note was stored."
 813   (interactive)
 814   (org-goto-marker-or-bmk org-capture-last-stored-marker
 815                           (plist-get org-bookmark-names-plist
 816                                  :last-capture))
 817   (message "This is the last note stored by a capture process"))
 818
 819 ;;; Supporting functions for handling the process
 820
 821 (defun org-capture-put-target-region-and-position ()
 822   "Store the initial region with `org-capture-put'."
 823   (org-capture-put
 824    :initial-target-region
 825    ;; Check if the buffer is currently narrowed
 826    (when (org-buffer-narrowed-p)
 827      (cons (point-min) (point-max))))
 828   ;; store the current point
 829   (org-capture-put :initial-target-position (point)))
 830
 831 (defvar org-time-was-given) ; dynamically scoped parameter
 832 (defun org-capture-set-target-location (&optional target)
 833   "Find TARGET buffer and position.
 834 Store them in the capture property list."
 835   (let ((target-entry-p t) decrypted-hl-pos)
 836     (setq target (or target (org-capture-get :target)))
 837     (save-excursion
 838       (cond
 839        ((eq (car target) 'file)
 840         (set-buffer (org-capture-target-buffer (nth 1 target)))
 841         (org-capture-put-target-region-and-position)
 842         (widen)
 843         (setq target-entry-p nil))
 844
 845        ((eq (car target) 'id)
 846         (let ((loc (org-id-find (nth 1 target))))
 847           (if (not loc)
 848               (error "Cannot find target ID \"%s\"" (nth 1 target))
 849             (set-buffer (org-capture-target-buffer (car loc)))
 850             (widen)
 851             (org-capture-put-target-region-and-position)
 852             (goto-char (cdr loc)))))
 853
 854        ((eq (car target) 'file+headline)
 855         (set-buffer (org-capture-target-buffer (nth 1 target)))
 856         (org-capture-put-target-region-and-position)
 857         (widen)
 858         (let ((hd (nth 2 target)))
 859           (goto-char (point-min))
 860           (unless (derived-mode-p 'org-mode)
 861             (error
 862              "Target buffer \"%s\" for file+headline should be in Org mode"
 863              (current-buffer)))
 864           (if (re-search-forward
 865                (format org-complex-heading-regexp-format (regexp-quote hd))
 866                nil t)
 867               (goto-char (point-at-bol))
 868             (goto-char (point-max))
 869             (or (bolp) (insert "\n"))
 870             (insert "* " hd "\n")
 871             (beginning-of-line 0))))
 872
 873        ((eq (car target) 'file+olp)
 874         (let ((m (org-find-olp
 875                   (cons (org-capture-expand-file (nth 1 target))
 876                         (cddr target)))))
 877           (set-buffer (marker-buffer m))
 878           (org-capture-put-target-region-and-position)
 879           (widen)
 880           (goto-char m)))
 881
 882        ((eq (car target) 'file+regexp)
 883         (set-buffer (org-capture-target-buffer (nth 1 target)))
 884         (org-capture-put-target-region-and-position)
 885         (widen)
 886         (goto-char (point-min))
 887         (if (re-search-forward (nth 2 target) nil t)
 888             (progn
 889               (goto-char (if (org-capture-get :prepend)
 890                              (match-beginning 0) (match-end 0)))
 891               (org-capture-put :exact-position (point))
 892               (setq target-entry-p (and (derived-mode-p 'org-mode) (org-at-heading-p))))
 893           (error "No match for target regexp in file %s" (nth 1 target))))
 894
 895        ((memq (car target) '(file+datetree file+datetree+prompt))
 896         (require 'org-datetree)
 897         (set-buffer (org-capture-target-buffer (nth 1 target)))
 898         (org-capture-put-target-region-and-position)
 899         (widen)
 900         ;; Make a date tree entry, with the current date (or yesterday,
 901         ;; if we are extending dates for a couple of hours)
 902         (org-datetree-find-date-create
 903          (calendar-gregorian-from-absolute
 904           (cond
 905            (org-overriding-default-time
 906             ;; use the overriding default time
 907             (time-to-days org-overriding-default-time))
 908
 909            ((eq (car target) 'file+datetree+prompt)
 910             ;; prompt for date
 911             (let ((prompt-time (org-read-date
 912                                 nil t nil "Date for tree entry:"
 913                                 (current-time))))
 914               (org-capture-put
 915                :default-time
 916                (cond ((and (or (not (boundp 'org-time-was-given))
 917                                (not org-time-was-given))
 918                            (not (= (time-to-days prompt-time) (org-today))))
 919                       ;; Use 00:00 when no time is given for another date than today?
 920                       (apply 'encode-time (append '(0 0 0) (cdddr (decode-time prompt-time)))))
 921                      ((string-match "\\([^ ]+\\)--?[^ ]+[ ]+\\(.*\\)" org-read-date-final-answer)
 922                       ;; Replace any time range by its start
 923                       (apply 'encode-time
 924                              (org-read-date-analyze
 925                               (replace-match "\\1 \\2" nil nil org-read-date-final-answer)
 926                               prompt-time (decode-time prompt-time))))
 927                      (t prompt-time)))
 928               (time-to-days prompt-time)))
 929            (t
 930             ;; current date, possibly corrected for late night workers
 931             (org-today))))))
 932
 933        ((eq (car target) 'file+function)
 934         (set-buffer (org-capture-target-buffer (nth 1 target)))
 935         (org-capture-put-target-region-and-position)
 936         (widen)
 937         (funcall (nth 2 target))
 938         (org-capture-put :exact-position (point))
 939         (setq target-entry-p (and (derived-mode-p 'org-mode) (org-at-heading-p))))
 940
 941        ((eq (car target) 'function)
 942         (funcall (nth 1 target))
 943         (org-capture-put :exact-position (point))
 944         (setq target-entry-p (and (derived-mode-p 'org-mode) (org-at-heading-p))))
 945
 946        ((eq (car target) 'clock)
 947         (if (and (markerp org-clock-hd-marker)
 948                  (marker-buffer org-clock-hd-marker))
 949             (progn (set-buffer (marker-buffer org-clock-hd-marker))
 950                    (org-capture-put-target-region-and-position)
 951                    (widen)
 952                    (goto-char org-clock-hd-marker))
 953           (error "No running clock that could be used as capture target")))
 954
 955        (t (error "Invalid capture target specification")))
 956
 957       (when (and (featurep 'org-crypt) (org-at-encrypted-entry-p))
 958         (org-decrypt-entry)
 959         (setq decrypted-hl-pos
 960               (save-excursion (and (org-back-to-heading t) (point)))))
 961
 962       (org-capture-put :buffer (current-buffer) :pos (point)
 963                        :target-entry-p target-entry-p
 964                        :decrypted decrypted-hl-pos))))
 965
 966 (defun org-capture-expand-file (file)
 967   "Expand functions and symbols for FILE.
 968 When FILE is a function, call it.  When it is a form, evaluate
 969 it.  When it is a variable, retrieve the value.  Return whatever we get."
 970   (cond
 971    ((org-string-nw-p file) file)
 972    ((functionp file) (funcall file))
 973    ((and (symbolp file) (boundp file)) (symbol-value file))
 974    ((and file (consp file)) (eval file))
 975    (t file)))
 976
 977 (defun org-capture-target-buffer (file)
 978   "Get a buffer for FILE."
 979   (setq file (org-capture-expand-file file))
 980   (setq file (or (org-string-nw-p file)
 981                  org-default-notes-file
 982                  (error "No notes file specified, and no default available")))
 983   (or (org-find-base-buffer-visiting file)
 984       (progn (org-capture-put :new-buffer t)
 985              (find-file-noselect (expand-file-name file org-directory)))))
 986
 987 (defun org-capture-steal-local-variables (buffer)
 988   "Install Org-mode local variables of BUFFER."
 989   (mapc (lambda (v)
 990           (ignore-errors (org-set-local (car v) (cdr v))))
 991         (buffer-local-variables buffer)))
 992
 993 (defun org-capture-place-template (&optional inhibit-wconf-store)
 994   "Insert the template at the target location, and display the buffer.
 995 When `inhibit-wconf-store', don't store the window configuration, as it
 996 may have been stored before."
 997   (unless inhibit-wconf-store
 998     (org-capture-put :return-to-wconf (current-window-configuration)))
 999   (delete-other-windows)
1000   (org-switch-to-buffer-other-window
1001    (org-capture-get-indirect-buffer (org-capture-get :buffer) "CAPTURE"))
1002   (widen)
1003   (show-all)
1004   (goto-char (org-capture-get :pos))
1005   (org-set-local 'org-capture-target-marker
1006                  (point-marker))
1007   (org-set-local 'outline-level 'org-outline-level)
1008   (let* ((template (org-capture-get :template))
1009          (type (org-capture-get :type)))
1010     (case type
1011       ((nil entry) (org-capture-place-entry))
1012       (table-line (org-capture-place-table-line))
1013       (plain (org-capture-place-plain-text))
1014       (item (org-capture-place-item))
1015       (checkitem (org-capture-place-item))))
1016   (org-capture-mode 1)
1017   (org-set-local 'org-capture-current-plist org-capture-plist))
1018
1019 (defun org-capture-place-entry ()
1020   "Place the template as a new Org entry."
1021   (let* ((txt (org-capture-get :template))
1022          (reversed (org-capture-get :prepend))
1023          (target-entry-p (org-capture-get :target-entry-p))
1024          level beg end file)
1025
1026     (and (org-capture-get :exact-position)
1027          (goto-char (org-capture-get :exact-position)))
1028     (cond
1029      ((not target-entry-p)
1030       ;; Insert as top-level entry, either at beginning or at end of file
1031       (setq level 1)
1032       (if reversed
1033           (progn (goto-char (point-min))
1034                  (or (org-at-heading-p)
1035                      (outline-next-heading)))
1036         (goto-char (point-max))
1037         (or (bolp) (insert "\n"))))
1038      (t
1039       ;; Insert as a child of the current entry
1040       (and (looking-at "\\*+")
1041            (setq level (- (match-end 0) (match-beginning 0))))
1042       (setq level (org-get-valid-level (or level 1) 1))
1043       (if reversed
1044           (progn
1045             (outline-next-heading)
1046             (or (bolp) (insert "\n")))
1047         (org-end-of-subtree t nil)
1048         (or (bolp) (insert "\n")))))
1049     (org-capture-empty-lines-before)
1050     (setq beg (point))
1051     (org-capture-verify-tree txt)
1052     (org-paste-subtree level txt 'for-yank)
1053     (org-capture-empty-lines-after 1)
1054     (org-capture-position-for-last-stored beg)
1055     (outline-next-heading)
1056     (setq end (point))
1057     (org-capture-mark-kill-region beg (1- end))
1058     (org-capture-narrow beg (1- end))
1059     (if (or (re-search-backward "%\\?" beg t)
1060             (re-search-forward "%\\?" end t))
1061         (replace-match ""))))
1062
1063 (defun org-capture-place-item ()
1064   "Place the template as a new plain list item."
1065   (let* ((txt (org-capture-get :template))
1066          (target-entry-p (org-capture-get :target-entry-p))
1067          (ind 0)
1068          beg end)
1069     (if (org-capture-get :exact-position)
1070         (goto-char (org-capture-get :exact-position))
1071       (cond
1072        ((not target-entry-p)
1073         ;; Insert as top-level entry, either at beginning or at end of file
1074         (setq beg (point-min) end (point-max)))
1075        (t
1076         (setq beg (1+ (point-at-eol))
1077               end (save-excursion (outline-next-heading) (point)))))
1078       (if (org-capture-get :prepend)
1079           (progn
1080             (goto-char beg)
1081             (if (org-list-search-forward (org-item-beginning-re) end t)
1082                 (progn
1083                   (goto-char (match-beginning 0))
1084                   (setq ind (org-get-indentation)))
1085               (goto-char end)
1086               (setq ind 0)))
1087         (goto-char end)
1088         (if (org-list-search-backward (org-item-beginning-re) beg t)
1089             (progn
1090               (setq ind (org-get-indentation))
1091               (org-end-of-item))
1092           (setq ind 0))))
1093     ;; Remove common indentation
1094     (setq txt (org-remove-indentation txt))
1095     ;; Make sure this is indeed an item
1096     (unless (string-match (concat "\\`" (org-item-re)) txt)
1097       (setq txt (concat "- "
1098                         (mapconcat 'identity (split-string txt "\n")
1099                                    "\n  "))))
1100     ;; Set the correct indentation, depending on context
1101     (setq ind (make-string ind ?\ ))
1102     (setq txt (concat ind
1103                       (mapconcat 'identity (split-string txt "\n")
1104                                  (concat "\n" ind))
1105                       "\n"))
1106     ;; Insert, with surrounding empty lines
1107     (org-capture-empty-lines-before)
1108     (setq beg (point))
1109     (insert txt)
1110     (or (bolp) (insert "\n"))
1111     (org-capture-empty-lines-after 1)
1112     (org-capture-position-for-last-stored beg)
1113     (forward-char 1)
1114     (setq end (point))
1115     (org-capture-mark-kill-region beg (1- end))
1116     (org-capture-narrow beg (1- end))
1117     (if (or (re-search-backward "%\\?" beg t)
1118             (re-search-forward "%\\?" end t))
1119         (replace-match ""))))
1120
1121 (defun org-capture-place-table-line ()
1122   "Place the template as a table line."
1123   (require 'org-table)
1124   (let* ((txt (org-capture-get :template))
1125          (target-entry-p (org-capture-get :target-entry-p))
1126          (table-line-pos (org-capture-get :table-line-pos))
1127          ind beg end)
1128     (cond
1129      ((org-capture-get :exact-position)
1130       (goto-char (org-capture-get :exact-position)))
1131      ((not target-entry-p)
1132       ;; Table is not necessarily under a heading
1133       (setq beg (point-min) end (point-max)))
1134      (t
1135       ;; WE are at a heading, limit search to the body
1136       (setq beg (1+ (point-at-eol))
1137             end (save-excursion (outline-next-heading) (point)))))
1138     (if (re-search-forward org-table-dataline-regexp end t)
1139         (let ((b (org-table-begin)) (e (org-table-end)) (case-fold-search t))
1140           (goto-char e)
1141           (if (looking-at "[ \t]*#\\+tblfm:")
1142               (forward-line 1))
1143           (narrow-to-region b (point)))
1144       (goto-char end)
1145       (insert "\n|   |\n|----|\n|    |\n")
1146       (narrow-to-region (1+ end) (point)))
1147     ;; We are narrowed to the table, or to an empty line if there was no table
1148
1149     ;; Check if the template is good
1150     (if (not (string-match org-table-dataline-regexp txt))
1151         (setq txt "| %?Bad template |\n"))
1152     (if (functionp table-line-pos)
1153         (setq table-line-pos (funcall table-line-pos))
1154       (setq table-line-pos (eval table-line-pos)))
1155     (cond
1156      ((and table-line-pos
1157            (string-match "\\(I+\\)\\([-+][0-9]\\)" table-line-pos))
1158       ;; we have a complex line specification
1159       (goto-char (point-min))
1160       (let ((nh (- (match-end 1) (match-beginning 1)))
1161             (delta (string-to-number (match-string 2 table-line-pos)))
1162             ll)
1163         ;; The user wants a special position in the table
1164         (org-table-get-specials)
1165         (setq ll (ignore-errors (aref org-table-hlines nh)))
1166         (unless ll (error "Invalid table line specification \"%s\""
1167                           table-line-pos))
1168         (setq ll (+ ll delta (if (< delta 0) 0 -1)))
1169         (org-goto-line ll)
1170         (org-table-insert-row 'below)
1171         (beginning-of-line 1)
1172         (delete-region (point) (1+ (point-at-eol)))
1173         (setq beg (point))
1174         (insert txt)
1175         (setq end (point))))
1176      ((org-capture-get :prepend)
1177       (goto-char (point-min))
1178       (re-search-forward org-table-hline-regexp nil t)
1179       (beginning-of-line 1)
1180       (re-search-forward org-table-dataline-regexp nil t)
1181       (beginning-of-line 1)
1182       (setq beg (point))
1183       (org-table-insert-row)
1184       (beginning-of-line 1)
1185       (delete-region (point) (1+ (point-at-eol)))
1186       (insert txt)
1187       (setq end (point)))
1188      (t
1189       (goto-char (point-max))
1190       (re-search-backward org-table-dataline-regexp nil t)
1191       (beginning-of-line 1)
1192       (org-table-insert-row 'below)
1193       (beginning-of-line 1)
1194       (delete-region (point) (1+ (point-at-eol)))
1195       (setq beg (point))
1196       (insert txt)
1197       (setq end (point))))
1198     (goto-char beg)
1199     (org-capture-position-for-last-stored 'table-line)
1200     (if (or (re-search-backward "%\\?" beg t)
1201             (re-search-forward "%\\?" end t))
1202         (replace-match ""))
1203     (org-table-align)))
1204
1205 (defun org-capture-place-plain-text ()
1206   "Place the template plainly.
1207 If the target locator points at an Org node, place the template into
1208 the text of the entry, before the first child.  If not, place the
1209 template at the beginning or end of the file.
1210 Of course, if exact position has been required, just put it there."
1211   (let* ((txt (org-capture-get :template))
1212          beg end)
1213     (cond
1214      ((org-capture-get :exact-position)
1215       (goto-char (org-capture-get :exact-position)))
1216      ((and (org-capture-get :target-entry-p)
1217            (bolp)
1218            (looking-at org-outline-regexp))
1219       ;; we should place the text into this entry
1220       (if (org-capture-get :prepend)
1221           ;; Skip meta data and drawers
1222           (org-end-of-meta-data-and-drawers)
1223         ;; go to ent of the entry text, before the next headline
1224         (outline-next-heading)))
1225      (t
1226       ;; beginning or end of file
1227       (goto-char (if (org-capture-get :prepend) (point-min) (point-max)))))
1228     (or (bolp) (newline))
1229     (org-capture-empty-lines-before)
1230     (setq beg (point))
1231     (insert txt)
1232     (org-capture-empty-lines-after 1)
1233     (org-capture-position-for-last-stored beg)
1234     (setq end (point))
1235     (org-capture-mark-kill-region beg (1- end))
1236     (org-capture-narrow beg (1- end))
1237     (if (or (re-search-backward "%\\?" beg t)
1238             (re-search-forward "%\\?" end t))
1239         (replace-match ""))))
1240
1241 (defun org-capture-mark-kill-region (beg end)
1242   "Mark the region that will have to be killed when aborting capture."
1243   (let ((m1 (move-marker (make-marker) beg))
1244         (m2 (move-marker (make-marker) end)))
1245     (org-capture-put :begin-marker m1)
1246     (org-capture-put :end-marker m2)))
1247
1248 (defun org-capture-position-for-last-stored (where)
1249   "Memorize the position that should later become the position of last capture."
1250   (cond
1251    ((integerp where)
1252     (org-capture-put :position-for-last-stored
1253                      (move-marker (make-marker) where
1254                                   (or (buffer-base-buffer (current-buffer))
1255                                       (current-buffer)))))
1256    ((eq where 'table-line)
1257     (org-capture-put :position-for-last-stored
1258                      (list 'table-line
1259                            (org-table-current-dline))))
1260    (t (error "This should not happen"))))
1261
1262 (defun org-capture-bookmark-last-stored-position ()
1263   "Bookmark the last-captured position."
1264   (let* ((where (org-capture-get :position-for-last-stored 'local))
1265          (pos (cond
1266                ((markerp where)
1267                 (prog1 (marker-position where)
1268                   (move-marker where nil)))
1269                ((and (listp where) (eq (car where) 'table-line))
1270                 (if (org-at-table-p)
1271                     (save-excursion
1272                       (org-table-goto-line (nth 1 where))
1273                       (point-at-bol))
1274                   (point))))))
1275     (with-current-buffer (buffer-base-buffer (current-buffer))
1276       (save-excursion
1277         (save-restriction
1278           (widen)
1279           (goto-char pos)
1280           (let ((bookmark-name (plist-get org-bookmark-names-plist
1281                                           :last-capture)))
1282             (when bookmark-name
1283               (with-demoted-errors
1284                 (bookmark-set bookmark-name))))
1285           (move-marker org-capture-last-stored-marker (point)))))))
1286
1287 (defun org-capture-narrow (beg end)
1288   "Narrow, unless configuration says not to narrow."
1289   (unless (org-capture-get :unnarrowed)
1290     (narrow-to-region beg end)
1291     (goto-char beg)))
1292
1293 (defun org-capture-empty-lines-before (&optional n)
1294   "Set the correct number of empty lines before the insertion point.
1295 Point will be after the empty lines, so insertion can directly be done."
1296   (setq n (or n (org-capture-get :empty-lines-before)
1297               (org-capture-get :empty-lines) 0))
1298   (let ((pos (point)))
1299     (org-back-over-empty-lines)
1300     (delete-region (point) pos)
1301     (if (> n 0) (newline n))))
1302
1303 (defun org-capture-empty-lines-after (&optional n)
1304   "Set the correct number of empty lines after the inserted string.
1305 Point will remain at the first line after the inserted text."
1306   (setq n (or n (org-capture-get :empty-lines-after)
1307               (org-capture-get :empty-lines) 0))
1308   (org-back-over-empty-lines)
1309   (while (looking-at "[ \t]*\n") (replace-match ""))
1310   (let ((pos (point)))
1311     (if (> n 0) (newline n))
1312     (goto-char pos)))
1313
1314 (defvar org-clock-marker) ; Defined in org.el
1315
1316 (defun org-capture-insert-template-here ()
1317   "Insert the capture template at point."
1318   (let* ((template (org-capture-get :template))
1319          (type  (org-capture-get :type))
1320          beg end pp)
1321     (or (bolp) (newline))
1322     (setq beg (point))
1323     (cond
1324      ((and (eq type 'entry) (derived-mode-p 'org-mode))
1325       (org-capture-verify-tree (org-capture-get :template))
1326       (org-paste-subtree nil template t))
1327      ((and (memq type '(item checkitem))
1328            (derived-mode-p 'org-mode)
1329            (save-excursion (skip-chars-backward " \t\n")
1330                            (setq pp (point))
1331                            (org-in-item-p)))
1332       (goto-char pp)
1333       (org-insert-item)
1334       (skip-chars-backward " ")
1335       (skip-chars-backward "-+*0123456789).")
1336       (delete-region (point) (point-at-eol))
1337       (setq beg (point))
1338       (org-remove-indentation template)
1339       (insert template)
1340       (org-capture-empty-lines-after)
1341       (goto-char beg)
1342       (org-list-repair)
1343       (org-end-of-item)
1344       (setq end (point)))
1345      (t (insert template)))
1346     (setq end (point))
1347     (goto-char beg)
1348     (if (re-search-forward "%\\?" end t)
1349         (replace-match ""))))
1350
1351 (defun org-capture-set-plist (entry)
1352   "Initialize the property list from the template definition."
1353   (setq org-capture-plist (copy-sequence (nthcdr 5 entry)))
1354   (org-capture-put :key (car entry) :description (nth 1 entry)
1355                    :target (nth 3 entry))
1356   (let ((txt (nth 4 entry)) (type (or (nth 2 entry) 'entry)))
1357     (when (or (not txt) (and (stringp txt) (not (string-match "\\S-" txt))))
1358       ;; The template may be empty or omitted for special types.
1359       ;; Here we insert the default templates for such cases.
1360       (cond
1361        ((eq type 'item) (setq txt "- %?"))
1362        ((eq type 'checkitem) (setq txt "- [ ] %?"))
1363        ((eq type 'table-line) (setq txt "| %? |"))
1364        ((member type '(nil entry)) (setq txt "* %?\n  %a"))))
1365     (org-capture-put :template txt :type type)))
1366
1367 (defun org-capture-goto-target (&optional template-key)
1368   "Go to the target location of a capture template.
1369 The user is queried for the template."
1370   (interactive)
1371   (let* (org-select-template-temp-major-mode
1372          (entry (org-capture-select-template template-key)))
1373     (unless entry
1374       (error "No capture template selected"))
1375     (org-capture-set-plist entry)
1376     (org-capture-set-target-location)
1377     (org-pop-to-buffer-same-window (org-capture-get :buffer))
1378     (goto-char (org-capture-get :pos))))
1379
1380 (defun org-capture-get-indirect-buffer (&optional buffer prefix)
1381   "Make an indirect buffer for a capture process.
1382 Use PREFIX as a prefix for the name of the indirect buffer."
1383   (setq buffer (or buffer (current-buffer)))
1384   (let ((n 1) (base (buffer-name buffer)) bname)
1385     (setq bname (concat prefix "-" base))
1386     (while (buffer-live-p (get-buffer bname))
1387       (setq bname (concat prefix "-" (number-to-string (incf n)) "-" base)))
1388     (condition-case nil
1389         (make-indirect-buffer buffer bname 'clone)
1390       (error
1391        (let ((buf (make-indirect-buffer buffer bname)))
1392          (with-current-buffer buf (org-mode))
1393          buf)))))
1394
1395 (defun org-capture-verify-tree (tree)
1396   "Throw error if TREE is not a valid tree."
1397   (unless (org-kill-is-subtree-p tree)
1398     (error "Template is not a valid Org entry or tree")))
1399
1400 (defun org-mks (table title &optional prompt specials)
1401   "Select a member of an alist with multiple keys.
1402 TABLE is the alist which should contain entries where the car is a string.
1403 There should be two types of entries.
1404
1405 1. prefix descriptions like (\"a\" \"Description\")
1406    This indicates that `a' is a prefix key for multi-letter selection, and
1407    that there are entries following with keys like \"ab\", \"ax\"...
1408
1409 2. Selectable members must have more than two elements, with the first
1410    being the string of keys that lead to selecting it, and the second a
1411    short description string of the item.
1412
1413 The command will then make a temporary buffer listing all entries
1414 that can be selected with a single key, and all the single key
1415 prefixes.  When you press the key for a single-letter entry, it is selected.
1416 When you press a prefix key, the commands (and maybe further prefixes)
1417 under this key will be shown and offered for selection.
1418
1419 TITLE will be placed over the selection in the temporary buffer,
1420 PROMPT will be used when prompting for a key.  SPECIAL is an alist with
1421 also (\"key\" \"description\") entries.  When one of these is selection,
1422 only the bare key is returned."
1423   (setq prompt (or prompt "Select: "))
1424   (let (tbl orig-table dkey ddesc des-keys allowed-keys
1425             current prefix rtn re pressed buffer (inhibit-quit t))
1426     (save-window-excursion
1427       (setq buffer (org-switch-to-buffer-other-window "*Org Select*"))
1428       (setq orig-table table)
1429       (catch 'exit
1430         (while t
1431           (erase-buffer)
1432           (insert title "\n\n")
1433           (setq tbl table
1434                 des-keys nil
1435                 allowed-keys nil
1436                 cursor-type nil)
1437           (setq prefix (if current (concat current " ") ""))
1438           (while tbl
1439             (cond
1440              ((and (= 2 (length (car tbl))) (= (length (caar tbl)) 1))
1441               ;; This is a description on this level
1442               (setq dkey (caar tbl) ddesc (cadar tbl))
1443               (pop tbl)
1444               (push dkey des-keys)
1445               (push dkey allowed-keys)
1446               (insert prefix "[" dkey "]" "..." "  " ddesc "..." "\n")
1447               ;; Skip keys which are below this prefix
1448               (setq re (concat "\\`" (regexp-quote dkey)))
1449               (let (case-fold-search)
1450                 (while (and tbl (string-match re (caar tbl))) (pop tbl))))
1451              ((= 2 (length (car tbl)))
1452               ;; Not yet a usable description, skip it
1453               )
1454              (t
1455               ;; usable entry on this level
1456               (insert prefix "[" (caar tbl) "]" "     " (nth 1 (car tbl)) "\n")
1457               (push (caar tbl) allowed-keys)
1458               (pop tbl))))
1459           (when specials
1460             (insert "-------------------------------------------------------------------------------\n")
1461             (let ((sp specials))
1462               (while sp
1463                 (insert (format "[%s]     %s\n"
1464                                 (caar sp) (nth 1 (car sp))))
1465                 (push (caar sp) allowed-keys)
1466                 (pop sp))))
1467           (push "\C-g" allowed-keys)
1468           (goto-char (point-min))
1469           (if (not (pos-visible-in-window-p (point-max)))
1470               (org-fit-window-to-buffer))
1471           (message prompt)
1472           (setq pressed (char-to-string (read-char-exclusive)))
1473           (while (not (member pressed allowed-keys))
1474             (message "Invalid key `%s'" pressed) (sit-for 1)
1475             (message prompt)
1476             (setq pressed (char-to-string (read-char-exclusive))))
1477           (when (equal pressed "\C-g")
1478             (kill-buffer buffer)
1479             (error "Abort"))
1480           (when (and (not (assoc pressed table))
1481                      (not (member pressed des-keys))
1482                      (assoc pressed specials))
1483             (throw 'exit (setq rtn pressed)))
1484           (unless (member pressed des-keys)
1485             (throw 'exit (setq rtn (rassoc (cdr (assoc pressed table))
1486                                            orig-table))))
1487           (setq current (concat current pressed))
1488           (setq table (mapcar
1489                        (lambda (x)
1490                          (if (and (> (length (car x)) 1)
1491                                   (equal (substring (car x) 0 1) pressed))
1492                              (cons (substring (car x) 1) (cdr x))
1493                            nil))
1494                        table))
1495           (setq table (remove nil table)))))
1496     (when buffer (kill-buffer buffer))
1497     rtn))
1498
1499 ;;; The template code
1500 (defun org-capture-select-template (&optional keys)
1501   "Select a capture template.
1502 Lisp programs can force the template by setting KEYS to a string."
1503   (let ((org-capture-templates
1504          (or (org-contextualize-keys
1505               org-capture-templates org-capture-templates-contexts)
1506              '(("t" "Task" entry (file+headline "" "Tasks")
1507                 "* TODO %?\n  %u\n  %a")))))
1508     (if keys
1509         (or (assoc keys org-capture-templates)
1510             (error "No capture template referred to by \"%s\" keys" keys))
1511       (org-mks org-capture-templates
1512                "Select a capture template\n========================="
1513                "Template key: "
1514                '(("C" "Customize org-capture-templates")
1515                  ("q" "Abort"))))))
1516
1517 (defun org-capture-fill-template (&optional template initial annotation)
1518   "Fill a template and return the filled template as a string.
1519 The template may still contain \"%?\" for cursor positioning."
1520   (setq template (or template (org-capture-get :template)))
1521   (when (stringp initial)
1522     (setq initial (org-no-properties initial)))
1523   (let* ((buffer (org-capture-get :buffer))
1524          (file (buffer-file-name (or (buffer-base-buffer buffer) buffer)))
1525          (ct (org-capture-get :default-time))
1526          (dct (decode-time ct))
1527          (ct1
1528           (if (< (nth 2 dct) org-extend-today-until)
1529               (encode-time 0 59 23 (1- (nth 3 dct)) (nth 4 dct) (nth 5 dct))
1530             ct))
1531          (plist-p (if org-store-link-plist t nil))
1532          (v-c (and (> (length kill-ring) 0) (current-kill 0)))
1533          (v-x (or (org-get-x-clipboard 'PRIMARY)
1534                   (org-get-x-clipboard 'CLIPBOARD)
1535                   (org-get-x-clipboard 'SECONDARY)))
1536          (v-t (format-time-string (car org-time-stamp-formats) ct))
1537          (v-T (format-time-string (cdr org-time-stamp-formats) ct))
1538          (v-u (concat "[" (substring v-t 1 -1) "]"))
1539          (v-U (concat "[" (substring v-T 1 -1) "]"))
1540          ;; `initial' and `annotation' might habe been passed.
1541          ;; But if the property list has them, we prefer those values
1542          (v-i (or (plist-get org-store-link-plist :initial)
1543                   initial
1544                   (org-capture-get :initial)
1545                   ""))
1546          (v-a (or (plist-get org-store-link-plist :annotation)
1547                   annotation
1548                   (org-capture-get :annotation)
1549                   ""))
1550          ;; Is the link empty?  Then we do not want it...
1551          (v-a (if (equal v-a "[[]]") "" v-a))
1552          (clipboards (remove nil (list v-i
1553                                        (org-get-x-clipboard 'PRIMARY)
1554                                        (org-get-x-clipboard 'CLIPBOARD)
1555                                        (org-get-x-clipboard 'SECONDARY)
1556                                        v-c)))
1557          (l-re "\\[\\[\\(.*?\\)\\]\\(\\[.*?\\]\\)?\\]")
1558          (v-A (if (and v-a (string-match l-re v-a))
1559                   (replace-match "[[\\1][%^{Link description}]]" nil nil v-a)
1560                 v-a))
1561          (v-l (if (and v-a (string-match l-re v-a))
1562                   (replace-match "\\1" nil nil v-a)
1563                 v-a))
1564          (v-n user-full-name)
1565          (v-k (if (marker-buffer org-clock-marker)
1566                   (org-no-properties org-clock-heading)))
1567          (v-K (if (marker-buffer org-clock-marker)
1568                   (org-make-link-string
1569                    (buffer-file-name (marker-buffer org-clock-marker))
1570                    org-clock-heading)))
1571          (v-f (or (org-capture-get :original-file-nondirectory) ""))
1572          (v-F (or (org-capture-get :original-file) ""))
1573          v-I
1574          (org-startup-folded nil)
1575          (org-inhibit-startup t)
1576          org-time-was-given org-end-time-was-given x
1577          prompt completions char time pos default histvar strings)
1578
1579     (setq org-store-link-plist
1580           (plist-put org-store-link-plist :annotation v-a)
1581           org-store-link-plist
1582           (plist-put org-store-link-plist :initial v-i))
1583     (setq initial v-i)
1584
1585     (unless template (setq template "") (message "No template") (ding)
1586             (sit-for 1))
1587     (save-window-excursion
1588       (delete-other-windows)
1589       (org-pop-to-buffer-same-window (get-buffer-create "*Capture*"))
1590       (erase-buffer)
1591       (insert template)
1592       (goto-char (point-min))
1593       (org-capture-steal-local-variables buffer)
1594       (setq buffer-file-name nil mark-active nil)
1595
1596       ;; %[] Insert contents of a file.
1597       (goto-char (point-min))
1598       (while (re-search-forward "%\\[\\(.+\\)\\]" nil t)
1599         (unless (org-capture-escaped-%)
1600           (let ((start (match-beginning 0))
1601                 (end (match-end 0))
1602                 (filename (expand-file-name (match-string 1))))
1603             (goto-char start)
1604             (delete-region start end)
1605             (condition-case error
1606                 (insert-file-contents filename)
1607               (error (insert (format "%%![Couldn't insert %s: %s]"
1608                                      filename error)))))))
1609       ;; %() embedded elisp
1610       (org-capture-expand-embedded-elisp)
1611
1612       ;; The current time
1613       (goto-char (point-min))
1614       (while (re-search-forward "%<\\([^>\n]+\\)>" nil t)
1615         (replace-match (format-time-string (match-string 1)) t t))
1616
1617       ;; Simple %-escapes
1618       (goto-char (point-min))
1619       (while (re-search-forward "%\\([tTuUaliAcxkKInfF]\\)" nil t)
1620         (unless (org-capture-escaped-%)
1621           (when (and initial (equal (match-string 0) "%i"))
1622             (save-match-data
1623               (let* ((lead (buffer-substring
1624                             (point-at-bol) (match-beginning 0))))
1625                 (setq v-i (mapconcat 'identity
1626                                      (org-split-string initial "\n")
1627                                      (concat "\n" lead))))))
1628           (replace-match (or (eval (intern (concat "v-" (match-string 1)))) "")
1629                          t t)))
1630
1631       ;; From the property list
1632       (when plist-p
1633         (goto-char (point-min))
1634         (while (re-search-forward "%\\(:[-a-zA-Z]+\\)" nil t)
1635           (unless (org-capture-escaped-%)
1636             (and (setq x (or (plist-get org-store-link-plist
1637                                         (intern (match-string 1))) ""))
1638                  (replace-match x t t)))))
1639
1640       ;; Turn on org-mode in temp buffer, set local variables
1641       ;; This is to support completion in interactive prompts
1642       (let ((org-inhibit-startup t)) (org-mode))
1643       ;; Interactive template entries
1644       (goto-char (point-min))
1645       (while (re-search-forward "%^\\({\\([^}]*\\)}\\)?\\([gGtTuUCLp]\\)?" nil t)
1646         (unless (org-capture-escaped-%)
1647           (setq char (if (match-end 3) (match-string-no-properties 3))
1648                 prompt (if (match-end 2) (match-string-no-properties 2)))
1649           (goto-char (match-beginning 0))
1650           (replace-match "")
1651           (setq completions nil default nil)
1652           (when prompt
1653             (setq completions (org-split-string prompt "|")
1654                   prompt (pop completions)
1655                   default (car completions)
1656                   histvar (intern (concat
1657                                    "org-capture-template-prompt-history::"
1658                                    (or prompt "")))
1659                   completions (mapcar 'list completions)))
1660           (unless (boundp histvar) (set histvar nil))
1661           (cond
1662            ((member char '("G" "g"))
1663             (let* ((org-last-tags-completion-table
1664                     (org-global-tags-completion-table
1665                      (if (equal char "G")
1666                          (org-agenda-files)
1667                        (and file (list file)))))
1668                    (org-add-colon-after-tag-completion t)
1669                    (ins (org-icompleting-read
1670                          (if prompt (concat prompt ": ") "Tags: ")
1671                          'org-tags-completion-function nil nil nil
1672                          'org-tags-history)))
1673               (setq ins (mapconcat 'identity
1674                                    (org-split-string
1675                                     ins (org-re "[^[:alnum:]_@#%]+"))
1676                                    ":"))
1677               (when (string-match "\\S-" ins)
1678                 (or (equal (char-before) ?:) (insert ":"))
1679                 (insert ins)
1680                 (or (equal (char-after) ?:) (insert ":"))
1681                 (and (org-at-heading-p)
1682                      (let ((org-ignore-region t))
1683                        (org-set-tags nil 'align))))))
1684            ((equal char "C")
1685             (cond ((= (length clipboards) 1) (insert (car clipboards)))
1686                   ((> (length clipboards) 1)
1687                    (insert (read-string "Clipboard/kill value: "
1688                                         (car clipboards) '(clipboards . 1)
1689                                         (car clipboards))))))
1690            ((equal char "L")
1691             (cond ((= (length clipboards) 1)
1692                    (org-insert-link 0 (car clipboards)))
1693                   ((> (length clipboards) 1)
1694                    (org-insert-link 0 (read-string "Clipboard/kill value: "
1695                                                    (car clipboards)
1696                                                    '(clipboards . 1)
1697                                                    (car clipboards))))))
1698            ((equal char "p")
1699             (org-set-property (org-no-properties prompt) nil))
1700            (char
1701             ;; These are the date/time related ones
1702             (setq org-time-was-given (equal (upcase char) char))
1703             (setq time (org-read-date (equal (upcase char) char) t nil
1704                                       prompt))
1705             (if (equal (upcase char) char) (setq org-time-was-given t))
1706             (org-insert-time-stamp time org-time-was-given
1707                                    (member char '("u" "U"))
1708                                    nil nil (list org-end-time-was-given)))
1709            (t
1710             (let (org-completion-use-ido)
1711               (push (org-completing-read-no-i
1712                      (concat (if prompt prompt "Enter string")
1713                              (if default (concat " [" default "]"))
1714                              ": ")
1715                      completions nil nil nil histvar default)
1716                     strings)
1717               (insert (car strings)))))))
1718       ;; Replace %n escapes with nth %^{...} string
1719       (setq strings (nreverse strings))
1720       (goto-char (point-min))
1721       (while (re-search-forward "%\\\\\\([1-9][0-9]*\\)" nil t)
1722         (unless (org-capture-escaped-%)
1723           (replace-match
1724            (nth (1- (string-to-number (match-string 1))) strings)
1725            nil t)))
1726       ;; Make sure there are no empty lines before the text, and that
1727       ;; it ends with a newline character
1728       (goto-char (point-min))
1729       (while (looking-at "[ \t]*\n") (replace-match ""))
1730       (if (re-search-forward "[ \t\n]*\\'" nil t) (replace-match "\n"))
1731       ;; Return the expanded template and kill the temporary buffer
1732       (untabify (point-min) (point-max))
1733       (set-buffer-modified-p nil)
1734       (prog1 (buffer-string) (kill-buffer (current-buffer))))))
1735
1736 (defun org-capture-escaped-% ()
1737   "Check if % was escaped - if yes, unescape it now."
1738   (if (equal (char-before (match-beginning 0)) ?\\)
1739       (progn
1740         (delete-region (1- (match-beginning 0)) (match-beginning 0))
1741         t)
1742     nil))
1743
1744 (defun org-capture-expand-embedded-elisp ()
1745   "Evaluate embedded elisp %(sexp) and replace with the result."
1746   (goto-char (point-min))
1747   (while (re-search-forward "%(" nil t)
1748     (unless (org-capture-escaped-%)
1749       (goto-char (match-beginning 0))
1750       (let ((template-start (point)))
1751         (forward-char 1)
1752         (let* ((sexp (read (current-buffer)))
1753                (result (org-eval
1754                         (org-capture--expand-keyword-in-embedded-elisp sexp))))
1755           (delete-region template-start (point))
1756           (when result
1757             (if (stringp result)
1758                 (insert result)
1759               (error "Capture template sexp `%s' must evaluate to string or nil"
1760                      sexp))))))))
1761
1762 (defun org-capture--expand-keyword-in-embedded-elisp (attr)
1763   "Recursively replace capture link keywords in ATTR sexp.
1764 Such keywords are prefixed with \"%:\".  See
1765 `org-capture-template' for more information."
1766   (cond ((consp attr)
1767          (mapcar 'org-capture--expand-keyword-in-embedded-elisp attr))
1768         ((symbolp attr)
1769          (let* ((attr-symbol (symbol-name attr))
1770                 (key (and (string-match "%\\(:.*\\)" attr-symbol)
1771                           (intern (match-string 1 attr-symbol)))))
1772            (or (plist-get org-store-link-plist key)
1773                attr)))
1774         (t attr)))
1775
1776 (defun org-capture-inside-embedded-elisp-p ()
1777   "Return non-nil if point is inside of embedded elisp %(sexp)."
1778   (let (beg end)
1779     (with-syntax-table emacs-lisp-mode-syntax-table
1780       (save-excursion
1781         ;; `looking-at' and `search-backward' below do not match the "%(" if
1782         ;; point is in its middle
1783         (when (equal (char-before) ?%)
1784           (backward-char))
1785         (save-match-data
1786           (when (or (looking-at "%(") (search-backward "%(" nil t))
1787             (setq beg (point))
1788             (setq end (progn (forward-char) (forward-sexp) (1- (point)))))))
1789       (when (and beg end)
1790         (and (<= (point) end) (>= (point) beg))))))
1791
1792 ;;;###autoload
1793 (defun org-capture-import-remember-templates ()
1794   "Set `org-capture-templates' to be similar to `org-remember-templates'."
1795   (interactive)
1796   (when (and (yes-or-no-p
1797               "Import old remember templates into org-capture-templates? ")
1798              (yes-or-no-p
1799               "Note that this will remove any templates currently defined in `org-capture-templates'.  Do you still want to go ahead? "))
1800     (require 'org-remember)
1801     (setq org-capture-templates
1802           (mapcar
1803            (lambda (entry)
1804              (let ((desc (car entry))
1805                    (key (char-to-string (nth 1 entry)))
1806                    (template (nth 2 entry))
1807                    (file (or (nth 3 entry) org-default-notes-file))
1808                    (position (or (nth 4 entry) org-remember-default-headline))
1809                    (type 'entry)
1810                    (prepend org-reverse-note-order)
1811                    immediate target jump-to-captured)
1812                (cond
1813                 ((member position '(top bottom))
1814                  (setq target (list 'file file)
1815                        prepend (eq position 'top)))
1816                 ((eq position 'date-tree)
1817                  (setq target (list 'file+datetree file)
1818                        prepend nil))
1819                 (t (setq target (list 'file+headline file position))))
1820
1821                (when (string-match "%!" template)
1822                  (setq template (replace-match "" t t template)
1823                        immediate t))
1824
1825                (when (string-match "%&" template)
1826                  (setq jump-to-captured t))
1827
1828                (append (list key desc type target template)
1829                        (if prepend '(:prepend t))
1830                        (if immediate '(:immediate-finish t))
1831                        (if jump-to-captured '(:jump-to-captured t)))))
1832
1833            org-remember-templates))))
1834
1835 (provide 'org-capture)
1836
1837 ;;; org-capture.el ends here