lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a Markdown back-end (vanilla flavor) for
  26 ;; Org exporter, based on `html' back-end.  See Org manual for more
  27 ;; information.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'ox-html)
  33 (require 'ox-publish)
  34
  35 \f
  36 ;;; User-Configurable Variables
  37
  38 (defgroup org-export-md nil
  39   "Options specific to Markdown export back-end."
  40   :tag "Org Markdown"
  41   :group 'org-export
  42   :version "24.4"
  43   :package-version '(Org . "8.0"))
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 \f
  55 ;;; Define Back-End
  56
  57 (org-export-define-derived-backend 'md 'html
  58   :export-block '("MD" "MARKDOWN")
  59   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  60   :menu-entry
  61   '(?m "Export to Markdown"
  62        ((?M "To temporary buffer"
  63             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  64         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  65         (?o "To file and open"
  66             (lambda (a s v b)
  67               (if a (org-md-export-to-markdown t s v)
  68                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  69   :translate-alist '((bold . org-md-bold)
  70                      (code . org-md-verbatim)
  71                      (comment . (lambda (&rest args) ""))
  72                      (comment-block . (lambda (&rest args) ""))
  73                      (example-block . org-md-example-block)
  74                      (fixed-width . org-md-example-block)
  75                      (footnote-definition . ignore)
  76                      (footnote-reference . ignore)
  77                      (headline . org-md-headline)
  78                      (horizontal-rule . org-md-horizontal-rule)
  79                      (inline-src-block . org-md-verbatim)
  80                      (inner-template . org-md-inner-template)
  81                      (italic . org-md-italic)
  82                      (item . org-md-item)
  83                      (keyword . org-md-keyword)
  84                      (line-break . org-md-line-break)
  85                      (link . org-md-link)
  86                      (node-property . org-md-node-property)
  87                      (paragraph . org-md-paragraph)
  88                      (plain-list . org-md-plain-list)
  89                      (plain-text . org-md-plain-text)
  90                      (property-drawer . org-md-property-drawer)
  91                      (quote-block . org-md-quote-block)
  92                      (section . org-md-section)
  93                      (src-block . org-md-example-block)
  94                      (template . org-md-template)
  95                      (verbatim . org-md-verbatim))
  96   :options-alist '((:md-headline-style nil nil org-md-headline-style)))
  97
  98 \f
  99 ;;; Filters
 100
 101 (defun org-md-separate-elements (tree backend info)
 102   "Fix blank lines between elements.
 103
 104 TREE is the parse tree being exported.  BACKEND is the export
 105 back-end used.  INFO is a plist used as a communication channel.
 106
 107 Enforce a blank line between elements.  There are three
 108 exceptions to this rule:
 109
 110   1. Preserve blank lines between sibling items in a plain list,
 111
 112   2. Outside of plain lists, preserve blank lines between
 113      a paragraph and a plain list,
 114
 115   3. In an item, remove any blank line before the very first
 116      paragraph and the next sub-list.
 117
 118 Assume BACKEND is `md'."
 119   (org-element-map tree (remq 'item org-element-all-elements)
 120     (lambda (e)
 121       (cond
 122        ((not (and (eq (org-element-type e) 'paragraph)
 123                   (eq (org-element-type (org-export-get-next-element e info))
 124                       'plain-list)))
 125         (org-element-put-property e :post-blank 1))
 126        ((not (eq (org-element-type (org-element-property :parent e)) 'item)))
 127        (t (org-element-put-property
 128            e :post-blank (if (org-export-get-previous-element e info) 1 0))))))
 129   ;; Return updated tree.
 130   tree)
 131
 132
 133 \f
 134 ;;; Transcode Functions
 135
 136 ;;;; Bold
 137
 138 (defun org-md-bold (bold contents info)
 139   "Transcode BOLD object into Markdown format.
 140 CONTENTS is the text within bold markup.  INFO is a plist used as
 141 a communication channel."
 142   (format "**%s**" contents))
 143
 144
 145 ;;;; Code and Verbatim
 146
 147 (defun org-md-verbatim (verbatim contents info)
 148   "Transcode VERBATIM object into Markdown format.
 149 CONTENTS is nil.  INFO is a plist used as a communication
 150 channel."
 151   (let ((value (org-element-property :value verbatim)))
 152     (format (cond ((not (string-match "`" value)) "`%s`")
 153                   ((or (string-match "\\``" value)
 154                        (string-match "`\\'" value))
 155                    "`` %s ``")
 156                   (t "``%s``"))
 157             value)))
 158
 159
 160 ;;;; Example Block and Src Block
 161
 162 (defun org-md-example-block (example-block contents info)
 163   "Transcode EXAMPLE-BLOCK element into Markdown format.
 164 CONTENTS is nil.  INFO is a plist used as a communication
 165 channel."
 166   (replace-regexp-in-string
 167    "^" "    "
 168    (org-remove-indentation
 169     (org-export-format-code-default example-block info))))
 170
 171
 172 ;;;; Headline
 173
 174 (defun org-md-headline (headline contents info)
 175   "Transcode HEADLINE element into Markdown format.
 176 CONTENTS is the headline contents.  INFO is a plist used as
 177 a communication channel."
 178   (unless (org-element-property :footnote-section-p headline)
 179     (let* ((level (org-export-get-relative-level headline info))
 180            (title (org-export-data (org-element-property :title headline) info))
 181            (todo (and (plist-get info :with-todo-keywords)
 182                       (let ((todo (org-element-property :todo-keyword
 183                                                         headline)))
 184                         (and todo (concat (org-export-data todo info) " ")))))
 185            (tags (and (plist-get info :with-tags)
 186                       (let ((tag-list (org-export-get-tags headline info)))
 187                         (and tag-list
 188                              (format "     :%s:"
 189                                      (mapconcat 'identity tag-list ":"))))))
 190            (priority
 191             (and (plist-get info :with-priority)
 192                  (let ((char (org-element-property :priority headline)))
 193                    (and char (format "[#%c] " char)))))
 194            (anchor
 195             (when (plist-get info :with-toc)
 196               (org-html--anchor
 197                (or (org-element-property :CUSTOM_ID headline)
 198                    (concat "sec-"
 199                            (mapconcat 'number-to-string
 200                                       (org-export-get-headline-number
 201                                        headline info) "-")))
 202                nil nil info)))
 203            ;; Headline text without tags.
 204            (heading (concat todo priority title))
 205            (style (plist-get info :md-headline-style)))
 206       (cond
 207        ;; Cannot create a headline.  Fall-back to a list.
 208        ((or (org-export-low-level-p headline info)
 209             (not (memq style '(atx setext)))
 210             (and (eq style 'atx) (> level 6))
 211             (and (eq style 'setext) (> level 2)))
 212         (let ((bullet
 213                (if (not (org-export-numbered-headline-p headline info)) "-"
 214                  (concat (number-to-string
 215                           (car (last (org-export-get-headline-number
 216                                       headline info))))
 217                          "."))))
 218           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 219                   "\n\n"
 220                   (and contents
 221                        (replace-regexp-in-string "^" "    " contents)))))
 222        ;; Use "Setext" style.
 223        ((eq style 'setext)
 224         (concat heading tags anchor "\n"
 225                 (make-string (length heading) (if (= level 1) ?= ?-))
 226                 "\n\n"
 227                 contents))
 228        ;; Use "atx" style.
 229        (t (concat (make-string level ?#) " " heading tags anchor "\n\n" contents))))))
 230
 231
 232 ;;;; Horizontal Rule
 233
 234 (defun org-md-horizontal-rule (horizontal-rule contents info)
 235   "Transcode HORIZONTAL-RULE element into Markdown format.
 236 CONTENTS is the horizontal rule contents.  INFO is a plist used
 237 as a communication channel."
 238   "---")
 239
 240
 241 ;;;; Italic
 242
 243 (defun org-md-italic (italic contents info)
 244   "Transcode ITALIC object into Markdown format.
 245 CONTENTS is the text within italic markup.  INFO is a plist used
 246 as a communication channel."
 247   (format "*%s*" contents))
 248
 249
 250 ;;;; Item
 251
 252 (defun org-md-item (item contents info)
 253   "Transcode ITEM element into Markdown format.
 254 CONTENTS is the item contents.  INFO is a plist used as
 255 a communication channel."
 256   (let* ((type (org-element-property :type (org-export-get-parent item)))
 257          (struct (org-element-property :structure item))
 258          (bullet (if (not (eq type 'ordered)) "-"
 259                    (concat (number-to-string
 260                             (car (last (org-list-get-item-number
 261                                         (org-element-property :begin item)
 262                                         struct
 263                                         (org-list-prevs-alist struct)
 264                                         (org-list-parents-alist struct)))))
 265                            "."))))
 266     (concat bullet
 267             (make-string (- 4 (length bullet)) ? )
 268             (case (org-element-property :checkbox item)
 269               (on "[X] ")
 270               (trans "[-] ")
 271               (off "[ ] "))
 272             (let ((tag (org-element-property :tag item)))
 273               (and tag (format "**%s:** "(org-export-data tag info))))
 274             (and contents
 275                  (org-trim (replace-regexp-in-string "^" "    " contents))))))
 276
 277
 278
 279 ;;;; Keyword
 280
 281 (defun org-md-keyword (keyword contents info)
 282   "Transcode a KEYWORD element into Markdown format.
 283 CONTENTS is nil.  INFO is a plist used as a communication
 284 channel."
 285   (if (member (org-element-property :key keyword) '("MARKDOWN" "MD"))
 286       (org-element-property :value keyword)
 287     (org-export-with-backend 'html keyword contents info)))
 288
 289
 290 ;;;; Line Break
 291
 292 (defun org-md-line-break (line-break contents info)
 293   "Transcode LINE-BREAK object into Markdown format.
 294 CONTENTS is nil.  INFO is a plist used as a communication
 295 channel."
 296   "  \n")
 297
 298
 299 ;;;; Link
 300
 301 (defun org-md-link (link contents info)
 302   "Transcode LINE-BREAK object into Markdown format.
 303 CONTENTS is the link's description.  INFO is a plist used as
 304 a communication channel."
 305   (let ((link-org-files-as-md
 306          (function
 307           (lambda (raw-path)
 308             ;; Treat links to `file.org' as links to `file.md'.
 309             (if (string= ".org" (downcase (file-name-extension raw-path ".")))
 310                 (concat (file-name-sans-extension raw-path) ".md")
 311               raw-path))))
 312         (type (org-element-property :type link)))
 313     (cond
 314      ((member type '("custom-id" "id"))
 315       (let ((destination (org-export-resolve-id-link link info)))
 316         (if (stringp destination)       ; External file.
 317             (let ((path (funcall link-org-files-as-md destination)))
 318               (if (not contents) (format "<%s>" path)
 319                 (format "[%s](%s)" contents path)))
 320           (concat
 321            (and contents (concat contents " "))
 322            (format "(%s)"
 323                    (format (org-export-translate "See section %s" :html info)
 324                            (mapconcat 'number-to-string
 325                                       (org-export-get-headline-number
 326                                        destination info)
 327                                       ".")))))))
 328      ((org-export-inline-image-p link org-html-inline-image-rules)
 329       (let ((path (let ((raw-path (org-element-property :path link)))
 330                     (if (not (file-name-absolute-p raw-path)) raw-path
 331                       (expand-file-name raw-path))))
 332             (caption (org-export-data
 333                       (org-export-get-caption
 334                        (org-export-get-parent-element link)) info)))
 335         (format "![img](%s)"
 336                 (if (not (org-string-nw-p caption)) path
 337                   (format "%s \"%s\"" path caption)))))
 338      ((string= type "coderef")
 339       (let ((ref (org-element-property :path link)))
 340         (format (org-export-get-coderef-format ref contents)
 341                 (org-export-resolve-coderef ref info))))
 342      ((equal type "radio") contents)
 343      ((equal type "fuzzy")
 344       (let ((destination (org-export-resolve-fuzzy-link link info)))
 345         (if (org-string-nw-p contents) contents
 346           (when destination
 347             (let ((number (org-export-get-ordinal destination info)))
 348               (when number
 349                 (if (atom number) (number-to-string number)
 350                   (mapconcat 'number-to-string number "."))))))))
 351      ;; Link type is handled by a special function.
 352      ((let ((protocol (nth 2 (assoc type org-link-protocols))))
 353         (and (functionp protocol)
 354              (funcall protocol
 355                       (org-link-unescape (org-element-property :path link))
 356                       contents
 357                       'md))))
 358      (t (let* ((raw-path (org-element-property :path link))
 359                (path
 360                 (cond
 361                  ((member type '("http" "https" "ftp"))
 362                   (concat type ":" raw-path))
 363                  ((string= type "file")
 364                   (let ((path (funcall link-org-files-as-md raw-path)))
 365                     (if (not (file-name-absolute-p path)) path
 366                       ;; If file path is absolute, prepend it
 367                       ;; with "file:" component.
 368                       (concat "file:" path))))
 369                  (t raw-path))))
 370           (if (not contents) (format "<%s>" path)
 371             (format "[%s](%s)" contents path)))))))
 372
 373
 374 ;;;; Node Property
 375
 376 (defun org-md-node-property (node-property contents info)
 377   "Transcode a NODE-PROPERTY element into Markdown syntax.
 378 CONTENTS is nil.  INFO is a plist holding contextual
 379 information."
 380   (format "%s:%s"
 381           (org-element-property :key node-property)
 382           (let ((value (org-element-property :value node-property)))
 383             (if value (concat " " value) ""))))
 384
 385
 386 ;;;; Paragraph
 387
 388 (defun org-md-paragraph (paragraph contents info)
 389   "Transcode PARAGRAPH element into Markdown format.
 390 CONTENTS is the paragraph contents.  INFO is a plist used as
 391 a communication channel."
 392   (let ((first-object (car (org-element-contents paragraph))))
 393     ;; If paragraph starts with a #, protect it.
 394     (if (and (stringp first-object) (string-match "\\`#" first-object))
 395         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 396       contents)))
 397
 398
 399 ;;;; Plain List
 400
 401 (defun org-md-plain-list (plain-list contents info)
 402   "Transcode PLAIN-LIST element into Markdown format.
 403 CONTENTS is the plain-list contents.  INFO is a plist used as
 404 a communication channel."
 405   contents)
 406
 407
 408 ;;;; Plain Text
 409
 410 (defun org-md-plain-text (text info)
 411   "Transcode a TEXT string into Markdown format.
 412 TEXT is the string to transcode.  INFO is a plist holding
 413 contextual information."
 414   (when (plist-get info :with-smart-quotes)
 415     (setq text (org-export-activate-smart-quotes text :html info)))
 416   ;; Protect ambiguous #.  This will protect # at the beginning of
 417   ;; a line, but not at the beginning of a paragraph.  See
 418   ;; `org-md-paragraph'.
 419   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 420   ;; Protect ambiguous !
 421   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 422   ;; Protect `, *, _ and \
 423   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 424   ;; Handle special strings, if required.
 425   (when (plist-get info :with-special-strings)
 426     (setq text (org-html-convert-special-strings text)))
 427   ;; Handle break preservation, if required.
 428   (when (plist-get info :preserve-breaks)
 429     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 430   ;; Return value.
 431   text)
 432
 433
 434 ;;;; Property Drawer
 435
 436 (defun org-md-property-drawer (property-drawer contents info)
 437   "Transcode a PROPERTY-DRAWER element into Markdown format.
 438 CONTENTS holds the contents of the drawer.  INFO is a plist
 439 holding contextual information."
 440   (and (org-string-nw-p contents)
 441        (replace-regexp-in-string "^" "    " contents)))
 442
 443
 444 ;;;; Quote Block
 445
 446 (defun org-md-quote-block (quote-block contents info)
 447   "Transcode QUOTE-BLOCK element into Markdown format.
 448 CONTENTS is the quote-block contents.  INFO is a plist used as
 449 a communication channel."
 450   (replace-regexp-in-string
 451    "^" "> "
 452    (replace-regexp-in-string "\n\\'" "" contents)))
 453
 454
 455 ;;;; Section
 456
 457 (defun org-md-section (section contents info)
 458   "Transcode SECTION element into Markdown format.
 459 CONTENTS is the section contents.  INFO is a plist used as
 460 a communication channel."
 461   contents)
 462
 463
 464 ;;;; Template
 465
 466 (defun org-md-inner-template (contents info)
 467   "Return body of document after converting it to Markdown syntax.
 468 CONTENTS is the transcoded contents string.  INFO is a plist
 469 holding export options."
 470   ;; Make sure CONTENTS is separated from table of contents and
 471   ;; footnotes with at least a blank line.
 472   (org-trim (org-html-inner-template (concat "\n" contents "\n") info)))
 473
 474 (defun org-md-template (contents info)
 475   "Return complete document string after Markdown conversion.
 476 CONTENTS is the transcoded contents string.  INFO is a plist used
 477 as a communication channel."
 478   contents)
 479
 480
 481 \f
 482 ;;; Interactive function
 483
 484 ;;;###autoload
 485 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 486   "Export current buffer to a Markdown buffer.
 487
 488 If narrowing is active in the current buffer, only export its
 489 narrowed part.
 490
 491 If a region is active, export that region.
 492
 493 A non-nil optional argument ASYNC means the process should happen
 494 asynchronously.  The resulting buffer should be accessible
 495 through the `org-export-stack' interface.
 496
 497 When optional argument SUBTREEP is non-nil, export the sub-tree
 498 at point, extracting information from the headline properties
 499 first.
 500
 501 When optional argument VISIBLE-ONLY is non-nil, don't export
 502 contents of hidden elements.
 503
 504 Export is done in a buffer named \"*Org MD Export*\", which will
 505 be displayed when `org-export-show-temporary-export-buffer' is
 506 non-nil."
 507   (interactive)
 508   (org-export-to-buffer 'md "*Org MD Export*"
 509     async subtreep visible-only nil nil (lambda () (text-mode))))
 510
 511 ;;;###autoload
 512 (defun org-md-convert-region-to-md ()
 513   "Assume the current region has org-mode syntax, and convert it to Markdown.
 514 This can be used in any buffer.  For example, you can write an
 515 itemized list in org-mode syntax in a Markdown buffer and use
 516 this command to convert it."
 517   (interactive)
 518   (org-export-replace-region-by 'md))
 519
 520
 521 ;;;###autoload
 522 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 523   "Export current buffer to a Markdown file.
 524
 525 If narrowing is active in the current buffer, only export its
 526 narrowed part.
 527
 528 If a region is active, export that region.
 529
 530 A non-nil optional argument ASYNC means the process should happen
 531 asynchronously.  The resulting file should be accessible through
 532 the `org-export-stack' interface.
 533
 534 When optional argument SUBTREEP is non-nil, export the sub-tree
 535 at point, extracting information from the headline properties
 536 first.
 537
 538 When optional argument VISIBLE-ONLY is non-nil, don't export
 539 contents of hidden elements.
 540
 541 Return output file's name."
 542   (interactive)
 543   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 544     (org-export-to-file 'md outfile async subtreep visible-only)))
 545
 546 ;;;###autoload
 547 (defun org-md-publish-to-md (plist filename pub-dir)
 548   "Publish an org file to Markdown.
 549
 550 FILENAME is the filename of the Org file to be published.  PLIST
 551 is the property list for the given project.  PUB-DIR is the
 552 publishing directory.
 553
 554 Return output file name."
 555   (org-publish-org-to 'md filename ".md" plist pub-dir))
 556
 557 (provide 'ox-md)
 558
 559 ;; Local variables:
 560 ;; generated-autoload-file: "org-loaddefs.el"
 561 ;; End:
 562
 563 ;;; ox-md.el ends here