lisp/org-crypt.el

   1 ;;; org-crypt.el --- Public key encryption for org-mode entries
   2
   3 ;; Copyright (C) 2007-2011  Free Software Foundation, Inc.
   4
   5 ;; Emacs Lisp Archive Entry
   6 ;; Filename: org-crypt.el
   7 ;; Keywords: org-mode
   8 ;; Author: John Wiegley <johnw@gnu.org>
   9 ;; Maintainer: Peter Jones <pjones@pmade.com>
  10 ;; Description: Adds public key encryption to org-mode buffers
  11 ;; URL: http://www.newartisans.com/software/emacs.html
  12 ;; Compatibility: Emacs22
  13
  14 ;; This file is part of GNU Emacs.
  15 ;;
  16 ;; GNU Emacs is free software: you can redistribute it and/or modify
  17 ;; it under the terms of the GNU General Public License as published by
  18 ;; the Free Software Foundation, either version 3 of the License, or
  19 ;; (at your option) any later version.
  20
  21 ;; GNU Emacs is distributed in the hope that it will be useful,
  22 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 ;; GNU General Public License for more details.
  25
  26 ;; You should have received a copy of the GNU General Public License
  27 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  28
  29 ;;; Commentary:
  30
  31 ;; Right now this is just a set of functions to play with.  It depends
  32 ;; on the epg library.  Here's how you would use it:
  33 ;;
  34 ;; 1. To mark an entry for encryption, tag the heading with "crypt".
  35 ;;    You can change the tag to any complex tag matching string by
  36 ;;    setting the `org-crypt-tag-matcher' variable.
  37 ;;
  38 ;; 2. Set the encryption key to use in the `org-crypt-key' variable,
  39 ;;    or use `M-x org-set-property' to set the property CRYPTKEY to
  40 ;;    any address in your public keyring.  The text of the entry (but
  41 ;;    not its properties or headline) will be encrypted for this user.
  42 ;;    For them to read it, the corresponding secret key must be
  43 ;;    located in the secret key ring of the account where you try to
  44 ;;    decrypt it.  This makes it possible to leave secure notes that
  45 ;;    only the intended recipient can read in a shared-org-mode-files
  46 ;;    scenario.
  47 ;;    If the key is not set, org-crypt will default to symmetric encryption.
  48 ;;
  49 ;; 3. To later decrypt an entry, use `org-decrypt-entries' or
  50 ;;    `org-decrypt-entry'.  It might be useful to bind this to a key,
  51 ;;    like C-c C-/.  I hope that in the future, C-c C-r can be might
  52 ;;    overloaded to also decrypt an entry if it's encrypted, since
  53 ;;    that fits nicely with the meaning of "reveal".
  54 ;;
  55 ;; 4. To automatically encrypt all necessary entries when saving a
  56 ;;    file, call `org-crypt-use-before-save-magic' after loading
  57 ;;    org-crypt.el.
  58
  59 ;;; Thanks:
  60
  61 ;; - Carsten Dominik
  62 ;; - Vitaly Ostanin
  63
  64 (require 'org)
  65
  66 ;;; Code:
  67
  68 (declare-function epg-decrypt-string "epg" (context cipher))
  69 (declare-function epg-list-keys "epg" (context &optional name mode))
  70 (declare-function epg-make-context "epg"
  71                   (&optional protocol armor textmode include-certs
  72                              cipher-algorithm digest-algorithm
  73                              compress-algorithm))
  74 (declare-function epg-encrypt-string "epg"
  75                   (context plain recipients &optional sign always-trust))
  76
  77 (defgroup org-crypt nil
  78   "Org Crypt"
  79   :tag "Org Crypt"
  80   :group 'org)
  81
  82 (defcustom org-crypt-tag-matcher "crypt"
  83   "The tag matcher used to find headings whose contents should be encrypted.
  84
  85 See the \"Match syntax\" section of the org manual for more details."
  86   :type 'string
  87   :group 'org-crypt)
  88
  89 (defcustom org-crypt-key ""
  90   "The default key to use when encrypting the contents of a heading.
  91
  92 This setting can also be overridden in the CRYPTKEY property."
  93   :type 'string
  94   :group 'org-crypt)
  95
  96 (defcustom org-crypt-disable-auto-save 'ask
  97   "What org-decrypt should do if `auto-save-mode' is enabled.
  98
  99 t        : Disable auto-save-mode for the current buffer
 100            prior to decrypting an entry.
 101
 102 nil      : Leave auto-save-mode enabled.
 103            This may cause data to be written to disk unencrypted!
 104
 105 'ask     : Ask user whether or not to disable auto-save-mode
 106            for the current buffer.
 107
 108 'encrypt : Leave auto-save-mode enabled for the current buffer,
 109            but automatically re-encrypt all decrypted entries
 110            *before* auto-saving.
 111            NOTE: This only works for entries which have a tag
 112            that matches `org-crypt-tag-matcher'."
 113   :group 'org-crypt
 114   :type '(choice (const :tag "Always"  t)
 115                  (const :tag "Never"   nil)
 116                  (const :tag "Ask"     ask)
 117                  (const :tag "Encrypt" encrypt)))
 118
 119 (defun org-crypt-key-for-heading ()
 120   "Return the encryption key for the current heading."
 121   (save-excursion
 122     (org-back-to-heading t)
 123     (or (org-entry-get nil "CRYPTKEY" 'selective)
 124         org-crypt-key
 125         (and (boundp 'epa-file-encrypt-to) epa-file-encrypt-to)
 126         (message "No crypt key set, using symmetric encryption."))))
 127
 128 (defun org-encrypt-string (str crypt-key)
 129   "Return STR encrypted with CRYPT-KEY."
 130   ;; Text and key have to be identical, otherwise we re-crypt.
 131   (if (and (string= crypt-key (get-text-property 0 'org-crypt-key str))
 132            (string= (sha1 str) (get-text-property 0 'org-crypt-checksum str)))
 133       (get-text-property 0 'org-crypt-text str)
 134     (let ((epg-context (epg-make-context nil t t)))
 135       (epg-encrypt-string epg-context str (epg-list-keys epg-context crypt-key)))))
 136
 137 (defun org-encrypt-entry ()
 138   "Encrypt the content of the current headline."
 139   (interactive)
 140   (require 'epg)
 141   (save-excursion
 142     (org-back-to-heading t)
 143     (let ((start-heading (point)))
 144       (forward-line)
 145       (when (not (looking-at "-----BEGIN PGP MESSAGE-----"))
 146         (let ((folded (outline-invisible-p))
 147               (epg-context (epg-make-context nil t t))
 148               (crypt-key (org-crypt-key-for-heading))
 149               (beg (point))
 150               end encrypted-text)
 151           (goto-char start-heading)
 152           (org-end-of-subtree t t)
 153           (org-back-over-empty-lines)
 154           (setq end (point)
 155                 encrypted-text
 156                 (org-encrypt-string (buffer-substring beg end) crypt-key))
 157           (delete-region beg end)
 158           (insert encrypted-text)
 159           (when folded
 160             (goto-char start-heading)
 161             (hide-subtree))
 162           nil)))))
 163
 164 (defun org-decrypt-entry ()
 165   "Decrypt the content of the current headline."
 166   (interactive)
 167
 168   ; auto-save-mode may cause leakage, so check whether it's enabled.
 169   (when buffer-auto-save-file-name
 170     (cond
 171      ((or
 172        (eq org-crypt-disable-auto-save t)
 173        (and
 174         (eq org-crypt-disable-auto-save 'ask)
 175         (y-or-n-p "org-decrypt: auto-save-mode may cause leakage. Disable it for current buffer? ")))
 176       (message (concat "org-decrypt: Disabling auto-save-mode for " (or (buffer-file-name) (current-buffer))))
 177       ; The argument to auto-save-mode has to be "-1", since
 178       ; giving a "nil" argument toggles instead of disabling.
 179       (auto-save-mode -1))
 180      ((eq org-crypt-disable-auto-save nil)
 181       (message "org-decrypt: Decrypting entry with auto-save-mode enabled. This may cause leakage."))
 182      ((eq org-crypt-disable-auto-save 'encrypt)
 183       (message "org-decrypt: Enabling re-encryption on auto-save.")
 184       (add-hook 'auto-save-hook
 185                 (lambda ()
 186                   (message "org-crypt: Re-encrypting all decrypted entries due to auto-save.")
 187                   (org-encrypt-entries))
 188                 nil t))
 189      (t nil)))
 190
 191   (require 'epg)
 192   (unless (org-before-first-heading-p)
 193     (save-excursion
 194       (org-back-to-heading t)
 195       (let ((heading-point (point))
 196             (heading-was-invisible-p
 197              (save-excursion
 198                (outline-end-of-heading)
 199                (outline-invisible-p))))
 200         (forward-line)
 201         (when (looking-at "-----BEGIN PGP MESSAGE-----")
 202           (let* ((end (save-excursion
 203                         (search-forward "-----END PGP MESSAGE-----")
 204                         (forward-line)
 205                         (point)))
 206                  (epg-context (epg-make-context nil t t))
 207                  (encrypted-text (buffer-substring-no-properties (point) end))
 208                  (decrypted-text
 209                   (decode-coding-string
 210                    (epg-decrypt-string
 211                     epg-context
 212                     encrypted-text)
 213                    'utf-8)))
 214             ;; Delete region starting just before point, because the
 215             ;; outline property starts at the \n of the heading.
 216             (delete-region (1- (point)) end)
 217             ;; Store a checksum of the decrypted and the encrypted
 218             ;; text value. This allow to reuse the same encrypted text
 219             ;; if the text does not change, and therefore avoid a
 220             ;; re-encryption process.
 221             (insert "\n" (propertize decrypted-text
 222                                      'org-crypt-checksum (sha1 decrypted-text)
 223                                      'org-crypt-key (org-crypt-key-for-heading)
 224                                      'org-crypt-text encrypted-text))
 225             (when heading-was-invisible-p
 226               (goto-char heading-point)
 227               (org-flag-subtree t))
 228             nil))))))
 229
 230 (defun org-encrypt-entries ()
 231   "Encrypt all top-level entries in the current buffer."
 232   (interactive)
 233   (org-scan-tags
 234    'org-encrypt-entry
 235    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 236
 237 (defun org-decrypt-entries ()
 238   "Decrypt all entries in the current buffer."
 239   (interactive)
 240   (org-scan-tags
 241    'org-decrypt-entry
 242    (cdr (org-make-tags-matcher org-crypt-tag-matcher))))
 243
 244 (defun org-crypt-use-before-save-magic ()
 245   "Add a hook to automatically encrypt entries before a file is saved to disk."
 246   (add-hook
 247    'org-mode-hook
 248    (lambda () (add-hook 'before-save-hook 'org-encrypt-entries nil t))))
 249
 250 (add-hook 'org-reveal-start-hook 'org-decrypt-entry)
 251
 252 (provide 'org-crypt)
 253
 254 ;;; org-crypt.el ends here