lisp/org-timer.el

   1 ;;; org-timer.el --- Timer code for Org mode
   2
   3 ;; Copyright (C) 2008-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements two types of timers for Org buffers:
  28 ;;
  29 ;; - A relative timer that counts up (from 0 or a specified offset)
  30 ;; - A countdown timer that counts down from a specified time
  31 ;;
  32 ;; The relative and countdown timers differ in their entry points.
  33 ;; Use `org-timer' or `org-timer-start' to start the relative timer,
  34 ;; and `org-timer-set-timer' to start the countdown timer.
  35
  36 ;;; Code:
  37
  38 (require 'org)
  39 (require 'org-clock)
  40
  41 (declare-function org-agenda-error "org-agenda" ())
  42
  43 (defvar org-timer-start-time nil
  44   "t=0 for the running timer.")
  45
  46 (defvar org-timer-pause-time nil
  47   "Time when the timer was paused.")
  48
  49 (defvar org-timer-countdown-timer nil
  50   "Current countdown timer.
  51 This is a timer object if there is an active countdown timer,
  52 'paused' if there is a paused countdown timer, and nil
  53 otherwise.")
  54
  55 (defvar org-timer-countdown-timer-title nil
  56   "Title for notification displayed when a countdown finishes.")
  57
  58 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  59   "Regular expression used to match timer stamps.")
  60
  61 (defcustom org-timer-format "%s "
  62   "The format to insert the time of the timer.
  63 This format must contain one instance of \"%s\" which will be replaced by
  64 the value of the timer."
  65   :group 'org-time
  66   :type 'string)
  67
  68 (defcustom org-timer-default-timer "0"
  69   "The default timer when a timer is set, in minutes or hh:mm:ss format.
  70 When 0, the user is prompted for a value."
  71   :group 'org-time
  72   :version "25.1"
  73   :package-version '(Org . "8.3")
  74   :type 'string)
  75
  76 (defcustom org-timer-display 'mode-line
  77   "When a timer is running, org-mode can display it in the mode
  78 line and/or frame title.
  79 Allowed values are:
  80
  81 both         displays in both mode line and frame title
  82 mode-line    displays only in mode line (default)
  83 frame-title  displays only in frame title
  84 nil          current timer is not displayed"
  85   :group 'org-time
  86   :type '(choice
  87           (const :tag "Mode line" mode-line)
  88           (const :tag "Frame title" frame-title)
  89           (const :tag "Both" both)
  90           (const :tag "None" nil)))
  91
  92 (defvar org-timer-start-hook nil
  93   "Hook run after relative timer is started.")
  94
  95 (defvar org-timer-stop-hook nil
  96   "Hook run before relative or countdown timer is stopped.")
  97
  98 (defvar org-timer-pause-hook nil
  99   "Hook run before relative or countdown timer is paused.")
 100
 101 (defvar org-timer-continue-hook nil
 102   "Hook run after relative or countdown timer is continued.")
 103
 104 (defvar org-timer-set-hook nil
 105   "Hook run after countdown timer is set.")
 106
 107 (defvar org-timer-done-hook nil
 108   "Hook run after countdown timer reaches zero.")
 109
 110 ;;;###autoload
 111 (defun org-timer-start (&optional offset)
 112   "Set the starting time for the relative timer to now.
 113 When called with prefix argument OFFSET, prompt the user for an offset time,
 114 with the default taken from a timer stamp at point, if any.
 115 If OFFSET is a string or an integer, it is directly taken to be the offset
 116 without user interaction.
 117 When called with a double prefix arg, all timer strings in the active
 118 region will be shifted by a specific amount.  You will be prompted for
 119 the amount, with the default to make the first timer string in
 120 the region 0:00:00."
 121   (interactive "P")
 122   (cond
 123    ((equal offset '(16))
 124     (call-interactively 'org-timer-change-times-in-region))
 125    (org-timer-countdown-timer
 126     (user-error "Countdown timer is running.  Cancel first"))
 127    (t
 128     (let (delta def s)
 129       (if (not offset)
 130           (setq org-timer-start-time (current-time))
 131         (cond
 132          ((integerp offset) (setq delta offset))
 133          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
 134          (t
 135           (setq def (if (org-in-regexp org-timer-re)
 136                         (match-string 0)
 137                       "0:00:00")
 138                 s (read-string
 139                    (format "Restart timer with offset [%s]: " def)))
 140           (unless (string-match "\\S-" s) (setq s def))
 141           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 142         (setq org-timer-start-time
 143               (seconds-to-time
 144                ;; Pass `current-time' result to `org-float-time'
 145                ;; (instead of calling without arguments) so that only
 146                ;; `current-time' has to be overriden in tests.
 147                (- (org-float-time (current-time)) delta))))
 148       (setq org-timer-pause-time nil)
 149       (org-timer-set-mode-line 'on)
 150       (message "Timer start time set to %s, current value is %s"
 151                (format-time-string "%T" org-timer-start-time)
 152                (org-timer-secs-to-hms (or delta 0)))
 153       (run-hooks 'org-timer-start-hook)))))
 154
 155 (defun org-timer-pause-or-continue (&optional stop)
 156   "Pause or continue the relative or countdown timer.
 157 With prefix arg STOP, stop it entirely."
 158   (interactive "P")
 159   (cond
 160    (stop (org-timer-stop))
 161    ((not org-timer-start-time) (error "No timer is running"))
 162    (org-timer-pause-time
 163     (let ((start-secs (org-float-time org-timer-start-time))
 164           (pause-secs (org-float-time org-timer-pause-time)))
 165       (if org-timer-countdown-timer
 166           (progn
 167             (let ((new-secs (- start-secs pause-secs)))
 168               (setq org-timer-countdown-timer
 169                     (org-timer--run-countdown-timer
 170                      new-secs org-timer-countdown-timer-title))
 171               (setq org-timer-start-time
 172                     (time-add (current-time) (seconds-to-time new-secs)))))
 173         (setq org-timer-start-time
 174               ;; Pass `current-time' result to `org-float-time'
 175               ;; (instead of calling without arguments) so that only
 176               ;; `current-time' has to be overriden in tests.
 177               (seconds-to-time (- (org-float-time (current-time))
 178                                   (- pause-secs start-secs)))))
 179       (setq org-timer-pause-time nil)
 180       (org-timer-set-mode-line 'on)
 181       (run-hooks 'org-timer-continue-hook)
 182       (message "Timer continues at %s" (org-timer-value-string))))
 183    (t
 184     ;; pause timer
 185     (when org-timer-countdown-timer
 186       (cancel-timer org-timer-countdown-timer)
 187       (setq org-timer-countdown-timer 'pause))
 188     (run-hooks 'org-timer-pause-hook)
 189     (setq org-timer-pause-time (current-time))
 190     (org-timer-set-mode-line 'pause)
 191     (message "Timer paused at %s" (org-timer-value-string)))))
 192
 193 (defun org-timer-stop ()
 194   "Stop the relative or countdown timer."
 195   (interactive)
 196   (unless org-timer-start-time
 197     (user-error "No timer running"))
 198   (when (timerp org-timer-countdown-timer)
 199     (cancel-timer org-timer-countdown-timer))
 200   (run-hooks 'org-timer-stop-hook)
 201   (setq org-timer-start-time nil
 202         org-timer-pause-time nil
 203         org-timer-countdown-timer nil)
 204   (org-timer-set-mode-line 'off)
 205   (message "Timer stopped"))
 206
 207 ;;;###autoload
 208 (defun org-timer (&optional restart no-insert-p)
 209   "Insert a H:MM:SS string from the timer into the buffer.
 210 The first time this command is used, the timer is started.  When used with
 211 a \\[universal-argument] prefix, force restarting the timer.
 212 When used with a double prefix argument \\[universal-argument], change all the timer string
 213 in the region by a fixed amount.  This can be used to recalibrate a timer
 214 that was not started at the correct moment.
 215
 216 If NO-INSERT-P is non-nil, return the string instead of inserting
 217 it in the buffer."
 218   (interactive "P")
 219   (if (equal restart '(16))
 220       (org-timer-start restart)
 221     (when (or (equal restart '(4)) (not org-timer-start-time))
 222       (org-timer-start))
 223     (if no-insert-p
 224         (org-timer-value-string)
 225       (insert (org-timer-value-string)))))
 226
 227 (defun org-timer-value-string ()
 228   "Set the timer string."
 229   (format org-timer-format
 230           (org-timer-secs-to-hms
 231            (abs (floor (org-timer-seconds))))))
 232
 233 (defun org-timer-seconds ()
 234   (if org-timer-countdown-timer
 235       (- (org-float-time org-timer-start-time)
 236          (org-float-time (or org-timer-pause-time (current-time))))
 237     (- (org-float-time (or org-timer-pause-time (current-time)))
 238        (org-float-time org-timer-start-time))))
 239
 240 ;;;###autoload
 241 (defun org-timer-change-times-in-region (beg end delta)
 242   "Change all h:mm:ss time in region by a DELTA."
 243   (interactive
 244    "r\nsEnter time difference like \"-1:08:26\".  Default is first time to zero: ")
 245   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 246     (unless (string-match "\\S-" delta)
 247       (save-excursion
 248         (goto-char beg)
 249         (when (re-search-forward re end t)
 250           (setq delta (match-string 0))
 251           (if (equal (string-to-char delta) ?-)
 252               (setq delta (substring delta 1))
 253             (setq delta (concat "-" delta))))))
 254     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 255     (when (= delta 0) (error "No change"))
 256     (save-excursion
 257       (goto-char end)
 258       (while (re-search-backward re beg t)
 259         (setq p (point))
 260         (replace-match
 261          (save-match-data
 262            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 263          t t)
 264         (goto-char p)))))
 265
 266 ;;;###autoload
 267 (defun org-timer-item (&optional arg)
 268   "Insert a description-type item with the current timer value."
 269   (interactive "P")
 270   (let ((itemp (org-in-item-p)) (pos (point)))
 271     (cond
 272      ;; In a timer list, insert with `org-list-insert-item',
 273      ;; then fix the list.
 274      ((and itemp (goto-char itemp) (org-at-item-timer-p))
 275       (let* ((struct (org-list-struct))
 276              (prevs (org-list-prevs-alist struct))
 277              (s (concat (org-timer (when arg '(4)) t) ":: ")))
 278         (setq struct (org-list-insert-item pos struct prevs nil s))
 279         (org-list-write-struct struct (org-list-parents-alist struct))
 280         (looking-at org-list-full-item-re)
 281         (goto-char (match-end 0))))
 282      ;; In a list of another type, don't break anything: throw an error.
 283      (itemp (goto-char pos) (error "This is not a timer list"))
 284      ;; Else, start a new list.
 285      (t
 286       (beginning-of-line)
 287       (org-indent-line)
 288       (insert  "- ")
 289       (org-timer (when arg '(4)))
 290       (insert ":: ")))))
 291
 292 (defun org-timer-fix-incomplete (hms)
 293   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 294   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 295       (replace-match
 296        (format "%d:%02d:%02d"
 297                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 298                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 299                (string-to-number (match-string 3 hms)))
 300        t t hms)
 301     (error "Cannot parse HMS string \"%s\"" hms)))
 302
 303 (defun org-timer-hms-to-secs (hms)
 304   "Convert h:mm:ss string to an integer time.
 305 If the string starts with a minus sign, the integer will be negative."
 306   (if (not (string-match
 307             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 308             hms))
 309       0
 310     (let* ((h (string-to-number (match-string 1 hms)))
 311            (m (string-to-number (match-string 2 hms)))
 312            (s (string-to-number (match-string 3 hms)))
 313            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 314       (setq h (abs h))
 315       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 316
 317 (defun org-timer-secs-to-hms (s)
 318   "Convert integer S into h:mm:ss.
 319 If the integer is negative, the string will start with \"-\"."
 320   (let (sign m h)
 321     (setq sign (if (< s 0) "-" "")
 322           s (abs s)
 323           m (/ s 60) s (- s (* 60 m))
 324           h (/ m 60) m (- m (* 60 h)))
 325     (format "%s%d:%02d:%02d" sign h m s)))
 326
 327 (defvar org-timer-mode-line-timer nil)
 328 (defvar org-timer-mode-line-string nil)
 329
 330 (defun org-timer-set-mode-line (value)
 331   "Set the mode-line display for relative or countdown timer.
 332 VALUE can be `on', `off', or `pause'."
 333   (when (or (eq org-timer-display 'mode-line)
 334             (eq org-timer-display 'both))
 335     (or global-mode-string (setq global-mode-string '("")))
 336     (or (memq 'org-timer-mode-line-string global-mode-string)
 337         (setq global-mode-string
 338               (append global-mode-string '(org-timer-mode-line-string)))))
 339   (when (or (eq org-timer-display 'frame-title)
 340             (eq org-timer-display 'both))
 341     (or (memq 'org-timer-mode-line-string frame-title-format)
 342         (setq frame-title-format
 343               (append frame-title-format '(org-timer-mode-line-string)))))
 344   (cond
 345    ((equal value 'off)
 346     (when org-timer-mode-line-timer
 347       (cancel-timer org-timer-mode-line-timer)
 348       (setq org-timer-mode-line-timer nil))
 349     (when (or (eq org-timer-display 'mode-line)
 350               (eq org-timer-display 'both))
 351       (setq global-mode-string
 352             (delq 'org-timer-mode-line-string global-mode-string)))
 353     (when (or (eq org-timer-display 'frame-title)
 354               (eq org-timer-display 'both))
 355       (setq frame-title-format
 356             (delq 'org-timer-mode-line-string frame-title-format)))
 357     (force-mode-line-update))
 358    ((equal value 'pause)
 359     (when org-timer-mode-line-timer
 360       (cancel-timer org-timer-mode-line-timer)
 361       (setq org-timer-mode-line-timer nil)))
 362    ((equal value 'on)
 363     (when (or (eq org-timer-display 'mode-line)
 364               (eq org-timer-display 'both))
 365       (or global-mode-string (setq global-mode-string '("")))
 366       (or (memq 'org-timer-mode-line-string global-mode-string)
 367           (setq global-mode-string
 368                 (append global-mode-string '(org-timer-mode-line-string)))))
 369     (when (or (eq org-timer-display 'frame-title)
 370               (eq org-timer-display 'both))
 371       (or (memq 'org-timer-mode-line-string frame-title-format)
 372           (setq frame-title-format
 373                 (append frame-title-format '(org-timer-mode-line-string)))))
 374     (org-timer-update-mode-line)
 375     (when org-timer-mode-line-timer
 376       (cancel-timer org-timer-mode-line-timer)
 377       (setq org-timer-mode-line-timer nil))
 378     (when org-timer-display
 379       (setq org-timer-mode-line-timer
 380             (run-with-timer 1 1 'org-timer-update-mode-line))))))
 381
 382 (defun org-timer-update-mode-line ()
 383   "Update the timer time in the mode line."
 384   (if org-timer-pause-time
 385       nil
 386     (setq org-timer-mode-line-string
 387           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 388     (force-mode-line-update)))
 389
 390 (defun org-timer-show-remaining-time ()
 391   "Display the remaining time before the timer ends."
 392   (interactive)
 393   (require 'time)
 394   (if (not org-timer-countdown-timer)
 395       (message "No timer set")
 396     (let* ((rtime (decode-time
 397                    (time-subtract (timer--time org-timer-countdown-timer)
 398                                   (current-time))))
 399            (rsecs (nth 0 rtime))
 400            (rmins (nth 1 rtime)))
 401       (message "%d minute(s) %d seconds left before next time out"
 402                rmins rsecs))))
 403
 404 ;;;###autoload
 405 (defun org-timer-set-timer (&optional opt)
 406   "Prompt for a duration in minutes or hh:mm:ss and set a timer.
 407
 408 If `org-timer-default-timer' is not zero, suggest this value as
 409 the default duration for the timer.  If a timer is already set,
 410 prompt the user if she wants to replace it.
 411
 412 Called with a numeric prefix argument, use this numeric value as
 413 the duration of the timer in minutes.
 414
 415 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 416 without prompting the user for a duration.
 417
 418 With two `C-u' prefix arguments, use `org-timer-default-timer'
 419 without prompting the user for a duration and automatically
 420 replace any running timer.
 421
 422 By default, the timer duration will be set to the number of
 423 minutes in the Effort property, if any.  You can ignore this by
 424 using three `C-u' prefix arguments."
 425   (interactive "P")
 426   (when (and org-timer-start-time
 427              (not org-timer-countdown-timer))
 428     (user-error "Relative timer is running.  Stop first"))
 429   (let* ((effort-minutes (ignore-errors (org-get-at-eol 'effort-minutes 1)))
 430          (minutes (or (and (not (equal opt '(64)))
 431                            effort-minutes
 432                            (number-to-string effort-minutes))
 433                       (and (numberp opt) (number-to-string opt))
 434                       (and (consp opt) org-timer-default-timer)
 435                       (and (stringp opt) opt)
 436                       (read-from-minibuffer
 437                        "How much time left? (minutes or h:mm:ss) "
 438                        (and (not (string-equal org-timer-default-timer "0"))
 439                             org-timer-default-timer)))))
 440     (when (string-match "\\`[0-9]+\\'" minutes)
 441       (setq minutes (concat minutes ":00")))
 442     (if (not (string-match "[0-9]+" minutes))
 443         (org-timer-show-remaining-time)
 444       (let ((secs (org-timer-hms-to-secs (org-timer-fix-incomplete minutes)))
 445             (hl (org-timer--get-timer-title)))
 446         (if (or (not org-timer-countdown-timer)
 447                 (equal opt '(16))
 448                 (y-or-n-p "Replace current timer? "))
 449             (progn
 450               (when (timerp org-timer-countdown-timer)
 451                 (cancel-timer org-timer-countdown-timer))
 452               (setq org-timer-countdown-timer-title
 453                     (org-timer--get-timer-title))
 454               (setq org-timer-countdown-timer
 455                     (org-timer--run-countdown-timer
 456                      secs org-timer-countdown-timer-title))
 457               (run-hooks 'org-timer-set-hook)
 458               (setq org-timer-start-time
 459                     (time-add (current-time) (seconds-to-time secs)))
 460               (setq org-timer-pause-time nil)
 461               (org-timer-set-mode-line 'on))
 462           (message "No timer set"))))))
 463
 464 (defun org-timer--run-countdown-timer (secs title)
 465   "Start countdown timer that will last SECS.
 466 TITLE will be appended to the notification message displayed when
 467 time is up."
 468   (let ((msg (format "%s: time out" title)))
 469     (run-with-timer
 470      secs nil `(lambda ()
 471                  (setq org-timer-countdown-timer nil
 472                        org-timer-start-time nil)
 473                  (org-notify ,msg ,org-clock-sound)
 474                  (org-timer-set-mode-line 'off)
 475                  (run-hooks 'org-timer-done-hook)))))
 476
 477 (defun org-timer--get-timer-title ()
 478   "Construct timer title from heading or file name of Org buffer."
 479   (cond
 480    ((derived-mode-p 'org-agenda-mode)
 481     (let* ((marker (or (get-text-property (point) 'org-marker)
 482                        (org-agenda-error)))
 483            (hdmarker (or (get-text-property (point) 'org-hd-marker)
 484                          marker)))
 485       (with-current-buffer (marker-buffer marker)
 486         (org-with-wide-buffer
 487          (goto-char hdmarker)
 488          (org-show-entry)
 489          (or (ignore-errors (org-get-heading))
 490              (buffer-name (buffer-base-buffer)))))))
 491    ((derived-mode-p 'org-mode)
 492     (or (ignore-errors (org-get-heading))
 493         (buffer-name (buffer-base-buffer))))
 494    (t (error "Not in an Org buffer"))))
 495
 496 (provide 'org-timer)
 497
 498 ;; Local variables:
 499 ;; generated-autoload-file: "org-loaddefs.el"
 500 ;; End:
 501
 502 ;;; org-timer.el ends here