lisp/org-protocol.el

   1 ;;; org-protocol.el --- Intercept calls from emacsclient to trigger custom actions.
   2 ;;
   3 ;; Copyright (c) 2008, 2009
   4 ;;          Bastien Guerry <bzg AT altern DOT org>,
   5 ;;          Daniel German <dmg AT uvic DOT org>,
   6 ;;          Sebastian Rose <sebastian_rose AT gmx DOT de>,
   7 ;;          Ross Patterson <me AT rpatterson DOT net>
   8 ;;          David Moffat
   9 ;;          (will be FSF when done)
  10 ;;
  11 ;;
  12 ;; Filename: org-protocol.el
  13 ;; Version: 6.25c
  14 ;; Author: Bastien Guerry <bzg AT altern DOT org>
  15 ;; Author: Daniel M German <dmg AT uvic DOT org>
  16 ;; Author: Sebastian Rose <sebastian_rose AT gmx DOT de>
  17 ;; Author: Ross Patterson <me AT rpatterson DOT net>
  18 ;; Maintainer: Sebastian Rose <sebastian_rose AT gmx DOT de>
  19 ;; Keywords: org, emacsclient, wp
  20
  21 ;; This file is not part of GNU Emacs.
  22
  23 ;; This program is free software: you can redistribute it and/or modify
  24 ;; it under the terms of the GNU General Public License as published by
  25 ;; the Free Software Foundation, either version 3 of the License, or
  26 ;; (at your option) any later version.
  27
  28 ;; This program is distributed in the hope that it will be useful,
  29 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  30 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  31 ;; GNU General Public License for more details.
  32
  33 ;; See <http://www.gnu.org/licenses/>.
  34
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Commentary:
  37 ;;
  38 ;; Intercept calls from emacsclient to trigger custom actions.
  39 ;;
  40 ;; This is done by advising `server-visit-files' to scann the list of filenames
  41 ;; for `org-protocol-the-protocol' and sub-procols defined in
  42 ;; `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'.
  43 ;;
  44 ;; Any application that supports calling external programs with an URL
  45 ;; as argument may be used with this functionality.
  46 ;;
  47 ;;
  48 ;; Usage:
  49 ;; ------
  50 ;;
  51 ;;   1.) Add this to your init file (.emacs probably):
  52 ;;
  53 ;;       (add-to-list 'load-path "/path/to/org-protocol/")
  54 ;;       (require 'org-protocol)
  55 ;;
  56 ;;   3.) Ensure emacs-server is up and running.
  57 ;;   4.) Try this from the command line (adjust the URL as needed):
  58 ;;
  59 ;;       $ emacsclient \
  60 ;;         org-protocol://store-link://http:%2F%2Flocalhost%2Findex.html/The%20title
  61 ;;
  62 ;;   5.) Optionally add custom sub-protocols and handlers:
  63 ;;
  64 ;;       (setq org-protocol-protocol-alist
  65 ;;             '(("my-protocol"
  66 ;;                :protocol "my-protocol"
  67 ;;                :function my-protocol-handler-fuction)))
  68 ;;
  69 ;;       A "sub-protocol" will be found in URLs like this:
  70 ;;
  71 ;;           org-protocol://sub-protocol://data
  72 ;;
  73 ;; If it works, you can now setup other applications for using this feature.
  74 ;;
  75 ;;
  76 ;; As of March 2009 Firefox users follow the steps documented on
  77 ;; http://kb.mozillazine.org/Register_protocol, Opera setup is described here:
  78 ;; http://www.opera.com/support/kb/view/535/
  79 ;;
  80 ;;
  81 ;; Documentation
  82 ;; -------------
  83 ;;
  84 ;; org-protocol.el comes with and installs handlers to open sources of published
  85 ;; online content, store and insert the browser's URLs and cite online content
  86 ;; by clicking on a bookmark in Firefox, Opera and probably other browsers and
  87 ;; applications:
  88 ;;
  89 ;;   * `org-protocol-open-source' uses the sub-protocol \"open-source\" and maps
  90 ;;     URLs to local filenames defined in `org-protocol-project-alist'.
  91 ;;
  92 ;;   * `org-protocol-store-link' stores an Org-link (if Org-mode is present) and
  93 ;;     pushes the browsers URL to the `kill-ring' for yanking. This handler is
  94 ;;     triggered through the sub-protocol \"store-link\".
  95 ;;
  96 ;;   * Call `org-protocol-remember' by using the sub-protocol \"remember\".  If
  97 ;;     Org-mode is loaded, emacs will popup a remember buffer and fill the
  98 ;;     template with the data provided. I.e. the browser's URL is inserted as an
  99 ;;     Org-link of which the page title will be the description part. If text
 100 ;;     was select in the browser, that text will be the body of the entry.
 101 ;;
 102 ;; You may use the same bookmark URL for all those standard handlers and just
 103 ;; adjust the sub-protocol used:
 104 ;;
 105 ;;     location.href='org-protocol://sub-protocol://'+
 106 ;;           encodeURIComponent(location.href)+'/'+
 107 ;;           encodeURIComponent(document.title)+'/'+
 108 ;;           encodeURIComponent(window.getSelection())
 109 ;;
 110 ;; The handler for the sub-protocol \"remember\" detects an optional template
 111 ;; char that, if present, triggers the use of a special template.
 112 ;; Example:
 113 ;;
 114 ;;     location.href='org-protocol://sub-protocol://x/'+ ...
 115 ;;
 116 ;;  use template ?x.
 117 ;;
 118 ;; Note, that using double shlashes is optional from org-protocol.el's point of
 119 ;; view because emacsclient sqashes the slashes to one.
 120 ;;
 121 ;;
 122 ;; provides: 'org-protocol
 123 ;;
 124 ;;; Code:
 125
 126 (require 'org)
 127 (require 'url)
 128 (eval-when-compile
 129   (require 'cl))
 130
 131 (declare-function org-publish-initialize-files-alist "org-publish"
 132                   (&optional refresh))
 133 (declare-function org-publish-get-project-from-filename "org-publish"
 134                   (filename &optional up))
 135
 136 (defgroup org-protocol nil
 137   "Intercept calls from emacsclient to trigger custom actions.
 138
 139 This is done by advising `server-visit-files' to scann the list of filenames
 140 for `org-protocol-the-protocol' and sub-procols defined in
 141 `org-protocol-protocol-alist' and `org-protocol-protocol-alist-default'."
 142   :version "22.1"
 143   :group 'convenience
 144   :group 'org)
 145
 146
 147 ;;; Variables:
 148
 149 (defconst org-protocol-protocol-alist-default
 150   '(("org-remember"    :protocol "remember"    :function org-protocol-remember :kill-client t)
 151     ("org-store-link"  :protocol "store-link"  :function org-protocol-store-link)
 152     ("org-open-source" :protocol "open-source" :function org-protocol-open-source))
 153   "Default protocols to use.
 154 See `org-protocol-protocol-alist' for a description of this variable.")
 155
 156
 157 (defconst org-protocol-the-protocol "org-protocol"
 158   "This is the protocol to detect if org-protocol.el is loaded.
 159 `org-protocol-protocol-alist-default' and `org-protocol-protocol-alist' hold the
 160 sub-protocols that trigger the required action. You will have to define just one
 161 protocol handler OS-wide (MS-Windows) or per application (Linux). That protocol
 162 handler should call emacsclient.")
 163
 164
 165 ;;; User variables:
 166
 167 (defcustom org-protocol-reverse-list-of-files t
 168   "* The filenames passed on the commandline are passed to the emacs-server in
 169 reversed order. Set to `t' (default) to re-reverse the list, i.e. use the
 170 sequence on the command line. If nil, the sequence of the filenames is
 171 unchanged."
 172   :group 'org-protocol
 173   :type 'boolean)
 174
 175
 176 (defcustom org-protocol-project-alist nil
 177   "* Map URLs to local filenames for `org-protocol-open-source' (open-source).
 178
 179 Each element of this list must be of the form:
 180
 181   (module-name :property value property: value ...)
 182
 183 where module-name is an arbitrary name. All the values are strings.
 184
 185 Possible properties are:
 186
 187   :online-suffix     - the suffix to strip from the published URLs
 188   :working-suffix    - the replacement for online-suffix
 189   :base-url          - the base URL, e.g. http://www.example.com/project/
 190                        Last slash required.
 191   :working-directory - the local working directory. This is, what base-url will
 192                        be replaced with.
 193
 194 Example:
 195
 196    (setq org-protocol-project-alist
 197        '((\"http://orgmode.org/worg/\"
 198           :online-suffix \".php\"
 199           :working-suffix \".org\"
 200           :base-url \"http://orgmode.org/worg/\"
 201           :working-directory \"/home/user/org/Worg/\")
 202          (\"http://localhost/org-notes/\"
 203           :online-suffix \".html\"
 204           :working-suffix \".org\"
 205           :base-url \"http://localhost/org/\"
 206           :working-directory \"/home/user/org/\")))
 207
 208 Consider using the interactive functions `org-protocol-create' and
 209 `org-protocol-create-for-org' to help you filling this variable with valid contents."
 210   :group 'org-protocol
 211   :type 'alist)
 212
 213
 214 (defcustom org-protocol-protocol-alist nil
 215   "* Register custom handlers for org-protocol.
 216
 217 Each element of this list must be of the form:
 218
 219   (module-name :protocol protocol :function func :kill-client nil)
 220
 221 protocol - protocol to detect in a filename without trailing colon and slashes.
 222            See rfc1738 section 2.1 for more on this.
 223            If you define a protocol \"my-protocol\", `org-protocol-check-filename-for-protocol'
 224            will search filenames for \"org-protocol:/my-protocol:/\"
 225            and trigger your action for every match. `org-protocol' is defined in
 226            `org-protocol-the-protocol'. Double and tripple slashes are compressed
 227            to one by emacsclient.
 228
 229 function - function that handles requests with protocol and takes exactly one
 230            argument: the filename with all protocols stripped. If the function
 231            returns nil, emacsclient and -server do nothing. Any non-nil return
 232            value is considered a valid filename and thus passed to the server.
 233
 234            `org-protocol.el provides some support for handling those filenames,
 235            if you stay with the conventions used for the standard handlers in
 236            `org-protocol-protocol-alist-default'. See `org-protocol-split-data'.
 237
 238 kill-client - If t, kill the client immediately, once the sub-protocol is
 239            detected. This is neccessary for actions that can be interupted by
 240            `C-g' to avoid dangeling emacsclients. Note, that all other command
 241            line arguments but the this one will be discarded, greedy handlers
 242            still receive the whole list of arguments though.
 243
 244 Here is an example:
 245
 246   (setq org-protocol-protocol-alist
 247       '((\"my-protocol\"
 248          :protocol \"my-protocol\"
 249          :function my-protocol-handler-fuction)
 250         (\"your-protocol\"
 251          :protocol \"your-protocol\"
 252          :function your-protocol-handler-fuction)))"
 253   :group 'org-protocol
 254   :type '(alist))
 255
 256
 257 ;;; Helper functions:
 258
 259 (defun org-protocol-sanitize-uri (uri)
 260   "emacsclient compresses double and tripple slashes.
 261 Slashes are sanitized to double slashes here."
 262   (when (string-match "^\\([a-z]+\\):/" uri)
 263     (let* ((splitparts (split-string uri "/+")))
 264       (setq uri (concat (car splitparts) "//" (mapconcat 'identity (cdr splitparts) "/")))))
 265   uri)
 266
 267
 268 (defun org-protocol-split-data(data &optional unhexify separator)
 269   "Split, what a org-protocol handler function gets as only argument.
 270 data is that one argument. Data is splitted at each occurrence of separator
 271  (regexp). If no separator is specified or separator is nil, assume \"/+\".
 272 The results of that splitting are return as a list. If unhexify is non-nil,
 273 hex-decode each split part."
 274   (let* ((sep (or separator "/+"))
 275          (split-parts (split-string data sep)))
 276     (if unhexify
 277         (mapcar 'url-unhex-string split-parts)
 278       split-parts)))
 279
 280
 281 (defun org-protocol-flatten-greedy (param-list &optional strip-path replacement)
 282   "Greedy handlers might recieve a list like this from emacsclient:
 283  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 284 where \"/dir/\" is the absolute path to emacsclients working directory. This
 285 function transforms it into a flat list utilizing `org-protocol-flatten' and
 286 transforms the elements of that list as follows:
 287
 288 If strip-path is non-nil, remove the \"/dir/\" prefix from all members of
 289 param-list.
 290
 291 If replacement is string, replace the \"/dir/\" prefix with it.
 292
 293 The first parameter, the one that contains the protocols, is always changed.
 294 Everything up to the end of the protocols is stripped.
 295
 296 Note, that this function will not work, if you set
 297 `org-protocol-reverse-list-of-files' to nil!"
 298 (let* ((l (org-protocol-flatten param-list))
 299       (trigger (car l))
 300       (len 0)
 301       dir
 302       ret)
 303   (when (string-match "^\\(.*\\)\\(org-protocol:/+[a-zA-z0-9][-_a-zA-z0-9]*:/+\\\\(.*\\)" trigger)
 304     (setq dir (match-string 1 trigger))
 305     (setq len (length dir))
 306     (setcar l (concat dir (match-string 3 trigger))))
 307   (if strip-path
 308       (progn
 309        (dolist (e l ret)
 310          (setq ret
 311                (append ret
 312                        (list
 313                         (if (stringp e)
 314                             (if (stringp replacement)
 315                                 (setq e (concat replacement (substring e len)))
 316                               (setq e (substring e len)))
 317                           e)))))
 318        ret)
 319     l)))
 320
 321
 322 (defun org-protocol-flatten (l)
 323   "Greedy handlers might recieve a list like this from emacsclient:
 324  '( (\"/dir/org-protocol:/greedy:/~/path1\" (23 . 12)) (\"/dir/param\")
 325 where \"/dir/\" is the absolute path to emacsclients working directory. This
 326 function transforms it into a flat list."
 327   (if (null l) ()
 328     (if (listp l)
 329        (append (org-protocol-flatten (car l)) (org-protocol-flatten (cdr l)))
 330       (list l))))
 331
 332 ;;; Standard protocol handlers:
 333
 334 (defun org-protocol-store-link (fname)
 335   "Process an org-protocol://store-link:// style url
 336 and store a browser URL as an org link. Also pushes the links URL to the
 337 `kill-ring'.
 338
 339 The location for a browser's bookmark has to look like this:
 340
 341   javascript:location.href='org-protocol://store-link://'+ \\
 342         encodeURIComponent(location.href)
 343         encodeURIComponent(document.title)+'/'+ \\
 344
 345 Don't use `escape()'! Use `encodeURIComponent()' instead. The title of the page
 346 could contain slashes and the location definitely will.
 347
 348 The sub-protocol used to reach this function is set in
 349 `org-protocol-protocol-alist'."
 350   (let* ((splitparts (org-protocol-split-data fname t))
 351          (uri (org-protocol-sanitize-uri (car splitparts)))
 352          (title (cadr splitparts))
 353          orglink)
 354     (if (boundp 'org-stored-links)
 355       (setq org-stored-links (cons (list uri title) org-stored-links)))
 356     (kill-new uri)
 357     (message "`%s' to insert new org-link, `%s' to insert `%s'"
 358              (substitute-command-keys"\\[org-insert-link]")
 359              (substitute-command-keys"\\[yank]")
 360              uri))
 361   nil)
 362
 363
 364 (defun org-protocol-remember  (info)
 365   "Process an org-protocol://remember:// style url.
 366
 367 The sub-protocol used to reach this function is set in
 368 `org-protocol-protocol-alist'.
 369
 370 This function detects an URL, title and optinal text, separated by '/'
 371 The location for a browser's bookmark has to look like this:
 372
 373   javascript:location.href='org-protocol://remember://'+ \\
 374         encodeURIComponent(location.href)+ \\
 375         encodeURIComponent(document.title)+'/'+ \\
 376         encodeURIComponent(window.getSelection())
 377
 378 By default the template character ?w is used. But you may prepend the encoded
 379 URL with a character and a slash like so:
 380
 381   javascript:location.href='org-protocol://org-store-link://b/'+ ...
 382
 383 Now template ?b will be used."
 384
 385   (if (and (boundp 'org-stored-links)
 386            (fboundp 'org-remember))
 387       (let* ((parts (org-protocol-split-data info t))
 388              (template (or (and (= 1 (length (car parts))) (pop parts)) "w"))
 389              (url (org-protocol-sanitize-uri (car parts)))
 390              (type (if (string-match "^\\([a-z]+\\):" url)
 391                        (match-string 1 url)))
 392              (title (cadr parts))
 393              (region (caddr parts))
 394              (orglink (org-make-link-string url title))
 395              remember-annotation-functions)
 396         (setq org-stored-links
 397               (cons (list url title) org-stored-links))
 398         (kill-new orglink)
 399         (org-store-link-props :type type
 400                               :link url
 401                               :description title
 402                               :initial region)
 403         (raise-frame)
 404         (org-remember nil (string-to-char template)))
 405
 406     (message "Org-mode not loaded."))
 407   nil)
 408
 409
 410 (defun org-protocol-open-source (fname)
 411   "Process an org-protocol://open-source:// style url.
 412
 413 Change a filename by mapping URLs to local filenames as set
 414 in `org-protocol-project-alist'.
 415
 416 The location for a browser's bookmark should look like this:
 417
 418   javascript:location.href='org-protocol://open-source://'+ \\
 419         encodeURIComponent(location.href)"
 420
 421   ;; As we enter this function for a match on our protocol, the return value
 422   ;; defaults to nil.
 423   (let ((result nil)
 424         (f (url-unhex-string fname)))
 425     (catch 'result
 426       (dolist (prolist org-protocol-project-alist)
 427         (let* ((base-url (plist-get (cdr prolist) :base-url))
 428                (wsearch (regexp-quote base-url)))
 429
 430           (when (string-match wsearch f)
 431             (let* ((wdir (plist-get (cdr prolist) :working-directory))
 432                    (strip-suffix (plist-get (cdr prolist) :online-suffix))
 433                    (add-suffix (plist-get (cdr prolist) :working-suffix))
 434                    (start-pos (+ (string-match wsearch f) (length base-url)))
 435                    (end-pos (string-match
 436                              (concat (regexp-quote strip-suffix) "\\([?#].*\\)?$") f))
 437                    (the-file (concat wdir (substring f start-pos end-pos) add-suffix)))
 438               (if (file-readable-p the-file)
 439                   (throw 'result the-file))
 440               (if (file-exists-p the-file)
 441                   (message "%s: permission denied!" the-file)
 442                 (message "%s: no such file or directory." the-file))))))
 443       result)))
 444
 445
 446 ;;; Core functions:
 447
 448 (defun org-protocol-check-filename-for-protocol (fname restoffiles client)
 449   "Detect if `org-protocol-the-protocol' and a known sub-protocol is used in fname.
 450 Sub-protocols are registered in `org-protocol-protocol-alist' and
 451 `org-protocol-protocol-alist-default'.
 452 This is, how the matching is done:
 453
 454   (string-match \"protocol:/+sub-protocol:/+\" ...)
 455
 456 protocol and sub-protocol are regexp-quoted.
 457
 458 If a matching protcol is found, the protcol is stripped from fname and the
 459 result is passed to the protocols function as the only parameter. If the
 460 function returns nil, the filename is removed from the list of filenames
 461 passed from emacsclient to the server.
 462 If the function returns a non nil value, that value is passed to the server
 463 as filename."
 464   (let ((sub-protocols (append org-protocol-protocol-alist org-protocol-protocol-alist-default)))
 465     (catch 'fname
 466       (let ((the-protocol (concat (regexp-quote org-protocol-the-protocol) ":/+")))
 467         (when (string-match the-protocol fname)
 468           (dolist (prolist sub-protocols)
 469             (let ((proto (concat the-protocol (regexp-quote (plist-get (cdr prolist) :protocol)) ":/+")))
 470               (when (string-match proto fname)
 471                 (let* ((func (plist-get (cdr prolist) :function))
 472                        (greedy (plist-get (cdr prolist) :greedy))
 473                        (splitted (split-string fname proto))
 474                        (result (if greedy restoffiles (cadr splitted))))
 475                   (if (plist-get (cdr prolist) :kill-client)
 476                       (server-delete-client client t))
 477                   (when (fboundp func)
 478                     (unless greedy
 479                       (throw 'fname (funcall func result)))
 480                     (funcall func result)
 481                     (throw 'fname t))))))))
 482       ;; (message "fname: %s" fname)
 483       fname)))
 484
 485
 486 (defadvice server-visit-files (before org-protocol-detect-protocol-server activate)
 487   "Advice server-visit-flist to call `org-protocol-modify-filename-for-protocol'."
 488   (let ((flist (if org-protocol-reverse-list-of-files
 489                    (reverse  (ad-get-arg 0))
 490                  (ad-get-arg 0)))
 491         (client (ad-get-arg 1)))
 492     (catch 'greedy
 493       (dolist (var flist)
 494         (let ((fname  (expand-file-name (car var)))) ;; `\' to `/' on windows. FIXME: could this be done any better?
 495           (setq fname (org-protocol-check-filename-for-protocol fname (member var flist)  client))
 496           (if (eq fname t) ;; greedy? We need the `t' return value.
 497               (progn
 498                 (ad-set-arg 0 nil)
 499                 (throw 'greedy t))
 500             (if (stringp fname) ;; probably filename
 501                 (setcar var fname)
 502               (ad-set-arg 0 (delq var (ad-get-arg 0))))))
 503         ))))
 504
 505 ;;; Org specific functions:
 506
 507 (defun org-protocol-create-for-org ()
 508   "Create a org-protocol project for the current file's Org-mode project.
 509 This works, if the file visited is part of a publishing project in
 510 `org-publish-project-alist'. This functions calls `org-protocol-create' to do
 511 most of the work."
 512   (interactive)
 513   (require 'org-publish)
 514   (org-publish-initialize-files-alist)
 515   (let ((all (or (org-publish-get-project-from-filename buffer-file-name))))
 516     (if all (org-protocol-create (cdr all))
 517       (message "Not in an org-project. Did mean %s?"
 518                (substitute-command-keys"\\[org-protocol-create]")))))
 519
 520
 521
 522 (defun org-protocol-create(&optional project-plist)
 523   "Create a new org-protocol project interactively.
 524 An org-protocol project is an entry in `org-protocol-project-alist'
 525 which is used by `org-protocol-open-source'.
 526 Optionally use project-plist to initialize the defaults for this worglet. If
 527 project-plist is the CDR of an element in `org-publish-project-alist', reuse
 528 :base-directory, :html-extension and :base-extension."
 529   (interactive)
 530   (let ((working-dir (expand-file-name(or (plist-get project-plist :base-directory) default-directory)))
 531         (base-url "http://orgmode.org/worg/")
 532         (strip-suffix (or (plist-get project-plist :html-extension) ".html"))
 533         (working-suffix (if (plist-get project-plist :base-extension)
 534                             (concat "." (plist-get project-plist :base-extension))
 535                           ".org"))
 536
 537         (worglet-buffer nil)
 538
 539         (insert-default-directory t)
 540         (minibuffer-allow-text-properties nil))
 541
 542     (setq base-url (read-string "Base URL of published content: " base-url nil base-url t))
 543     (if (not (string-match "\\/$" base-url))
 544         (setq base-url (concat base-url "/")))
 545
 546     (setq working-dir
 547           (expand-file-name
 548            (read-directory-name "Local working directory: " working-dir working-dir t)))
 549     (if (not (string-match "\\/$" working-dir))
 550         (setq working-dir (concat working-dir "/")))
 551
 552     (setq strip-suffix
 553           (read-string
 554            (concat "Extension to strip from published URLs ("strip-suffix"): ")
 555                    strip-suffix nil strip-suffix t))
 556
 557     (setq working-suffix
 558           (read-string
 559            (concat "Extension of editable files ("working-suffix"): ")
 560                    working-suffix nil working-suffix t))
 561
 562     (when (yes-or-no-p "Save the new worglet to your init file? ")
 563       (setq org-protocol-project-alist
 564             (cons `(,base-url . (:base-url ,base-url
 565                                  :working-directory ,working-dir
 566                                  :online-suffix ,strip-suffix
 567                                  :working-suffix ,working-suffix))
 568                   org-protocol-project-alist))
 569       (customize-save-variable 'org-protocol-project-alist org-protocol-project-alist))
 570 ))
 571
 572 (provide 'org-protocol)
 573 ;;; org-protocol.el ends here