lisp/org-exp-blocks.el

   1 ;;; org-exp-blocks.el --- pre-process blocks when exporting org files
   2
   3 ;; Copyright (C) 2009-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; This is a utility for pre-processing blocks in org files before
  25 ;; export using the `org-export-preprocess-hook'.  It can be used for
  26 ;; exporting new types of blocks from org-mode files and also for
  27 ;; changing the default export behavior of existing org-mode blocks.
  28 ;; The `org-export-blocks' and `org-export-interblocks' variables can
  29 ;; be used to control how blocks and the spaces between blocks
  30 ;; respectively are processed upon export.
  31 ;;
  32 ;; The type of a block is defined as the string following =#+begin_=,
  33 ;; so for example the following block would be of type ditaa.  Note
  34 ;; that both upper or lower case are allowed in =#+BEGIN_= and
  35 ;; =#+END_=.
  36 ;;
  37 ;; #+begin_ditaa blue.png -r -S
  38 ;; +---------+
  39 ;; | cBLU    |
  40 ;; |         |
  41 ;; |    +----+
  42 ;; |    |cPNK|
  43 ;; |    |    |
  44 ;; +----+----+
  45 ;; #+end_ditaa
  46 ;;
  47 ;;; Currently Implemented Block Types
  48 ;;
  49 ;; ditaa :: (DEPRECATED--use "#+begin_src ditaa" code blocks) Convert
  50 ;;          ascii pictures to actual images using ditaa
  51 ;;          http://ditaa.sourceforge.net/.  To use this set
  52 ;;          `org-ditaa-jar-path' to the path to ditaa.jar on your
  53 ;;          system (should be set automatically in most cases) .
  54 ;;
  55 ;; dot :: (DEPRECATED--use "#+begin_src dot" code blocks) Convert
  56 ;;        graphs defined using the dot graphing language to images
  57 ;;        using the dot utility.  For information on dot see
  58 ;;        http://www.graphviz.org/
  59 ;;
  60 ;; export-comment :: Wrap comments with titles and author information,
  61 ;;            in their own divs with author-specific ids allowing for
  62 ;;            css coloring of comments based on the author.
  63 ;;
  64 ;;; Adding new blocks
  65 ;;
  66 ;; When adding a new block type first define a formatting function
  67 ;; along the same lines as `org-export-blocks-format-dot' and then use
  68 ;; `org-export-blocks-add-block' to add your block type to
  69 ;; `org-export-blocks'.
  70
  71 ;;; Code:
  72
  73 (eval-when-compile
  74   (require 'cl))
  75 (require 'org)
  76 (require 'find-func)
  77
  78 (defun org-export-blocks-set (var value)
  79   "Set the value of `org-export-blocks' and install fontification."
  80   (set var value)
  81   (mapc (lambda (spec)
  82           (if (nth 2 spec)
  83               (setq org-protecting-blocks
  84                     (delete (symbol-name (car spec))
  85                             org-protecting-blocks))
  86             (add-to-list 'org-protecting-blocks
  87                          (symbol-name (car spec)))))
  88         value))
  89
  90 (defcustom org-export-blocks
  91   '((export-comment org-export-blocks-format-comment t)
  92     (ditaa org-export-blocks-format-ditaa nil)
  93     (dot org-export-blocks-format-dot nil))
  94   "Use this alist to associate block types with block exporting functions.
  95 The type of a block is determined by the text immediately
  96 following the '#+BEGIN_' portion of the block header.  Each block
  97 export function should accept three arguments."
  98   :group 'org-export-general
  99   :type '(repeat
 100           (list
 101            (symbol :tag "Block name")
 102            (function :tag "Block formatter")
 103            (boolean :tag "Fontify content as Org syntax")))
 104   :set 'org-export-blocks-set)
 105
 106 (defun org-export-blocks-add-block (block-spec)
 107   "Add a new block type to `org-export-blocks'.
 108 BLOCK-SPEC should be a three element list the first element of
 109 which should indicate the name of the block, the second element
 110 should be the formatting function called by
 111 `org-export-blocks-preprocess' and the third element a flag
 112 indicating whether these types of blocks should be fontified in
 113 org-mode buffers (see `org-protecting-blocks').  For example the
 114 BLOCK-SPEC for ditaa blocks is as follows.
 115
 116   (ditaa org-export-blocks-format-ditaa nil)"
 117   (unless (member block-spec org-export-blocks)
 118     (setq org-export-blocks (cons block-spec org-export-blocks))
 119     (org-export-blocks-set 'org-export-blocks org-export-blocks)))
 120
 121 (defcustom org-export-interblocks
 122   '()
 123   "Use this a-list to associate block types with block exporting functions.
 124 The type of a block is determined by the text immediately
 125 following the '#+BEGIN_' portion of the block header.  Each block
 126 export function should accept three arguments."
 127   :group 'org-export-general
 128   :type 'alist)
 129
 130 (defcustom org-export-blocks-witheld
 131   '(hidden)
 132   "List of block types (see `org-export-blocks') which should not be exported."
 133   :group 'org-export-general
 134   :type 'list)
 135
 136 (defcustom org-export-blocks-postblock-hook nil
 137   "Run after blocks have been processed with `org-export-blocks-preprocess'."
 138   :group 'org-export-general
 139   :version "24.1"
 140   :type 'hook)
 141
 142 (defun org-export-blocks-html-quote (body &optional open close)
 143   "Protect BODY from org html export.
 144 The optional OPEN and CLOSE tags will be inserted around BODY."
 145
 146   (concat
 147    "\n#+BEGIN_HTML\n"
 148    (or open "")
 149    body (if (string-match "\n$" body) "" "\n")
 150    (or close "")
 151    "#+END_HTML\n"))
 152
 153 (defun org-export-blocks-latex-quote (body &optional open close)
 154   "Protect BODY from org latex export.
 155 The optional OPEN and CLOSE tags will be inserted around BODY."
 156   (concat
 157    "\n#+BEGIN_LaTeX\n"
 158    (or open "")
 159    body (if (string-match "\n$" body) "" "\n")
 160    (or close "")
 161    "#+END_LaTeX\n"))
 162
 163 (defun org-export-blocks-preprocess ()
 164   "Export all blocks according to the `org-export-blocks' block export alist.
 165 Does not export block types specified in specified in BLOCKS
 166 which defaults to the value of `org-export-blocks-witheld'."
 167   (interactive)
 168   (save-window-excursion
 169     (let ((case-fold-search t)
 170           (types '())
 171           matched indentation type func
 172           start end body headers preserve-indent progress-marker)
 173       (flet ((interblock (start end)
 174                          (mapcar (lambda (pair) (funcall (second pair) start end))
 175                                  org-export-interblocks)))
 176         (goto-char (point-min))
 177         (setq start (point))
 178         (let ((beg-re "^\\([ \t]*\\)#\\+begin_\\(\\S-+\\)[ \t]*\\(.*\\)?[\r\n]"))
 179           (while (re-search-forward beg-re nil t)
 180             (let* ((match-start (copy-marker (match-beginning 0)))
 181                    (body-start (copy-marker (match-end 0)))
 182                    (indentation (length (match-string 1)))
 183                    (inner-re (format "^[ \t]*#\\+\\(begin\\|end\\)_%s"
 184                                      (regexp-quote (downcase (match-string 2)))))
 185                    (type (intern (downcase (match-string 2))))
 186                    (headers (save-match-data
 187                               (org-split-string (match-string 3) "[ \t]+")))
 188                    (balanced 1)
 189                    (preserve-indent (or org-src-preserve-indentation
 190                                         (member "-i" headers)))
 191                    match-end)
 192               (while (and (not (zerop balanced))
 193                           (re-search-forward inner-re nil t))
 194                 (if (string= (downcase (match-string 1)) "end")
 195                     (decf balanced)
 196                   (incf balanced)))
 197               (when (not (zerop balanced))
 198                 (error "unbalanced begin/end_%s blocks with %S"
 199                        type (buffer-substring match-start (point))))
 200               (setq match-end (copy-marker (match-end 0)))
 201               (unless preserve-indent
 202                 (setq body (save-match-data (org-remove-indentation
 203                                              (buffer-substring
 204                                               body-start (match-beginning 0))))))
 205               (unless (memq type types) (setq types (cons type types)))
 206               (save-match-data (interblock start match-start))
 207               (when (setq func (cadr (assoc type org-export-blocks)))
 208                 (let ((replacement (save-match-data
 209                                      (if (memq type org-export-blocks-witheld) ""
 210                                        (apply func body headers)))))
 211                   ;; ;; un-comment this code after the org-element merge
 212                   ;; (save-match-data
 213                   ;;   (when (and replacement (string= replacement ""))
 214                   ;;     (delete-region
 215                   ;;      (car (org-element-collect-affiliated-keyword))
 216                   ;;      match-start)))
 217                   (when replacement
 218                     (delete-region match-start match-end)
 219                     (goto-char match-start) (insert replacement)
 220                     (if preserve-indent
 221                         ;; indent only the code block markers
 222                         (save-excursion
 223                           (indent-line-to indentation) ; indent end_block
 224                           (goto-char match-start)
 225                           (indent-line-to indentation)) ; indent begin_block
 226                       ;; indent everything
 227                       (indent-code-rigidly match-start (point) indentation)))))
 228               ;; cleanup markers
 229               (set-marker match-start nil)
 230               (set-marker body-start nil)
 231               (set-marker match-end nil))
 232             (setq start (point))))
 233         (interblock start (point-max))
 234         (run-hooks 'org-export-blocks-postblock-hook)))))
 235
 236 ;;================================================================================
 237 ;; type specific functions
 238
 239 ;;--------------------------------------------------------------------------------
 240 ;; ditaa: create images from ASCII art using the ditaa utility
 241 (defcustom org-ditaa-jar-path (expand-file-name
 242                             "ditaa.jar"
 243                             (file-name-as-directory
 244                              (expand-file-name
 245                               "scripts"
 246                               (file-name-as-directory
 247                                (expand-file-name
 248                                 "../contrib"
 249                                 (file-name-directory (org-find-library-dir "org")))))))
 250   "Path to the ditaa jar executable."
 251   :group 'org-babel
 252   :type 'string)
 253
 254 (defvar org-export-current-backend) ; dynamically bound in org-exp.el
 255 (defun org-export-blocks-format-ditaa (body &rest headers)
 256   "DEPRECATED: use begin_src ditaa code blocks
 257
 258 Pass block BODY to the ditaa utility creating an image.
 259 Specify the path at which the image should be saved as the first
 260 element of headers, any additional elements of headers will be
 261 passed to the ditaa utility as command line arguments."
 262   (message "begin_ditaa blocks are DEPRECATED, use begin_src blocks")
 263   (let* ((args (if (cdr headers) (mapconcat 'identity (cdr headers) " ")))
 264          (data-file (make-temp-file "org-ditaa"))
 265          (hash (progn
 266                  (set-text-properties 0 (length body) nil body)
 267                  (sha1 (prin1-to-string (list body args)))))
 268          (raw-out-file (if headers (car headers)))
 269          (out-file-parts (if (string-match "\\(.+\\)\\.\\([^\\.]+\\)$" raw-out-file)
 270                              (cons (match-string 1 raw-out-file)
 271                                    (match-string 2 raw-out-file))
 272                            (cons raw-out-file "png")))
 273          (out-file (concat (car out-file-parts) "_" hash "." (cdr out-file-parts))))
 274     (unless (file-exists-p org-ditaa-jar-path)
 275       (error (format "Could not find ditaa.jar at %s" org-ditaa-jar-path)))
 276     (setq body (if (string-match "^\\([^:\\|:[^ ]\\)" body)
 277                    body
 278                  (mapconcat (lambda (x) (substring x (if (> (length x) 1) 2 1)))
 279                             (org-split-string body "\n")
 280                             "\n")))
 281     (prog1
 282     (cond
 283      ((member org-export-current-backend '(html latex docbook))
 284       (unless (file-exists-p out-file)
 285         (mapc ;; remove old hashed versions of this file
 286          (lambda (file)
 287            (when (and (string-match (concat (regexp-quote (car out-file-parts))
 288                                             "_\\([[:alnum:]]+\\)\\."
 289                                             (regexp-quote (cdr out-file-parts)))
 290                                     file)
 291                       (= (length (match-string 1 out-file)) 40))
 292              (delete-file (expand-file-name file
 293                                             (file-name-directory out-file)))))
 294          (directory-files (or (file-name-directory out-file)
 295                               default-directory)))
 296         (with-temp-file data-file (insert body))
 297         (message (concat "java -jar " org-ditaa-jar-path " " args " " data-file " " out-file))
 298         (shell-command (concat "java -jar " org-ditaa-jar-path " " args " " data-file " " out-file)))
 299       (format "\n[[file:%s]]\n" out-file))
 300      (t (concat
 301          "\n#+BEGIN_EXAMPLE\n"
 302          body (if (string-match "\n$" body) "" "\n")
 303          "#+END_EXAMPLE\n")))
 304     (message "begin_ditaa blocks are DEPRECATED, use begin_src blocks"))))
 305
 306 ;;--------------------------------------------------------------------------------
 307 ;; dot: create graphs using the dot graphing language
 308 ;;      (require the dot executable to be in your path)
 309 (defun org-export-blocks-format-dot (body &rest headers)
 310   "DEPRECATED: use \"#+begin_src dot\" code blocks
 311
 312 Pass block BODY to the dot graphing utility creating an image.
 313 Specify the path at which the image should be saved as the first
 314 element of headers, any additional elements of headers will be
 315 passed to the dot utility as command line arguments.  Don't
 316 forget to specify the output type for the dot command, so if you
 317 are exporting to a file with a name like 'image.png' you should
 318 include a '-Tpng' argument, and your block should look like the
 319 following.
 320
 321 #+begin_dot models.png -Tpng
 322 digraph data_relationships {
 323   \"data_requirement\" [shape=Mrecord, label=\"{DataRequirement|description\lformat\l}\"]
 324   \"data_product\" [shape=Mrecord, label=\"{DataProduct|name\lversion\lpoc\lformat\l}\"]
 325   \"data_requirement\" -> \"data_product\"
 326 }
 327 #+end_dot"
 328   (message "begin_dot blocks are DEPRECATED, use begin_src blocks")
 329   (let* ((args (if (cdr headers) (mapconcat 'identity (cdr headers) " ")))
 330          (data-file (make-temp-file "org-ditaa"))
 331          (hash (progn
 332                  (set-text-properties 0 (length body) nil body)
 333                  (sha1 (prin1-to-string (list body args)))))
 334          (raw-out-file (if headers (car headers)))
 335          (out-file-parts (if (string-match "\\(.+\\)\\.\\([^\\.]+\\)$" raw-out-file)
 336                              (cons (match-string 1 raw-out-file)
 337                                    (match-string 2 raw-out-file))
 338                            (cons raw-out-file "png")))
 339          (out-file (concat (car out-file-parts) "_" hash "." (cdr out-file-parts))))
 340     (prog1
 341     (cond
 342      ((member org-export-current-backend '(html latex docbook))
 343       (unless (file-exists-p out-file)
 344         (mapc ;; remove old hashed versions of this file
 345          (lambda (file)
 346            (when (and (string-match (concat (regexp-quote (car out-file-parts))
 347                                             "_\\([[:alnum:]]+\\)\\."
 348                                             (regexp-quote (cdr out-file-parts)))
 349                                     file)
 350                       (= (length (match-string 1 out-file)) 40))
 351              (delete-file (expand-file-name file
 352                                             (file-name-directory out-file)))))
 353          (directory-files (or (file-name-directory out-file)
 354                               default-directory)))
 355         (with-temp-file data-file (insert body))
 356         (message (concat "dot " data-file " " args " -o " out-file))
 357         (shell-command (concat "dot " data-file " " args " -o " out-file)))
 358       (format "\n[[file:%s]]\n" out-file))
 359      (t (concat
 360          "\n#+BEGIN_EXAMPLE\n"
 361          body (if (string-match "\n$" body) "" "\n")
 362          "#+END_EXAMPLE\n")))
 363     (message "begin_dot blocks are DEPRECATED, use begin_src blocks"))))
 364
 365 ;;--------------------------------------------------------------------------------
 366 ;; comment: export comments in author-specific css-stylable divs
 367 (defun org-export-blocks-format-comment (body &rest headers)
 368   "Format comment BODY by OWNER and return it formatted for export.
 369 Currently, this only does something for HTML export, for all
 370 other backends, it converts the comment into an EXAMPLE segment."
 371   (let ((owner (if headers (car headers)))
 372         (title (if (cdr headers) (mapconcat 'identity (cdr headers) " "))))
 373     (cond
 374      ((eq org-export-current-backend 'html) ;; We are exporting to HTML
 375       (concat "#+BEGIN_HTML\n"
 376               "<div class=\"org-comment\""
 377               (if owner (format " id=\"org-comment-%s\" " owner))
 378               ">\n"
 379               (if owner (concat "<b>" owner "</b> ") "")
 380               (if (and title (> (length title) 0)) (concat " -- " title "<br/>\n") "<br/>\n")
 381               "<p>\n"
 382               "#+END_HTML\n"
 383               body
 384               "\n#+BEGIN_HTML\n"
 385               "</p>\n"
 386               "</div>\n"
 387               "#+END_HTML\n"))
 388      (t ;; This is not HTML, so just make it an example.
 389       (concat "#+BEGIN_EXAMPLE\n"
 390               (if title (concat "Title:" title "\n") "")
 391               (if owner (concat "By:" owner "\n") "")
 392               body
 393               (if (string-match "\n\\'" body) "" "\n")
 394               "#+END_EXAMPLE\n")))))
 395
 396 (provide 'org-exp-blocks)
 397
 398 ;;; org-exp-blocks.el ends here