lisp/ob-ref.el

   1 ;;; ob-ref.el --- Babel Functions for Referencing External Data -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for referencing data from the header arguments of a
  28 ;; org-babel block.  The syntax of such a reference should be
  29
  30 ;;   #+VAR: variable-name=file:resource-id
  31
  32 ;; - variable-name :: the name of the variable to which the value
  33 ;;                    will be assigned
  34
  35 ;; - file :: path to the file containing the resource, or omitted if
  36 ;;           resource is in the current file
  37
  38 ;; - resource-id :: the id or name of the resource
  39
  40 ;; So an example of a simple src block referencing table data in the
  41 ;; same file would be
  42
  43 ;;  #+NAME: sandbox
  44 ;;  | 1 |         2 | 3 |
  45 ;;  | 4 | org-babel | 6 |
  46 ;;
  47 ;;  #+begin_src emacs-lisp :var table=sandbox
  48 ;;    (message table)
  49 ;;  #+end_src
  50
  51 ;;; Code:
  52 (require 'ob-core)
  53 (require 'cl-lib)
  54
  55 (declare-function org-babel-lob-get-info "ob-lob" (&optional datum))
  56 (declare-function org-element-at-point "org-element" ())
  57 (declare-function org-element-property "org-element" (property element))
  58 (declare-function org-element-type "org-element" (element))
  59 (declare-function org-end-of-meta-data "org" (&optional full))
  60 (declare-function org-find-property "org" (property &optional value))
  61 (declare-function org-id-find-id-file "org-id" (id))
  62 (declare-function org-id-find-id-in-file "org-id" (id file &optional markerp))
  63 (declare-function org-in-commented-heading-p "org" (&optional no-inheritance))
  64 (declare-function org-narrow-to-subtree "org" ())
  65 (declare-function org-show-context "org" (&optional key))
  66 (declare-function org-trim "org" (s &optional keep-lead))
  67
  68 (defvar org-babel-ref-split-regexp
  69   "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  70
  71 (defvar org-babel-update-intermediate nil
  72   "Update the in-buffer results of code blocks executed to resolve references.")
  73
  74 (defun org-babel-ref-parse (assignment)
  75   "Parse a variable ASSIGNMENT in a header argument.
  76 If the right hand side of the assignment has a literal value
  77 return that value, otherwise interpret as a reference to an
  78 external resource and find its value using
  79 `org-babel-ref-resolve'.  Return a list with two elements.  The
  80 first element of the list will be the name of the variable, and
  81 the second will be an emacs-lisp representation of the value of
  82 the variable."
  83   (when (string-match org-babel-ref-split-regexp assignment)
  84     (let ((var (match-string 1 assignment))
  85           (ref (match-string 2 assignment)))
  86       (cons (intern var)
  87             (let ((out (save-excursion
  88                          (when org-babel-current-src-block-location
  89                            (goto-char (if (markerp org-babel-current-src-block-location)
  90                                           (marker-position org-babel-current-src-block-location)
  91                                         org-babel-current-src-block-location)))
  92                          (org-babel-read ref))))
  93               (if (equal out ref)
  94                   (if (and (string-prefix-p "\"" ref)
  95                            (string-suffix-p "\"" ref))
  96                       (read ref)
  97                     (org-babel-ref-resolve ref))
  98                 out))))))
  99
 100 (defun org-babel-ref-goto-headline-id (id)
 101   (or (let ((h (org-find-property "CUSTOM_ID" id)))
 102         (when h (goto-char h)))
 103       (let* ((file (org-id-find-id-file id))
 104              (m (when file (org-id-find-id-in-file id file 'marker))))
 105         (when (and file m)
 106           (message "file:%S" file)
 107           (pop-to-buffer-same-window (marker-buffer m))
 108           (goto-char m)
 109           (move-marker m nil)
 110           (org-show-context)
 111           t))))
 112
 113 (defun org-babel-ref-headline-body ()
 114   (save-restriction
 115     (org-narrow-to-subtree)
 116     (buffer-substring
 117      (save-excursion (goto-char (point-min))
 118                      (org-end-of-meta-data)
 119                      (point))
 120      (point-max))))
 121
 122 (defvar org-babel-library-of-babel)
 123 (defun org-babel-ref-resolve (ref)
 124   "Resolve the reference REF and return its value."
 125   (save-window-excursion
 126     (with-current-buffer (or org-babel-exp-reference-buffer (current-buffer))
 127       (save-excursion
 128         (let ((case-fold-search t)
 129               args new-refere new-header-args new-referent split-file split-ref
 130               index)
 131           ;; if ref is indexed grab the indices -- beware nested indices
 132           (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
 133                      (let ((str (substring ref 0 (match-beginning 0))))
 134                        (= (cl-count ?( str) (cl-count ?) str))))
 135             (setq index (match-string 1 ref))
 136             (setq ref (substring ref 0 (match-beginning 0))))
 137           ;; assign any arguments to pass to source block
 138           (when (string-match
 139                  "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)(\\(.*\\))$" ref)
 140             (setq new-refere      (match-string 1 ref))
 141             (setq new-header-args (match-string 3 ref))
 142             (setq new-referent    (match-string 5 ref))
 143             (when (> (length new-refere) 0)
 144               (when (> (length new-referent) 0)
 145                 (setq args (mapcar (lambda (ref) (cons :var ref))
 146                                    (org-babel-ref-split-args new-referent))))
 147               (when (> (length new-header-args) 0)
 148                 (setq args (append (org-babel-parse-header-arguments
 149                                     new-header-args) args)))
 150               (setq ref new-refere)))
 151           (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
 152             (setq split-file (match-string 1 ref))
 153             (setq split-ref (match-string 2 ref))
 154             (find-file split-file)
 155             (setq ref split-ref))
 156           (org-with-wide-buffer
 157            (goto-char (point-min))
 158            (let* ((params (append args '((:results . "silent"))))
 159                   (regexp (org-babel-named-data-regexp-for-name ref))
 160                   (result
 161                    (catch :found
 162                      ;; Check for code blocks or named data.
 163                      (while (re-search-forward regexp nil t)
 164                        ;; Ignore COMMENTed headings and orphaned
 165                        ;; affiliated keywords.
 166                        (unless (org-in-commented-heading-p)
 167                          (let ((e (org-element-at-point)))
 168                            (when (equal (org-element-property :name e) ref)
 169                              (goto-char
 170                               (org-element-property :post-affiliated e))
 171                              (pcase (org-element-type e)
 172                                (`babel-call
 173                                 (throw :found
 174                                        (org-babel-execute-src-block
 175                                         nil (org-babel-lob-get-info e) params)))
 176                                (`src-block
 177                                 (throw :found
 178                                        (org-babel-execute-src-block
 179                                         nil nil
 180                                         (and
 181                                          (not org-babel-update-intermediate)
 182                                          params))))
 183                                ((and (let v (org-babel-read-element e))
 184                                      (guard v))
 185                                 (throw :found v))
 186                                (_ (error "Reference not found")))))))
 187                      ;; Check for local or global headlines by ID.
 188                      (when (org-babel-ref-goto-headline-id ref)
 189                        (throw :found (org-babel-ref-headline-body)))
 190                      ;; Check the Library of Babel.
 191                      (let ((info (cdr (assq (intern ref)
 192                                             org-babel-library-of-babel))))
 193                        (when info
 194                          (throw :found
 195                                 (org-babel-execute-src-block nil info params))))
 196                      (error "Reference `%s' not found in this buffer" ref))))
 197              (cond
 198               ((symbolp result) (format "%S" result))
 199               ((and index (listp result))
 200                (org-babel-ref-index-list index result))
 201               (t result)))))))))
 202
 203 (defun org-babel-ref-index-list (index lis)
 204   "Return the subset of LIS indexed by INDEX.
 205
 206 Indices are 0 based and negative indices count from the end of
 207 LIS, so 0 references the first element of LIS and -1 references
 208 the last.  If INDEX is separated by \",\"s then each \"portion\"
 209 is assumed to index into the next deepest nesting or dimension.
 210
 211 A valid \"portion\" can consist of either an integer index, two
 212 integers separated by a \":\" in which case the entire range is
 213 returned, or an empty string or \"*\" both of which are
 214 interpreted to mean the entire range and as such are equivalent
 215 to \"0:-1\"."
 216   (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
 217       (let* ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\\*\\)")
 218              (lgth (length lis))
 219              (portion (match-string 1 index))
 220              (remainder (substring index (match-end 0)))
 221              (wrap (lambda (num) (if (< num 0) (+ lgth num) num)))
 222              (open (lambda (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls))))
 223         (funcall
 224          open
 225          (mapcar
 226           (lambda (sub-lis)
 227             (if (listp sub-lis)
 228                 (org-babel-ref-index-list remainder sub-lis)
 229               sub-lis))
 230           (if (or (= 0 (length portion)) (string-match ind-re portion))
 231               (mapcar
 232                (lambda (n) (nth n lis))
 233                (apply 'org-number-sequence
 234                       (if (and (> (length portion) 0) (match-string 2 portion))
 235                           (list
 236                            (funcall wrap (string-to-number (match-string 2 portion)))
 237                            (funcall wrap (string-to-number (match-string 3 portion))))
 238                         (list (funcall wrap 0) (funcall wrap -1)))))
 239             (list (nth (funcall wrap (string-to-number portion)) lis))))))
 240     lis))
 241
 242 (defun org-babel-ref-split-args (arg-string)
 243   "Split ARG-STRING into top-level arguments of balanced parenthesis."
 244   (mapcar #'org-trim (org-babel-balanced-split arg-string 44)))
 245
 246
 247 (provide 'ob-ref)
 248
 249 ;;; ob-ref.el ends here