lisp/org-timer.el

   1 ;;; org-timer.el --- The relative timer code for Org-mode
   2
   3 ;; Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the relative timer code for Org-mode
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-notify "org-clock" (notification &optional play-sound))
  34 (declare-function org-agenda-error "org-agenda" ())
  35
  36 (defvar org-timer-start-time nil
  37   "t=0 for the running timer.")
  38
  39 (defvar org-timer-pause-time nil
  40   "Time when the timer was paused.")
  41
  42 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  43   "Regular expression used to match timer stamps.")
  44
  45 (defcustom org-timer-format "%s "
  46   "The format to insert the time of the timer.
  47 This format must contain one instance of \"%s\" which will be replaced by
  48 the value of the relative timer."
  49   :group 'org-time
  50   :type 'string)
  51
  52 (defcustom org-timer-default-timer 0
  53   "The default timer when a timer is set.
  54 When 0, the user is prompted for a value."
  55   :group 'org-time
  56   :version "24.1"
  57   :type 'number)
  58
  59 (defcustom org-timer-display 'mode-line
  60   "When a timer is running, org-mode can display it in the mode
  61 line and/or frame title.
  62 Allowed values are:
  63
  64 both         displays in both mode line and frame title
  65 mode-line    displays only in mode line (default)
  66 frame-title  displays only in frame title
  67 nil          current timer is not displayed"
  68   :group 'org-time
  69   :type '(choice
  70           (const :tag "Mode line" mode-line)
  71           (const :tag "Frame title" frame-title)
  72           (const :tag "Both" both)
  73           (const :tag "None" nil)))
  74
  75 (defvar org-timer-start-hook nil
  76   "Hook run after relative timer is started.")
  77
  78 (defvar org-timer-stop-hook nil
  79   "Hook run before relative timer is stopped.")
  80
  81 (defvar org-timer-pause-hook nil
  82   "Hook run before relative timer is paused.")
  83
  84 (defvar org-timer-continue-hook nil
  85  "Hook run after relative timer is continued.")
  86
  87 (defvar org-timer-set-hook nil
  88   "Hook run after countdown timer is set.")
  89
  90 (defvar org-timer-done-hook nil
  91   "Hook run after countdown timer reaches zero.")
  92
  93 (defvar org-timer-cancel-hook nil
  94   "Hook run before countdown timer is canceled.")
  95
  96 ;;;###autoload
  97 (defun org-timer-start (&optional offset)
  98   "Set the starting time for the relative timer to now.
  99 When called with prefix argument OFFSET, prompt the user for an offset time,
 100 with the default taken from a timer stamp at point, if any.
 101 If OFFSET is a string or an integer, it is directly taken to be the offset
 102 without user interaction.
 103 When called with a double prefix arg, all timer strings in the active
 104 region will be shifted by a specific amount.  You will be prompted for
 105 the amount, with the default to make the first timer string in
 106 the region 0:00:00."
 107   (interactive "P")
 108   (if (equal offset '(16))
 109       (call-interactively 'org-timer-change-times-in-region)
 110     (let (delta def s)
 111       (if (not offset)
 112           (setq org-timer-start-time (current-time))
 113         (cond
 114          ((integerp offset) (setq delta offset))
 115          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 116          (t
 117           (setq def (if (org-in-regexp org-timer-re)
 118                         (match-string 0)
 119                       "0:00:00")
 120                 s (read-string
 121                    (format "Restart timer with offset [%s]: " def)))
 122           (unless (string-match "\\S-" s) (setq s def))
 123           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 124         (setq org-timer-start-time
 125               (seconds-to-time
 126                (- (org-float-time) delta))))
 127       (org-timer-set-mode-line 'on)
 128       (message "Timer start time set to %s, current value is %s"
 129                (format-time-string "%T" org-timer-start-time)
 130                (org-timer-secs-to-hms (or delta 0)))
 131       (run-hooks 'org-timer-start-hook))))
 132
 133 (defun org-timer-pause-or-continue (&optional stop)
 134   "Pause or continue the relative timer.
 135 With prefix arg STOP, stop it entirely."
 136   (interactive "P")
 137   (cond
 138    (stop (org-timer-stop))
 139    ((not org-timer-start-time) (error "No timer is running"))
 140    (org-timer-pause-time
 141     ;; timer is paused, continue
 142     (setq org-timer-start-time
 143           (seconds-to-time
 144            (-
 145             (org-float-time)
 146             (- (org-float-time org-timer-pause-time)
 147                (org-float-time org-timer-start-time))))
 148           org-timer-pause-time nil)
 149     (org-timer-set-mode-line 'on)
 150     (run-hooks 'org-timer-continue-hook)
 151     (message "Timer continues at %s" (org-timer-value-string)))
 152    (t
 153     ;; pause timer
 154     (run-hooks 'org-timer-pause-hook)
 155     (setq org-timer-pause-time (current-time))
 156     (org-timer-set-mode-line 'pause)
 157     (message "Timer paused at %s" (org-timer-value-string)))))
 158
 159 (defun org-timer-stop ()
 160   "Stop the relative timer."
 161   (interactive)
 162   (run-hooks 'org-timer-stop-hook)
 163   (setq org-timer-start-time nil
 164         org-timer-pause-time nil)
 165   (org-timer-set-mode-line 'off))
 166
 167 ;;;###autoload
 168 (defun org-timer (&optional restart no-insert-p)
 169   "Insert a H:MM:SS string from the timer into the buffer.
 170 The first time this command is used, the timer is started.  When used with
 171 a \\[universal-argument] prefix, force restarting the timer.
 172 When used with a double prefix argument \\[universal-argument], change all the timer string
 173 in the region by a fixed amount.  This can be used to recalibrate a timer
 174 that was not started at the correct moment.
 175
 176 If NO-INSERT-P is non-nil, return the string instead of inserting
 177 it in the buffer."
 178   (interactive "P")
 179   (when (or (equal restart '(4)) (not org-timer-start-time))
 180     (org-timer-start))
 181   (if no-insert-p
 182       (org-timer-value-string)
 183     (insert (org-timer-value-string))))
 184
 185 (defun org-timer-value-string ()
 186   (format org-timer-format (org-timer-secs-to-hms (floor (org-timer-seconds)))))
 187
 188 (defvar org-timer-timer-is-countdown nil)
 189 (defun org-timer-seconds ()
 190   (if org-timer-timer-is-countdown
 191       (- (org-float-time org-timer-start-time)
 192          (org-float-time (current-time)))
 193     (- (org-float-time (or org-timer-pause-time (current-time)))
 194        (org-float-time org-timer-start-time))))
 195
 196 ;;;###autoload
 197 (defun org-timer-change-times-in-region (beg end delta)
 198   "Change all h:mm:ss time in region by a DELTA."
 199   (interactive
 200    "r\nsEnter time difference like \"-1:08:26\". Default is first time to zero: ")
 201   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 202     (unless (string-match "\\S-" delta)
 203       (save-excursion
 204         (goto-char beg)
 205         (when (re-search-forward re end t)
 206           (setq delta (match-string 0))
 207           (if (equal (string-to-char delta) ?-)
 208               (setq delta (substring delta 1))
 209             (setq delta (concat "-" delta))))))
 210     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 211     (when (= delta 0) (error "No change"))
 212     (save-excursion
 213       (goto-char end)
 214       (while (re-search-backward re beg t)
 215         (setq p (point))
 216         (replace-match
 217          (save-match-data
 218            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 219          t t)
 220         (goto-char p)))))
 221
 222 ;;;###autoload
 223 (defun org-timer-item (&optional arg)
 224   "Insert a description-type item with the current timer value."
 225   (interactive "P")
 226   (let ((itemp (org-in-item-p)) (pos (point)))
 227     (cond
 228      ;; In a timer list, insert with `org-list-insert-item',
 229      ;; then fix the list.
 230      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 231       (let* ((struct (org-list-struct))
 232              (prevs (org-list-prevs-alist struct))
 233              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 234         (setq struct (org-list-insert-item pos struct prevs nil s))
 235         (org-list-write-struct struct (org-list-parents-alist struct))
 236         (looking-at org-list-full-item-re)
 237         (goto-char (match-end 0))))
 238      ;; In a list of another type, don't break anything: throw an error.
 239      (itemp (goto-char pos) (error "This is not a timer list"))
 240      ;; Else, start a new list.
 241      (t
 242       (beginning-of-line)
 243       (org-indent-line-function)
 244       (insert  "- ")
 245       (org-timer (when arg '(4)))
 246       (insert ":: ")))))
 247
 248 (defun org-timer-fix-incomplete (hms)
 249   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 250   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 251       (replace-match
 252        (format "%d:%02d:%02d"
 253                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 254                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 255                (string-to-number (match-string 3 hms)))
 256        t t hms)
 257     (error "Cannot parse HMS string \"%s\"" hms)))
 258
 259 (defun org-timer-hms-to-secs (hms)
 260   "Convert h:mm:ss string to an integer time.
 261 If the string starts with a minus sign, the integer will be negative."
 262   (if (not (string-match
 263             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 264             hms))
 265       0
 266     (let* ((h (string-to-number (match-string 1 hms)))
 267            (m (string-to-number (match-string 2 hms)))
 268            (s (string-to-number (match-string 3 hms)))
 269            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 270       (setq h (abs h))
 271       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 272
 273 (defun org-timer-secs-to-hms (s)
 274   "Convert integer S into h:mm:ss.
 275 If the integer is negative, the string will start with \"-\"."
 276   (let (sign m h)
 277     (setq sign (if (< s 0) "-" "")
 278           s (abs s)
 279           m (/ s 60) s (- s (* 60 m))
 280           h (/ m 60) m (- m (* 60 h)))
 281     (format "%s%d:%02d:%02d" sign h m s)))
 282
 283 (defvar org-timer-mode-line-timer nil)
 284 (defvar org-timer-mode-line-string nil)
 285
 286 (defun org-timer-set-mode-line (value)
 287   "Set the mode-line display of the relative timer.
 288 VALUE can be `on', `off', or `pause'."
 289   (when (or (eq org-timer-display 'mode-line)
 290             (eq org-timer-display 'both))
 291     (or global-mode-string (setq global-mode-string '("")))
 292     (or (memq 'org-timer-mode-line-string global-mode-string)
 293         (setq global-mode-string
 294               (append global-mode-string '(org-timer-mode-line-string)))))
 295   (when (or (eq org-timer-display 'frame-title)
 296              (eq org-timer-display 'both))
 297     (or (memq 'org-timer-mode-line-string frame-title-format)
 298         (setq frame-title-format
 299               (append frame-title-format '(org-timer-mode-line-string)))))
 300   (cond
 301    ((equal value 'off)
 302     (when org-timer-mode-line-timer
 303       (cancel-timer org-timer-mode-line-timer)
 304       (setq org-timer-mode-line-timer nil))
 305     (setq global-mode-string
 306           (delq 'org-timer-mode-line-string global-mode-string))
 307     (setq frame-title-format
 308           (delq 'org-timer-mode-line-string frame-title-format))
 309     (force-mode-line-update))
 310    ((equal value 'pause)
 311     (when org-timer-mode-line-timer
 312       (cancel-timer org-timer-mode-line-timer)
 313       (setq org-timer-mode-line-timer nil)))
 314    ((equal value 'on)
 315   (when (or (eq org-timer-display 'mode-line)
 316             (eq org-timer-display 'both))
 317     (or global-mode-string (setq global-mode-string '("")))
 318     (or (memq 'org-timer-mode-line-string global-mode-string)
 319         (setq global-mode-string
 320               (append global-mode-string '(org-timer-mode-line-string)))))
 321   (when (or (eq org-timer-display 'frame-title)
 322             (eq org-timer-display 'both))
 323     (or (memq 'org-timer-mode-line-string frame-title-format)
 324         (setq frame-title-format
 325               (append frame-title-format '(org-timer-mode-line-string)))))
 326     (org-timer-update-mode-line)
 327     (when org-timer-mode-line-timer
 328       (cancel-timer org-timer-mode-line-timer)
 329       (setq org-timer-mode-line-timer nil))
 330     (when org-timer-display
 331       (setq org-timer-mode-line-timer
 332             (run-with-timer 1 1 'org-timer-update-mode-line))))))
 333
 334 (defun org-timer-update-mode-line ()
 335   "Update the timer time in the mode line."
 336   (if org-timer-pause-time
 337       nil
 338     (setq org-timer-mode-line-string
 339           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 340     (force-mode-line-update)))
 341
 342 (defvar org-timer-current-timer nil)
 343 (defun org-timer-cancel-timer ()
 344   "Cancel the current timer."
 345   (interactive)
 346   (when (eval org-timer-current-timer)
 347     (run-hooks 'org-timer-cancel-hook)
 348     (cancel-timer org-timer-current-timer)
 349     (setq org-timer-current-timer nil)
 350     (setq org-timer-timer-is-countdown nil)
 351     (org-timer-set-mode-line 'off))
 352   (message "Last timer canceled"))
 353
 354 (defun org-timer-show-remaining-time ()
 355   "Display the remaining time before the timer ends."
 356   (interactive)
 357   (require 'time)
 358   (if (not org-timer-current-timer)
 359       (message "No timer set")
 360     (let* ((rtime (decode-time
 361                    (time-subtract (timer--time org-timer-current-timer)
 362                                   (current-time))))
 363            (rsecs (nth 0 rtime))
 364            (rmins (nth 1 rtime)))
 365       (message "%d minute(s) %d seconds left before next time out"
 366                rmins rsecs))))
 367
 368 ;;;###autoload
 369 (defun org-timer-set-timer (&optional opt)
 370   "Prompt for a duration and set a timer.
 371
 372 If `org-timer-default-timer' is not zero, suggest this value as
 373 the default duration for the timer.  If a timer is already set,
 374 prompt the user if she wants to replace it.
 375
 376 Called with a numeric prefix argument, use this numeric value as
 377 the duration of the timer.
 378
 379 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 380 without prompting the user for a duration.
 381
 382 With two `C-u' prefix arguments, use `org-timer-default-timer'
 383 without prompting the user for a duration and automatically
 384 replace any running timer."
 385   (interactive "P")
 386   (let ((minutes (or (and (numberp opt) (number-to-string opt))
 387                      (and (listp opt) (not (null opt))
 388                           (number-to-string org-timer-default-timer))
 389                      (read-from-minibuffer
 390                       "How many minutes left? "
 391                       (if (not (eq org-timer-default-timer 0))
 392                           (number-to-string org-timer-default-timer))))))
 393     (if (not (string-match "[0-9]+" minutes))
 394         (org-timer-show-remaining-time)
 395     (let* ((mins (string-to-number (match-string 0 minutes)))
 396            (secs (* mins 60))
 397            (hl (cond
 398                 ((string-match "Org Agenda" (buffer-name))
 399                  (let* ((marker (or (get-text-property (point) 'org-marker)
 400                                     (org-agenda-error)))
 401                         (hdmarker (or (get-text-property (point) 'org-hd-marker)
 402                                       marker))
 403                         (pos (marker-position marker)))
 404                    (with-current-buffer (marker-buffer marker)
 405                      (widen)
 406                      (goto-char pos)
 407                      (org-show-entry)
 408                      (or (ignore-errors (org-get-heading))
 409                          (concat "File:" (file-name-nondirectory (buffer-file-name)))))))
 410                 ((derived-mode-p 'org-mode)
 411                  (or (ignore-errors (org-get-heading))
 412                      (concat "File:" (file-name-nondirectory (buffer-file-name)))))
 413                 (t (error "Not in an Org buffer"))))
 414            timer-set)
 415       (if (or (and org-timer-current-timer
 416                    (or (equal opt '(16))
 417                        (y-or-n-p "Replace current timer? ")))
 418               (not org-timer-current-timer))
 419           (progn
 420             (require 'org-clock)
 421             (when org-timer-current-timer
 422               (cancel-timer org-timer-current-timer))
 423             (setq org-timer-current-timer
 424                   (run-with-timer
 425                    secs nil `(lambda ()
 426                                (setq org-timer-current-timer nil)
 427                                (org-notify ,(format "%s: time out" hl) t)
 428                                (setq org-timer-timer-is-countdown nil)
 429                                (org-timer-set-mode-line 'off)
 430                                (run-hooks 'org-timer-done-hook))))
 431             (run-hooks 'org-timer-set-hook)
 432             (setq org-timer-timer-is-countdown t
 433                   org-timer-start-time
 434                   (time-add (current-time) (seconds-to-time (* mins 60))))
 435             (org-timer-set-mode-line 'on))
 436         (message "No timer set"))))))
 437
 438 (provide 'org-timer)
 439
 440 ;;; org-timer.el ends here