lisp/ob-table.el

   1 ;;; ob-table.el --- Support for Calling Babel Functions from Tables -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Should allow calling functions from Org tables using the function
  27 ;; `org-sbe' as so...
  28
  29 ;; #+begin_src emacs-lisp :results silent
  30 ;;   (defun fibbd (n) (if (< n 2) 1 (+ (fibbd (- n 1)) (fibbd (- n 2)))))
  31 ;; #+end_src
  32
  33 ;; #+name: fibbd
  34 ;; #+begin_src emacs-lisp :var n=2 :results silent
  35 ;; (fibbd n)
  36 ;; #+end_src
  37
  38 ;; | original | fibbd  |
  39 ;; |----------+--------|
  40 ;; |        0 |        |
  41 ;; |        1 |        |
  42 ;; |        2 |        |
  43 ;; |        3 |        |
  44 ;; |        4 |        |
  45 ;; |        5 |        |
  46 ;; |        6 |        |
  47 ;; |        7 |        |
  48 ;; |        8 |        |
  49 ;; |        9 |        |
  50 ;; #+TBLFM: $2='(org-sbe "fibbd" (n $1))
  51
  52 ;; NOTE: The quotation marks around the function name, 'fibbd' here,
  53 ;; are optional.
  54
  55 ;;; Code:
  56 (require 'ob-core)
  57
  58 (declare-function org-trim "org" (s &optional keep-lead))
  59
  60 (defun org-babel-table-truncate-at-newline (string)
  61   "Replace newline character with ellipses.
  62 If STRING ends in a newline character, then remove the newline
  63 character and replace it with ellipses."
  64   (if (and (stringp string) (string-match "[\n\r]\\(.\\)?" string))
  65       (concat (substring string 0 (match-beginning 0))
  66               (when (match-string 1 string) "...")) string))
  67
  68 (defmacro org-sbe (source-block &rest variables)
  69   "Return the results of calling SOURCE-BLOCK with VARIABLES.
  70
  71 Each element of VARIABLES should be a list of two elements: the
  72 first element is the name of the variable and second element is a
  73 string of its value.
  74
  75 So this `org-sbe' construct
  76
  77  (org-sbe \"source-block\" (n $2) (m 3))
  78
  79 is the equivalent of the following source code block:
  80
  81  #+begin_src emacs-lisp :var results=source-block(n=val_at_col_2, m=3) :results silent
  82  results
  83  #+end_src
  84
  85 NOTE: The quotation marks around the function name,
  86 'source-block', are optional.
  87
  88 NOTE: By default, string variable names are interpreted as
  89 references to source-code blocks, to force interpretation of a
  90 cell's value as a string, prefix the identifier a \"$\" (e.g.,
  91 \"$$2\" instead of \"$2\" or \"$@2$2\" instead of \"@2$2\").
  92
  93 NOTE: It is also possible to pass header arguments to the code
  94 block.  In this case a table cell should hold the string value of
  95 the header argument which can then be passed before all variables
  96 as shown in the example below.
  97
  98 | 1 | 2 | :file nothing.png | nothing.png |
  99 #+TBLFM: @1$4=\\='(org-sbe test-sbe $3 (x $1) (y $2))"
 100   (declare (debug (form form)))
 101   (let* ((header-args (if (stringp (car variables)) (car variables) ""))
 102          (variables (if (stringp (car variables)) (cdr variables) variables)))
 103     (let* (quote
 104            (variables
 105             (mapcar
 106              (lambda (var)
 107                ;; ensure that all cells prefixed with $'s are strings
 108                (cons (car var)
 109                      (delq nil (mapcar
 110                                 (lambda (el)
 111                                   (if (eq '$ el)
 112                                       (prog1 nil (setq quote t))
 113                                     (prog1
 114                                         (cond
 115                                          (quote (format "\"%s\"" el))
 116                                          ((stringp el) (org-no-properties el))
 117                                          (t el))
 118                                       (setq quote nil))))
 119                                 (cdr var)))))
 120              variables)))
 121       (unless (stringp source-block)
 122         (setq source-block (symbol-name source-block)))
 123       (let ((result
 124              (if (and source-block (> (length source-block) 0))
 125                  (let ((params
 126                         ;; FIXME: Why `eval'?!?!?
 127                         (eval `(org-babel-parse-header-arguments
 128                                 (concat
 129                                  ":var results="
 130                                  ,source-block
 131                                  "[" ,header-args "]"
 132                                  "("
 133                                  (mapconcat
 134                                   (lambda (var-spec)
 135                                     (if (> (length (cdr var-spec)) 1)
 136                                         (format "%S='%S"
 137                                                 (car var-spec)
 138                                                 (mapcar #'read (cdr var-spec)))
 139                                       (format "%S=%s"
 140                                               (car var-spec) (cadr var-spec))))
 141                                   ',variables ", ")
 142                                  ")")))))
 143                    (org-babel-execute-src-block
 144                     nil (list "emacs-lisp" "results" params)
 145                     '((:results . "silent"))))
 146                "")))
 147         (org-trim (if (stringp result) result (format "%S" result)))))))
 148
 149 (provide 'ob-table)
 150
 151
 152
 153 ;;; ob-table.el ends here