lisp/org-colview.el

   1 ;;; org-colview.el --- Column View in Org-mode
   2
   3 ;; Copyright (C) 2004-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the column view for Org.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'org)
  33
  34 (declare-function org-agenda-redo "org-agenda" ())
  35 (declare-function org-agenda-do-context-action "org-agenda" ())
  36 (declare-function org-clock-sum-today "org-clock" (&optional headline-filter))
  37
  38 (when (featurep 'xemacs)
  39   (error "Do not load this file into XEmacs, use `org-colview-xemacs.el' from the contrib/ directory"))
  40
  41 ;;; Column View
  42
  43 (defvar org-columns-overlays nil
  44   "Holds the list of current column overlays.")
  45
  46 (defvar org-columns-current-fmt nil
  47   "Local variable, holds the currently active column format.")
  48 (make-variable-buffer-local 'org-columns-current-fmt)
  49 (defvar org-columns-current-fmt-compiled nil
  50   "Local variable, holds the currently active column format.
  51 This is the compiled version of the format.")
  52 (make-variable-buffer-local 'org-columns-current-fmt-compiled)
  53 (defvar org-columns-current-widths nil
  54   "Loval variable, holds the currently widths of fields.")
  55 (make-variable-buffer-local 'org-columns-current-widths)
  56 (defvar org-columns-current-maxwidths nil
  57   "Loval variable, holds the currently active maximum column widths.")
  58 (make-variable-buffer-local 'org-columns-current-maxwidths)
  59 (defvar org-columns-begin-marker (make-marker)
  60   "Points to the position where last a column creation command was called.")
  61 (defvar org-columns-top-level-marker (make-marker)
  62   "Points to the position where current columns region starts.")
  63
  64 (defvar org-columns-map (make-sparse-keymap)
  65   "The keymap valid in column display.")
  66
  67 (defun org-columns-content ()
  68   "Switch to contents view while in columns view."
  69   (interactive)
  70   (org-overview)
  71   (org-content))
  72
  73 (org-defkey org-columns-map "c" 'org-columns-content)
  74 (org-defkey org-columns-map "o" 'org-overview)
  75 (org-defkey org-columns-map "e" 'org-columns-edit-value)
  76 (org-defkey org-columns-map "\C-c\C-t" 'org-columns-todo)
  77 (org-defkey org-columns-map "\C-c\C-c" 'org-columns-set-tags-or-toggle)
  78 (org-defkey org-columns-map "\C-c\C-o" 'org-columns-open-link)
  79 (org-defkey org-columns-map "v" 'org-columns-show-value)
  80 (org-defkey org-columns-map "q" 'org-columns-quit)
  81 (org-defkey org-columns-map "r" 'org-columns-redo)
  82 (org-defkey org-columns-map "g" 'org-columns-redo)
  83 (org-defkey org-columns-map [left] 'backward-char)
  84 (org-defkey org-columns-map "\M-b" 'backward-char)
  85 (org-defkey org-columns-map "a" 'org-columns-edit-allowed)
  86 (org-defkey org-columns-map "s" 'org-columns-edit-attributes)
  87 (org-defkey org-columns-map "\M-f"
  88             (lambda () (interactive) (goto-char (1+ (point)))))
  89 (org-defkey org-columns-map [right]
  90             (lambda () (interactive) (goto-char (1+ (point)))))
  91 (org-defkey org-columns-map [down]
  92             (lambda () (interactive)
  93               (let ((col (current-column)))
  94                 (beginning-of-line 2)
  95                 (while (and (org-invisible-p2) (not (eobp)))
  96                   (beginning-of-line 2))
  97                 (move-to-column col)
  98                 (if (eq major-mode 'org-agenda-mode)
  99                     (org-agenda-do-context-action)))))
 100 (org-defkey org-columns-map [up]
 101             (lambda () (interactive)
 102               (let ((col (current-column)))
 103                 (beginning-of-line 0)
 104                 (while (and (org-invisible-p2) (not (bobp)))
 105                   (beginning-of-line 0))
 106                 (move-to-column col)
 107                 (if (eq major-mode 'org-agenda-mode)
 108                     (org-agenda-do-context-action)))))
 109 (org-defkey org-columns-map [(shift right)] 'org-columns-next-allowed-value)
 110 (org-defkey org-columns-map "n" 'org-columns-next-allowed-value)
 111 (org-defkey org-columns-map [(shift left)] 'org-columns-previous-allowed-value)
 112 (org-defkey org-columns-map "p" 'org-columns-previous-allowed-value)
 113 (org-defkey org-columns-map "<" 'org-columns-narrow)
 114 (org-defkey org-columns-map ">" 'org-columns-widen)
 115 (org-defkey org-columns-map [(meta right)] 'org-columns-move-right)
 116 (org-defkey org-columns-map [(meta left)] 'org-columns-move-left)
 117 (org-defkey org-columns-map [(shift meta right)] 'org-columns-new)
 118 (org-defkey org-columns-map [(shift meta left)] 'org-columns-delete)
 119 (dotimes (i 10)
 120   (org-defkey org-columns-map (number-to-string i)
 121               `(lambda () (interactive)
 122                  (org-columns-next-allowed-value nil ,i))))
 123
 124 (easy-menu-define org-columns-menu org-columns-map "Org Column Menu"
 125   '("Column"
 126     ["Edit property" org-columns-edit-value t]
 127     ["Next allowed value" org-columns-next-allowed-value t]
 128     ["Previous allowed value" org-columns-previous-allowed-value t]
 129     ["Show full value" org-columns-show-value t]
 130     ["Edit allowed values" org-columns-edit-allowed t]
 131     "--"
 132     ["Edit column attributes" org-columns-edit-attributes t]
 133     ["Increase column width" org-columns-widen t]
 134     ["Decrease column width" org-columns-narrow t]
 135     "--"
 136     ["Move column right" org-columns-move-right t]
 137     ["Move column left" org-columns-move-left t]
 138     ["Add column" org-columns-new t]
 139     ["Delete column" org-columns-delete t]
 140     "--"
 141     ["CONTENTS" org-columns-content t]
 142     ["OVERVIEW" org-overview t]
 143     ["Refresh columns display" org-columns-redo t]
 144     "--"
 145     ["Open link" org-columns-open-link t]
 146     "--"
 147     ["Quit" org-columns-quit t]))
 148
 149 (defun org-columns-new-overlay (beg end &optional string face)
 150   "Create a new column overlay and add it to the list."
 151   (let ((ov (make-overlay beg end)))
 152     (overlay-put ov 'face (or face 'secondary-selection))
 153     (remove-text-properties 0 (length string) '(face nil) string)
 154     (org-overlay-display ov string face)
 155     (push ov org-columns-overlays)
 156     ov))
 157
 158 (defun org-columns-display-here (&optional props dateline)
 159   "Overlay the current line with column display."
 160   (interactive)
 161   (let* ((fmt org-columns-current-fmt-compiled)
 162          (beg (point-at-bol))
 163          (level-face (save-excursion
 164                        (beginning-of-line 1)
 165                        (and (looking-at "\\(\\**\\)\\(\\* \\)")
 166                             (org-get-level-face 2))))
 167          (ref-face (or level-face
 168                        (and (eq major-mode 'org-agenda-mode)
 169                             (get-text-property (point-at-bol) 'face))
 170                        'default))
 171          (color (list :foreground (face-attribute ref-face :foreground)))
 172          (font (list :height (face-attribute 'default :height)
 173                      :family (face-attribute 'default :family)))
 174          (face (list color font 'org-column ref-face))
 175          (face1 (list color font 'org-agenda-column-dateline ref-face))
 176          (cphr (get-text-property (point-at-bol) 'org-complex-heading-regexp))
 177          pom property ass width f fc string fm ov column val modval s2 title calc)
 178     ;; Check if the entry is in another buffer.
 179     (unless props
 180       (if (eq major-mode 'org-agenda-mode)
 181           (setq pom (or (org-get-at-bol 'org-hd-marker)
 182                         (org-get-at-bol 'org-marker))
 183                 props (if pom (org-entry-properties pom) nil))
 184         (setq props (org-entry-properties nil))))
 185     ;; Walk the format
 186     (while (setq column (pop fmt))
 187       (setq property (car column)
 188             title (nth 1 column)
 189             ass (assoc-string property props t)
 190             width (or (cdr
 191                        (assoc-string property org-columns-current-maxwidths t))
 192                       (nth 2 column)
 193                       (length property))
 194             f (format "%%-%d.%ds | " width width)
 195             fm (nth 4 column)
 196             fc (nth 5 column)
 197             calc (nth 7 column)
 198             val (or (cdr ass) "")
 199             modval (cond ((and org-columns-modify-value-for-display-function
 200                                (functionp
 201                                 org-columns-modify-value-for-display-function))
 202                           (funcall org-columns-modify-value-for-display-function
 203                                    title val))
 204                          ((equal property "ITEM")
 205                           (org-columns-compact-links val))
 206                          (fc (org-columns-number-to-string
 207                               (org-columns-string-to-number val fm) fm fc))
 208                          ((and calc (functionp calc)
 209                                (not (string= val ""))
 210                                (not (get-text-property 0 'org-computed val)))
 211                           (org-columns-number-to-string
 212                            (funcall calc (org-columns-string-to-number
 213                                           val fm)) fm))))
 214       (setq s2 (org-columns-add-ellipses (or modval val) width))
 215       (setq string (format f s2))
 216       ;; Create the overlay
 217       (org-with-silent-modifications
 218        (setq ov (org-columns-new-overlay
 219                  beg (setq beg (1+ beg)) string (if dateline face1 face)))
 220        (overlay-put ov 'keymap org-columns-map)
 221        (overlay-put ov 'org-columns-key property)
 222        (overlay-put ov 'org-columns-value (cdr ass))
 223        (overlay-put ov 'org-columns-value-modified modval)
 224        (overlay-put ov 'org-columns-pom pom)
 225        (overlay-put ov 'org-columns-format f)
 226        (overlay-put ov 'line-prefix "")
 227        (overlay-put ov 'wrap-prefix ""))
 228       (if (or (not (char-after beg))
 229               (equal (char-after beg) ?\n))
 230           (let ((inhibit-read-only t))
 231             (save-excursion
 232               (goto-char beg)
 233               (org-unmodified (insert " ")))))) ;; FIXME: add props and remove later?
 234     ;; Make the rest of the line disappear.
 235     (org-unmodified
 236      (setq ov (org-columns-new-overlay beg (point-at-eol)))
 237      (overlay-put ov 'invisible t)
 238      (overlay-put ov 'keymap org-columns-map)
 239      (overlay-put ov 'line-prefix "")
 240      (overlay-put ov 'wrap-prefix "")
 241      (push ov org-columns-overlays)
 242      (setq ov (make-overlay (1- (point-at-eol)) (1+ (point-at-eol))))
 243      (overlay-put ov 'keymap org-columns-map)
 244      (push ov org-columns-overlays)
 245      (let ((inhibit-read-only t))
 246        (put-text-property (max (point-min) (1- (point-at-bol)))
 247                           (min (point-max) (1+ (point-at-eol)))
 248                           'read-only "Type `e' to edit property")))))
 249
 250 (defun org-columns-add-ellipses (string width)
 251   "Truncate STRING with WIDTH characters, with ellipses."
 252   (cond
 253    ((<= (length string) width) string)
 254    ((<= width (length org-columns-ellipses))
 255     (substring org-columns-ellipses 0 width))
 256    (t (concat (substring string 0 (- width (length org-columns-ellipses)))
 257               org-columns-ellipses))))
 258
 259 (defvar org-columns-full-header-line-format nil
 260   "The full header line format, will be shifted by horizontal scrolling." )
 261 (defvar org-previous-header-line-format nil
 262   "The header line format before column view was turned on.")
 263 (defvar org-columns-inhibit-recalculation nil
 264   "Inhibit recomputing of columns on column view startup.")
 265 (defvar org-columns-flyspell-was-active nil
 266   "Remember the state of `flyspell-mode' before column view.
 267 Flyspell-mode can cause problems in columns view, so it is turned off
 268 for the duration of the command.")
 269
 270 (defvar header-line-format)
 271 (defvar org-columns-previous-hscroll 0)
 272
 273 (defun org-columns-display-here-title ()
 274   "Overlay the newline before the current line with the table title."
 275   (interactive)
 276   (let ((fmt org-columns-current-fmt-compiled)
 277         string (title "")
 278         property width f column str widths)
 279     (while (setq column (pop fmt))
 280       (setq property (car column)
 281             str (or (nth 1 column) property)
 282             width (or (cdr (assoc-string property
 283                                          org-columns-current-maxwidths
 284                                          t))
 285                       (nth 2 column)
 286                       (length str))
 287             widths (push width widths)
 288             f (format "%%-%d.%ds | " width width)
 289             string (format f str)
 290             title (concat title string)))
 291     (setq title (concat
 292                  (org-add-props " " nil 'display '(space :align-to 0))
 293                  ;;(org-add-props title nil 'face '(:weight bold :underline t :inherit default))))
 294                  (org-add-props title nil 'face 'org-column-title)))
 295     (org-set-local 'org-previous-header-line-format header-line-format)
 296     (org-set-local 'org-columns-current-widths (nreverse widths))
 297     (setq org-columns-full-header-line-format title)
 298     (setq org-columns-previous-hscroll -1)
 299                                         ;    (org-columns-hscoll-title)
 300     (org-add-hook 'post-command-hook 'org-columns-hscoll-title nil 'local)))
 301
 302 (defun org-columns-hscoll-title ()
 303   "Set the `header-line-format' so that it scrolls along with the table."
 304   (sit-for .0001) ; need to force a redisplay to update window-hscroll
 305   (when (not (= (window-hscroll) org-columns-previous-hscroll))
 306     (setq header-line-format
 307           (concat (substring org-columns-full-header-line-format 0 1)
 308                   (substring org-columns-full-header-line-format
 309                              (1+ (window-hscroll))))
 310           org-columns-previous-hscroll (window-hscroll))
 311     (force-mode-line-update)))
 312
 313 (defvar org-colview-initial-truncate-line-value nil
 314   "Remember the value of `truncate-lines' across colview.")
 315
 316 ;;;###autoload
 317 (defun org-columns-remove-overlays ()
 318   "Remove all currently active column overlays."
 319   (interactive)
 320   (when (marker-buffer org-columns-begin-marker)
 321     (with-current-buffer (marker-buffer org-columns-begin-marker)
 322       (when (local-variable-p 'org-previous-header-line-format)
 323         (setq header-line-format org-previous-header-line-format)
 324         (kill-local-variable 'org-previous-header-line-format)
 325         (remove-hook 'post-command-hook 'org-columns-hscoll-title 'local))
 326       (move-marker org-columns-begin-marker nil)
 327       (move-marker org-columns-top-level-marker nil)
 328       (org-with-silent-modifications
 329        (mapc 'delete-overlay org-columns-overlays)
 330        (setq org-columns-overlays nil)
 331        (let ((inhibit-read-only t))
 332          (remove-text-properties (point-min) (point-max) '(read-only t))))
 333       (when org-columns-flyspell-was-active
 334         (flyspell-mode 1))
 335       (when (local-variable-p 'org-colview-initial-truncate-line-value)
 336         (setq truncate-lines org-colview-initial-truncate-line-value)))))
 337
 338 (defun org-columns-compact-links (s)
 339   "Replace [[link][desc]] with [desc] or [link]."
 340   (while (string-match org-bracket-link-regexp s)
 341     (setq s (replace-match
 342              (concat "[" (match-string (if (match-end 3) 3 1) s) "]")
 343              t t s)))
 344   s)
 345
 346 (defun org-columns-show-value ()
 347   "Show the full value of the property."
 348   (interactive)
 349   (let ((value (get-char-property (point) 'org-columns-value)))
 350     (message "Value is: %s" (or value ""))))
 351
 352 (defvar org-agenda-columns-active) ;; defined in org-agenda.el
 353
 354 (defun org-columns-quit ()
 355   "Remove the column overlays and in this way exit column editing."
 356   (interactive)
 357   (org-with-silent-modifications
 358    (org-columns-remove-overlays)
 359    (let ((inhibit-read-only t))
 360      (remove-text-properties (point-min) (point-max) '(read-only t))))
 361   (when (eq major-mode 'org-agenda-mode)
 362     (setq org-agenda-columns-active nil)
 363     (message
 364      "Modification not yet reflected in Agenda buffer, use `r' to refresh")))
 365
 366 (defun org-columns-check-computed ()
 367   "Check if this column value is computed.
 368 If yes, throw an error indicating that changing it does not make sense."
 369   (let ((val (get-char-property (point) 'org-columns-value)))
 370     (when (and (stringp val)
 371                (get-char-property 0 'org-computed val))
 372       (error "This value is computed from the entry's children"))))
 373
 374 (defun org-columns-todo (&optional arg)
 375   "Change the TODO state during column view."
 376   (interactive "P")
 377   (org-columns-edit-value "TODO"))
 378
 379 (defun org-columns-set-tags-or-toggle (&optional arg)
 380   "Toggle checkbox at point, or set tags for current headline."
 381   (interactive "P")
 382   (if (string-match "\\`\\[[ xX-]\\]\\'"
 383                     (get-char-property (point) 'org-columns-value))
 384       (org-columns-next-allowed-value)
 385     (org-columns-edit-value "TAGS")))
 386
 387 (defvar org-agenda-overriding-columns-format nil
 388   "When set, overrides any other format definition for the agenda.
 389 Don't set this, this is meant for dynamic scoping.")
 390
 391 (defun org-columns-edit-value (&optional key)
 392   "Edit the value of the property at point in column view.
 393 Where possible, use the standard interface for changing this line."
 394   (interactive)
 395   (org-columns-check-computed)
 396   (let* ((col (current-column))
 397          (key (or key (get-char-property (point) 'org-columns-key)))
 398          (value (get-char-property (point) 'org-columns-value))
 399          (bol (point-at-bol)) (eol (point-at-eol))
 400          (pom (or (get-text-property bol 'org-hd-marker)
 401                   (point)))          ; keep despite of compiler waring
 402          (line-overlays
 403           (delq nil (mapcar (lambda (x)
 404                               (and (eq (overlay-buffer x) (current-buffer))
 405                                    (>= (overlay-start x) bol)
 406                                    (<= (overlay-start x) eol)
 407                                    x))
 408                             org-columns-overlays)))
 409          (org-columns-time (time-to-number-of-days (current-time)))
 410          nval eval allowed)
 411     (cond
 412      ((equal key "CLOCKSUM")
 413       (error "This special column cannot be edited"))
 414      ((equal key "ITEM")
 415       (setq eval '(org-with-point-at pom
 416                     (org-edit-headline))))
 417      ((equal key "TODO")
 418       (setq eval '(org-with-point-at
 419                       pom
 420                     (call-interactively 'org-todo))))
 421      ((equal key "PRIORITY")
 422       (setq eval '(org-with-point-at pom
 423                     (call-interactively 'org-priority))))
 424      ((equal key "TAGS")
 425       (setq eval '(org-with-point-at pom
 426                     (let ((org-fast-tag-selection-single-key
 427                            (if (eq org-fast-tag-selection-single-key 'expert)
 428                                t org-fast-tag-selection-single-key)))
 429                       (call-interactively 'org-set-tags)))))
 430      ((equal key "DEADLINE")
 431       (setq eval '(org-with-point-at pom
 432                     (call-interactively 'org-deadline))))
 433      ((equal key "SCHEDULED")
 434       (setq eval '(org-with-point-at pom
 435                     (call-interactively 'org-schedule))))
 436      ((equal key "BEAMER_env")
 437       (setq eval '(org-with-point-at pom
 438                     (call-interactively 'org-beamer-select-environment))))
 439      (t
 440       (setq allowed (org-property-get-allowed-values pom key 'table))
 441       (if allowed
 442           (setq nval (org-icompleting-read
 443                       "Value: " allowed nil
 444                       (not (get-text-property 0 'org-unrestricted
 445                                               (caar allowed)))))
 446         (setq nval (read-string "Edit: " value)))
 447       (setq nval (org-trim nval))
 448       (when (not (equal nval value))
 449         (setq eval '(org-entry-put pom key nval)))))
 450     (when eval
 451
 452       (cond
 453        ((equal major-mode 'org-agenda-mode)
 454         (org-columns-eval eval)
 455         ;; The following let preserves the current format, and makes sure
 456         ;; that in only a single file things need to be updated.
 457         (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 458                (buffer (marker-buffer pom))
 459                (org-agenda-contributing-files
 460                 (list (with-current-buffer buffer
 461                         (buffer-file-name (buffer-base-buffer))))))
 462           (org-agenda-columns)))
 463        (t
 464         (let ((inhibit-read-only t))
 465           (org-with-silent-modifications
 466            (remove-text-properties
 467             (max (point-min) (1- bol)) eol '(read-only t)))
 468           (unwind-protect
 469               (progn
 470                 (setq org-columns-overlays
 471                       (org-delete-all line-overlays org-columns-overlays))
 472                 (mapc 'delete-overlay line-overlays)
 473                 (org-columns-eval eval))
 474             (org-columns-display-here)))
 475         (org-move-to-column col)
 476         (if (and (derived-mode-p 'org-mode)
 477                  (nth 3 (assoc-string key org-columns-current-fmt-compiled t)))
 478             (org-columns-update key)))))))
 479
 480 (defun org-edit-headline () ; FIXME: this is not columns specific.  Make interactive?????  Use from agenda????
 481   "Edit the current headline, the part without TODO keyword, TAGS."
 482   (org-back-to-heading)
 483   (when (looking-at org-todo-line-regexp)
 484     (let ((pos (point))
 485           (pre (buffer-substring (match-beginning 0) (match-beginning 3)))
 486           (txt (match-string 3))
 487           (post "")
 488           txt2)
 489       (if (string-match (org-re "[ \t]+:[[:alnum:]:_@#%]+:[ \t]*$") txt)
 490           (setq post (match-string 0 txt)
 491                 txt (substring txt 0 (match-beginning 0))))
 492       (setq txt2 (read-string "Edit: " txt))
 493       (when (not (equal txt txt2))
 494         (goto-char pos)
 495         (insert pre txt2 post)
 496         (delete-region (point) (point-at-eol))
 497         (org-set-tags nil t)))))
 498
 499 (defun org-columns-edit-allowed ()
 500   "Edit the list of allowed values for the current property."
 501   (interactive)
 502   (let* ((pom (or (org-get-at-bol 'org-marker)
 503                   (org-get-at-bol 'org-hd-marker)
 504                   (point)))
 505          (key (get-char-property (point) 'org-columns-key))
 506          (key1 (concat key "_ALL"))
 507          (allowed (org-entry-get pom key1 t))
 508          nval)
 509     ;; FIXME: Cover editing TODO, TAGS etc in-buffer settings.????
 510     ;; FIXME: Write back to #+PROPERTY setting if that is needed.
 511     (setq nval (read-string "Allowed: " allowed))
 512     (org-entry-put
 513      (cond ((marker-position org-entry-property-inherited-from)
 514             org-entry-property-inherited-from)
 515            ((marker-position org-columns-top-level-marker)
 516             org-columns-top-level-marker)
 517            (t pom))
 518      key1 nval)))
 519
 520 (defun org-columns-eval (form)
 521   (let (hidep)
 522     (save-excursion
 523       (beginning-of-line 1)
 524       ;; `next-line' is needed here, because it skips invisible line.
 525       (condition-case nil (org-no-warnings (next-line 1)) (error nil))
 526       (setq hidep (org-at-heading-p 1)))
 527     (eval form)
 528     (and hidep (hide-entry))))
 529
 530 (defun org-columns-previous-allowed-value ()
 531   "Switch to the previous allowed value for this column."
 532   (interactive)
 533   (org-columns-next-allowed-value t))
 534
 535 (defun org-columns-next-allowed-value (&optional previous nth)
 536   "Switch to the next allowed value for this column.
 537 When PREVIOUS is set, go to the previous value.  When NTH is
 538 an integer, select that value."
 539   (interactive)
 540   (org-columns-check-computed)
 541   (let* ((col (current-column))
 542          (key (get-char-property (point) 'org-columns-key))
 543          (value (get-char-property (point) 'org-columns-value))
 544          (bol (point-at-bol)) (eol (point-at-eol))
 545          (pom (or (get-text-property bol 'org-hd-marker)
 546                   (point)))          ; keep despite of compiler waring
 547          (line-overlays
 548           (delq nil (mapcar (lambda (x)
 549                               (and (eq (overlay-buffer x) (current-buffer))
 550                                    (>= (overlay-start x) bol)
 551                                    (<= (overlay-start x) eol)
 552                                    x))
 553                             org-columns-overlays)))
 554          (allowed (or (org-property-get-allowed-values pom key)
 555                       (and (memq
 556                             (nth 4 (assoc-string key
 557                                                  org-columns-current-fmt-compiled
 558                                                  t))
 559                             '(checkbox checkbox-n-of-m checkbox-percent))
 560                            '("[ ]" "[X]"))
 561                       (org-colview-construct-allowed-dates value)))
 562          nval)
 563     (when (integerp nth)
 564       (setq nth (1- nth))
 565       (if (= nth -1) (setq nth 9)))
 566     (when (equal key "ITEM")
 567       (error "Cannot edit item headline from here"))
 568     (unless (or allowed (member key '("SCHEDULED" "DEADLINE" "CLOCKSUM")))
 569       (error "Allowed values for this property have not been defined"))
 570     (if (member key '("SCHEDULED" "DEADLINE" "CLOCKSUM"))
 571         (setq nval (if previous 'earlier 'later))
 572       (if previous (setq allowed (reverse allowed)))
 573       (cond
 574        (nth
 575         (setq nval (nth nth allowed))
 576         (if (not nval)
 577             (error "There are only %d allowed values for property `%s'"
 578                    (length allowed) key)))
 579        ((member value allowed)
 580         (setq nval (or (car (cdr (member value allowed)))
 581                        (car allowed)))
 582         (if (equal nval value)
 583             (error "Only one allowed value for this property")))
 584        (t (setq nval (car allowed)))))
 585     (cond
 586      ((equal major-mode 'org-agenda-mode)
 587       (org-columns-eval '(org-entry-put pom key nval))
 588       ;; The following let preserves the current format, and makes sure
 589       ;; that in only a single file things need to be updated.
 590       (let* ((org-agenda-overriding-columns-format org-columns-current-fmt)
 591              (buffer (marker-buffer pom))
 592              (org-agenda-contributing-files
 593               (list (with-current-buffer buffer
 594                       (buffer-file-name (buffer-base-buffer))))))
 595         (org-agenda-columns)))
 596      (t
 597       (let ((inhibit-read-only t))
 598         (remove-text-properties (1- bol) eol '(read-only t))
 599         (unwind-protect
 600             (progn
 601               (setq org-columns-overlays
 602                     (org-delete-all line-overlays org-columns-overlays))
 603               (mapc 'delete-overlay line-overlays)
 604               (org-columns-eval '(org-entry-put pom key nval)))
 605           (org-columns-display-here)))
 606       (org-move-to-column col)
 607       (and (nth 3 (assoc-string key org-columns-current-fmt-compiled t))
 608            (org-columns-update key))))))
 609
 610 (defun org-colview-construct-allowed-dates (s)
 611   "Construct a list of three dates around the date in S.
 612 This respects the format of the time stamp in S, active or non-active,
 613 and also including time or not.  S must be just a time stamp, no text
 614 around it."
 615   (when (and s (string-match (concat "^" org-ts-regexp3 "$") s))
 616     (let* ((time (org-parse-time-string s 'nodefaults))
 617            (active (equal (string-to-char s) ?<))
 618            (fmt (funcall (if (nth 1 time) 'cdr 'car) org-time-stamp-formats))
 619            time-before time-after)
 620       (unless active (setq fmt (concat "[" (substring fmt 1 -1) "]")))
 621       (setf (car time) (or (car time) 0))
 622       (setf (nth 1 time) (or (nth 1 time) 0))
 623       (setf (nth 2 time) (or (nth 2 time) 0))
 624       (setq time-before (copy-sequence time))
 625       (setq time-after (copy-sequence time))
 626       (setf (nth 3 time-before) (1- (nth 3 time)))
 627       (setf (nth 3 time-after) (1+ (nth 3 time)))
 628       (mapcar (lambda (x) (format-time-string fmt (apply 'encode-time x)))
 629               (list time-before time time-after)))))
 630
 631 (defun org-verify-version (task)
 632   (cond
 633    ((eq task 'columns)
 634     (if (or (featurep 'xemacs)
 635             (< emacs-major-version 22))
 636         (error "Emacs 22 is required for the columns feature")))))
 637
 638 (defun org-columns-open-link (&optional arg)
 639   (interactive "P")
 640   (let ((value (get-char-property (point) 'org-columns-value)))
 641     (org-open-link-from-string value arg)))
 642
 643 ;;;###autoload
 644 (defun org-columns-get-format-and-top-level ()
 645   (let ((fmt (org-columns-get-format)))
 646     (org-columns-goto-top-level)
 647     fmt))
 648
 649 (defun org-columns-get-format (&optional fmt-string)
 650   (interactive)
 651   (let (fmt-as-property fmt)
 652     (when (condition-case nil (org-back-to-heading) (error nil))
 653       (setq fmt-as-property (org-entry-get nil "COLUMNS" t)))
 654     (setq fmt (or fmt-string fmt-as-property org-columns-default-format))
 655     (org-set-local 'org-columns-current-fmt fmt)
 656     (org-columns-compile-format fmt)
 657     fmt))
 658
 659 (defun org-columns-goto-top-level ()
 660   (when (condition-case nil (org-back-to-heading) (error nil))
 661     (org-entry-get nil "COLUMNS" t))
 662   (if (marker-position org-entry-property-inherited-from)
 663       (move-marker org-columns-top-level-marker org-entry-property-inherited-from)
 664     (move-marker org-columns-top-level-marker (point))))
 665
 666 ;;;###autoload
 667 (defun org-columns (&optional columns-fmt-string)
 668   "Turn on column view on an org-mode file.
 669 When COLUMNS-FMT-STRING is non-nil, use it as the column format."
 670   (interactive)
 671   (org-verify-version 'columns)
 672   (org-columns-remove-overlays)
 673   (move-marker org-columns-begin-marker (point))
 674   (org-columns-goto-top-level)
 675   ;; Initialize `org-columns-current-fmt' and
 676   ;; `org-columns-current-fmt-compiled'.
 677   (let ((org-columns-time (time-to-number-of-days (current-time))))
 678     (org-columns-get-format columns-fmt-string))
 679   (unless org-columns-inhibit-recalculation (org-columns-compute-all))
 680   (save-excursion
 681     (save-restriction
 682       (narrow-to-region
 683        org-columns-top-level-marker
 684        (or (ignore-errors (org-end-of-subtree t t)) (point-max)))
 685       (goto-char (point-min))
 686       (when (assoc "CLOCKSUM" org-columns-current-fmt-compiled)
 687         (org-clock-sum))
 688       (when (assoc "CLOCKSUM_T" org-columns-current-fmt-compiled)
 689         (org-clock-sum-today))
 690       (let* ((column-names (mapcar #'car org-columns-current-fmt-compiled))
 691              (cache
 692               (org-map-entries
 693                (lambda ()
 694                  (cons (point)
 695                        (mapcar
 696                         (lambda (p)
 697                           (cons p (org-entry-get nil p 'selective t)))
 698                         column-names)))
 699                nil nil (and org-columns-skip-archived-trees 'archive))))
 700         (when cache
 701           (org-set-local 'org-columns-current-maxwidths
 702                          (org-columns-get-autowidth-alist
 703                           org-columns-current-fmt
 704                           cache))
 705           (org-columns-display-here-title)
 706           (when (org-set-local 'org-columns-flyspell-was-active
 707                                (org-bound-and-true-p flyspell-mode))
 708             (flyspell-mode 0))
 709           (unless (local-variable-p 'org-colview-initial-truncate-line-value)
 710             (org-set-local 'org-colview-initial-truncate-line-value
 711                            truncate-lines))
 712           (setq truncate-lines t)
 713           (dolist (x cache)
 714             (goto-char (car x))
 715             (org-columns-display-here (cdr x))))))))
 716
 717 (eval-when-compile (defvar org-columns-time))
 718
 719 (defvar org-columns-compile-map
 720   '(("none" none +)
 721     (":" add_times +)
 722     ("+" add_numbers +)
 723     ("$" currency +)
 724     ("X" checkbox +)
 725     ("X/" checkbox-n-of-m +)
 726     ("X%" checkbox-percent +)
 727     ("max" max_numbers max)
 728     ("min" min_numbers min)
 729     ("mean" mean_numbers
 730      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 731     (":max" max_times max)
 732     (":min" min_times min)
 733     (":mean" mean_times
 734      (lambda (&rest x) (/ (apply '+ x) (float (length x)))))
 735     ("@min" min_age min (lambda (x) (- org-columns-time x)))
 736     ("@max" max_age max (lambda (x) (- org-columns-time x)))
 737     ("@mean" mean_age
 738      (lambda (&rest x) (/ (apply '+ x) (float (length x))))
 739      (lambda (x) (- org-columns-time x)))
 740     ("est+" estimate org-estimate-combine))
 741   "Operator <-> format,function,calc  map.
 742 Used to compile/uncompile columns format and completing read in
 743 interactive function `org-columns-new'.
 744
 745 operator    string used in #+COLUMNS definition describing the
 746             summary type
 747 format      symbol describing summary type selected interactively in
 748             `org-columns-new' and internally in
 749             `org-columns-number-to-string' and
 750             `org-columns-string-to-number'
 751 function    called with a list of values as argument to calculate
 752             the summary value
 753 calc        function called on every element before summarizing.  This is
 754             optional and should only be specified if needed")
 755
 756 (defun org-columns-new (&optional prop title width op fmt fun &rest rest)
 757   "Insert a new column, to the left of the current column."
 758   (interactive)
 759   (let ((editp (and prop
 760                     (assoc-string prop org-columns-current-fmt-compiled t)))
 761         cell)
 762     (setq prop (org-icompleting-read
 763                 "Property: " (mapcar 'list (org-buffer-property-keys t nil t))
 764                 nil nil prop))
 765     (setq title (read-string (concat "Column title [" prop "]: ") (or title prop)))
 766     (setq width (read-string "Column width: " (if width (number-to-string width))))
 767     (if (string-match "\\S-" width)
 768         (setq width (string-to-number width))
 769       (setq width nil))
 770     (setq fmt (org-icompleting-read
 771                "Summary [none]: "
 772                (mapcar (lambda (x) (list (symbol-name (cadr x))))
 773                        org-columns-compile-map)
 774                nil t))
 775     (setq fmt (intern fmt)
 776           fun (cdr (assoc fmt (mapcar 'cdr org-columns-compile-map))))
 777     (if (eq fmt 'none) (setq fmt nil))
 778     (if editp
 779         (progn
 780           (setcar editp prop)
 781           (setcdr editp (list title width nil fmt nil fun)))
 782       (setq cell (nthcdr (1- (current-column))
 783                          org-columns-current-fmt-compiled))
 784       (setcdr cell (cons (list prop title width nil fmt nil
 785                                (car fun) (cadr fun))
 786                          (cdr cell))))
 787     (org-columns-store-format)
 788     (org-columns-redo)))
 789
 790 (defun org-columns-delete ()
 791   "Delete the column at point from columns view."
 792   (interactive)
 793   (let* ((n (current-column))
 794          (title (nth 1 (nth n org-columns-current-fmt-compiled))))
 795     (when (y-or-n-p
 796            (format "Are you sure you want to remove column \"%s\"? " title))
 797       (setq org-columns-current-fmt-compiled
 798             (delq (nth n org-columns-current-fmt-compiled)
 799                   org-columns-current-fmt-compiled))
 800       (org-columns-store-format)
 801       (org-columns-redo)
 802       (if (>= (current-column) (length org-columns-current-fmt-compiled))
 803           (backward-char 1)))))
 804
 805 (defun org-columns-edit-attributes ()
 806   "Edit the attributes of the current column."
 807   (interactive)
 808   (let* ((n (current-column))
 809          (info (nth n org-columns-current-fmt-compiled)))
 810     (apply 'org-columns-new info)))
 811
 812 (defun org-columns-widen (arg)
 813   "Make the column wider by ARG characters."
 814   (interactive "p")
 815   (let* ((n (current-column))
 816          (entry (nth n org-columns-current-fmt-compiled))
 817          (width (or (nth 2 entry)
 818                     (cdr (assoc-string (car entry)
 819                                        org-columns-current-maxwidths
 820                                        t)))))
 821     (setq width (max 1 (+ width arg)))
 822     (setcar (nthcdr 2 entry) width)
 823     (org-columns-store-format)
 824     (org-columns-redo)))
 825
 826 (defun org-columns-narrow (arg)
 827   "Make the column narrower by ARG characters."
 828   (interactive "p")
 829   (org-columns-widen (- arg)))
 830
 831 (defun org-columns-move-right ()
 832   "Swap this column with the one to the right."
 833   (interactive)
 834   (let* ((n (current-column))
 835          (cell (nthcdr n org-columns-current-fmt-compiled))
 836          e)
 837     (when (>= n (1- (length org-columns-current-fmt-compiled)))
 838       (error "Cannot shift this column further to the right"))
 839     (setq e (car cell))
 840     (setcar cell (car (cdr cell)))
 841     (setcdr cell (cons e (cdr (cdr cell))))
 842     (org-columns-store-format)
 843     (org-columns-redo)
 844     (forward-char 1)))
 845
 846 (defun org-columns-move-left ()
 847   "Swap this column with the one to the left."
 848   (interactive)
 849   (let* ((n (current-column)))
 850     (when (= n 0)
 851       (error "Cannot shift this column further to the left"))
 852     (backward-char 1)
 853     (org-columns-move-right)
 854     (backward-char 1)))
 855
 856 (defun org-columns-store-format ()
 857   "Store the text version of the current columns format in appropriate place.
 858 This is either in the COLUMNS property of the node starting the current column
 859 display, or in the #+COLUMNS line of the current buffer."
 860   (let (fmt (cnt 0))
 861     (setq fmt (org-columns-uncompile-format org-columns-current-fmt-compiled))
 862     (org-set-local 'org-columns-current-fmt fmt)
 863     (if (marker-position org-columns-top-level-marker)
 864         (save-excursion
 865           (goto-char org-columns-top-level-marker)
 866           (if (and (org-at-heading-p)
 867                    (org-entry-get nil "COLUMNS"))
 868               (org-entry-put nil "COLUMNS" fmt)
 869             (goto-char (point-min))
 870             ;; Overwrite all #+COLUMNS lines....
 871             (while (re-search-forward "^[ \t]*#\\+COLUMNS:.*" nil t)
 872               (setq cnt (1+ cnt))
 873               (replace-match (concat "#+COLUMNS: " fmt) t t))
 874             (unless (> cnt 0)
 875               (goto-char (point-min))
 876               (or (org-at-heading-p t) (outline-next-heading))
 877               (let ((inhibit-read-only t))
 878                 (insert-before-markers "#+COLUMNS: " fmt "\n")))
 879             (org-set-local 'org-columns-default-format fmt))))))
 880
 881 (defun org-columns-get-autowidth-alist (s cache)
 882   "Derive the maximum column widths from the format and the cache."
 883   (let ((start 0) rtn)
 884     (while (string-match (org-re "%\\([[:alpha:]][[:alnum:]_-]*\\)") s start)
 885       (push (cons (match-string 1 s) 1) rtn)
 886       (setq start (match-end 0)))
 887     (mapc (lambda (x)
 888             (setcdr x
 889                     (apply #'max
 890                            (let ((prop (car x)))
 891                              (mapcar
 892                               (lambda (y)
 893                                 (length (or (cdr (assoc-string prop (cdr y) t))
 894                                             " ")))
 895                               cache)))))
 896           rtn)
 897     rtn))
 898
 899 (defun org-columns-compute-all ()
 900   "Compute all columns that have operators defined."
 901   (org-with-silent-modifications
 902    (remove-text-properties (point-min) (point-max) '(org-summaries t)))
 903   (let ((columns org-columns-current-fmt-compiled)
 904         (org-columns-time (time-to-number-of-days (current-time)))
 905         col)
 906     (while (setq col (pop columns))
 907       (when (nth 3 col)
 908         (save-excursion
 909           (org-columns-compute (car col)))))))
 910
 911 (defun org-columns-update (property)
 912   "Recompute PROPERTY, and update the columns display for it."
 913   (org-columns-compute property)
 914   (let (fmt val pos)
 915     (save-excursion
 916       (mapc (lambda (ov)
 917               (when (equal (overlay-get ov 'org-columns-key) property)
 918                 (setq pos (overlay-start ov))
 919                 (goto-char pos)
 920                 (when (setq val (cdr (assoc-string
 921                                       property
 922                                       (get-text-property
 923                                        (point-at-bol) 'org-summaries)
 924                                       t)))
 925                   (setq fmt (overlay-get ov 'org-columns-format))
 926                   (overlay-put ov 'org-columns-value val)
 927                   (overlay-put ov 'display (format fmt val)))))
 928             org-columns-overlays))))
 929
 930 (defvar org-inlinetask-min-level
 931   (if (featurep 'org-inlinetask) org-inlinetask-min-level 15))
 932
 933 ;;;###autoload
 934 (defun org-columns-compute (property)
 935   "Sum the values of property PROPERTY hierarchically, for the entire buffer."
 936   (interactive)
 937   (let* ((re org-outline-regexp-bol)
 938          (lmax 30)                  ; Does anyone use deeper levels???
 939          (lvals (make-vector lmax nil))
 940          (lflag (make-vector lmax nil))
 941          (level 0)
 942          (ass (assoc-string property org-columns-current-fmt-compiled t))
 943          (format (nth 4 ass))
 944          (printf (nth 5 ass))
 945          (fun (nth 6 ass))
 946          (calc (or (nth 7 ass) 'identity))
 947          (beg org-columns-top-level-marker)
 948          (inminlevel org-inlinetask-min-level)
 949          (last-level org-inlinetask-min-level)
 950          val valflag flag end sumpos sum-alist sum str str1 useval)
 951     (save-excursion
 952       ;; Find the region to compute
 953       (goto-char beg)
 954       (setq end (condition-case nil (org-end-of-subtree t) (error (point-max))))
 955       (goto-char end)
 956       ;; Walk the tree from the back and do the computations
 957       (while (re-search-backward re beg t)
 958         (setq sumpos (match-beginning 0)
 959               last-level (if (not (or (zerop level) (eq level inminlevel)))
 960                              level last-level)
 961               level (org-outline-level)
 962               val (org-entry-get nil property)
 963               valflag (and val (string-match "\\S-" val)))
 964         (cond
 965          ((< level last-level)
 966           ;; Put the sum of lower levels here as a property.  If
 967           ;; values are estimate, use an appropriate sum function.
 968           (setq sum (funcall
 969                      (if (eq fun 'org-estimate-combine) #'org-estimate-combine
 970                        #'+)
 971                      (if (and (/= last-level inminlevel)
 972                               (aref lvals last-level))
 973                          (apply fun (aref lvals last-level)) 0)
 974                      (if (aref lvals inminlevel)
 975                          (apply fun (aref lvals inminlevel)) 0))
 976                 flag (or (aref lflag last-level) ; any valid entries from children?
 977                          (aref lflag inminlevel)) ; or inline tasks?
 978                 str (org-columns-number-to-string sum format printf)
 979                 str1 (org-add-props (copy-sequence str) nil 'org-computed t 'face 'bold)
 980                 useval (if flag str1 (if valflag val ""))
 981                 sum-alist (get-text-property sumpos 'org-summaries))
 982           (let ((old (assoc-string property sum-alist t)))
 983             (if old (setcdr old useval)
 984               (push (cons property useval) sum-alist)
 985               (org-with-silent-modifications
 986                (add-text-properties sumpos (1+ sumpos)
 987                                     (list 'org-summaries sum-alist)))))
 988           (when (and val (not (equal val (if flag str val))))
 989             (org-entry-put nil property (if flag str val)))
 990           ;; add current to current level accumulator
 991           (when (or flag valflag)
 992             (push (if flag
 993                       sum
 994                     (funcall calc (org-columns-string-to-number
 995                                    (if flag str val) format)))
 996                   (aref lvals level))
 997             (aset lflag level t))
 998           ;; clear accumulators for deeper levels
 999           (loop for l from (1+ level) to (1- lmax) do
1000                 (aset lvals l nil)
1001                 (aset lflag l nil)))
1002          ((>= level last-level)
1003           ;; add what we have here to the accumulator for this level
1004           (when valflag
1005             (push (funcall calc (org-columns-string-to-number val format))
1006                   (aref lvals level))
1007             (aset lflag level t)))
1008          (t (error "This should not happen")))))))
1009
1010 (defun org-columns-redo ()
1011   "Construct the column display again."
1012   (interactive)
1013   (message "Recomputing columns...")
1014   (let ((line (org-current-line))
1015         (col (current-column)))
1016     (save-excursion
1017       (if (marker-position org-columns-begin-marker)
1018           (goto-char org-columns-begin-marker))
1019       (org-columns-remove-overlays)
1020       (if (derived-mode-p 'org-mode)
1021           (call-interactively 'org-columns)
1022         (org-agenda-redo)
1023         (call-interactively 'org-agenda-columns)))
1024     (org-goto-line line)
1025     (move-to-column col))
1026   (message "Recomputing columns...done"))
1027
1028 (defun org-columns-not-in-agenda ()
1029   (if (eq major-mode 'org-agenda-mode)
1030       (error "This command is only allowed in Org-mode buffers")))
1031
1032 (defun org-string-to-number (s)
1033   "Convert string to number, and interpret hh:mm:ss."
1034   (if (not (string-match ":" s))
1035       (string-to-number s)
1036     (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1037       (while l
1038         (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1039       sum)))
1040
1041 ;;;###autoload
1042 (defun org-columns-number-to-string (n fmt &optional printf)
1043   "Convert a computed column number to a string value, according to FMT."
1044   (cond
1045    ((memq fmt '(estimate)) (org-estimate-print n printf))
1046    ((not (numberp n)) "")
1047    ((memq fmt '(add_times max_times min_times mean_times))
1048     (org-hours-to-clocksum-string n))
1049    ((eq fmt 'checkbox)
1050     (cond ((= n (floor n)) "[X]")
1051           ((> n 1.) "[-]")
1052           (t "[ ]")))
1053    ((memq fmt '(checkbox-n-of-m checkbox-percent))
1054     (let* ((n1 (floor n)) (n2 (floor (+ .5 (* 1000000 (- n n1))))))
1055       (org-nofm-to-completion n1 (+ n2 n1) (eq fmt 'checkbox-percent))))
1056    (printf (format printf n))
1057    ((eq fmt 'currency)
1058     (format "%.2f" n))
1059    ((memq fmt '(min_age max_age mean_age))
1060     (org-format-time-period n))
1061    (t (number-to-string n))))
1062
1063 (defun org-nofm-to-completion (n m &optional percent)
1064   (if (not percent)
1065       (format "[%d/%d]" n m)
1066     (format "[%d%%]"(floor (+ 0.5 (* 100. (/ (* 1.0 n) m)))))))
1067
1068
1069 (defun org-columns-string-to-number (s fmt)
1070   "Convert a column value to a number that can be used for column computing."
1071   (if s
1072       (cond
1073        ((memq fmt '(min_age max_age mean_age))
1074         (cond ((string= s "") org-columns-time)
1075               ((string-match
1076                 "\\([0-9]+\\)d \\([0-9]+\\)h \\([0-9]+\\)m \\([0-9]+\\)s"
1077                 s)
1078                (+ (* 60 (+ (* 60 (+ (* 24 (string-to-number (match-string 1 s)))
1079                                     (string-to-number (match-string 2 s))))
1080                            (string-to-number (match-string 3 s))))
1081                   (string-to-number (match-string 4 s))))
1082               (t (time-to-number-of-days (apply 'encode-time
1083                                                 (org-parse-time-string s t))))))
1084        ((string-match ":" s)
1085         (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1086           (while l
1087             (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1088           sum))
1089        ((memq fmt '(checkbox checkbox-n-of-m checkbox-percent))
1090         (if (equal s "[X]") 1. 0.000001))
1091        ((memq fmt '(estimate)) (org-string-to-estimate s))
1092        ((string-match (concat "\\([0-9.]+\\) *\\("
1093                               (regexp-opt (mapcar 'car org-effort-durations))
1094                               "\\)") s)
1095         (setq s (concat "0:" (org-duration-string-to-minutes s t)))
1096         (let ((l (nreverse (org-split-string s ":"))) (sum 0.0))
1097           (while l
1098             (setq sum (+ (string-to-number (pop l)) (/ sum 60))))
1099           sum))
1100        (t (string-to-number s)))))
1101
1102 (defun org-columns-uncompile-format (cfmt)
1103   "Turn the compiled columns format back into a string representation."
1104   (let ((rtn "") e s prop title op op-match width fmt printf fun calc ee map)
1105     (while (setq e (pop cfmt))
1106       (setq prop (car e)
1107             title (nth 1 e)
1108             width (nth 2 e)
1109             op (nth 3 e)
1110             fmt (nth 4 e)
1111             printf (nth 5 e)
1112             fun (nth 6 e)
1113             calc (nth 7 e))
1114       (setq map (copy-sequence org-columns-compile-map))
1115       (while (setq ee (pop map))
1116         (if (equal fmt (nth 1 ee))
1117             (setq op (car ee) map nil)))
1118       (if (and op printf) (setq op (concat op ";" printf)))
1119       (if (equal title prop) (setq title nil))
1120       (setq s (concat "%" (if width (number-to-string width))
1121                       prop
1122                       (if title (concat "(" title ")"))
1123                       (if op (concat "{" op "}"))))
1124       (setq rtn (concat rtn " " s)))
1125     (org-trim rtn)))
1126
1127 (defun org-columns-compile-format (fmt)
1128   "Turn a column format string FMT into an alist of specifications.
1129
1130 The alist has one entry for each column in the format.  The elements of
1131 that list are:
1132 property     the property
1133 title        the title field for the columns
1134 width        the column width in characters, can be nil for automatic
1135 operator     the operator if any
1136 format       the output format for computed results, derived from operator
1137 printf       a printf format for computed values
1138 fun          the lisp function to compute summary values, derived from operator
1139 calc         function to get values from base elements
1140
1141 This function updates `org-columns-current-fmt-compiled'."
1142   (let ((start 0) width prop title op op-match f printf fun calc)
1143     (setq org-columns-current-fmt-compiled nil)
1144     (while (string-match
1145             (org-re "%\\([0-9]+\\)?\\([[:alnum:]_-]+\\)\\(?:(\\([^)]+\\))\\)?\\(?:{\\([^}]+\\)}\\)?\\s-*")
1146             fmt start)
1147       (setq start (match-end 0)
1148             width (match-string 1 fmt)
1149             prop (match-string 2 fmt)
1150             title (or (match-string 3 fmt) prop)
1151             op (match-string 4 fmt)
1152             f nil
1153             printf nil
1154             fun '+
1155             calc nil)
1156       (if width (setq width (string-to-number width)))
1157       (when (and op (string-match ";" op))
1158         (setq printf (substring op (match-end 0))
1159               op (substring op 0 (match-beginning 0))))
1160       (when (setq op-match (assoc op org-columns-compile-map))
1161         (setq f (cadr op-match)
1162               fun (caddr op-match)
1163               calc (cadddr op-match)))
1164       (push (list prop title width op f printf fun calc)
1165             org-columns-current-fmt-compiled))
1166     (setq org-columns-current-fmt-compiled
1167           (nreverse org-columns-current-fmt-compiled))))
1168
1169
1170 ;;; Dynamic block for Column view
1171
1172 (defvar org-heading-regexp) ; defined in org.el
1173 (defvar org-heading-keyword-regexp-format) ; defined in org.el
1174 (defun org-columns-capture-view (&optional maxlevel skip-empty-rows)
1175   "Get the column view of the current buffer or subtree.
1176 The first optional argument MAXLEVEL sets the level limit.  A
1177 second optional argument SKIP-EMPTY-ROWS tells whether to skip
1178 empty rows, an empty row being one where all the column view
1179 specifiers except ITEM are empty.  This function returns a list
1180 containing the title row and all other rows.  Each row is a list
1181 of fields."
1182   (save-excursion
1183     (let* ((title (mapcar 'cadr org-columns-current-fmt-compiled))
1184            (re-archive (concat ".*:" org-archive-tag ":"))
1185            (n (length title)) row tbl)
1186       (goto-char (point-min))
1187       (while (re-search-forward org-heading-regexp nil t)
1188         (catch 'next
1189           (when (and (or (null maxlevel)
1190                          (>= maxlevel
1191                              (if org-odd-levels-only
1192                                  (/ (1+ (length (match-string 1))) 2)
1193                                (length (match-string 1)))))
1194                      (get-char-property (match-beginning 0) 'org-columns-key))
1195             (when (or (org-in-commented-heading-p t)
1196                       (save-excursion
1197                         (beginning-of-line)
1198                         (looking-at re-archive)))
1199               (org-end-of-subtree t)
1200               (throw 'next t))
1201             (setq row nil)
1202             (loop for i from 0 to (1- n) do
1203                   (push
1204                    (org-quote-vert
1205                     (or (get-char-property (+ (match-beginning 0) i) 'org-columns-value-modified)
1206                         (get-char-property (+ (match-beginning 0) i) 'org-columns-value)
1207                         ""))
1208                    row))
1209             (setq row (nreverse row))
1210             (unless (and skip-empty-rows
1211                          (eq 1 (length (delete "" (delete-dups (copy-sequence row))))))
1212               (push row tbl)))))
1213       (append (list title 'hline) (nreverse tbl)))))
1214
1215 ;;;###autoload
1216 (defun org-dblock-write:columnview (params)
1217   "Write the column view table.
1218 PARAMS is a property list of parameters:
1219
1220 :width    enforce same column widths with <N> specifiers.
1221 :id       the :ID: property of the entry where the columns view
1222           should be built.  When the symbol `local', call locally.
1223           When `global' call column view with the cursor at the beginning
1224           of the buffer (usually this means that the whole buffer switches
1225           to column view).  When \"file:path/to/file.org\", invoke column
1226           view at the start of that file.  Otherwise, the ID is located
1227           using `org-id-find'.
1228 :hlines   When t, insert a hline before each item.  When a number, insert
1229           a hline before each level <= that number.
1230 :vlines   When t, make each column a colgroup to enforce vertical lines.
1231 :maxlevel When set to a number, don't capture headlines below this level.
1232 :skip-empty-rows
1233           When t, skip rows where all specifiers other than ITEM are empty.
1234 :format   When non-nil, specify the column view format to use."
1235   (let ((pos (point-marker))
1236         (hlines (plist-get params :hlines))
1237         (vlines (plist-get params :vlines))
1238         (maxlevel (plist-get params :maxlevel))
1239         (content-lines (org-split-string (plist-get params :content) "\n"))
1240         (skip-empty-rows (plist-get params :skip-empty-rows))
1241         (columns-fmt (plist-get params :format))
1242         (case-fold-search t)
1243         tbl id idpos nfields tmp recalc line
1244         id-as-string view-file view-pos)
1245     (when (setq id (plist-get params :id))
1246       (setq id-as-string (cond ((numberp id) (number-to-string id))
1247                                ((symbolp id) (symbol-name id))
1248                                ((stringp id) id)
1249                                (t "")))
1250       (cond ((not id) nil)
1251             ((eq id 'global) (setq view-pos (point-min)))
1252             ((eq id 'local))
1253             ((string-match "^file:\\(.*\\)" id-as-string)
1254              (setq view-file (match-string 1 id-as-string)
1255                    view-pos 1)
1256              (unless (file-exists-p view-file)
1257                (error "No such file: \"%s\"" id-as-string)))
1258             ((setq idpos (org-find-entry-with-id id))
1259              (setq view-pos idpos))
1260             ((setq idpos (org-id-find id))
1261              (setq view-file (car idpos))
1262              (setq view-pos (cdr idpos)))
1263             (t (error "Cannot find entry with :ID: %s" id))))
1264     (with-current-buffer (if view-file
1265                              (get-file-buffer view-file)
1266                            (current-buffer))
1267       (save-excursion
1268         (save-restriction
1269           (widen)
1270           (goto-char (or view-pos (point)))
1271           (org-columns columns-fmt)
1272           (setq tbl (org-columns-capture-view maxlevel skip-empty-rows))
1273           (setq nfields (length (car tbl)))
1274           (org-columns-quit))))
1275     (goto-char pos)
1276     (move-marker pos nil)
1277     (when tbl
1278       (when (plist-get params :hlines)
1279         (setq tmp nil)
1280         (while tbl
1281           (if (eq (car tbl) 'hline)
1282               (push (pop tbl) tmp)
1283             (if (string-match "\\` *\\(\\*+\\)" (caar tbl))
1284                 (if (and (not (eq (car tmp) 'hline))
1285                          (or (eq hlines t)
1286                              (and (numberp hlines)
1287                                   (<= (- (match-end 1) (match-beginning 1))
1288                                       hlines))))
1289                     (push 'hline tmp)))
1290             (push (pop tbl) tmp)))
1291         (setq tbl (nreverse tmp)))
1292       (when vlines
1293         (setq tbl (mapcar (lambda (x)
1294                             (if (eq 'hline x) x (cons "" x)))
1295                           tbl))
1296         (setq tbl (append tbl (list (cons "/" (make-list nfields "<>"))))))
1297       (when content-lines
1298         (while (string-match "^#" (car content-lines))
1299           (insert (pop content-lines) "\n")))
1300       (setq pos (point))
1301       (insert (org-listtable-to-string tbl))
1302       (when (plist-get params :width)
1303         (insert "\n|" (mapconcat (lambda (x) (format "<%d>" (max 3 x)))
1304                                  org-columns-current-widths "|")))
1305       (while (setq line (pop content-lines))
1306         (when (string-match "^#" line)
1307           (insert "\n" line)
1308           (when (string-match "^[ \t]*#\\+tblfm" line)
1309             (setq recalc t))))
1310       (if recalc
1311           (progn (goto-char pos) (org-table-recalculate 'all))
1312         (goto-char pos)
1313         (org-table-align)))))
1314
1315 (defun org-listtable-to-string (tbl)
1316   "Convert a listtable TBL to a string that contains the Org-mode table.
1317 The table still need to be aligned.  The resulting string has no leading
1318 and tailing newline characters."
1319   (mapconcat
1320    (lambda (x)
1321      (cond
1322       ((listp x)
1323        (concat "|" (mapconcat 'identity x "|") "|"))
1324       ((eq x 'hline) "|-|")
1325       (t (error "Garbage in listtable: %s" x))))
1326    tbl "\n"))
1327
1328 ;;;###autoload
1329 (defun org-insert-columns-dblock ()
1330   "Create a dynamic block capturing a column view table."
1331   (interactive)
1332   (let ((defaults '(:name "columnview" :hlines 1))
1333         (id (org-icompleting-read
1334              "Capture columns (local, global, entry with :ID: property) [local]: "
1335              (append '(("global") ("local"))
1336                      (mapcar 'list (org-property-values "ID"))))))
1337     (if (equal id "") (setq id 'local))
1338     (if (equal id "global") (setq id 'global))
1339     (setq defaults (append defaults (list :id id)))
1340     (org-create-dblock defaults)
1341     (org-update-dblock)))
1342
1343 ;;; Column view in the agenda
1344
1345 (defvar org-agenda-view-columns-initially nil
1346   "When set, switch to columns view immediately after creating the agenda.")
1347
1348 (defvar org-agenda-columns-show-summaries) ; defined in org-agenda.el
1349 (defvar org-agenda-columns-compute-summary-properties); defined in org-agenda.el
1350 (defvar org-agenda-columns-add-appointments-to-effort-sum); as well
1351
1352 ;;;###autoload
1353 (defun org-agenda-columns ()
1354   "Turn on or update column view in the agenda."
1355   (interactive)
1356   (org-verify-version 'columns)
1357   (org-columns-remove-overlays)
1358   (move-marker org-columns-begin-marker (point))
1359   (let ((org-columns-time (time-to-number-of-days (current-time)))
1360         (fmt
1361          (cond
1362           ((org-bound-and-true-p org-agenda-overriding-columns-format))
1363           ((let ((m (org-get-at-bol 'org-hd-marker)))
1364              (and m
1365                   (or (org-entry-get m "COLUMNS" t)
1366                       (with-current-buffer (marker-buffer m)
1367                         org-columns-default-format)))))
1368           ((and (local-variable-p 'org-columns-current-fmt)
1369                 org-columns-current-fmt))
1370           ((let ((m (next-single-property-change (point-min) 'org-hd-marker)))
1371              (and m
1372                   (let ((m (get-text-property m 'org-hd-marker)))
1373                     (or (org-entry-get m "COLUMNS" t)
1374                         (with-current-buffer (marker-buffer m)
1375                           org-columns-default-format))))))
1376           (t org-columns-default-format))))
1377     (org-set-local 'org-columns-current-fmt fmt)
1378     (org-columns-compile-format fmt)
1379     (when org-agenda-columns-compute-summary-properties
1380       (org-agenda-colview-compute org-columns-current-fmt-compiled))
1381     (save-excursion
1382       ;; Collect properties for each headline in current view.
1383       (goto-char (point-min))
1384       (let (cache)
1385         (let ((names (mapcar #'car org-columns-current-fmt-compiled)) m)
1386           (while (not (eobp))
1387             (when (setq m (or (org-get-at-bol 'org-hd-marker)
1388                               (org-get-at-bol 'org-marker)))
1389               (push
1390                (cons
1391                 (line-beginning-position)
1392                 (org-with-point-at m
1393                   (mapcar
1394                    (lambda (name)
1395                      (let ((value (org-entry-get (point) name 'selective t)))
1396                        (cons
1397                         name
1398                         (if (and org-agenda-columns-add-appointments-to-effort-sum
1399                                  (not value)
1400                                  (eq (compare-strings name nil nil
1401                                                       org-effort-property nil nil
1402                                                       t)
1403                                      t)
1404                                  ;; Effort property is not defined.  Try
1405                                  ;; to use appointment duration.
1406                                  (get-text-property (point) 'duration))
1407                             (org-propertize
1408                              (org-minutes-to-clocksum-string
1409                               (get-text-property (point) 'duration))
1410                              'face 'org-warning)
1411                           value))))
1412                    names)))
1413                cache))
1414             (forward-line)))
1415         (when cache
1416           (org-set-local 'org-columns-current-maxwidths
1417                          (org-columns-get-autowidth-alist fmt cache))
1418           (org-columns-display-here-title)
1419           (when (org-set-local 'org-columns-flyspell-was-active
1420                                (org-bound-and-true-p flyspell-mode))
1421             (flyspell-mode 0))
1422           (dolist (x cache)
1423             (goto-char (car x))
1424             (org-columns-display-here (cdr x)))
1425           (when org-agenda-columns-show-summaries
1426             (org-agenda-colview-summarize cache)))))))
1427
1428 (defun org-agenda-colview-summarize (cache)
1429   "Summarize the summarizable columns in column view in the agenda.
1430 This will add overlays to the date lines, to show the summary for each day."
1431   (let* ((fmt (mapcar (lambda (x)
1432                         (if (string-match "CLOCKSUM.*" (car x))
1433                             (list (match-string 0 (car x))
1434                                   (nth 1 x) (nth 2 x) ":" 'add_times
1435                                   nil '+ nil)
1436                           x))
1437                       org-columns-current-fmt-compiled))
1438          line c c1 stype calc sumfunc props lsum entries prop v title)
1439     (catch 'exit
1440       (when (delq nil (mapcar 'cadr fmt))
1441         ;; OK, at least one summation column, it makes sense to try this
1442         (goto-char (point-max))
1443         (while t
1444           (when (or (get-text-property (point) 'org-date-line)
1445                     (eq (get-text-property (point) 'face)
1446                         'org-agenda-structure))
1447             ;; OK, this is a date line that should be used
1448             (setq line (org-current-line))
1449             (setq entries nil c cache cache nil)
1450             (while (setq c1 (pop c))
1451               (if (> (car c1) line)
1452                   (push c1 entries)
1453                 (push c1 cache)))
1454             ;; now ENTRIES are the ones we want to use, CACHE is the rest
1455             ;; Compute the summaries for the properties we want,
1456             ;; set nil properties for the rest.
1457             (when (setq entries (mapcar 'cdr entries))
1458               (setq props
1459                     (mapcar
1460                      (lambda (f)
1461                        (setq prop (car f)
1462                              title (nth 1 f)
1463                              stype (nth 4 f)
1464                              sumfunc (nth 6 f)
1465                              calc (or (nth 7 f) 'identity))
1466                        (cond
1467                         ((equal prop "ITEM")
1468                          (cons prop (buffer-substring (point-at-bol)
1469                                                       (point-at-eol))))
1470                         ((not stype) (cons prop ""))
1471                         (t ;; do the summary
1472                          (setq lsum nil)
1473                          (dolist (x entries)
1474                            (setq v (cdr (assoc-string prop x t)))
1475                            (if v
1476                                (push
1477                                 (funcall
1478                                  (if (not (get-text-property 0 'org-computed v))
1479                                      calc
1480                                    'identity)
1481                                  (org-columns-string-to-number
1482                                   v stype))
1483                                 lsum)))
1484                          (setq lsum (remove nil lsum))
1485                          (setq lsum
1486                                (cond ((> (length lsum) 1)
1487                                       (org-columns-number-to-string
1488                                        (apply sumfunc lsum) stype))
1489                                      ((eq (length lsum) 1)
1490                                       (org-columns-number-to-string
1491                                        (car lsum) stype))
1492                                      (t "")))
1493                          (put-text-property 0 (length lsum) 'face 'bold lsum)
1494                          (unless (eq calc 'identity)
1495                            (put-text-property 0 (length lsum) 'org-computed t lsum))
1496                          (cons prop lsum))))
1497                      fmt))
1498               (org-columns-display-here props 'dateline)
1499               (org-set-local 'org-agenda-columns-active t)))
1500           (if (bobp) (throw 'exit t))
1501           (beginning-of-line 0))))))
1502
1503 (defun org-agenda-colview-compute (fmt)
1504   "Compute the relevant columns in the contributing source buffers."
1505   (let ((files org-agenda-contributing-files)
1506         (org-columns-begin-marker (make-marker))
1507         (org-columns-top-level-marker (make-marker))
1508         f fm a b)
1509     (while (setq f (pop files))
1510       (setq b (find-buffer-visiting f))
1511       (with-current-buffer (or (buffer-base-buffer b) b)
1512         (save-excursion
1513           (save-restriction
1514             (widen)
1515             (org-with-silent-modifications
1516              (remove-text-properties (point-min) (point-max) '(org-summaries t)))
1517             (goto-char (point-min))
1518             (org-columns-get-format-and-top-level)
1519             (while (setq fm (pop fmt))
1520               (cond ((equal (car fm) "CLOCKSUM")
1521                      (org-clock-sum))
1522                     ((equal (car fm) "CLOCKSUM_T")
1523                      (org-clock-sum-today))
1524                     ((and (nth 4 fm)
1525                           (setq a (assoc-string (car fm)
1526                                                 org-columns-current-fmt-compiled
1527                                                 t))
1528                           (equal (nth 4 a) (nth 4 fm)))
1529                      (org-columns-compute (car fm)))))))))))
1530
1531 (defun org-format-time-period (interval)
1532   "Convert time in fractional days to days/hours/minutes/seconds."
1533   (if (numberp interval)
1534       (let* ((days (floor interval))
1535              (frac-hours (* 24 (- interval days)))
1536              (hours (floor frac-hours))
1537              (minutes (floor (* 60 (- frac-hours hours))))
1538              (seconds (floor (* 60 (- (* 60 (- frac-hours hours)) minutes)))))
1539         (format "%dd %02dh %02dm %02ds" days hours minutes seconds))
1540     ""))
1541
1542 (defun org-estimate-mean-and-var (v)
1543   "Return the mean and variance of an estimate."
1544   (let* ((v (cond ((consp v) v)
1545                   ((numberp v) (list v v))
1546                   (t (error "Invalid estimate type"))))
1547          (low (float (car v)))
1548          (high (float (cadr v)))
1549          (mean (/ (+ low high) 2.0))
1550          (var (/ (+ (expt (- mean low) 2.0) (expt (- high mean) 2.0)) 2.0)))
1551     (list  mean var)))
1552
1553 (defun org-estimate-combine (&rest el)
1554   "Combine a list of estimates, using mean and variance.
1555 The mean and variance of the result will be the sum of the means
1556 and variances (respectively) of the individual estimates."
1557   (let ((mean 0)
1558         (var 0))
1559     (mapc (lambda (e)
1560             (let ((stats (org-estimate-mean-and-var e)))
1561               (setq mean (+ mean (car stats)))
1562               (setq var (+ var (cadr stats)))))
1563           el)
1564     (let ((stdev (sqrt var)))
1565       (list (- mean stdev) (+ mean stdev)))))
1566
1567 (defun org-estimate-print (e &optional fmt)
1568   "Prepare a string representation of an estimate.
1569 This formats these numbers as two numbers with a \"-\" between them."
1570   (let ((fmt (or fmt "%.0f"))
1571         (e (cond ((consp e) e)
1572                  ((numberp e) (list e e))
1573                  (t (error "Invalid estimate type")))))
1574     (format "%s" (mapconcat (lambda (n) (format fmt n)) e "-"))))
1575
1576 (defun org-string-to-estimate (s)
1577   "Convert a string to an estimate.
1578 The string should be two numbers joined with a \"-\"."
1579   (if (string-match "\\(.*\\)-\\(.*\\)" s)
1580       (list (string-to-number (match-string 1 s))
1581             (string-to-number(match-string 2 s)))
1582     (list (string-to-number s) (string-to-number s))))
1583
1584 (provide 'org-colview)
1585
1586 ;;; org-colview.el ends here