lisp/ob-lob.el

   1 ;;; ob-lob.el --- functions supporting the Library of Babel
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26 (eval-when-compile
  27   (require 'cl))
  28 (require 'ob-core)
  29 (require 'ob-table)
  30
  31 (declare-function org-babel-in-example-or-verbatim "ob-exp" nil)
  32
  33 (defvar org-babel-library-of-babel nil
  34   "Library of source-code blocks.
  35 This is an association list.  Populate the library by adding
  36 files to `org-babel-lob-files'.")
  37
  38 (defcustom org-babel-lob-files nil
  39   "Files used to populate the `org-babel-library-of-babel'.
  40 To add files to this list use the `org-babel-lob-ingest' command."
  41   :group 'org-babel
  42   :version "24.1"
  43   :type 'list)
  44
  45 (defvar org-babel-default-lob-header-args '((:exports . "results"))
  46   "Default header arguments to use when exporting #+lob/call lines.")
  47
  48 (defun org-babel-lob-ingest (&optional file)
  49   "Add all named source-blocks defined in FILE to
  50 `org-babel-library-of-babel'."
  51   (interactive "fFile: ")
  52   (let ((lob-ingest-count 0))
  53     (org-babel-map-src-blocks file
  54       (let* ((info (org-babel-get-src-block-info 'light))
  55              (source-name (nth 4 info)))
  56         (when source-name
  57           (setq source-name (intern source-name)
  58                 org-babel-library-of-babel
  59                 (cons (cons source-name info)
  60                       (assq-delete-all source-name org-babel-library-of-babel))
  61                 lob-ingest-count (1+ lob-ingest-count)))))
  62     (message "%d src block%s added to Library of Babel"
  63              lob-ingest-count (if (> lob-ingest-count 1) "s" ""))
  64     lob-ingest-count))
  65
  66 (defconst org-babel-block-lob-one-liner-regexp
  67   (concat
  68    "^\\([ \t]*?\\)#\\+call:[ \t]+\\([^\(\)\n]+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)"
  69    "\(\\([^\n]*?\\)\)\\(\\[.+\\]\\|\\)[ \t]*\\(\\([^\n]*\\)\\)?")
  70   "Regexp to match non-inline calls to predefined source block functions.")
  71
  72 (defconst org-babel-inline-lob-one-liner-regexp
  73   (concat
  74    "\\([^\n]*?\\)call_\\([^\(\)\n]+?\\)\\(\\[\\(.*?\\)\\]\\|\\(\\)\\)"
  75    "\(\\([^\n]*?\\)\)\\(\\[\\(.*?\\)\\]\\)?")
  76   "Regexp to match inline calls to predefined source block functions.")
  77
  78 (defconst org-babel-lob-one-liner-regexp
  79   (concat "\\(" org-babel-block-lob-one-liner-regexp
  80           "\\|" org-babel-inline-lob-one-liner-regexp "\\)")
  81   "Regexp to match calls to predefined source block functions.")
  82
  83 ;; functions for executing lob one-liners
  84
  85 ;;;###autoload
  86 (defun org-babel-lob-execute-maybe ()
  87   "Execute a Library of Babel source block, if appropriate.
  88 Detect if this is context for a Library Of Babel source block and
  89 if so then run the appropriate source block from the Library."
  90   (interactive)
  91   (let ((info (org-babel-lob-get-info)))
  92     (if (and (nth 0 info) (not (org-babel-in-example-or-verbatim)))
  93         (progn (org-babel-lob-execute info) t)
  94       nil)))
  95
  96 ;;;###autoload
  97 (defun org-babel-lob-get-info ()
  98   "Return a Library of Babel function call as a string."
  99   (let ((case-fold-search t)
 100         (nonempty (lambda (a b)
 101                     (let ((it (match-string a)))
 102                       (if (= (length it) 0) (match-string b) it)))))
 103     (save-excursion
 104       (beginning-of-line 1)
 105       (when (looking-at org-babel-lob-one-liner-regexp)
 106         (append
 107          (mapcar #'org-no-properties
 108                  (list
 109                   (format "%s%s(%s)%s"
 110                           (funcall nonempty 3 12)
 111                           (if (not (= 0 (length (funcall nonempty 5 14))))
 112                               (concat "[" (funcall nonempty 5 14) "]") "")
 113                           (or (funcall nonempty 7 16) "")
 114                           (or (funcall nonempty 8 19) ""))
 115                   (funcall nonempty 9 18)))
 116          (list (length (if (= (length (match-string 12)) 0)
 117                            (match-string 2) (match-string 11)))))))))
 118
 119 (defvar org-babel-default-header-args:emacs-lisp) ; Defined in ob-emacs-lisp.el
 120 (defun org-babel-lob-execute (info)
 121   "Execute the lob call specified by INFO."
 122   (let* ((mkinfo (lambda (p) (list "emacs-lisp" "results" p nil nil (nth 2 info))))
 123          (pre-params (org-babel-merge-params
 124                       org-babel-default-header-args
 125                       org-babel-default-header-args:emacs-lisp
 126                       (org-babel-params-from-properties)
 127                       (org-babel-parse-header-arguments
 128                        (org-no-properties
 129                         (concat ":var results="
 130                                 (mapconcat #'identity (butlast info) " "))))))
 131          (pre-info (funcall mkinfo pre-params))
 132          (cache-p (and (cdr (assoc :cache pre-params))
 133                        (string= "yes" (cdr (assoc :cache pre-params)))))
 134          (new-hash (when cache-p (org-babel-sha1-hash pre-info)))
 135          (old-hash (when cache-p (org-babel-current-result-hash))))
 136     (if (and cache-p (equal new-hash old-hash))
 137         (save-excursion (goto-char (org-babel-where-is-src-block-result))
 138                         (forward-line 1)
 139                         (message "%S" (org-babel-read-result)))
 140       (prog1 (let* ((proc-params (org-babel-process-params pre-params))
 141                      org-confirm-babel-evaluate)
 142                (org-babel-execute-src-block nil (funcall mkinfo proc-params)))
 143         ;; update the hash
 144         (when new-hash (org-babel-set-current-result-hash new-hash))))))
 145
 146 (provide 'ob-lob)
 147
 148 ;; Local variables:
 149 ;; generated-autoload-file: "org-loaddefs.el"
 150 ;; End:
 151
 152 ;;; ob-lob.el ends here