lisp/ob-C.el

   1 ;;; ob-C.el --- org-babel functions for C and similar languages
   2
   3 ;; Copyright (C) 2010-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;;      Thierry Banel
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating C, C++, D code.
  28 ;;
  29 ;; very limited implementation:
  30 ;; - currently only support :results output
  31 ;; - not much in the way of error feedback
  32
  33 ;;; Code:
  34 (eval-when-compile
  35   (require 'cl))
  36 (require 'ob)
  37 (require 'cc-mode)
  38
  39 (declare-function org-entry-get "org"
  40                   (pom property &optional inherit literal-nil))
  41 (declare-function org-remove-indentation "org" (code &optional n))
  42
  43 (defvar org-babel-tangle-lang-exts)
  44 (add-to-list 'org-babel-tangle-lang-exts '("C++" . "cpp"))
  45 (add-to-list 'org-babel-tangle-lang-exts '("D" . "d"))
  46
  47 (defvar org-babel-default-header-args:C '())
  48
  49 (defcustom org-babel-C-compiler "gcc"
  50   "Command used to compile a C source code file into an executable.
  51 May be either a command in the path, like gcc
  52 or an absolute path name, like /usr/local/bin/gcc
  53 parameter may be used, like gcc -v"
  54   :group 'org-babel
  55   :version "24.3"
  56   :type 'string)
  57
  58 (defcustom org-babel-C++-compiler "g++"
  59   "Command used to compile a C++ source code file into an executable.
  60 May be either a command in the path, like g++
  61 or an absolute path name, like /usr/local/bin/g++
  62 parameter may be used, like g++ -v"
  63   :group 'org-babel
  64   :version "24.3"
  65   :type 'string)
  66
  67 (defcustom org-babel-D-compiler "rdmd"
  68   "Command used to compile and execute a D source code file.
  69 May be either a command in the path, like rdmd
  70 or an absolute path name, like /usr/local/bin/rdmd
  71 parameter may be used, like rdmd --chatty"
  72   :group 'org-babel
  73   :version "24.3"
  74   :type 'string)
  75
  76 (defvar org-babel-c-variant nil
  77   "Internal variable used to hold which type of C (e.g. C or C++ or D)
  78 is currently being evaluated.")
  79
  80 (defun org-babel-execute:cpp (body params)
  81   "Execute BODY according to PARAMS.
  82 This function calls `org-babel-execute:C++'."
  83   (org-babel-execute:C++ body params))
  84
  85 (defun org-babel-expand-body:cpp (body params)
  86   "Expand a block of C++ code with org-babel according to it's
  87 header arguments."
  88   (org-babel-expand-body:C++ body params))
  89
  90 (defun org-babel-execute:C++ (body params)
  91   "Execute a block of C++ code with org-babel.
  92 This function is called by `org-babel-execute-src-block'."
  93   (let ((org-babel-c-variant 'cpp)) (org-babel-C-execute body params)))
  94
  95 (defun org-babel-expand-body:C++ (body params)
  96   "Expand a block of C++ code with org-babel according to it's
  97 header arguments."
  98   (let ((org-babel-c-variant 'cpp)) (org-babel-C-expand-C++ body params)))
  99
 100 (defun org-babel-execute:D (body params)
 101   "Execute a block of D code with org-babel.
 102 This function is called by `org-babel-execute-src-block'."
 103   (let ((org-babel-c-variant 'd)) (org-babel-C-execute body params)))
 104
 105 (defun org-babel-expand-body:D (body params)
 106   "Expand a block of D code with org-babel according to it's
 107 header arguments."
 108   (let ((org-babel-c-variant 'd)) (org-babel-C-expand-D body params)))
 109
 110 (defun org-babel-execute:C (body params)
 111   "Execute a block of C code with org-babel.
 112 This function is called by `org-babel-execute-src-block'."
 113   (let ((org-babel-c-variant 'c)) (org-babel-C-execute body params)))
 114
 115 (defun org-babel-expand-body:C (body params)
 116   "Expand a block of C code with org-babel according to it's
 117 header arguments."
 118   (let ((org-babel-c-variant 'c)) (org-babel-C-expand-C body params)))
 119
 120 (defun org-babel-C-execute (body params)
 121   "This function should only be called by `org-babel-execute:C'
 122 or `org-babel-execute:C++' or `org-babel-execute:D'."
 123   (let* ((tmp-src-file (org-babel-temp-file
 124                         "C-src-"
 125                         (case org-babel-c-variant
 126                          (c   ".c"  )
 127                          (cpp ".cpp")
 128                          (d   ".d"  ))))
 129          (tmp-bin-file (org-babel-temp-file "C-bin-" org-babel-exeext)) ;; not used for D
 130          (cmdline (cdr (assoc :cmdline params)))
 131          (cmdline (if cmdline (concat " " cmdline) ""))
 132          (flags (cdr (assoc :flags params)))
 133          (flags (mapconcat 'identity
 134                            (if (listp flags) flags (list flags)) " "))
 135          (full-body
 136           (case org-babel-c-variant
 137             (c   (org-babel-C-expand-C   body params))
 138             (cpp (org-babel-C-expand-C++ body params))
 139             (d   (org-babel-C-expand-D   body params)))))
 140     (with-temp-file tmp-src-file (insert full-body))
 141     (case org-babel-c-variant
 142       ((c cpp)
 143        (org-babel-eval
 144         (format "%s -o %s %s %s"
 145                 (case org-babel-c-variant
 146                  (c   org-babel-C-compiler)
 147                  (cpp org-babel-C++-compiler))
 148                 (org-babel-process-file-name tmp-bin-file)
 149                 flags
 150                 (org-babel-process-file-name tmp-src-file)) ""))
 151       (d nil)) ;; no separate compilation for D
 152     (let ((results
 153            (org-babel-eval
 154             (case org-babel-c-variant
 155               ((c cpp)
 156                (concat tmp-bin-file cmdline))
 157               (d
 158                (format "%s %s %s %s"
 159                        org-babel-D-compiler
 160                        flags
 161                        (org-babel-process-file-name tmp-src-file)
 162                        cmdline)))
 163             "")))
 164       (when results
 165         (setq results (org-babel-trim (org-remove-indentation results)))
 166         (org-babel-reassemble-table
 167          (org-babel-result-cond (cdr (assoc :result-params params))
 168            (org-babel-read results t)
 169            (let ((tmp-file (org-babel-temp-file "c-")))
 170              (with-temp-file tmp-file (insert results))
 171              (org-babel-import-elisp-from-file tmp-file)))
 172          (org-babel-pick-name
 173           (cdr (assoc :colname-names params)) (cdr (assoc :colnames params)))
 174          (org-babel-pick-name
 175           (cdr (assoc :rowname-names params)) (cdr (assoc :rownames params)))))
 176       )))
 177
 178 (defun org-babel-C-expand-C++ (body params)
 179   "Expand a block of C or C++ code with org-babel according to
 180 it's header arguments."
 181   (org-babel-C-expand-C body params))
 182
 183 (defun org-babel-C-expand-C (body params)
 184   "Expand a block of C or C++ code with org-babel according to
 185 it's header arguments."
 186   (let ((vars (mapcar #'cdr (org-babel-get-header params :var)))
 187         (colnames (cdar (org-babel-get-header params :colname-names)))
 188         (main-p (not (string= (cdr (assoc :main params)) "no")))
 189         (includes (or (cdr (assoc :includes params))
 190                       (org-babel-read (org-entry-get nil "includes" t))))
 191         (defines (org-babel-read
 192                   (or (cdr (assoc :defines params))
 193                       (org-babel-read (org-entry-get nil "defines" t))))))
 194     (unless (listp includes) (setq includes (list includes)))
 195     (setq includes (append includes '("<string.h>" "<stdio.h>" "<stdlib.h>")))
 196     (mapconcat 'identity
 197                (list
 198                 ;; includes
 199                 (mapconcat
 200                  (lambda (inc) (format "#include %s" inc))
 201                  includes "\n")
 202                 ;; defines
 203                 (mapconcat
 204                  (lambda (inc) (format "#define %s" inc))
 205                  (if (listp defines) defines (list defines)) "\n")
 206                 ;; variables
 207                 (mapconcat 'org-babel-C-var-to-C vars "\n")
 208                 ;; table sizes
 209                 (mapconcat 'org-babel-C-table-sizes-to-C vars "\n")
 210                 ;; tables headers utility
 211                 (when colnames
 212                   (org-babel-C-utility-header-to-C))
 213                 ;; tables headers
 214                 (mapconcat 'org-babel-C-header-to-C colnames "\n")
 215                 ;; body
 216                 (if main-p
 217                     (org-babel-C-ensure-main-wrap body)
 218                   body) "\n") "\n")))
 219
 220 (defun org-babel-C-expand-D (body params)
 221   "Expand a block of D code with org-babel according to
 222 it's header arguments."
 223   (let ((vars (mapcar #'cdr (org-babel-get-header params :var)))
 224         (colnames (cdar (org-babel-get-header params :colname-names)))
 225         (main-p (not (string= (cdr (assoc :main params)) "no")))
 226         (imports (or (cdr (assoc :imports params))
 227                      (org-babel-read (org-entry-get nil "imports" t)))))
 228     (unless (listp imports) (setq imports (list imports)))
 229     (setq imports (append imports '("std.stdio" "std.conv")))
 230     (mapconcat 'identity
 231                (list
 232                 "module mmm;"
 233                 ;; imports
 234                 (mapconcat
 235                  (lambda (inc) (format "import %s;" inc))
 236                  imports "\n")
 237                 ;; variables
 238                 (mapconcat 'org-babel-C-var-to-C vars "\n")
 239                 ;; table sizes
 240                 (mapconcat 'org-babel-C-table-sizes-to-C vars "\n")
 241                 ;; tables headers utility
 242                 (when colnames
 243                   (org-babel-C-utility-header-to-C))
 244                 ;; tables headers
 245                 (mapconcat 'org-babel-C-header-to-C colnames "\n")
 246                 ;; body
 247                 (if main-p
 248                     (org-babel-C-ensure-main-wrap body)
 249                   body) "\n") "\n")))
 250
 251 (defun org-babel-C-ensure-main-wrap (body)
 252   "Wrap BODY in a \"main\" function call if none exists."
 253   (if (string-match "^[ \t]*[intvod]+[ \t\n\r]*main[ \t]*(.*)" body)
 254       body
 255     (format "int main() {\n%s\nreturn 0;\n}\n" body)))
 256
 257 (defun org-babel-prep-session:C (session params)
 258   "This function does nothing as C is a compiled language with no
 259 support for sessions"
 260   (error "C is a compiled languages -- no support for sessions"))
 261
 262 (defun org-babel-load-session:C (session body params)
 263   "This function does nothing as C is a compiled language with no
 264 support for sessions"
 265   (error "C is a compiled languages -- no support for sessions"))
 266
 267 ;; helper functions
 268
 269 (defun org-babel-C-format-val (type val)
 270   "Handle the FORMAT part of TYPE with the data from VAL."
 271   (let ((format-data (cadr type)))
 272     (if (stringp format-data)
 273         (cons "" (format format-data val))
 274       (funcall format-data val))))
 275
 276 (defun org-babel-C-val-to-C-type (val)
 277   "Determine the type of VAL.
 278 Return a list (TYPE-NAME FORMAT).  TYPE-NAME should be the name of the type.
 279 FORMAT can be either a format string or a function which is called with VAL."
 280   (let* ((basetype (org-babel-C-val-to-base-type val))
 281          (type
 282           (case basetype
 283             (integerp '("int" "%d"))
 284             (floatp '("double" "%f"))
 285             (stringp
 286              (list
 287               (if (equal org-babel-c-variant 'd) "string" "const char*")
 288               "\"%s\""))
 289             (t (error "unknown type %S" basetype)))))
 290     (cond
 291      ((integerp val) type) ;; an integer declared in the #+begin_src line
 292      ((floatp val) type) ;; a numeric declared in the #+begin_src line
 293      ((and (listp val) (listp (car val))) ;; a table
 294       `(,(car type)
 295         (lambda (val)
 296           (cons
 297            (format "[%d][%d]" (length val) (length (car val)))
 298            (concat
 299             (if (equal org-babel-c-variant 'd) "[\n" "{\n")
 300             (mapconcat
 301              (lambda (v)
 302                (concat
 303                 (if (equal org-babel-c-variant 'd) " [" " {")
 304                 (mapconcat (lambda (w) (format ,(cadr type) w)) v ",")
 305                 (if (equal org-babel-c-variant 'd) "]" "}")))
 306              val
 307              ",\n")
 308             (if (equal org-babel-c-variant 'd) "\n]" "\n}"))))))
 309      ((or (listp val) (vectorp val)) ;; a list declared in the #+begin_src line
 310       `(,(car type)
 311         (lambda (val)
 312           (cons
 313            (format "[%d]" (length val))
 314            (concat
 315             (if (equal org-babel-c-variant 'd) "[" "{")
 316             (mapconcat (lambda (v) (format ,(cadr type) v)) val ",")
 317             (if (equal org-babel-c-variant 'd) "]" "}"))))))
 318      (t ;; treat unknown types as string
 319       type))))
 320
 321 (defun org-babel-C-val-to-base-type (val)
 322   "Determine the base type of VAL which may be
 323 'integerp if all base values are integers
 324 'floatp if all base values are either floating points or integers
 325 'stringp otherwise."
 326   (cond
 327    ((integerp val) 'integerp)
 328    ((floatp val) 'floatp)
 329    ((or (listp val) (vectorp val))
 330     (let ((type nil))
 331       (mapc (lambda (v)
 332               (case (org-babel-C-val-to-base-type v)
 333                 (stringp (setq type 'stringp))
 334                 (floatp
 335                  (if (or (not type) (eq type 'integerp))
 336                      (setq type 'floatp)))
 337                 (integerp
 338                  (unless type (setq type 'integerp)))))
 339             val)
 340       type))
 341    (t 'stringp)))
 342
 343 (defun org-babel-C-var-to-C (pair)
 344   "Convert an elisp val into a string of C code specifying a var
 345 of the same value."
 346   ;; TODO list support
 347   (let ((var (car pair))
 348         (val (cdr pair)))
 349     (when (symbolp val)
 350       (setq val (symbol-name val))
 351       (when (= (length val) 1)
 352         (setq val (string-to-char val))))
 353     (let* ((type-data (org-babel-C-val-to-C-type val))
 354            (type (car type-data))
 355            (formated (org-babel-C-format-val type-data val))
 356            (suffix (car formated))
 357            (data (cdr formated)))
 358       (format "%s %s%s = %s;"
 359               type
 360               var
 361               suffix
 362               data))))
 363
 364 (defun org-babel-C-table-sizes-to-C (pair)
 365   "Create constants of table dimensions, if PAIR is a table."
 366   (when (listp (cdr pair))
 367     (cond
 368      ((listp (cadr pair)) ;; a table
 369       (concat
 370        (format "const int %s_rows = %d;" (car pair) (length (cdr pair)))
 371        "\n"
 372        (format "const int %s_cols = %d;" (car pair) (length (cadr pair)))))
 373      (t ;; a list declared in the #+begin_src line
 374       (format "const int %s_cols = %d;" (car pair) (length (cdr pair)))))))
 375
 376 (defun org-babel-C-utility-header-to-C ()
 377   "Generate a utility function to convert a column name
 378 into a column number."
 379   (case org-babel-c-variant
 380     ((c cpp)
 381      "int get_column_num (int nbcols, const char** header, const char* column)
 382 {
 383   int c;
 384   for (c=0; c<nbcols; c++)
 385     if (strcmp(header[c],column)==0)
 386       return c;
 387   return -1;
 388 }
 389 "
 390      )
 391     (d
 392      "int get_column_num (string[] header, string column)
 393 {
 394   foreach (c, h; header)
 395     if (h==column)
 396       return to!int(c);
 397   return -1;
 398 }
 399 "
 400      )))
 401
 402 (defun org-babel-C-header-to-C (head)
 403   "Convert an elisp list of header table into a C or D vector
 404 specifying a variable with the name of the table."
 405   (let ((table (car head))
 406         (headers (cdr head)))
 407     (concat
 408      (format
 409       (case org-babel-c-variant
 410         ((c cpp) "const char* %s_header[%d] = {%s};")
 411         (d       "string %s_header[%d] = [%s];"))
 412       table
 413       (length headers)
 414       (mapconcat (lambda (h) (format "%S" h)) headers ","))
 415      "\n"
 416      (case org-babel-c-variant
 417        ((c cpp)
 418         (format
 419          "const char* %s_h (int row, const char* col) { return %s[row][get_column_num(%d,%s_header,col)]; }"
 420          table table (length headers) table))
 421        (d
 422         (format
 423          "string %s_h (ulong row, string col) { return %s[row][get_column_num(%s_header,col)]; }"
 424          table table table))))))
 425
 426 (provide 'ob-C)
 427
 428 ;;; ob-C.el ends here