lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>,
   6 ;;         Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112           (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115 (declare-function bbdb-record-get-field "ext:bbdb"
 116                   (fn file &optional arglist fileonly))
 117 ;; These two functions below are part of BBDB3:
 118 (declare-function bbdb-search-name "ext:bbdb" (regexp &optional layout))
 119 (declare-function bbdb-search-organization "ext:bbdb" (regexp &optional layout))
 120
 121 (declare-function calendar-leap-year-p "calendar" (year))
 122 (declare-function diary-ordinal-suffix "diary-lib" (n))
 123
 124 (defvar date)   ;; dynamically scoped from Org
 125 (defvar name)   ;; dynamically scoped from Org
 126
 127 ;; Customization
 128
 129 (defgroup org-bbdb-anniversaries nil
 130   "Customizations for including anniversaries from BBDB into Agenda."
 131   :group 'org-bbdb)
 132
 133 (defcustom org-bbdb-default-anniversary-format "birthday"
 134   "Default anniversary class."
 135   :type  'string
 136   :group 'org-bbdb-anniversaries
 137   :require 'bbdb)
 138
 139 (defcustom org-bbdb-anniversary-format-alist
 140   '(("birthday" lambda
 141      (name years suffix)
 142      (concat "Birthday: [[bbdb:" name "][" name " ("
 143              (format "%s" years)        ; handles numbers as well as strings
 144              suffix ")]]"))
 145     ("wedding" lambda
 146      (name years suffix)
 147      (concat "[[bbdb:" name "][" name "'s "
 148              (format "%s" years)
 149              suffix " wedding anniversary]]")))
 150   "How different types of anniversaries should be formatted.
 151 An alist of elements (STRING . FORMAT) where STRING is the name of an
 152 anniversary class and format is either:
 153 1) A format string with the following substitutions (in order):
 154     * the name of the record containing this anniversary
 155     * the number of years
 156     * an ordinal suffix (st, nd, rd, th) for the year
 157
 158 2) A function to be called with three arguments: NAME YEARS SUFFIX
 159    (string int string) returning a string for the diary or nil.
 160
 161 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 162    scope of variables NAME, YEARS and SUFFIX (among others)."
 163   :type 'sexp
 164   :group 'org-bbdb-anniversaries
 165   :require 'bbdb)
 166
 167 (defcustom org-bbdb-anniversary-field 'anniversary
 168   "The BBDB field which contains anniversaries.
 169 The anniversaries are stored in the following format
 170
 171 YYYY-MM-DD Class-or-Format-String
 172
 173 where class is one of the customized classes for anniversaries;
 174 birthday and wedding are predefined.  Format-String can take three
 175 substitutions 1) the name of the record containing this
 176 anniversary, 2) the number of years, and 3) an ordinal suffix for
 177 the year.
 178
 179 Multiple anniversaries can be separated by \\n."
 180   :type    'symbol
 181   :group   'org-bbdb-anniversaries
 182   :require 'bbdb)
 183
 184 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 185   "How to retrieve `month date year' from the anniversary field.
 186
 187 Customize if you have already filled your BBDB with dates
 188 different from YYYY-MM-DD.  The function must return a list (month
 189 date year)."
 190   :type 'function
 191   :group 'org-bbdb-anniversaries
 192   :require 'bbdb)
 193
 194
 195 ;; Install the link type
 196 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 197 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 198
 199 ;; Implementation
 200 (defun org-bbdb-store-link ()
 201   "Store a link to a BBDB database entry."
 202   (when (eq major-mode 'bbdb-mode)
 203     ;; This is BBDB, we make this link!
 204     (let* ((rec (bbdb-current-record))
 205            (name (bbdb-record-name rec))
 206            (company (if (fboundp 'bbdb-record-getprop)
 207                         (bbdb-record-getprop rec 'company)
 208                       (car (bbdb-record-get-field rec 'organization))))
 209            (link (org-make-link "bbdb:" name)))
 210       (org-store-link-props :type "bbdb" :name name :company company
 211                             :link link :description name)
 212       link)))
 213
 214 (defun org-bbdb-export (path desc format)
 215   "Create the export version of a BBDB link specified by PATH or DESC.
 216 If exporting to either HTML or LaTeX FORMAT the link will be
 217 italicized, in all other cases it is left unchanged."
 218   (when (string= desc (format "bbdb:%s" path))
 219     (setq desc path))
 220   (cond
 221    ((eq format 'html) (format "<i>%s</i>" desc))
 222    ((eq format 'latex) (format "\\textit{%s}" desc))
 223    (t desc)))
 224
 225 (defun org-bbdb-open (name)
 226   "Follow a BBDB link to NAME."
 227   (require 'bbdb-com)
 228   (let ((inhibit-redisplay (not debug-on-error))
 229         (bbdb-electric-p nil))
 230     (if (fboundp 'bbdb-name)
 231         (org-bbdb-open-old)
 232       (org-bbdb-open-new))))
 233
 234 (defun org-bbdb-open-old ()
 235   (catch 'exit
 236     ;; Exact match on name
 237     (bbdb-name (concat "\\`" name "\\'") nil)
 238     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 239     ;; Exact match on name
 240     (bbdb-company (concat "\\`" name "\\'") nil)
 241     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 242     ;; Partial match on name
 243     (bbdb-name name nil)
 244     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 245     ;; Partial match on company
 246     (bbdb-company name nil)
 247     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 248     ;; General match including network address and notes
 249     (bbdb name nil)
 250     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 251       (delete-window (get-buffer-window "*BBDB*"))
 252       (error "No matching BBDB record"))))
 253
 254 (defun org-bbdb-open-new ()
 255   (catch 'exit
 256     ;; Exact match on name
 257     (bbdb-search-name (concat "\\`" name "\\'") nil)
 258     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 259     ;; Exact match on name
 260     (bbdb-search-organization (concat "\\`" name "\\'") nil)
 261     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 262     ;; Partial match on name
 263     (bbdb-search-name name nil)
 264     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 265     ;; Partial match on company
 266     (bbdb-search-organization name nil)
 267     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 268     ;; General match including network address and notes
 269     (bbdb name nil)
 270     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 271       (delete-window (get-buffer-window "*BBDB*"))
 272       (error "No matching BBDB record"))))
 273
 274 (defun org-bbdb-anniv-extract-date (time-str)
 275   "Convert YYYY-MM-DD to (month date year).
 276 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 277 it will be considered unknown."
 278   (multiple-value-bind (a b c) (values-list (bbdb-split time-str "-"))
 279     (if (eq c nil)
 280         (list (string-to-number a)
 281               (string-to-number b)
 282               nil)
 283       (list (string-to-number b)
 284             (string-to-number c)
 285             (string-to-number a)))))
 286
 287 (defun org-bbdb-anniv-split (str)
 288   "Split multiple entries in the BBDB anniversary field.
 289 Argument STR is the anniversary field in BBDB."
 290   (let ((pos (string-match "[ \t]" str)))
 291     (if pos (list (substring str 0 pos)
 292                   (bbdb-string-trim (substring str pos)))
 293       (list str nil))))
 294
 295 (defvar org-bbdb-anniv-hash nil
 296   "A hash holding anniversaries extracted from BBDB.
 297 The hash table is created on first use.")
 298
 299 (defvar org-bbdb-updated-p t
 300   "This is non-nil if BBDB has been updated since we last built the hash.")
 301
 302 (defun org-bbdb-make-anniv-hash ()
 303   "Create a hash with anniversaries extracted from BBDB, for fast access.
 304 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 305
 306   (let (split tmp annivs)
 307     (clrhash org-bbdb-anniv-hash)
 308     (dolist (rec (bbdb-records))
 309       (when (setq annivs (bbdb-record-getprop
 310                           rec org-bbdb-anniversary-field))
 311         (setq annivs (bbdb-split annivs "\n"))
 312         (while annivs
 313           (setq split (org-bbdb-anniv-split (pop annivs)))
 314           (multiple-value-bind (m d y)
 315               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 316             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 317             (puthash (list m d) (cons (list y
 318                                             (bbdb-record-name rec)
 319                                             (cadr split))
 320                                       tmp)
 321                      org-bbdb-anniv-hash))))))
 322   (setq org-bbdb-updated-p nil))
 323
 324 (defun org-bbdb-updated (rec)
 325   "Record the fact that BBDB has been updated.
 326 This is used by Org to re-create the anniversary hash table."
 327   (setq org-bbdb-updated-p t))
 328
 329 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 330
 331 ;;;###autoload
 332 (defun org-bbdb-anniversaries()
 333   "Extract anniversaries from BBDB for display in the agenda."
 334   (require 'bbdb)
 335   (require 'diary-lib)
 336   (unless (hash-table-p org-bbdb-anniv-hash)
 337     (setq org-bbdb-anniv-hash
 338           (make-hash-table :test 'equal :size 366)))
 339
 340   (when (or org-bbdb-updated-p
 341             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 342     (org-bbdb-make-anniv-hash))
 343
 344   (let* ((m (car date))    ; month
 345          (d (nth 1 date))  ; day
 346          (y (nth 2 date))  ; year
 347          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 348          (text ())
 349          rec recs)
 350
 351     ;; we don't want to miss people born on Feb. 29th
 352     (when (and (= m 3) (= d 1)
 353                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 354                (not (calendar-leap-year-p y)))
 355       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 356       (while (setq rec (pop recs))
 357         (push rec annivs)))
 358
 359     (when annivs
 360       (while (setq rec (pop annivs))
 361         (when rec
 362           (let* ((class (or (nth 2 rec)
 363                             org-bbdb-default-anniversary-format))
 364                  (form (or (cdr (assoc-string
 365                                  class org-bbdb-anniversary-format-alist t))
 366                            class))      ; (as format string)
 367                  (name (nth 1 rec))
 368                  (years (if (eq (car rec) nil)
 369                             "unknown"
 370                           (- y (car rec))))
 371                  (suffix (if (eq (car rec) nil)
 372                              ""
 373                            (diary-ordinal-suffix years)))
 374                  (tmp (cond
 375                        ((functionp form)
 376                         (funcall form name years suffix))
 377                        ((listp form) (eval form))
 378                        (t (format form name years suffix)))))
 379             (org-add-props tmp nil 'org-bbdb-name name)
 380             (if text
 381                 (setq text (append text (list tmp)))
 382               (setq text (list tmp)))))
 383         ))
 384     text))
 385
 386 (defun org-bbdb-complete-link ()
 387   "Read a bbdb link with name completion."
 388   (require 'bbdb-com)
 389   (concat "bbdb:"
 390           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 391
 392 (defun org-bbdb-anniv-export-ical ()
 393   "Extract anniversaries from BBDB and convert them to icalendar format."
 394   (require 'bbdb)
 395   (require 'diary-lib)
 396   (unless (hash-table-p org-bbdb-anniv-hash)
 397     (setq org-bbdb-anniv-hash
 398           (make-hash-table :test 'equal :size 366)))
 399   (when (or org-bbdb-updated-p
 400             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 401     (org-bbdb-make-anniv-hash))
 402   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 403
 404 (defun org-bbdb-format-vevent (key recs)
 405   (let (rec categ)
 406     (while (setq rec (pop recs))
 407       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 408       (princ (format "BEGIN:VEVENT
 409 UID: ANNIV-%4i%02i%02i-%s
 410 DTSTART:%4i%02i%02i
 411 SUMMARY:%s
 412 DESCRIPTION:%s
 413 CATEGORIES:%s
 414 RRULE:FREQ=YEARLY
 415 END:VEVENT\n"
 416                      (nth 0 rec) (nth 0 key) (nth 1 key)
 417                      (mapconcat 'identity
 418                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 419                                 "-")
 420                      (nth 0 rec) (nth 0 key) (nth 1 key)
 421                      (nth 1 rec)
 422                      (concat (capitalize categ) " " (nth 1 rec))
 423                      categ)))))
 424
 425 (provide 'org-bbdb)
 426
 427 ;;; org-bbdb.el ends here