lisp/ox-org.el

   1 ;;; ox-org.el --- Org Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'ox)
  28 (declare-function htmlize-buffer "htmlize" (&optional buffer))
  29
  30 (defgroup org-export-org nil
  31   "Options for exporting Org mode files to Org."
  32   :tag "Org Export Org"
  33   :group 'org-export
  34   :version "24.4"
  35   :package-version '(Org . "8.0"))
  36
  37 (define-obsolete-variable-alias
  38   'org-export-htmlized-org-css-url 'org-org-htmlized-css-url "24.4")
  39 (defcustom org-org-htmlized-css-url nil
  40   "URL pointing to the CSS defining colors for htmlized Emacs buffers.
  41 Normally when creating an htmlized version of an Org buffer,
  42 htmlize will create the CSS to define the font colors.  However,
  43 this does not work when converting in batch mode, and it also can
  44 look bad if different people with different fontification setup
  45 work on the same website.  When this variable is non-nil,
  46 creating an htmlized version of an Org buffer using
  47 `org-org-export-as-org' will include a link to this URL if the
  48 setting of `org-html-htmlize-output-type' is 'css."
  49   :group 'org-export-org
  50   :type '(choice
  51           (const :tag "Don't include external stylesheet link" nil)
  52           (string :tag "URL or local href")))
  53
  54 (org-export-define-backend 'org
  55   '((babel-call . org-org-identity)
  56     (bold . org-org-identity)
  57     (center-block . org-org-identity)
  58     (clock . org-org-identity)
  59     (code . org-org-identity)
  60     (comment . (lambda (&rest args) ""))
  61     (comment-block . (lambda (&rest args) ""))
  62     (diary-sexp . org-org-identity)
  63     (drawer . org-org-identity)
  64     (dynamic-block . org-org-identity)
  65     (entity . org-org-identity)
  66     (example-block . org-org-identity)
  67     (fixed-width . org-org-identity)
  68     (footnote-definition . ignore)
  69     (footnote-reference . org-org-identity)
  70     (headline . org-org-headline)
  71     (horizontal-rule . org-org-identity)
  72     (inline-babel-call . org-org-identity)
  73     (inline-src-block . org-org-identity)
  74     (inlinetask . org-org-identity)
  75     (italic . org-org-identity)
  76     (item . org-org-identity)
  77     (keyword . org-org-keyword)
  78     (latex-environment . org-org-identity)
  79     (latex-fragment . org-org-identity)
  80     (line-break . org-org-identity)
  81     (link . org-org-identity)
  82     (node-property . org-org-identity)
  83     (template . org-org-template)
  84     (paragraph . org-org-identity)
  85     (plain-list . org-org-identity)
  86     (planning . org-org-identity)
  87     (property-drawer . org-org-identity)
  88     (quote-block . org-org-identity)
  89     (radio-target . org-org-identity)
  90     (section . org-org-section)
  91     (special-block . org-org-identity)
  92     (src-block . org-org-identity)
  93     (statistics-cookie . org-org-identity)
  94     (strike-through . org-org-identity)
  95     (subscript . org-org-identity)
  96     (superscript . org-org-identity)
  97     (table . org-org-identity)
  98     (table-cell . org-org-identity)
  99     (table-row . org-org-identity)
 100     (target . org-org-identity)
 101     (timestamp . org-org-identity)
 102     (underline . org-org-identity)
 103     (verbatim . org-org-identity)
 104     (verse-block . org-org-identity))
 105   :menu-entry
 106   '(?O "Export to Org"
 107        ((?O "As Org buffer" org-org-export-as-org)
 108         (?o "As Org file" org-org-export-to-org)
 109         (?v "As Org file and open"
 110             (lambda (a s v b)
 111               (if a (org-org-export-to-org t s v b)
 112                 (org-open-file (org-org-export-to-org nil s v b))))))))
 113
 114 (defun org-org-identity (blob contents info)
 115   "Transcode BLOB element or object back into Org syntax.
 116 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 117   (let ((case-fold-search t))
 118     (replace-regexp-in-string
 119      "^[ \t]*#\\+ATTR_[-_A-Za-z0-9]+:\\(?: .*\\)?\n" ""
 120      (org-export-expand blob contents t))))
 121
 122 (defun org-org-headline (headline contents info)
 123   "Transcode HEADLINE element back into Org syntax.
 124 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 125   (unless (org-element-property :footnote-section-p headline)
 126     (unless (plist-get info :with-todo-keywords)
 127       (org-element-put-property headline :todo-keyword nil))
 128     (unless (plist-get info :with-tags)
 129       (org-element-put-property headline :tags nil))
 130     (unless (plist-get info :with-priority)
 131       (org-element-put-property headline :priority nil))
 132     (org-element-put-property headline :level
 133                               (org-export-get-relative-level headline info))
 134     (org-element-headline-interpreter headline contents)))
 135
 136 (defun org-org-keyword (keyword contents info)
 137   "Transcode KEYWORD element back into Org syntax.
 138 CONTENTS is nil.  INFO is ignored."
 139   (let ((key (org-element-property :key keyword)))
 140     (unless (member key
 141                     '("AUTHOR" "CREATOR" "DATE" "DESCRIPTION" "EMAIL" "KEYWORDS"
 142                       "OPTIONS" "TITLE"))
 143       (org-element-keyword-interpreter keyword nil))))
 144
 145 (defun org-org-template (contents info)
 146   "Return Org document template with document keywords.
 147 CONTENTS is the transcoded contents string.  INFO is a plist used
 148 as a communication channel."
 149   (concat
 150    (and (plist-get info :time-stamp-file)
 151         (format-time-string "# Created %Y-%m-%d %a %H:%M\n"))
 152    (org-element-normalize-string
 153     (mapconcat #'identity
 154                (org-element-map (plist-get info :parse-tree) 'keyword
 155                  (lambda (k)
 156                    (and (string-equal (org-element-property :key k) "OPTIONS")
 157                         (concat "#+OPTIONS: "
 158                                 (org-element-property :value k)))))
 159                "\n"))
 160    (format "#+TITLE: %s\n" (org-export-data (plist-get info :title) info))
 161    (and (plist-get info :with-date)
 162         (let ((date (org-export-data (org-export-get-date info) info)))
 163           (and (org-string-nw-p date)
 164                (format "#+DATE: %s\n" date))))
 165    (and (plist-get info :with-author)
 166         (let ((author (org-export-data (plist-get info :author) info)))
 167           (and (org-string-nw-p author)
 168                (format "#+AUTHOR: %s\n" author))))
 169    (and (plist-get info :with-email)
 170         (let ((email (org-export-data (plist-get info :email) info)))
 171           (and (org-string-nw-p email)
 172                (format "#+EMAIL: %s\n" email))))
 173    (and (eq (plist-get info :with-creator) t)
 174         (org-string-nw-p (plist-get info :creator))
 175         (format "#+CREATOR: %s\n" (plist-get info :creator)))
 176    (and (org-string-nw-p (plist-get info :keywords))
 177         (format "#+KEYWORDS: %s\n" (plist-get info :keywords)))
 178    (and (org-string-nw-p (plist-get info :description))
 179         (format "#+DESCRIPTION: %s\n" (plist-get info :description)))
 180    contents
 181    (and (eq (plist-get info :with-creator) 'comment)
 182         (org-string-nw-p (plist-get info :creator))
 183         (format "\n# %s\n" (plist-get info :creator)))))
 184
 185 (defun org-org-section (section contents info)
 186   "Transcode SECTION element back into Org syntax.
 187 CONTENTS is the contents of the section.  INFO is a plist used as
 188 a communication channel."
 189   (concat
 190    (org-element-normalize-string contents)
 191    ;; Insert footnote definitions appearing for the first time in this
 192    ;; section.  Indeed, some of them may not be available to narrowing
 193    ;; so we make sure all of them are included in the result.
 194    (let ((footnotes-alist
 195           (org-element-map section 'footnote-reference
 196             (lambda (fn)
 197               (and (eq (org-element-property :type fn) 'standard)
 198                    (org-export-footnote-first-reference-p fn info)
 199                    (cons (org-element-property :label fn)
 200                          (org-export-get-footnote-definition fn info))))
 201             info)))
 202      (and footnotes-alist
 203           (concat "\n"
 204                   (mapconcat
 205                    (lambda (d)
 206                      (org-element-normalize-string
 207                       (concat (format "[%s] "(car d))
 208                               (org-export-data (cdr d) info))))
 209                    footnotes-alist "\n"))))
 210    (make-string (or (org-element-property :post-blank section) 0) ?\n)))
 211
 212 ;;;###autoload
 213 (defun org-org-export-as-org
 214   (&optional async subtreep visible-only body-only ext-plist)
 215   "Export current buffer to an Org buffer.
 216
 217 If narrowing is active in the current buffer, only export its
 218 narrowed part.
 219
 220 If a region is active, export that region.
 221
 222 A non-nil optional argument ASYNC means the process should happen
 223 asynchronously.  The resulting buffer should be accessible
 224 through the `org-export-stack' interface.
 225
 226 When optional argument SUBTREEP is non-nil, export the sub-tree
 227 at point, extracting information from the headline properties
 228 first.
 229
 230 When optional argument VISIBLE-ONLY is non-nil, don't export
 231 contents of hidden elements.
 232
 233 When optional argument BODY-ONLY is non-nil, strip document
 234 keywords from output.
 235
 236 EXT-PLIST, when provided, is a property list with external
 237 parameters overriding Org default settings, but still inferior to
 238 file-local settings.
 239
 240 Export is done in a buffer named \"*Org ORG Export*\", which will
 241 be displayed when `org-export-show-temporary-export-buffer' is
 242 non-nil."
 243   (interactive)
 244   (org-export-to-buffer 'org "*Org ORG Export*"
 245     async subtreep visible-only body-only ext-plist (lambda () (org-mode))))
 246
 247 ;;;###autoload
 248 (defun org-org-export-to-org
 249   (&optional async subtreep visible-only body-only ext-plist)
 250   "Export current buffer to an org file.
 251
 252 If narrowing is active in the current buffer, only export its
 253 narrowed part.
 254
 255 If a region is active, export that region.
 256
 257 A non-nil optional argument ASYNC means the process should happen
 258 asynchronously.  The resulting file should be accessible through
 259 the `org-export-stack' interface.
 260
 261 When optional argument SUBTREEP is non-nil, export the sub-tree
 262 at point, extracting information from the headline properties
 263 first.
 264
 265 When optional argument VISIBLE-ONLY is non-nil, don't export
 266 contents of hidden elements.
 267
 268 When optional argument BODY-ONLY is non-nil, strip document
 269 keywords from output.
 270
 271 EXT-PLIST, when provided, is a property list with external
 272 parameters overriding Org default settings, but still inferior to
 273 file-local settings.
 274
 275 Return output file name."
 276   (interactive)
 277   (let ((outfile (org-export-output-file-name ".org" subtreep)))
 278     (org-export-to-file 'org outfile
 279       async subtreep visible-only body-only ext-plist)))
 280
 281 ;;;###autoload
 282 (defun org-org-publish-to-org (plist filename pub-dir)
 283   "Publish an org file to org.
 284
 285 FILENAME is the filename of the Org file to be published.  PLIST
 286 is the property list for the given project.  PUB-DIR is the
 287 publishing directory.
 288
 289 Return output file name."
 290   (org-publish-org-to 'org filename ".org" plist pub-dir)
 291   (when (plist-get plist :htmlized-source)
 292     (require 'htmlize)
 293     (require 'ox-html)
 294     (let* ((org-inhibit-startup t)
 295            (htmlize-output-type 'css)
 296            (html-ext (concat "." (or (plist-get plist :html-extension)
 297                                      org-html-extension "html")))
 298            (visitingp (find-buffer-visiting filename))
 299            (work-buffer (or visitingp (find-file filename)))
 300            newbuf)
 301       (font-lock-ensure)
 302       (show-all)
 303       (org-show-block-all)
 304       (setq newbuf (htmlize-buffer))
 305       (with-current-buffer newbuf
 306         (when org-org-htmlized-css-url
 307           (goto-char (point-min))
 308           (and (re-search-forward
 309                 "<style type=\"text/css\">[^\000]*?\n[ \t]*</style>.*" nil t)
 310                (replace-match
 311                 (format
 312                  "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">"
 313                  org-org-htmlized-css-url) t t)))
 314         (write-file (concat pub-dir (file-name-nondirectory filename) html-ext)))
 315       (kill-buffer newbuf)
 316       (unless visitingp (kill-buffer work-buffer)))
 317     (set-buffer-modified-p nil)))
 318
 319
 320 (provide 'ox-org)
 321
 322 ;; Local variables:
 323 ;; generated-autoload-file: "org-loaddefs.el"
 324 ;; End:
 325
 326 ;;; ox-org.el ends here