lisp/ob-awk.el

   1 ;;; ob-awk.el --- org-babel functions for awk evaluation
   2
   3 ;; Copyright (C) 2011-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Babel's awk can use special header argument:
  27 ;;
  28 ;; - :in-file takes a path to a file of data to be processed by awk
  29 ;;
  30 ;; - :stdin takes an Org-mode data or code block reference, the value
  31 ;;          of which will be passed to the awk process through STDIN
  32
  33 ;;; Code:
  34 (require 'ob)
  35 (require 'org-compat)
  36 (eval-when-compile (require 'cl))
  37
  38 (declare-function org-babel-ref-resolve "ob-ref" (ref))
  39 (declare-function orgtbl-to-generic "org-table" (table params))
  40
  41 (defvar org-babel-tangle-lang-exts)
  42 (add-to-list 'org-babel-tangle-lang-exts '("awk" . "awk"))
  43
  44 (defvar org-babel-awk-command "awk"
  45   "Name of the awk executable command.")
  46
  47 (defun org-babel-expand-body:awk (body params)
  48   "Expand BODY according to PARAMS, return the expanded body."
  49   body)
  50
  51 (defun org-babel-execute:awk (body params)
  52   "Execute a block of Awk code with org-babel.  This function is
  53 called by `org-babel-execute-src-block'"
  54   (message "executing Awk source code block")
  55   (let* ((result-params (cdr (assoc :result-params params)))
  56          (cmd-line (cdr (assoc :cmd-line params)))
  57          (in-file (cdr (assoc :in-file params)))
  58          (full-body (org-babel-expand-body:awk body params))
  59          (code-file (let ((file (org-babel-temp-file "awk-")))
  60                       (with-temp-file file (insert full-body)) file))
  61          (stdin (let ((stdin (cdr (assoc :stdin params))))
  62                    (when stdin
  63                      (let ((tmp (org-babel-temp-file "awk-stdin-"))
  64                            (res (org-babel-ref-resolve stdin)))
  65                        (with-temp-file tmp
  66                          (insert (org-babel-awk-var-to-awk res)))
  67                        tmp))))
  68          (cmd (mapconcat #'identity
  69                          (append
  70                           (list org-babel-awk-command
  71                                 "-f" code-file cmd-line)
  72                           (mapcar (lambda (pair)
  73                                     (format "-v %s='%s'"
  74                                             (cadr pair)
  75                                             (org-babel-awk-var-to-awk
  76                                              (cddr pair))))
  77                                   (org-babel-get-header params :var))
  78                           (list in-file))
  79                          " ")))
  80     (org-babel-reassemble-table
  81      (let ((results
  82             (cond
  83              (stdin (with-temp-buffer
  84                       (call-process-shell-command cmd stdin (current-buffer))
  85                       (buffer-string)))
  86              (t (org-babel-eval cmd "")))))
  87        (when results
  88          (org-babel-result-cond result-params
  89            results
  90            (let ((tmp (org-babel-temp-file "awk-results-")))
  91              (with-temp-file tmp (insert results))
  92              (org-babel-import-elisp-from-file tmp)))))
  93      (org-babel-pick-name
  94       (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
  95      (org-babel-pick-name
  96       (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params))))))
  97
  98 (defun org-babel-awk-var-to-awk (var &optional sep)
  99   "Return a printed value of VAR suitable for parsing with awk."
 100   (let ((echo-var (lambda (v) (if (stringp v) v (format "%S" v)))))
 101     (cond
 102      ((and (listp var) (listp (car var)))
 103       (orgtbl-to-generic var  (list :sep (or sep "\t") :fmt echo-var)))
 104      ((listp var)
 105       (mapconcat echo-var var "\n"))
 106      (t (funcall echo-var var)))))
 107
 108 (provide 'ob-awk)
 109
 110
 111
 112 ;;; ob-awk.el ends here