lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2013 Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg at gnu dot org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, capture
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; capture templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a capture template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-capure-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to capture this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-capture' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/res/writing/latex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better capture template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114 (require 'org-compat)
 115
 116 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 117 (defvar org-id-locations)
 118
 119 (declare-function bibtex-beginning-of-entry "bibtex" ())
 120 (declare-function bibtex-generate-autokey "bibtex" ())
 121 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 122 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 123 (declare-function org-babel-trim "ob" (string &optional regexp))
 124
 125 \f
 126 ;;; Bibtex data
 127 (defvar org-bibtex-types
 128   '((:article
 129      (:description . "An article from a journal or magazine")
 130      (:required :author :title :journal :year)
 131      (:optional :volume :number :pages :month :note))
 132     (:book
 133      (:description . "A book with an explicit publisher")
 134      (:required (:editor :author) :title :publisher :year)
 135      (:optional (:volume :number) :series :address :edition :month :note))
 136     (:booklet
 137      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 138      (:required :title)
 139      (:optional :author :howpublished :address :month :year :note))
 140     (:conference
 141      (:description . "")
 142      (:required :author :title :booktitle :year)
 143      (:optional :editor :pages :organization :publisher :address :month :note))
 144     (:inbook
 145      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 146      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 147      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 148     (:incollection
 149      (:description . "A part of a book having its own title.")
 150      (:required :author :title :booktitle :publisher :year)
 151      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 152     (:inproceedings
 153      (:description . "An article in a conference proceedings")
 154      (:required :author :title :booktitle :year)
 155      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 156     (:manual
 157      (:description . "Technical documentation.")
 158      (:required :title)
 159      (:optional :author :organization :address :edition :month :year :note))
 160     (:mastersthesis
 161      (:description . "A Master’s thesis.")
 162      (:required :author :title :school :year)
 163      (:optional :type :address :month :note))
 164     (:misc
 165      (:description . "Use this type when nothing else fits.")
 166      (:required)
 167      (:optional :author :title :howpublished :month :year :note))
 168     (:phdthesis
 169      (:description . "A PhD thesis.")
 170      (:required :author :title :school :year)
 171      (:optional :type :address :month :note))
 172     (:proceedings
 173      (:description . "The proceedings of a conference.")
 174      (:required :title :year)
 175      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 176     (:techreport
 177      (:description . "A report published by a school or other institution.")
 178      (:required :author :title :institution :year)
 179      (:optional :type :address :month :note))
 180     (:unpublished
 181      (:description . "A document having an author and title, but not formally published.")
 182      (:required :author :title :note)
 183      (:optional :month :year)))
 184   "Bibtex entry types with required and optional parameters.")
 185
 186 (defvar org-bibtex-fields
 187   '((:address      . "Usually the address of the publisher or other type of institution.  For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 188     (:annote       . "An annotation.  It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 189     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 190     (:booktitle    . "Title of a book, part of which is being cited.  See the LaTeX book for how to type titles.  For book entries, use the title field instead.")
 191     (:chapter      . "A chapter (or section or whatever) number.")
 192     (:crossref     . "The database key of the entry being cross referenced.")
 193     (:edition      . "The edition of a book for example, 'Second'.  This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 194     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book.  If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 195     (:howpublished . "How something strange has been published.  The first word should be capitalized.")
 196     (:institution  . "The sponsoring institution of a technical report.")
 197     (:journal      . "A journal name.")
 198     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing.  This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 199     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written.  You should use the standard three-letter abbreviation,")
 200     (:note         . "Any additional information that can help the reader.  The first word should be capitalized.")
 201     (:number       . "Any additional information that can help the reader.  The first word should be capitalized.")
 202     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 203     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 204     (:publisher    . "The publisher’s name.")
 205     (:school       . "The name of the school where a thesis was written.")
 206     (:series       . "The name of a series or set of books.  When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 207     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 208     (:type         . "The type of a technical report for example, 'Research Note'.")
 209     (:volume       . "The volume of a journal or multi-volume book.")
 210     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 211   "Bibtex fields with descriptions.")
 212
 213 (defvar org-bibtex-entries nil
 214   "List to hold parsed bibtex entries.")
 215
 216 (defcustom org-bibtex-autogen-keys nil
 217   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 218   :group 'org-bibtex
 219   :version "24.1"
 220   :type  'boolean)
 221
 222 (defcustom org-bibtex-prefix nil
 223   "Optional prefix for all bibtex property names.
 224 For example setting to 'BIB_' would allow interoperability with fireforg."
 225   :group 'org-bibtex
 226   :version "24.1"
 227   :type  '(choice
 228            (const nil)
 229            (string)))
 230
 231 (defcustom org-bibtex-treat-headline-as-title t
 232   "Treat headline text as title if title property is absent.
 233 If an entry is missing a title property, use the headline text as
 234 the property.  If this value is t, `org-bibtex-check' will ignore
 235 a missing title field."
 236   :group 'org-bibtex
 237   :version "24.1"
 238   :type 'boolean)
 239
 240 (defcustom org-bibtex-export-arbitrary-fields nil
 241   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 242 This only has effect if `org-bibtex-prefix' is defined, so as to
 243 ensure that other org-properties, such as CATEGORY or LOGGING are
 244 not placed in the exported bibtex entry."
 245   :group 'org-bibtex
 246   :version "24.1"
 247   :type 'boolean)
 248
 249 (defcustom org-bibtex-key-property "CUSTOM_ID"
 250   "Property that holds the bibtex key.
 251 By default, this is CUSTOM_ID, which enables easy linking to
 252 bibtex headlines from within an org file.  This can be set to ID
 253 to enable global links, but only with great caution, as global
 254 IDs must be unique."
 255   :group 'org-bibtex
 256   :version "24.1"
 257   :type 'string)
 258
 259 (defcustom org-bibtex-tags nil
 260   "List of tag(s) that should be added to new bib entries."
 261   :group 'org-bibtex
 262   :version "24.1"
 263   :type '(repeat  :tag "Tag" (string)))
 264
 265 (defcustom org-bibtex-tags-are-keywords nil
 266   "Convert the value of the keywords field to tags and vice versa.
 267 If set to t, comma-separated entries in a bibtex entry's keywords
 268 field will be converted to org tags.  Note: spaces will be escaped
 269 with underscores, and characters that are not permitted in org
 270 tags will be removed.
 271
 272 If t, local tags in an org entry will be exported as a
 273 comma-separated string of keywords when exported to bibtex.  Tags
 274 defined in `org-bibtex-tags' or `org-bibtex-no-export-tags' will
 275 not be exported."
 276   :group 'org-bibtex
 277   :version "24.1"
 278   :type 'boolean)
 279
 280 (defcustom org-bibtex-no-export-tags nil
 281   "List of tag(s) that should not be converted to keywords.
 282 This variable is relevant only if `org-bibtex-export-tags-as-keywords' is t."
 283   :group 'org-bibtex
 284   :version "24.1"
 285   :type '(repeat :tag "Tag" (string)))
 286
 287 (defcustom org-bibtex-type-property-name "btype"
 288   "Property in which to store bibtex entry type (e.g., article)."
 289   :group 'org-bibtex
 290   :version "24.1"
 291   :type 'string)
 292
 293 \f
 294 ;;; Utility functions
 295 (defun org-bibtex-get (property)
 296   ((lambda (it) (when it (org-babel-trim it)))
 297    (let ((org-special-properties
 298           (delete "FILE" (copy-sequence org-special-properties))))
 299      (or
 300       (org-entry-get (point) (upcase property))
 301       (org-entry-get (point) (concat org-bibtex-prefix (upcase property)))))))
 302
 303 (defun org-bibtex-put (property value)
 304   (let ((prop (upcase (if (keywordp property)
 305                           (substring (symbol-name property) 1)
 306                         property))))
 307     (org-set-property
 308      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 309              prop)
 310      value)))
 311
 312 (defun org-bibtex-headline ()
 313   "Return a bibtex entry of the given headline as a string."
 314   (let* ((val (lambda (key lst) (cdr (assoc key lst))))
 315          (to (lambda (string) (intern (concat ":" string))))
 316          (from (lambda (key) (substring (symbol-name key) 1)))
 317          flatten ; silent compiler warning
 318          (flatten (lambda (&rest lsts)
 319                     (apply #'append (mapcar
 320                                      (lambda (e)
 321                                        (if (listp e) (apply flatten e) (list e)))
 322                                      lsts))))
 323          (notes (buffer-string))
 324          (id (org-bibtex-get org-bibtex-key-property))
 325          (type (org-bibtex-get org-bibtex-type-property-name))
 326          (tags (when org-bibtex-tags-are-keywords
 327                  (delq nil
 328                        (mapcar
 329                         (lambda (tag)
 330                           (unless (member tag
 331                                           (append org-bibtex-tags
 332                                                   org-bibtex-no-export-tags))
 333                             tag))
 334                         (org-get-local-tags-at))))))
 335     (when type
 336       (let ((entry (format
 337                     "@%s{%s,\n%s\n}\n" type id
 338                     (mapconcat
 339                      (lambda (pair)
 340                        (format "  %s={%s}" (car pair) (cdr pair)))
 341                      (remove nil
 342                              (if (and org-bibtex-export-arbitrary-fields
 343                                       org-bibtex-prefix)
 344                                  (mapcar
 345                                   (lambda (kv)
 346                                     (let ((key (car kv)) (val0 (cdr kv)))
 347                                       (when (and
 348                                              (string-match org-bibtex-prefix key)
 349                                              (not (string=
 350                                                    (downcase (concat org-bibtex-prefix
 351                                                                      org-bibtex-type-property-name))
 352                                                    (downcase key))))
 353                                         (cons (downcase (replace-regexp-in-string
 354                                                          org-bibtex-prefix "" key))
 355                                               val0))))
 356                                   (org-entry-properties nil 'standard))
 357                                (mapcar
 358                                 (lambda (field)
 359                                   (let ((value (or (org-bibtex-get (funcall from field))
 360                                                    (and (equal :title field)
 361                                                         (nth 4 (org-heading-components))))))
 362                                     (when value (cons (funcall from field) value))))
 363                                 (funcall flatten
 364                                          (funcall val :required (funcall val (funcall to type) org-bibtex-types))
 365                                          (funcall val :optional (funcall val (funcall to type) org-bibtex-types))))))
 366                      ",\n"))))
 367         (with-temp-buffer
 368           (insert entry)
 369           (when tags
 370             (bibtex-beginning-of-entry)
 371             (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 372                 (progn (goto-char (match-end 1)) (insert ", "))
 373               (bibtex-make-field "keywords" t t))
 374             (insert (mapconcat #'identity tags ", ")))
 375           (buffer-string))))))
 376
 377 (defun org-bibtex-ask (field)
 378   (unless (assoc field org-bibtex-fields)
 379     (error "Field:%s is not known" field))
 380   (save-window-excursion
 381     (let* ((name (substring (symbol-name field) 1))
 382            (buf-name (format "*Bibtex Help %s*" name)))
 383       (with-output-to-temp-buffer buf-name
 384         (princ (cdr (assoc field org-bibtex-fields))))
 385       (with-current-buffer buf-name (visual-line-mode 1))
 386       (org-fit-window-to-buffer (get-buffer-window buf-name))
 387       ((lambda (result) (when (> (length result) 0) result))
 388        (read-from-minibuffer (format "%s: " name))))))
 389
 390 (defun org-bibtex-autokey ()
 391   "Generate an autokey for the current headline."
 392   (org-bibtex-put org-bibtex-key-property
 393                   (if org-bibtex-autogen-keys
 394                       (let* ((entry (org-bibtex-headline))
 395                              (key
 396                               (with-temp-buffer
 397                                 (insert entry)
 398                                 (bibtex-generate-autokey))))
 399                         ;; test for duplicate IDs if using global ID
 400                         (when (and
 401                                (equal org-bibtex-key-property "ID")
 402                                (featurep 'org-id)
 403                                (hash-table-p org-id-locations)
 404                                (gethash key org-id-locations))
 405                           (warn "Another entry has the same ID"))
 406                         key)
 407                     (read-from-minibuffer "id: "))))
 408
 409 (defun org-bibtex-fleshout (type &optional optional)
 410   "Fleshout current heading, ensuring all required fields are present.
 411 With optional argument OPTIONAL, also prompt for optional fields."
 412   (let ((val (lambda (key lst) (cdr (assoc key lst))))
 413         (keyword (lambda (name) (intern (concat ":" (downcase name)))))
 414         (name (lambda (keyword) (substring (symbol-name keyword) 1))))
 415     (dolist (field (append
 416                     (if org-bibtex-treat-headline-as-title
 417                         (remove :title (funcall val :required (funcall val type org-bibtex-types)))
 418                       (funcall val :required (funcall val type org-bibtex-types)))
 419                     (when optional (funcall val :optional (funcall val type org-bibtex-types)))))
 420       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 421         (let ((present (first (remove
 422                                nil
 423                                (mapcar
 424                                 (lambda (f) (when (org-bibtex-get (funcall name f)) f))
 425                                 field)))))
 426           (setf field (or present (funcall keyword
 427                                            (org-icompleting-read
 428                                             "Field: " (mapcar name field)))))))
 429       (let ((name (funcall name field)))
 430         (unless (org-bibtex-get name)
 431           (let ((prop (org-bibtex-ask field)))
 432             (when prop (org-bibtex-put name prop)))))))
 433   (when (and type (assoc type org-bibtex-types)
 434              (not (org-bibtex-get org-bibtex-key-property)))
 435     (org-bibtex-autokey)))
 436
 437 \f
 438 ;;; Bibtex link functions
 439 (org-add-link-type "bibtex" 'org-bibtex-open)
 440 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 441
 442 (defun org-bibtex-open (path)
 443   "Visit the bibliography entry on PATH."
 444   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 445                    (match-string 1 path)))
 446          (path (substring path 0 (match-beginning 0))))
 447     (org-open-file path t nil search)))
 448
 449 (defun org-bibtex-store-link ()
 450   "Store a link to a BibTeX entry."
 451   (when (eq major-mode 'bibtex-mode)
 452     (let* ((search (org-create-file-search-in-bibtex))
 453            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 454                          "::" search))
 455            (entry (mapcar ; repair strings enclosed in "..." or {...}
 456                    (lambda(c)
 457                      (if (string-match
 458                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 459                          (cons (car c) (match-string 1 (cdr c))) c))
 460                    (save-excursion
 461                      (bibtex-beginning-of-entry)
 462                      (bibtex-parse-entry)))))
 463       (org-store-link-props
 464        :key (cdr (assoc "=key=" entry))
 465        :author (or (cdr (assoc "author" entry)) "[no author]")
 466        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 467        :title (or (cdr (assoc "title" entry)) "[no title]")
 468        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 469        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 470        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 471        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 472        :url (or (cdr (assoc "url" entry)) "[no url]")
 473        :year (or (cdr (assoc "year" entry)) "[no year]")
 474        :month (or (cdr (assoc "month" entry)) "[no month]")
 475        :address (or (cdr (assoc "address" entry)) "[no address]")
 476        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 477        :number (or (cdr (assoc "number" entry)) "[no number]")
 478        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 479        :series (or (cdr (assoc "series" entry)) "[no series]")
 480        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 481        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 482        :type "bibtex"
 483        :link link
 484        :description org-bibtex-description))))
 485
 486 (defun org-create-file-search-in-bibtex ()
 487   "Create the search string and description for a BibTeX database entry."
 488   ;; Make a good description for this entry, using names, year and the title
 489   ;; Put it into the `description' variable which is dynamically scoped.
 490   (let ((bibtex-autokey-names 1)
 491         (bibtex-autokey-names-stretch 1)
 492         (bibtex-autokey-name-case-convert-function 'identity)
 493         (bibtex-autokey-name-separator " & ")
 494         (bibtex-autokey-additional-names " et al.")
 495         (bibtex-autokey-year-length 4)
 496         (bibtex-autokey-name-year-separator " ")
 497         (bibtex-autokey-titlewords 3)
 498         (bibtex-autokey-titleword-separator " ")
 499         (bibtex-autokey-titleword-case-convert-function 'identity)
 500         (bibtex-autokey-titleword-length 'infty)
 501         (bibtex-autokey-year-title-separator ": "))
 502     (setq org-bibtex-description (bibtex-generate-autokey)))
 503   ;; Now parse the entry, get the key and return it.
 504   (save-excursion
 505     (bibtex-beginning-of-entry)
 506     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 507
 508 (defun org-execute-file-search-in-bibtex (s)
 509   "Find the link search string S as a key for a database entry."
 510   (when (eq major-mode 'bibtex-mode)
 511     ;; Yes, we want to do the search in this file.
 512     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 513     (goto-char (point-min))
 514     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 515                                     (regexp-quote s) "[ \t\n]*,") nil t)
 516          (goto-char (match-beginning 0)))
 517     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 518         ;; Use double prefix to indicate that any web link should be browsed
 519         (let ((b (current-buffer)) (p (point)))
 520           ;; Restore the window configuration because we just use the web link
 521           (set-window-configuration org-window-config-before-follow-link)
 522           (with-current-buffer b
 523             (goto-char p)
 524             (bibtex-url)))
 525       (recenter 0))  ; Move entry start to beginning of window
 526     ;; return t to indicate that the search is done.
 527     t))
 528
 529 ;; Finally add the link search function to the right hook.
 530 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 531
 532 \f
 533 ;;; Bibtex <-> Org-mode headline translation functions
 534 (defun org-bibtex (&optional filename)
 535   "Export each headline in the current file to a bibtex entry.
 536 Headlines are exported using `org-bibtex-export-headline'."
 537   (interactive
 538    (list (read-file-name
 539           "Bibtex file: " nil nil nil
 540           (file-name-nondirectory
 541            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 542   ((lambda (error-point)
 543      (when error-point
 544        (goto-char error-point)
 545        (message "Bibtex error at %S" (nth 4 (org-heading-components)))))
 546    (catch 'bib
 547      (let ((bibtex-entries (remove nil (org-map-entries
 548                                         (lambda ()
 549                                           (condition-case foo
 550                                               (org-bibtex-headline)
 551                                             (error (throw 'bib (point)))))))))
 552        (with-temp-file filename
 553          (insert (mapconcat #'identity bibtex-entries "\n")))
 554        (message "Successfully exported %d BibTeX entries to %s"
 555                 (length bibtex-entries) filename) nil))))
 556
 557 (defun org-bibtex-check (&optional optional)
 558   "Check the current headline for required fields.
 559 With prefix argument OPTIONAL also prompt for optional fields."
 560   (interactive "P")
 561   (save-restriction
 562     (org-narrow-to-subtree)
 563     (let ((type ((lambda (name) (when name (intern (concat ":" name))))
 564                  (org-bibtex-get org-bibtex-type-property-name))))
 565       (when type (org-bibtex-fleshout type optional)))))
 566
 567 (defun org-bibtex-check-all (&optional optional)
 568   "Check all headlines in the current file.
 569 With prefix argument OPTIONAL also prompt for optional fields."
 570   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 571
 572 (defun org-bibtex-create (&optional arg nonew)
 573   "Create a new entry at the given level.
 574 With a prefix arg, query for optional fields as well.
 575 If nonew is t, add data to the headline of the entry at point."
 576   (interactive "P")
 577   (let* ((type (org-icompleting-read
 578                 "Type: " (mapcar (lambda (type)
 579                                    (substring (symbol-name (car type)) 1))
 580                                  org-bibtex-types)
 581                 nil nil (when nonew
 582                           (org-bibtex-get org-bibtex-type-property-name))))
 583          (type (if (keywordp type) type (intern (concat ":" type))))
 584          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 585     (unless (assoc type org-bibtex-types)
 586       (error "Type:%s is not known" type))
 587     (if nonew
 588         (org-back-to-heading)
 589       (org-insert-heading)
 590       (let ((title (org-bibtex-ask :title)))
 591         (insert title)
 592         (org-bibtex-put "TITLE" title)))
 593     (org-bibtex-put org-bibtex-type-property-name
 594                     (substring (symbol-name type) 1))
 595     (org-bibtex-fleshout type arg)
 596     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 597
 598 (defun org-bibtex-create-in-current-entry (&optional arg)
 599   "Add bibliographical data to the current entry.
 600 With a prefix arg, query for optional fields."
 601   (interactive "P")
 602   (org-bibtex-create arg t))
 603
 604 (defun org-bibtex-read ()
 605   "Read a bibtex entry and save to `org-bibtex-entries'.
 606 This uses `bibtex-parse-entry'."
 607   (interactive)
 608   (let ((keyword (lambda (str) (intern (concat ":" (downcase str)))))
 609         (clean-space (lambda (str) (replace-regexp-in-string
 610                                     "[[:space:]\n\r]+" " " str)))
 611         (strip-delim
 612          (lambda (str)       ; strip enclosing "..." and {...}
 613            (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 614              (when (and (= (aref str 0) (car pair))
 615                         (= (aref str (1- (length str))) (cdr pair)))
 616                (setf str (substring str 1 (1- (length str)))))) str)))
 617     (push (mapcar
 618            (lambda (pair)
 619              (cons (let ((field (funcall keyword (car pair))))
 620                      (case field
 621                        (:=type= :type)
 622                        (:=key= :key)
 623                        (otherwise field)))
 624                    (funcall clean-space (funcall strip-delim (cdr pair)))))
 625            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 626           org-bibtex-entries)))
 627
 628 (defun org-bibtex-read-buffer (buffer)
 629   "Read all bibtex entries in BUFFER and save to `org-bibtex-entries'.
 630 Return the number of saved entries."
 631   (interactive "bbuffer: ")
 632   (let ((start-length (length org-bibtex-entries)))
 633     (with-current-buffer buffer
 634       (save-excursion
 635         (goto-char (point-max))
 636         (while (not (= (point) (point-min)))
 637           (backward-char 1)
 638           (org-bibtex-read)
 639           (bibtex-beginning-of-entry))))
 640     (let ((added (- (length org-bibtex-entries) start-length)))
 641       (message "parsed %d entries" added)
 642       added)))
 643
 644 (defun org-bibtex-read-file (file)
 645   "Read FILE with `org-bibtex-read-buffer'."
 646   (interactive "ffile: ")
 647   (org-bibtex-read-buffer (find-file-noselect file 'nowarn 'rawfile)))
 648
 649 (defun org-bibtex-write ()
 650   "Insert a heading built from the first element of `org-bibtex-entries'."
 651   (interactive)
 652   (when (= (length org-bibtex-entries) 0)
 653     (error "No entries in `org-bibtex-entries'"))
 654   (let* ((entry (pop org-bibtex-entries))
 655          (org-special-properties nil) ; avoids errors with `org-entry-put'
 656          (val (lambda (field) (cdr (assoc field entry))))
 657          (togtag (lambda (tag) (org-toggle-tag tag 'on))))
 658     (org-insert-heading)
 659     (insert (funcall val :title))
 660     (org-bibtex-put "TITLE" (funcall val :title))
 661     (org-bibtex-put org-bibtex-type-property-name
 662                     (downcase (funcall val :type)))
 663     (dolist (pair entry)
 664       (case (car pair)
 665         (:title    nil)
 666         (:type     nil)
 667         (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 668         (:keywords (if org-bibtex-tags-are-keywords
 669                        (mapc
 670                         (lambda (kw)
 671                           (funcall
 672                            togtag
 673                            (replace-regexp-in-string
 674                             "[^[:alnum:]_@#%]" ""
 675                             (replace-regexp-in-string "[ \t]+" "_" kw))))
 676                         (split-string (cdr pair) ", *"))
 677                      (org-bibtex-put (car pair) (cdr pair))))
 678         (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 679     (mapc togtag org-bibtex-tags)))
 680
 681 (defun org-bibtex-yank ()
 682   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 683   (interactive)
 684   (let (entry)
 685     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 686     (if entry
 687         (org-bibtex-write)
 688       (error "Yanked text does not appear to contain a BibTeX entry"))))
 689
 690 (defun org-bibtex-import-from-file (file)
 691   "Read bibtex entries from FILE and insert as Org-mode headlines after point."
 692   (interactive "ffile: ")
 693   (dotimes (_ (org-bibtex-read-file file))
 694     (save-excursion (org-bibtex-write))
 695     (re-search-forward org-property-end-re)
 696     (open-line 1) (forward-char 1)))
 697
 698 (defun org-bibtex-export-to-kill-ring ()
 699   "Export current headline to kill ring as bibtex entry."
 700   (interactive)
 701   (let ((result (org-bibtex-headline)))
 702     (kill-new result) result))
 703
 704 (defun org-bibtex-search (string)
 705   "Search for bibliographical entries in agenda files.
 706 This function relies `org-search-view' to locate results."
 707   (interactive "sSearch string: ")
 708   (let ((org-agenda-overriding-header "Bib search results:")
 709         (org-agenda-search-view-always-boolean t))
 710     (org-search-view nil
 711                      (format "%s +{:%s%s:}"
 712                              string (or org-bibtex-prefix "")
 713                              org-bibtex-type-property-name))))
 714
 715 (provide 'org-bibtex)
 716
 717 ;;; org-bibtex.el ends here