lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2012  Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg at altern dot org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, remember
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; remember templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a remember template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-remember-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to remember this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-remember' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/misc/latex/sessions/bibtex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better remember template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114
 115 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 116 (defvar org-id-locations)
 117
 118 (declare-function bibtex-beginning-of-entry "bibtex" ())
 119 (declare-function bibtex-generate-autokey "bibtex" ())
 120 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 121 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 122 (declare-function longlines-mode "longlines" (&optional arg))
 123 (declare-function org-babel-trim "ob" (string &optional regexp))
 124
 125 \f
 126 ;;; Bibtex data
 127 (defvar org-bibtex-types
 128   '((:article
 129      (:description . "An article from a journal or magazine")
 130      (:required :author :title :journal :year)
 131      (:optional :volume :number :pages :month :note))
 132     (:book
 133      (:description . "A book with an explicit publisher")
 134      (:required (:editor :author) :title :publisher :year)
 135      (:optional (:volume :number) :series :address :edition :month :note))
 136     (:booklet
 137      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 138      (:required :title)
 139      (:optional :author :howpublished :address :month :year :note))
 140     (:conference
 141      (:description . "")
 142      (:required :author :title :booktitle :year)
 143      (:optional :editor :pages :organization :publisher :address :month :note))
 144     (:inbook
 145      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 146      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 147      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 148     (:incollection
 149      (:description . "A part of a book having its own title.")
 150      (:required :author :title :booktitle :publisher :year)
 151      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 152     (:inproceedings
 153      (:description . "An article in a conference proceedings")
 154      (:required :author :title :booktitle :year)
 155      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 156     (:manual
 157      (:description . "Technical documentation.")
 158      (:required :title)
 159      (:optional :author :organization :address :edition :month :year :note))
 160     (:mastersthesis
 161      (:description . "A Master’s thesis.")
 162      (:required :author :title :school :year)
 163      (:optional :type :address :month :note))
 164     (:misc
 165      (:description . "Use this type when nothing else fits.")
 166      (:required)
 167      (:optional :author :title :howpublished :month :year :note))
 168     (:phdthesis
 169      (:description . "A PhD thesis.")
 170      (:required :author :title :school :year)
 171      (:optional :type :address :month :note))
 172     (:proceedings
 173      (:description . "The proceedings of a conference.")
 174      (:required :title :year)
 175      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 176     (:techreport
 177      (:description . "A report published by a school or other institution.")
 178      (:required :author :title :institution :year)
 179      (:optional :type :address :month :note))
 180     (:unpublished
 181      (:description . "A document having an author and title, but not formally published.")
 182      (:required :author :title :note)
 183      (:optional :month :year)))
 184   "Bibtex entry types with required and optional parameters.")
 185
 186 (defvar org-bibtex-fields
 187   '((:address      . "Usually the address of the publisher or other type of institution. For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 188     (:annote       . "An annotation. It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 189     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 190     (:booktitle    . "Title of a book, part of which is being cited. See the LaTeX book for how to type titles. For book entries, use the title field instead.")
 191     (:chapter      . "A chapter (or section or whatever) number.")
 192     (:crossref     . "The database key of the entry being cross referenced.")
 193     (:edition      . "The edition of a book for example, 'Second'. This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 194     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book. If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 195     (:howpublished . "How something strange has been published. The first word should be capitalized.")
 196     (:institution  . "The sponsoring institution of a technical report.")
 197     (:journal      . "A journal name.")
 198     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing. This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 199     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written. You should use the standard three-letter abbreviation,")
 200     (:note         . "Any additional information that can help the reader. The first word should be capitalized.")
 201     (:number       . "Any additional information that can help the reader. The first word should be capitalized.")
 202     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 203     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 204     (:publisher    . "The publisher’s name.")
 205     (:school       . "The name of the school where a thesis was written.")
 206     (:series       . "The name of a series or set of books. When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 207     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 208     (:type         . "The type of a technical report for example, 'Research Note'.")
 209     (:volume       . "The volume of a journal or multi-volume book.")
 210     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 211   "Bibtex fields with descriptions.")
 212
 213 (defvar org-bibtex-entries nil
 214   "List to hold parsed bibtex entries.")
 215
 216 (defcustom org-bibtex-autogen-keys nil
 217   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 218   :group 'org-bibtex
 219   :version "24.1"
 220   :type  'boolean)
 221
 222 (defcustom org-bibtex-prefix nil
 223   "Optional prefix for all bibtex property names.
 224 For example setting to 'BIB_' would allow interoperability with fireforg."
 225   :group 'org-bibtex
 226   :version "24.1"
 227   :type  'string)
 228
 229 (defcustom org-bibtex-treat-headline-as-title t
 230   "Treat headline text as title if title property is absent.
 231 If an entry is missing a title property, use the headline text as
 232 the property. If this value is t, `org-bibtex-check' will ignore
 233 a missing title field."
 234   :group 'org-bibtex
 235   :version "24.1"
 236   :type 'boolean)
 237
 238 (defcustom org-bibtex-export-arbitrary-fields nil
 239   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 240 This only has effect if `org-bibtex-prefix' is defined, so as to
 241 ensure that other org-properties, such as CATEGORY or LOGGING are
 242 not placed in the exported bibtex entry."
 243   :group 'org-bibtex
 244   :version "24.1"
 245   :type 'boolean)
 246
 247 (defcustom org-bibtex-key-property "CUSTOM_ID"
 248   "Property that holds the bibtex key.
 249 By default, this is CUSTOM_ID, which enables easy linking to
 250 bibtex headlines from within an org file. This can be set to ID
 251 to enable global links, but only with great caution, as global
 252 IDs must be unique."
 253   :group 'org-bibtex
 254   :version "24.1"
 255   :type 'string)
 256
 257 (defcustom org-bibtex-tags nil
 258   "List of tag(s) that should be added to new bib entries."
 259   :group 'org-bibtex
 260   :version "24.1"
 261   :type '(repeat  :tag "Tag" (string)))
 262
 263 (defcustom org-bibtex-tags-are-keywords nil
 264   "Convert the value of the keywords field to tags and vice versa.
 265 If set to t, comma-separated entries in a bibtex entry's keywords
 266 field will be converted to org tags. Note: spaces will be escaped
 267 with underscores, and characters that are not permitted in org
 268 tags will be removed.
 269
 270 If t, local tags in an org entry will be exported as a
 271 comma-separated string of keywords when exported to bibtex. Tags
 272 defined in `org-bibtex-tags' or `org-bibtex-no-export-tags' will
 273 not be exported."
 274   :group 'org-bibtex
 275   :version "24.1"
 276   :type 'boolean)
 277
 278 (defcustom org-bibtex-no-export-tags nil
 279   "List of tag(s) that should not be converted to keywords.
 280 This variable is relevant only if `org-bibtex-export-tags-as-keywords` is t."
 281   :group 'org-bibtex
 282   :version "24.1"
 283   :type '(repeat :tag "Tag" (string)))
 284
 285 (defcustom org-bibtex-type-property-name "btype"
 286   "Property in which to store bibtex entry type (e.g., article)."
 287   :group 'org-bibtex
 288   :version "24.1"
 289   :type 'string)
 290
 291 \f
 292 ;;; Utility functions
 293 (defun org-bibtex-get (property)
 294   ((lambda (it) (when it (org-babel-trim it)))
 295    (let ((org-special-properties
 296           (delete "FILE" (copy-sequence org-special-properties))))
 297      (or
 298       (org-entry-get (point) (upcase property))
 299       (org-entry-get (point) (concat org-bibtex-prefix (upcase property)))))))
 300
 301 (defun org-bibtex-put (property value)
 302   (let ((prop (upcase (if (keywordp property)
 303                           (substring (symbol-name property) 1)
 304                         property))))
 305     (org-set-property
 306      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 307              prop)
 308      value)))
 309
 310 (defun org-bibtex-headline ()
 311   "Return a bibtex entry of the given headline as a string."
 312   (flet ((val (key lst) (cdr (assoc key lst)))
 313          (to (string) (intern (concat ":" string)))
 314          (from (key) (substring (symbol-name key) 1))
 315          (flatten (&rest lsts)
 316                   (apply #'append (mapcar
 317                                    (lambda (e)
 318                                      (if (listp e) (apply #'flatten e) (list e)))
 319                                    lsts))))
 320     (let ((notes (buffer-string))
 321           (id (org-bibtex-get org-bibtex-key-property))
 322           (type (org-bibtex-get org-bibtex-type-property-name))
 323           (tags (when org-bibtex-tags-are-keywords
 324                   (delq nil
 325                         (mapcar
 326                          (lambda (tag)
 327                            (unless (member tag
 328                                            (append org-bibtex-tags
 329                                                    org-bibtex-no-export-tags))
 330                              tag))
 331                          (org-get-local-tags-at))))))
 332       (when type
 333         (let ((entry (format
 334                       "@%s{%s,\n%s\n}\n" type id
 335                       (mapconcat
 336                        (lambda (pair)
 337                          (format "  %s={%s}" (car pair) (cdr pair)))
 338                        (remove nil
 339                          (if (and org-bibtex-export-arbitrary-fields
 340                                   org-bibtex-prefix)
 341                              (mapcar
 342                               (lambda (kv)
 343                                 (let ((key (car kv)) (val (cdr kv)))
 344                                   (when (and
 345                                          (string-match org-bibtex-prefix key)
 346                                          (not (string=
 347                                                (downcase (concat org-bibtex-prefix
 348                                                                  org-bibtex-type-property-name))
 349                                                (downcase key))))
 350                                     (cons (downcase (replace-regexp-in-string
 351                                                      org-bibtex-prefix "" key))
 352                                           val))))
 353                               (org-entry-properties nil 'standard))
 354                            (mapcar
 355                             (lambda (field)
 356                               (let ((value (or (org-bibtex-get (from field))
 357                                                (and (equal :title field)
 358                                                     (nth 4 (org-heading-components))))))
 359                                 (when value (cons (from field) value))))
 360                             (flatten
 361                              (val :required (val (to type) org-bibtex-types))
 362                              (val :optional (val (to type) org-bibtex-types))))))
 363                        ",\n"))))
 364           (with-temp-buffer
 365             (insert entry)
 366             (when tags
 367               (bibtex-beginning-of-entry)
 368               (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 369                   (progn (goto-char (match-end 1)) (insert ", "))
 370                 (bibtex-make-field "keywords" t t))
 371               (insert (mapconcat #'identity tags ", ")))
 372             (buffer-string)))))))
 373
 374 (defun org-bibtex-ask (field)
 375   (unless (assoc field org-bibtex-fields)
 376     (error "field:%s is not known" field))
 377   (save-window-excursion
 378     (let* ((name (substring (symbol-name field) 1))
 379            (buf-name (format "*Bibtex Help %s*" name)))
 380       (with-output-to-temp-buffer buf-name
 381         (princ (cdr (assoc field org-bibtex-fields))))
 382       (with-current-buffer buf-name (longlines-mode t))
 383       (org-fit-window-to-buffer (get-buffer-window buf-name))
 384       ((lambda (result) (when (> (length result) 0) result))
 385        (read-from-minibuffer (format "%s: " name))))))
 386
 387 (defun org-bibtex-autokey ()
 388   "Generate an autokey for the current headline"
 389   (org-bibtex-put org-bibtex-key-property
 390                   (if org-bibtex-autogen-keys
 391                       (let* ((entry (org-bibtex-headline))
 392                              (key
 393                               (with-temp-buffer
 394                                 (insert entry)
 395                                 (bibtex-generate-autokey))))
 396                         ;; test for duplicate IDs if using global ID
 397                         (when (and
 398                                (equal org-bibtex-key-property "ID")
 399                                (featurep 'org-id)
 400                                (hash-table-p org-id-locations)
 401                                (gethash key org-id-locations))
 402                           (warn "Another entry has the same ID"))
 403                         key)
 404                     (read-from-minibuffer "id: "))))
 405
 406 (defun org-bibtex-fleshout (type &optional optional)
 407   "Fleshout the current heading, ensuring that all required fields are present.
 408 With optional argument OPTIONAL, also prompt for optional fields."
 409   (flet ((val (key lst) (cdr (assoc key lst)))
 410          (keyword (name) (intern (concat ":" (downcase name))))
 411          (name (keyword) (substring (symbol-name keyword) 1)))
 412     (dolist (field (append
 413                     (if org-bibtex-treat-headline-as-title
 414                         (remove :title (val :required (val type org-bibtex-types)))
 415                       (val :required (val type org-bibtex-types)))
 416                     (when optional (val :optional (val type org-bibtex-types)))))
 417       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 418         (let ((present (first (remove nil
 419                                 (mapcar
 420                                  (lambda (f) (when (org-bibtex-get (name f)) f))
 421                                  field)))))
 422           (setf field (or present (keyword (org-icompleting-read
 423                                             "Field: " (mapcar #'name field)))))))
 424       (let ((name (name field)))
 425         (unless (org-bibtex-get name)
 426           (let ((prop (org-bibtex-ask field)))
 427             (when prop (org-bibtex-put name prop)))))))
 428   (when (and type (assoc type org-bibtex-types)
 429              (not (org-bibtex-get org-bibtex-key-property)))
 430     (org-bibtex-autokey)))
 431
 432 \f
 433 ;;; Bibtex link functions
 434 (org-add-link-type "bibtex" 'org-bibtex-open)
 435 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 436
 437 (defun org-bibtex-open (path)
 438   "Visit the bibliography entry on PATH."
 439   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 440                    (match-string 1 path)))
 441          (path (substring path 0 (match-beginning 0))))
 442     (org-open-file path t nil search)))
 443
 444 (defun org-bibtex-store-link ()
 445   "Store a link to a BibTeX entry."
 446   (when (eq major-mode 'bibtex-mode)
 447     (let* ((search (org-create-file-search-in-bibtex))
 448            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 449                          "::" search))
 450            (entry (mapcar ; repair strings enclosed in "..." or {...}
 451                    (lambda(c)
 452                      (if (string-match
 453                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 454                          (cons (car c) (match-string 1 (cdr c))) c))
 455                    (save-excursion
 456                      (bibtex-beginning-of-entry)
 457                      (bibtex-parse-entry)))))
 458       (org-store-link-props
 459        :key (cdr (assoc "=key=" entry))
 460        :author (or (cdr (assoc "author" entry)) "[no author]")
 461        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 462        :title (or (cdr (assoc "title" entry)) "[no title]")
 463        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 464        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 465        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 466        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 467        :url (or (cdr (assoc "url" entry)) "[no url]")
 468        :year (or (cdr (assoc "year" entry)) "[no year]")
 469        :month (or (cdr (assoc "month" entry)) "[no month]")
 470        :address (or (cdr (assoc "address" entry)) "[no address]")
 471        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 472        :number (or (cdr (assoc "number" entry)) "[no number]")
 473        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 474        :series (or (cdr (assoc "series" entry)) "[no series]")
 475        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 476        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 477        :type "bibtex"
 478        :link link
 479        :description org-bibtex-description))))
 480
 481 (defun org-create-file-search-in-bibtex ()
 482   "Create the search string and description for a BibTeX database entry."
 483   ;; Make a good description for this entry, using names, year and the title
 484   ;; Put it into the `description' variable which is dynamically scoped.
 485   (let ((bibtex-autokey-names 1)
 486         (bibtex-autokey-names-stretch 1)
 487         (bibtex-autokey-name-case-convert-function 'identity)
 488         (bibtex-autokey-name-separator " & ")
 489         (bibtex-autokey-additional-names " et al.")
 490         (bibtex-autokey-year-length 4)
 491         (bibtex-autokey-name-year-separator " ")
 492         (bibtex-autokey-titlewords 3)
 493         (bibtex-autokey-titleword-separator " ")
 494         (bibtex-autokey-titleword-case-convert-function 'identity)
 495         (bibtex-autokey-titleword-length 'infty)
 496         (bibtex-autokey-year-title-separator ": "))
 497     (setq org-bibtex-description (bibtex-generate-autokey)))
 498   ;; Now parse the entry, get the key and return it.
 499   (save-excursion
 500     (bibtex-beginning-of-entry)
 501     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 502
 503 (defun org-execute-file-search-in-bibtex (s)
 504   "Find the link search string S as a key for a database entry."
 505   (when (eq major-mode 'bibtex-mode)
 506     ;; Yes, we want to do the search in this file.
 507     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 508     (goto-char (point-min))
 509     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 510                                     (regexp-quote s) "[ \t\n]*,") nil t)
 511          (goto-char (match-beginning 0)))
 512     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 513         ;; Use double prefix to indicate that any web link should be browsed
 514         (let ((b (current-buffer)) (p (point)))
 515           ;; Restore the window configuration because we just use the web link
 516           (set-window-configuration org-window-config-before-follow-link)
 517           (with-current-buffer b
 518             (goto-char p)
 519             (bibtex-url)))
 520       (recenter 0))  ; Move entry start to beginning of window
 521     ;; return t to indicate that the search is done.
 522     t))
 523
 524 ;; Finally add the link search function to the right hook.
 525 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 526
 527 \f
 528 ;;; Bibtex <-> Org-mode headline translation functions
 529 (defun org-bibtex (&optional filename)
 530   "Export each headline in the current file to a bibtex entry.
 531 Headlines are exported using `org-bibtex-export-headline'."
 532   (interactive
 533    (list (read-file-name
 534           "Bibtex file: " nil nil nil
 535           (file-name-nondirectory
 536            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 537   ((lambda (error-point)
 538      (when error-point
 539        (goto-char error-point)
 540        (message "Bibtex error at %S" (nth 4 (org-heading-components)))))
 541    (catch 'bib
 542      (let ((bibtex-entries (remove nil (org-map-entries
 543                                         (lambda ()
 544                                           (condition-case foo
 545                                               (org-bibtex-headline)
 546                                             (error (throw 'bib (point)))))))))
 547        (with-temp-file filename
 548          (insert (mapconcat #'identity bibtex-entries "\n")))
 549        (message "Successfully exported %d bibtex entries to %s"
 550                 (length bibtex-entries) filename) nil))))
 551
 552 (defun org-bibtex-check (&optional optional)
 553   "Check the current headline for required fields.
 554 With prefix argument OPTIONAL also prompt for optional fields."
 555   (interactive "P")
 556   (save-restriction
 557     (org-narrow-to-subtree)
 558     (let ((type ((lambda (name) (when name (intern (concat ":" name))))
 559                  (org-bibtex-get org-bibtex-type-property-name))))
 560       (when type (org-bibtex-fleshout type optional)))))
 561
 562 (defun org-bibtex-check-all (&optional optional)
 563   "Check all headlines in the current file.
 564 With prefix argument OPTIONAL also prompt for optional fields."
 565   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 566
 567 (defun org-bibtex-create (&optional arg nonew)
 568   "Create a new entry at the given level.
 569 With a prefix arg, query for optional fields as well.
 570 If nonew is t, add data to the headline of the entry at point."
 571   (interactive "P")
 572   (let* ((type (org-icompleting-read
 573                 "Type: " (mapcar (lambda (type)
 574                                    (substring (symbol-name (car type)) 1))
 575                                  org-bibtex-types)
 576                 nil nil (when nonew
 577                           (org-bibtex-get org-bibtex-type-property-name))))
 578          (type (if (keywordp type) type (intern (concat ":" type))))
 579          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 580     (unless (assoc type org-bibtex-types)
 581       (error "type:%s is not known" type))
 582     (if nonew
 583         (org-back-to-heading)
 584       (org-insert-heading)
 585       (let ((title (org-bibtex-ask :title)))
 586         (insert title)
 587         (org-bibtex-put "TITLE" title)))
 588     (org-bibtex-put org-bibtex-type-property-name
 589                     (substring (symbol-name type) 1))
 590     (org-bibtex-fleshout type arg)
 591     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 592
 593 (defun org-bibtex-create-in-current-entry (&optional arg)
 594   "Add bibliographical data to the current entry.
 595 With a prefix arg, query for optional fields."
 596   (interactive "P")
 597   (org-bibtex-create arg t))
 598
 599 (defun org-bibtex-read ()
 600   "Read a bibtex entry and save to `org-bibtex-entries'.
 601 This uses `bibtex-parse-entry'."
 602   (interactive)
 603   (flet ((keyword (str) (intern (concat ":" (downcase str))))
 604          (clean-space (str) (replace-regexp-in-string
 605                              "[[:space:]\n\r]+" " " str))
 606          (strip-delim (str)          ; strip enclosing "..." and {...}
 607                       (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 608                         (when (and (= (aref str 0) (car pair))
 609                                    (= (aref str (1- (length str))) (cdr pair)))
 610                           (setf str (substring str 1 (1- (length str)))))) str))
 611     (push (mapcar
 612            (lambda (pair)
 613              (cons (let ((field (keyword (car pair))))
 614                      (case field
 615                        (:=type= :type)
 616                        (:=key= :key)
 617                        (otherwise field)))
 618                    (clean-space (strip-delim (cdr pair)))))
 619            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 620           org-bibtex-entries)))
 621
 622 (defun org-bibtex-write ()
 623   "Insert a heading built from the first element of `org-bibtex-entries'."
 624   (interactive)
 625   (when (= (length org-bibtex-entries) 0)
 626     (error "No entries in `org-bibtex-entries'."))
 627   (let ((entry (pop org-bibtex-entries))
 628         (org-special-properties nil)) ; avoids errors with `org-entry-put'
 629     (flet ((val (field) (cdr (assoc field entry)))
 630            (togtag (tag) (org-toggle-tag tag 'on)))
 631       (org-insert-heading)
 632       (insert (val :title))
 633       (org-bibtex-put "TITLE" (val :title))
 634       (org-bibtex-put org-bibtex-type-property-name (downcase (val :type)))
 635       (dolist (pair entry)
 636         (case (car pair)
 637           (:title    nil)
 638           (:type     nil)
 639           (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 640           (:keywords (if org-bibtex-tags-are-keywords
 641                           (mapc
 642                            (lambda (kw)
 643                              (togtag
 644                               (replace-regexp-in-string
 645                                "[^[:alnum:]_@#%]" ""
 646                                (replace-regexp-in-string "[ \t]+" "_" kw))))
 647                            (split-string (cdr pair) ", *"))
 648                        (org-bibtex-put (car pair) (cdr pair))))
 649           (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 650       (mapc #'togtag org-bibtex-tags))))
 651
 652 (defun org-bibtex-yank ()
 653   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 654   (interactive)
 655   (let (entry)
 656     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 657     (if entry
 658         (org-bibtex-write)
 659       (error "yanked text does not appear to contain a bibtex entry"))))
 660
 661 (defun org-bibtex-export-to-kill-ring ()
 662   "Export current headline to kill ring as bibtex entry."
 663   (interactive)
 664   (let ((result (org-bibtex-headline)))
 665     (kill-new result) result))
 666
 667 (defun org-bibtex-search (string)
 668   "Search for bibliographical entries in agenda files.
 669 This function relies `org-search-view' to locate results."
 670   (interactive "sSearch string: ")
 671   (let ((org-agenda-overriding-header "Bib search results:")
 672         (org-agenda-search-view-always-boolean t))
 673     (org-search-view nil
 674                      (format "%s +{:%s%s:}"
 675                              string org-bibtex-prefix
 676                              org-bibtex-type-property-name))))
 677
 678 (provide 'org-bibtex)
 679
 680 ;;; org-bibtex.el ends here