ox-md: Fix TOC's internal links
[org-mode.git] / lisp / ox-md.el
blob08358eb44f9817fafe58da1a92727a5f903190ed
1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
3 ;; Copyright (C) 2012-2015 Free Software Foundation, Inc.
5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
6 ;; Keywords: org, wp, markdown
8 ;; This file is part of GNU Emacs.
10 ;; GNU Emacs is free software: you can redistribute it and/or modify
11 ;; it under the terms of the GNU General Public License as published by
12 ;; the Free Software Foundation, either version 3 of the License, or
13 ;; (at your option) any later version.
15 ;; GNU Emacs is distributed in the hope that it will be useful,
16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 ;; GNU General Public License for more details.
20 ;; You should have received a copy of the GNU General Public License
21 ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
23 ;;; Commentary:
25 ;; This library implements a Markdown back-end (vanilla flavor) for
26 ;; Org exporter, based on `html' back-end. See Org manual for more
27 ;; information.
29 ;;; Code:
31 (eval-when-compile (require 'cl))
32 (require 'ox-html)
33 (require 'ox-publish)
36 ;;; User-Configurable Variables
38 (defgroup org-export-md nil
39 "Options specific to Markdown export back-end."
40 :tag "Org Markdown"
41 :group 'org-export
42 :version "24.4"
43 :package-version '(Org . "8.0"))
45 (defcustom org-md-headline-style 'atx
46 "Style used to format headlines.
47 This variable can be set to either `atx' or `setext'."
48 :group 'org-export-md
49 :type '(choice
50 (const :tag "Use \"atx\" style" atx)
51 (const :tag "Use \"Setext\" style" setext)))
55 ;;; Define Back-End
57 (org-export-define-derived-backend 'md 'html
58 :export-block '("MD" "MARKDOWN")
59 :filters-alist '((:filter-parse-tree . org-md-separate-elements))
60 :menu-entry
61 '(?m "Export to Markdown"
62 ((?M "To temporary buffer"
63 (lambda (a s v b) (org-md-export-as-markdown a s v)))
64 (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
65 (?o "To file and open"
66 (lambda (a s v b)
67 (if a (org-md-export-to-markdown t s v)
68 (org-open-file (org-md-export-to-markdown nil s v)))))))
69 :translate-alist '((bold . org-md-bold)
70 (code . org-md-verbatim)
71 (example-block . org-md-example-block)
72 (export-block . org-md-export-block)
73 (fixed-width . org-md-example-block)
74 (headline . org-md-headline)
75 (horizontal-rule . org-md-horizontal-rule)
76 (inline-src-block . org-md-verbatim)
77 (inner-template . org-md-inner-template)
78 (italic . org-md-italic)
79 (item . org-md-item)
80 (keyword . org-md-keyword)
81 (line-break . org-md-line-break)
82 (link . org-md-link)
83 (node-property . org-md-node-property)
84 (paragraph . org-md-paragraph)
85 (plain-list . org-md-plain-list)
86 (plain-text . org-md-plain-text)
87 (property-drawer . org-md-property-drawer)
88 (quote-block . org-md-quote-block)
89 (section . org-md-section)
90 (src-block . org-md-example-block)
91 (template . org-md-template)
92 (verbatim . org-md-verbatim))
93 :options-alist '((:md-headline-style nil nil org-md-headline-style)))
96 ;;; Filters
98 (defun org-md-separate-elements (tree backend info)
99 "Fix blank lines between elements.
101 TREE is the parse tree being exported. BACKEND is the export
102 back-end used. INFO is a plist used as a communication channel.
104 Enforce a blank line between elements. There are two exceptions
105 to this rule:
107 1. Preserve blank lines between sibling items in a plain list,
109 2. In an item, remove any blank line before the very first
110 paragraph and the next sub-list.
112 Assume BACKEND is `md'."
113 (org-element-map tree (remq 'item org-element-all-elements)
114 (lambda (e)
115 (org-element-put-property
116 e :post-blank
117 (if (and (eq (org-element-type e) 'paragraph)
118 (eq (org-element-type (org-element-property :parent e)) 'item)
119 (eq (org-element-type (org-export-get-next-element e info))
120 'plain-list)
121 (not (org-export-get-previous-element e info)))
123 1))))
124 ;; Return updated tree.
125 tree)
129 ;;; Transcode Functions
131 ;;;; Bold
133 (defun org-md-bold (bold contents info)
134 "Transcode BOLD object into Markdown format.
135 CONTENTS is the text within bold markup. INFO is a plist used as
136 a communication channel."
137 (format "**%s**" contents))
140 ;;;; Code and Verbatim
142 (defun org-md-verbatim (verbatim contents info)
143 "Transcode VERBATIM object into Markdown format.
144 CONTENTS is nil. INFO is a plist used as a communication
145 channel."
146 (let ((value (org-element-property :value verbatim)))
147 (format (cond ((not (string-match "`" value)) "`%s`")
148 ((or (string-match "\\``" value)
149 (string-match "`\\'" value))
150 "`` %s ``")
151 (t "``%s``"))
152 value)))
155 ;;;; Example Block, Src Block and export Block
157 (defun org-md-example-block (example-block contents info)
158 "Transcode EXAMPLE-BLOCK element into Markdown format.
159 CONTENTS is nil. INFO is a plist used as a communication
160 channel."
161 (replace-regexp-in-string
162 "^" " "
163 (org-remove-indentation
164 (org-export-format-code-default example-block info))))
166 (defun org-md-export-block (export-block contents info)
167 "Transcode a EXPORT-BLOCK element from Org to Markdown.
168 CONTENTS is nil. INFO is a plist holding contextual information."
169 (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
170 (org-remove-indentation (org-element-property :value export-block))
171 ;; Also include HTML export blocks.
172 (org-export-with-backend 'html export-block contents info)))
175 ;;;; Headline
177 (defun org-md-headline (headline contents info)
178 "Transcode HEADLINE element into Markdown format.
179 CONTENTS is the headline contents. INFO is a plist used as
180 a communication channel."
181 (unless (org-element-property :footnote-section-p headline)
182 (let* ((level (org-export-get-relative-level headline info))
183 (title (org-export-data (org-element-property :title headline) info))
184 (todo (and (plist-get info :with-todo-keywords)
185 (let ((todo (org-element-property :todo-keyword
186 headline)))
187 (and todo (concat (org-export-data todo info) " ")))))
188 (tags (and (plist-get info :with-tags)
189 (let ((tag-list (org-export-get-tags headline info)))
190 (and tag-list
191 (format " :%s:"
192 (mapconcat 'identity tag-list ":"))))))
193 (priority
194 (and (plist-get info :with-priority)
195 (let ((char (org-element-property :priority headline)))
196 (and char (format "[#%c] " char)))))
197 (anchor
198 (and (plist-get info :with-toc)
199 (format "<a id=\"%s\"></a>"
200 (or (org-element-property :CUSTOM_ID headline)
201 (org-export-get-reference headline info)))))
202 ;; Headline text without tags.
203 (heading (concat todo priority title))
204 (style (plist-get info :md-headline-style)))
205 (cond
206 ;; Cannot create a headline. Fall-back to a list.
207 ((or (org-export-low-level-p headline info)
208 (not (memq style '(atx setext)))
209 (and (eq style 'atx) (> level 6))
210 (and (eq style 'setext) (> level 2)))
211 (let ((bullet
212 (if (not (org-export-numbered-headline-p headline info)) "-"
213 (concat (number-to-string
214 (car (last (org-export-get-headline-number
215 headline info))))
216 "."))))
217 (concat bullet (make-string (- 4 (length bullet)) ?\s) heading tags
218 "\n\n"
219 (and contents
220 (replace-regexp-in-string "^" " " contents)))))
221 ;; Use "Setext" style.
222 ((eq style 'setext)
223 (concat heading tags anchor "\n"
224 (make-string (length heading) (if (= level 1) ?= ?-))
225 "\n\n"
226 contents))
227 ;; Use "atx" style.
228 (t (concat (make-string level ?#) " " heading tags anchor "\n\n"
229 contents))))))
232 ;;;; Horizontal Rule
234 (defun org-md-horizontal-rule (horizontal-rule contents info)
235 "Transcode HORIZONTAL-RULE element into Markdown format.
236 CONTENTS is the horizontal rule contents. INFO is a plist used
237 as a communication channel."
238 "---")
241 ;;;; Italic
243 (defun org-md-italic (italic contents info)
244 "Transcode ITALIC object into Markdown format.
245 CONTENTS is the text within italic markup. INFO is a plist used
246 as a communication channel."
247 (format "*%s*" contents))
250 ;;;; Item
252 (defun org-md-item (item contents info)
253 "Transcode ITEM element into Markdown format.
254 CONTENTS is the item contents. INFO is a plist used as
255 a communication channel."
256 (let* ((type (org-element-property :type (org-export-get-parent item)))
257 (struct (org-element-property :structure item))
258 (bullet (if (not (eq type 'ordered)) "-"
259 (concat (number-to-string
260 (car (last (org-list-get-item-number
261 (org-element-property :begin item)
262 struct
263 (org-list-prevs-alist struct)
264 (org-list-parents-alist struct)))))
265 "."))))
266 (concat bullet
267 (make-string (- 4 (length bullet)) ? )
268 (case (org-element-property :checkbox item)
269 (on "[X] ")
270 (trans "[-] ")
271 (off "[ ] "))
272 (let ((tag (org-element-property :tag item)))
273 (and tag (format "**%s:** "(org-export-data tag info))))
274 (and contents
275 (org-trim (replace-regexp-in-string "^" " " contents))))))
279 ;;;; Keyword
281 (defun org-md-keyword (keyword contents info)
282 "Transcode a KEYWORD element into Markdown format.
283 CONTENTS is nil. INFO is a plist used as a communication
284 channel."
285 (if (member (org-element-property :key keyword) '("MARKDOWN" "MD"))
286 (org-element-property :value keyword)
287 (org-export-with-backend 'html keyword contents info)))
290 ;;;; Line Break
292 (defun org-md-line-break (line-break contents info)
293 "Transcode LINE-BREAK object into Markdown format.
294 CONTENTS is nil. INFO is a plist used as a communication
295 channel."
296 " \n")
299 ;;;; Link
301 (defun org-md-link (link contents info)
302 "Transcode LINE-BREAK object into Markdown format.
303 CONTENTS is the link's description. INFO is a plist used as
304 a communication channel."
305 (let ((link-org-files-as-md
306 (lambda (raw-path)
307 ;; Treat links to `file.org' as links to `file.md'.
308 (if (string= ".org" (downcase (file-name-extension raw-path ".")))
309 (concat (file-name-sans-extension raw-path) ".md")
310 raw-path)))
311 (type (org-element-property :type link)))
312 (cond
313 ;; Link type is handled by a special function.
314 ((org-export-custom-protocol-maybe link contents 'md))
315 ((member type '("custom-id" "id"))
316 (let ((destination (org-export-resolve-id-link link info)))
317 (if (stringp destination) ; External file.
318 (let ((path (funcall link-org-files-as-md destination)))
319 (if (not contents) (format "<%s>" path)
320 (format "[%s](%s)" contents path)))
321 (concat
322 (and contents (concat contents " "))
323 (format "(%s)"
324 (format (org-export-translate "See section %s" :html info)
325 (if (org-export-numbered-headline-p destination info)
326 (mapconcat #'number-to-string
327 (org-export-get-headline-number
328 destination info)
329 ".")
330 (org-export-data
331 (org-element-property :title destination) info))))))))
332 ((org-export-inline-image-p link org-html-inline-image-rules)
333 (let ((path (let ((raw-path (org-element-property :path link)))
334 (if (not (file-name-absolute-p raw-path)) raw-path
335 (expand-file-name raw-path))))
336 (caption (org-export-data
337 (org-export-get-caption
338 (org-export-get-parent-element link)) info)))
339 (format "![img](%s)"
340 (if (not (org-string-nw-p caption)) path
341 (format "%s \"%s\"" path caption)))))
342 ((string= type "coderef")
343 (let ((ref (org-element-property :path link)))
344 (format (org-export-get-coderef-format ref contents)
345 (org-export-resolve-coderef ref info))))
346 ((equal type "radio") contents)
347 ((equal type "fuzzy")
348 (let* ((destination (org-export-resolve-fuzzy-link link info))
349 (description
350 (or (org-string-nw-p contents)
351 (let ((number (org-export-get-ordinal destination info)))
352 (cond
353 ((not number)
354 (and (eq 'headline (org-element-type destination))
355 (org-export-data
356 (org-element-property :title destination) info)))
357 ((atom number) (number-to-string number))
358 (t (mapconcat #'number-to-string number ".")))))))
359 (format "[%s](#%s)"
360 description
361 (org-export-get-reference destination info))))
362 (t (let* ((raw-path (org-element-property :path link))
363 (path
364 (cond
365 ((member type '("http" "https" "ftp"))
366 (concat type ":" raw-path))
367 ((string= type "file")
368 (org-export-file-uri (funcall link-org-files-as-md raw-path)))
369 (t raw-path))))
370 (if (not contents) (format "<%s>" path)
371 (format "[%s](%s)" contents path)))))))
374 ;;;; Node Property
376 (defun org-md-node-property (node-property contents info)
377 "Transcode a NODE-PROPERTY element into Markdown syntax.
378 CONTENTS is nil. INFO is a plist holding contextual
379 information."
380 (format "%s:%s"
381 (org-element-property :key node-property)
382 (let ((value (org-element-property :value node-property)))
383 (if value (concat " " value) ""))))
386 ;;;; Paragraph
388 (defun org-md-paragraph (paragraph contents info)
389 "Transcode PARAGRAPH element into Markdown format.
390 CONTENTS is the paragraph contents. INFO is a plist used as
391 a communication channel."
392 (let ((first-object (car (org-element-contents paragraph))))
393 ;; If paragraph starts with a #, protect it.
394 (if (and (stringp first-object) (string-match "\\`#" first-object))
395 (replace-regexp-in-string "\\`#" "\\#" contents nil t)
396 contents)))
399 ;;;; Plain List
401 (defun org-md-plain-list (plain-list contents info)
402 "Transcode PLAIN-LIST element into Markdown format.
403 CONTENTS is the plain-list contents. INFO is a plist used as
404 a communication channel."
405 contents)
408 ;;;; Plain Text
410 (defun org-md-plain-text (text info)
411 "Transcode a TEXT string into Markdown format.
412 TEXT is the string to transcode. INFO is a plist holding
413 contextual information."
414 (when (plist-get info :with-smart-quotes)
415 (setq text (org-export-activate-smart-quotes text :html info)))
416 ;; Protect ambiguous #. This will protect # at the beginning of
417 ;; a line, but not at the beginning of a paragraph. See
418 ;; `org-md-paragraph'.
419 (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
420 ;; Protect ambiguous !
421 (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
422 ;; Protect `, *, _ and \
423 (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
424 ;; Handle special strings, if required.
425 (when (plist-get info :with-special-strings)
426 (setq text (org-html-convert-special-strings text)))
427 ;; Handle break preservation, if required.
428 (when (plist-get info :preserve-breaks)
429 (setq text (replace-regexp-in-string "[ \t]*\n" " \n" text)))
430 ;; Return value.
431 text)
434 ;;;; Property Drawer
436 (defun org-md-property-drawer (property-drawer contents info)
437 "Transcode a PROPERTY-DRAWER element into Markdown format.
438 CONTENTS holds the contents of the drawer. INFO is a plist
439 holding contextual information."
440 (and (org-string-nw-p contents)
441 (replace-regexp-in-string "^" " " contents)))
444 ;;;; Quote Block
446 (defun org-md-quote-block (quote-block contents info)
447 "Transcode QUOTE-BLOCK element into Markdown format.
448 CONTENTS is the quote-block contents. INFO is a plist used as
449 a communication channel."
450 (replace-regexp-in-string
451 "^" "> "
452 (replace-regexp-in-string "\n\\'" "" contents)))
455 ;;;; Section
457 (defun org-md-section (section contents info)
458 "Transcode SECTION element into Markdown format.
459 CONTENTS is the section contents. INFO is a plist used as
460 a communication channel."
461 contents)
464 ;;;; Template
466 (defun org-md-inner-template (contents info)
467 "Return body of document after converting it to Markdown syntax.
468 CONTENTS is the transcoded contents string. INFO is a plist
469 holding export options."
470 ;; Make sure CONTENTS is separated from table of contents and
471 ;; footnotes with at least a blank line.
472 (org-trim (org-html-inner-template (concat "\n" contents "\n") info)))
474 (defun org-md-template (contents info)
475 "Return complete document string after Markdown conversion.
476 CONTENTS is the transcoded contents string. INFO is a plist used
477 as a communication channel."
478 contents)
482 ;;; Interactive function
484 ;;;###autoload
485 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
486 "Export current buffer to a Markdown buffer.
488 If narrowing is active in the current buffer, only export its
489 narrowed part.
491 If a region is active, export that region.
493 A non-nil optional argument ASYNC means the process should happen
494 asynchronously. The resulting buffer should be accessible
495 through the `org-export-stack' interface.
497 When optional argument SUBTREEP is non-nil, export the sub-tree
498 at point, extracting information from the headline properties
499 first.
501 When optional argument VISIBLE-ONLY is non-nil, don't export
502 contents of hidden elements.
504 Export is done in a buffer named \"*Org MD Export*\", which will
505 be displayed when `org-export-show-temporary-export-buffer' is
506 non-nil."
507 (interactive)
508 (org-export-to-buffer 'md "*Org MD Export*"
509 async subtreep visible-only nil nil (lambda () (text-mode))))
511 ;;;###autoload
512 (defun org-md-convert-region-to-md ()
513 "Assume the current region has org-mode syntax, and convert it to Markdown.
514 This can be used in any buffer. For example, you can write an
515 itemized list in org-mode syntax in a Markdown buffer and use
516 this command to convert it."
517 (interactive)
518 (org-export-replace-region-by 'md))
521 ;;;###autoload
522 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
523 "Export current buffer to a Markdown file.
525 If narrowing is active in the current buffer, only export its
526 narrowed part.
528 If a region is active, export that region.
530 A non-nil optional argument ASYNC means the process should happen
531 asynchronously. The resulting file should be accessible through
532 the `org-export-stack' interface.
534 When optional argument SUBTREEP is non-nil, export the sub-tree
535 at point, extracting information from the headline properties
536 first.
538 When optional argument VISIBLE-ONLY is non-nil, don't export
539 contents of hidden elements.
541 Return output file's name."
542 (interactive)
543 (let ((outfile (org-export-output-file-name ".md" subtreep)))
544 (org-export-to-file 'md outfile async subtreep visible-only)))
546 ;;;###autoload
547 (defun org-md-publish-to-md (plist filename pub-dir)
548 "Publish an org file to Markdown.
550 FILENAME is the filename of the Org file to be published. PLIST
551 is the property list for the given project. PUB-DIR is the
552 publishing directory.
554 Return output file name."
555 (org-publish-org-to 'md filename ".md" plist pub-dir))
557 (provide 'ox-md)
559 ;; Local variables:
560 ;; generated-autoload-file: "org-loaddefs.el"
561 ;; End:
563 ;;; ox-md.el ends here