lisp/ob-lob.el

   1 ;;; ob-lob.el --- functions supporting the Library of Babel
   2
   3 ;; Copyright (C) 2009-2016 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (eval-when-compile
  27   (require 'cl))
  28 (require 'ob-core)
  29 (require 'ob-table)
  30
  31 (declare-function org-babel-in-example-or-verbatim "ob-exp" nil)
  32
  33 (defvar org-babel-library-of-babel nil
  34   "Library of source-code blocks.
  35 This is an association list.  Populate the library by adding
  36 files to `org-babel-lob-files'.")
  37
  38 (defcustom org-babel-lob-files nil
  39   "Files used to populate the `org-babel-library-of-babel'.
  40 To add files to this list use the `org-babel-lob-ingest' command."
  41   :group 'org-babel
  42   :version "24.1"
  43   :type '(repeat file))
  44
  45 (defvar org-babel-default-lob-header-args '((:exports . "results"))
  46   "Default header arguments to use when exporting #+lob/call lines.")
  47
  48 (defun org-babel-lob-ingest (&optional file)
  49   "Add all named source blocks defined in FILE to `org-babel-library-of-babel'."
  50   (interactive "fFile: ")
  51   (let ((lob-ingest-count 0))
  52     (org-babel-map-src-blocks file
  53       (let* ((info (org-babel-get-src-block-info 'light))
  54              (source-name (nth 4 info)))
  55         (when source-name
  56           (setq source-name (intern source-name)
  57                 org-babel-library-of-babel
  58                 (cons (cons source-name info)
  59                       (assq-delete-all source-name org-babel-library-of-babel))
  60                 lob-ingest-count (1+ lob-ingest-count)))))
  61     (message "%d src block%s added to Library of Babel"
  62              lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
  63     lob-ingest-count))
  64
  65 (defconst org-babel-block-lob-one-liner-regexp
  66   (concat
  67    "^\\([ \t]*?\\)#\\+call:[ \t]+\\([^()\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
  68    "(\\([^\n]*?\\))\\(\\[.+\\]\\|\\)[ \t]*\\(\\([^\n]*\\)\\)?")
  69   "Regexp to match non-inline calls to predefined source block functions.")
  70
  71 (defconst org-babel-inline-lob-one-liner-regexp
  72   (concat
  73    "\\([^\n]*?\\)call_\\([^()[:space:]\n]+?\\)\\(\\[\\(.*?\\)\\]\\|\\(\\)\\)"
  74    "(\\(.*?\\))\\(\\[\\(.*?\\)\\]\\)?")
  75   "Regexp to match inline calls to predefined source block functions.")
  76
  77 (defconst org-babel-lob-one-liner-regexp
  78   (concat "\\(" org-babel-block-lob-one-liner-regexp
  79           "\\|" org-babel-inline-lob-one-liner-regexp "\\)")
  80   "Regexp to match calls to predefined source block functions.")
  81
  82 ;; functions for executing lob one-liners
  83
  84 ;;;###autoload
  85 (defun org-babel-lob-execute-maybe ()
  86   "Execute a Library of Babel source block, if appropriate.
  87 Detect if this is context for a Library Of Babel source block and
  88 if so then run the appropriate source block from the Library."
  89   (interactive)
  90   (let ((info (org-babel-lob-get-info)))
  91     (if (and (nth 0 info) (not (org-babel-in-example-or-verbatim)))
  92         (progn (org-babel-lob-execute info) t)
  93       nil)))
  94
  95 ;;;###autoload
  96 (defun org-babel-lob-get-info ()
  97   "Return a Library of Babel function call as a string."
  98   (let ((case-fold-search t)
  99         (nonempty (lambda (a b)
 100                     (let ((it (match-string a)))
 101                       (if (= (length it) 0) (match-string b) it)))))
 102     (save-excursion
 103       (beginning-of-line 1)
 104       (when (looking-at org-babel-lob-one-liner-regexp)
 105         (append
 106          (mapcar #'org-no-properties
 107                  (list
 108                   (format "%s%s(%s)%s"
 109                           (funcall nonempty 3 12)
 110                           (if (not (= 0 (length (funcall nonempty 5 14))))
 111                               (concat "[" (funcall nonempty 5 14) "]") "")
 112                           (or (funcall nonempty 7 16) "")
 113                           (or (funcall nonempty 8 19) ""))
 114                   (funcall nonempty 9 18)))
 115          (list (length (if (= (length (match-string 12)) 0)
 116                            (match-string 2) (match-string 11)))
 117                (save-excursion
 118                  (forward-line -1)
 119                  (save-match-data
 120                    (and (looking-at (concat org-babel-src-name-regexp
 121                                             "\\([^\n]*\\)$"))
 122                         (org-no-properties (match-string 1)))))))))))
 123
 124 (defvar org-babel-default-header-args:emacs-lisp) ; Defined in ob-emacs-lisp.el
 125 (defun org-babel-lob-execute (info)
 126   "Execute the lob call specified by INFO."
 127   (let* ((mkinfo (lambda (p)
 128                    (list "emacs-lisp" "results" p nil
 129                          (nth 3 info) ;; name
 130                          (nth 2 info))))
 131          (pre-params (apply #'org-babel-merge-params
 132                             org-babel-default-header-args
 133                             org-babel-default-header-args:emacs-lisp
 134                             (append
 135                              (org-babel-params-from-properties)
 136                              (list
 137                               (org-babel-parse-header-arguments
 138                                (org-no-properties
 139                                 (concat
 140                                  ":var results="
 141                                  (mapconcat #'identity (butlast info 2)
 142                                             " "))))))))
 143          (pre-info (funcall mkinfo pre-params))
 144          (cache-p (and (cdr (assoc :cache pre-params))
 145                        (string= "yes" (cdr (assoc :cache pre-params)))))
 146          (new-hash (when cache-p
 147                      (org-babel-sha1-hash
 148                       ;; Do *not* pre-process params for call line
 149                       ;; hash evaluation, since for a call line :var
 150                       ;; extension *is* execution.
 151                       (let* ((params (nth 2 pre-info))
 152                              (sha1-nth2 (list
 153                                     (cons
 154                                      (cons :c-var (cdr (assoc :var params)))
 155                                      (assq-delete-all :var (copy-tree params)))))
 156                              (sha1-info (copy-tree pre-info)))
 157                         (prog1 sha1-info
 158                           (setcar (cddr sha1-info) sha1-nth2))))))
 159          (old-hash (when cache-p (org-babel-current-result-hash pre-info)))
 160          (org-babel-current-src-block-location (point-marker)))
 161     (if (and cache-p (equal new-hash old-hash))
 162         (save-excursion (goto-char (org-babel-where-is-src-block-result
 163                                     nil pre-info))
 164                         (forward-line 1)
 165                         (message "%S" (org-babel-read-result)))
 166       (prog1 (let* ((proc-params (org-babel-process-params pre-params))
 167                      org-confirm-babel-evaluate)
 168                (org-babel-execute-src-block nil (funcall mkinfo proc-params)))
 169         ;; update the hash
 170         (when new-hash
 171           (org-babel-set-current-result-hash new-hash pre-info))))))
 172
 173 (provide 'ob-lob)
 174
 175 ;; Local variables:
 176 ;; generated-autoload-file: "org-loaddefs.el"
 177 ;; End:
 178
 179 ;;; ob-lob.el ends here