lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'ob)
  30 (require 'org-src)
  31 (eval-when-compile
  32   (require 'cl))
  33
  34 (declare-function org-link-escape "org" (text &optional table))
  35 (declare-function org-heading-components "org" ())
  36 (declare-function org-back-to-heading "org" (invisible-ok))
  37 (declare-function org-fill-template "org" (template alist))
  38 (declare-function org-babel-update-block-body "org" (new-body))
  39 (declare-function make-directory "files" (dir &optional parents))
  40
  41 ;;;###autoload
  42 (defcustom org-babel-tangle-lang-exts
  43   '(("emacs-lisp" . "el"))
  44   "Alist mapping languages to their file extensions.
  45 The key is the language name, the value is the string that should
  46 be inserted as the extension commonly used to identify files
  47 written in this language.  If no entry is found in this list,
  48 then the name of the language is used."
  49   :group 'org-babel-tangle
  50   :type '(repeat
  51           (cons
  52            (string "Language name")
  53            (string "File Extension"))))
  54
  55 (defcustom org-babel-post-tangle-hook nil
  56   "Hook run in code files tangled by `org-babel-tangle'."
  57   :group 'org-babel
  58   :type 'hook)
  59
  60 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  61   "Hook run at the beginning of `org-babel-tangle'."
  62   :group 'org-babel
  63   :type 'hook)
  64
  65 (defcustom org-babel-tangle-body-hook nil
  66   "Hook run over the contents of each code block body."
  67   :group 'org-babel
  68   :type 'hook)
  69
  70 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  71   "Format of inserted comments in tangled code files.
  72 The following format strings can be used to insert special
  73 information into the output using `org-fill-template'.
  74 %start-line --- the line number at the start of the code block
  75 %file --------- the file from which the code block was tangled
  76 %link --------- Org-mode style link to the code block
  77 %source-name -- name of the code block
  78
  79 Whether or not comments are inserted during tangling is
  80 controlled by the :comments header argument."
  81   :group 'org-babel
  82   :type 'string)
  83
  84 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  85   "Format of inserted comments in tangled code files.
  86 The following format strings can be used to insert special
  87 information into the output using `org-fill-template'.
  88 %start-line --- the line number at the start of the code block
  89 %file --------- the file from which the code block was tangled
  90 %link --------- Org-mode style link to the code block
  91 %source-name -- name of the code block
  92
  93 Whether or not comments are inserted during tangling is
  94 controlled by the :comments header argument."
  95   :group 'org-babel
  96   :type 'string)
  97
  98 (defcustom org-babel-process-comment-text #'org-babel-trim
  99   "Function called to process raw Org-mode text collected to be
 100 inserted as comments in tangled source-code files.  The function
 101 should take a single string argument and return a string
 102 result.  The default value is `org-babel-trim'."
 103   :group 'org-babel
 104   :type 'function)
 105
 106 (defun org-babel-find-file-noselect-refresh (file)
 107   "Find file ensuring that the latest changes on disk are
 108 represented in the file."
 109   (find-file-noselect file)
 110   (with-current-buffer (get-file-buffer file)
 111     (revert-buffer t t t)))
 112
 113 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 114   "Open FILE into a temporary buffer execute BODY there like
 115 `progn', then kill the FILE buffer returning the result of
 116 evaluating BODY."
 117   (declare (indent 1))
 118   (let ((temp-result (make-symbol "temp-result"))
 119         (temp-file (make-symbol "temp-file"))
 120         (visited-p (make-symbol "visited-p")))
 121     `(let (,temp-result ,temp-file
 122            (,visited-p (get-file-buffer ,file)))
 123        (org-babel-find-file-noselect-refresh ,file)
 124        (setf ,temp-file (get-file-buffer ,file))
 125        (with-current-buffer ,temp-file
 126          (setf ,temp-result (progn ,@body)))
 127        (unless ,visited-p (kill-buffer ,temp-file))
 128        ,temp-result)))
 129 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 130
 131 ;;;###autoload
 132 (defun org-babel-load-file (file)
 133   "Load Emacs Lisp source code blocks in the Org-mode FILE.
 134 This function exports the source code using
 135 `org-babel-tangle' and then loads the resulting file using
 136 `load-file'."
 137   (interactive "fFile to load: ")
 138   (flet ((age (file)
 139               (float-time
 140                (time-subtract (current-time)
 141                               (nth 5 (or (file-attributes (file-truename file))
 142                                          (file-attributes file)))))))
 143     (let* ((base-name (file-name-sans-extension file))
 144            (exported-file (concat base-name ".el")))
 145       ;; tangle if the org-mode file is newer than the elisp file
 146       (unless (and (file-exists-p exported-file)
 147                    (> (age file) (age exported-file)))
 148         (org-babel-tangle-file file exported-file "emacs-lisp"))
 149       (load-file exported-file)
 150       (message "loaded %s" exported-file))))
 151
 152 ;;;###autoload
 153 (defun org-babel-tangle-file (file &optional target-file lang)
 154   "Extract the bodies of source code blocks in FILE.
 155 Source code blocks are extracted with `org-babel-tangle'.
 156 Optional argument TARGET-FILE can be used to specify a default
 157 export file for all source blocks.  Optional argument LANG can be
 158 used to limit the exported source code blocks by language."
 159   (interactive "fFile to tangle: \nP")
 160   (let ((visited-p (get-file-buffer (expand-file-name file)))
 161         to-be-removed)
 162     (save-window-excursion
 163       (find-file file)
 164       (setq to-be-removed (current-buffer))
 165       (org-babel-tangle nil target-file lang))
 166     (unless visited-p
 167       (kill-buffer to-be-removed))))
 168
 169 (defun org-babel-tangle-publish (_ filename pub-dir)
 170   "Tangle FILENAME and place the results in PUB-DIR."
 171   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 172
 173 ;;;###autoload
 174 (defun org-babel-tangle (&optional only-this-block target-file lang)
 175   "Write code blocks to source-specific files.
 176 Extract the bodies of all source code blocks from the current
 177 file into their own source-specific files.  Optional argument
 178 TARGET-FILE can be used to specify a default export file for all
 179 source blocks.  Optional argument LANG can be used to limit the
 180 exported source code blocks by language."
 181   (interactive "P")
 182   (run-hooks 'org-babel-pre-tangle-hook)
 183   ;; possibly restrict the buffer to the current code block
 184   (save-restriction
 185   (when only-this-block
 186     (unless (org-babel-where-is-src-block-head)
 187       (error "Point is not currently inside of a code block"))
 188     (unless target-file
 189       (setq target-file
 190             (read-from-minibuffer "Tangle to: " (buffer-file-name))))
 191     (narrow-to-region (match-beginning 0) (match-end 0)))
 192   (save-excursion
 193     (let ((block-counter 0)
 194           (org-babel-default-header-args
 195            (if target-file
 196                (org-babel-merge-params org-babel-default-header-args
 197                                        (list (cons :tangle target-file)))
 198              org-babel-default-header-args))
 199           path-collector)
 200       (mapc ;; map over all languages
 201        (lambda (by-lang)
 202          (let* ((lang (car by-lang))
 203                 (specs (cdr by-lang))
 204                 (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 205                 (lang-f (intern
 206                          (concat
 207                           (or (and (cdr (assoc lang org-src-lang-modes))
 208                                    (symbol-name
 209                                     (cdr (assoc lang org-src-lang-modes))))
 210                               lang)
 211                           "-mode")))
 212                 she-banged)
 213            (mapc
 214             (lambda (spec)
 215               (flet ((get-spec (name)
 216                                (cdr (assoc name (nth 4 spec)))))
 217                 (let* ((tangle (get-spec :tangle))
 218                        (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 219                                   (get-spec :shebang)))
 220                        (base-name (cond
 221                                    ((string= "yes" tangle)
 222                                     (file-name-sans-extension
 223                                      (buffer-file-name)))
 224                                    ((string= "no" tangle) nil)
 225                                    ((> (length tangle) 0) tangle)))
 226                        (file-name (when base-name
 227                                     ;; decide if we want to add ext to base-name
 228                                     (if (and ext (string= "yes" tangle))
 229                                         (concat base-name "." ext) base-name))))
 230                   (when file-name
 231                     ;; possibly create the parent directories for file
 232                     (when ((lambda (m) (and m (not (string= m "no"))))
 233                            (get-spec :mkdirp))
 234                       (make-directory (file-name-directory file-name) 'parents))
 235                     ;; delete any old versions of file
 236                     (when (and (file-exists-p file-name)
 237                                (not (member file-name path-collector)))
 238                       (delete-file file-name))
 239                     ;; drop source-block to file
 240                     (with-temp-buffer
 241                       (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 242                       (when (and she-bang (not (member file-name she-banged)))
 243                         (insert (concat she-bang "\n"))
 244                         (setq she-banged (cons file-name she-banged)))
 245                       (org-babel-spec-to-string spec)
 246                       ;; We avoid append-to-file as it does not work with tramp.
 247                       (let ((content (buffer-string)))
 248                         (with-temp-buffer
 249                           (if (file-exists-p file-name)
 250                               (insert-file-contents file-name))
 251                           (goto-char (point-max))
 252                           (insert content)
 253                           (write-region nil nil file-name))))
 254                     ;; if files contain she-bangs, then make the executable
 255                     (when she-bang (set-file-modes file-name #o755))
 256                     ;; update counter
 257                     (setq block-counter (+ 1 block-counter))
 258                     (add-to-list 'path-collector file-name)))))
 259             specs)))
 260        (org-babel-tangle-collect-blocks lang))
 261       (message "tangled %d code block%s from %s" block-counter
 262                (if (= block-counter 1) "" "s")
 263                (file-name-nondirectory
 264                 (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
 265       ;; run `org-babel-post-tangle-hook' in all tangled files
 266       (when org-babel-post-tangle-hook
 267         (mapc
 268          (lambda (file)
 269            (org-babel-with-temp-filebuffer file
 270              (run-hooks 'org-babel-post-tangle-hook)))
 271          path-collector))
 272       path-collector))))
 273
 274 (defun org-babel-tangle-clean ()
 275   "Remove comments inserted by `org-babel-tangle'.
 276 Call this function inside of a source-code file generated by
 277 `org-babel-tangle' to remove all comments inserted automatically
 278 by `org-babel-tangle'.  Warning, this comment removes any lines
 279 containing constructs which resemble org-mode file links or noweb
 280 references."
 281   (interactive)
 282   (goto-char (point-min))
 283   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 284              (re-search-forward "<<[^[:space:]]*>>" nil t))
 285     (delete-region (save-excursion (beginning-of-line 1) (point))
 286                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 287
 288 (defvar org-stored-links)
 289 (defvar org-bracket-link-regexp)
 290 (defun org-babel-tangle-collect-blocks (&optional language)
 291   "Collect source blocks in the current Org-mode file.
 292 Return an association list of source-code block specifications of
 293 the form used by `org-babel-spec-to-string' grouped by language.
 294 Optional argument LANG can be used to limit the collected source
 295 code blocks by language."
 296   (let ((block-counter 1) (current-heading "") blocks)
 297     (org-babel-map-src-blocks (buffer-file-name)
 298       ((lambda (new-heading)
 299          (if (not (string= new-heading current-heading))
 300              (progn
 301                (setq block-counter 1)
 302                (setq current-heading new-heading))
 303            (setq block-counter (+ 1 block-counter))))
 304        (replace-regexp-in-string "[ \t]" "-"
 305                                  (condition-case nil
 306                                      (nth 4 (org-heading-components))
 307                                    (error (buffer-file-name)))))
 308       (let* ((start-line (save-restriction (widen)
 309                                            (+ 1 (line-number-at-pos (point)))))
 310              (file (buffer-file-name))
 311              (info (org-babel-get-src-block-info 'light))
 312              (src-lang (nth 0 info)))
 313         (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
 314           (unless (and language (not (string= language src-lang)))
 315             (let* ((info (org-babel-get-src-block-info))
 316                    (params (nth 2 info))
 317                    (link ((lambda (link)
 318                             (and (string-match org-bracket-link-regexp link)
 319                                  (match-string 1 link)))
 320                           (org-babel-clean-text-properties
 321                            (org-store-link nil))))
 322                    (source-name
 323                     (intern (or (nth 4 info)
 324                                 (format "%s:%d"
 325                                         current-heading block-counter))))
 326                    (expand-cmd
 327                     (intern (concat "org-babel-expand-body:" src-lang)))
 328                    (assignments-cmd
 329                     (intern (concat "org-babel-variable-assignments:" src-lang)))
 330                    (body
 331                     ((lambda (body) ;; run the tangle-body-hook
 332                        (with-temp-buffer
 333                          (insert body)
 334                          (run-hooks 'org-babel-tangle-body-hook)
 335                          (buffer-string)))
 336                      ((lambda (body) ;; expand the body in language specific manner
 337                         (if (assoc :no-expand params)
 338                             body
 339                           (if (fboundp expand-cmd)
 340                               (funcall expand-cmd body params)
 341                             (org-babel-expand-body:generic
 342                              body params
 343                              (and (fboundp assignments-cmd)
 344                                   (funcall assignments-cmd params))))))
 345                       (if (and (cdr (assoc :noweb params)) ;; expand noweb refs
 346                                (let ((nowebs (split-string
 347                                               (cdr (assoc :noweb params)))))
 348                                  (or (member "yes" nowebs)
 349                                      (member "tangle" nowebs))))
 350                           (org-babel-expand-noweb-references info)
 351                         (nth 1 info)))))
 352                    (comment
 353                     (when (or (string= "both" (cdr (assoc :comments params)))
 354                               (string= "org" (cdr (assoc :comments params))))
 355                       ;; from the previous heading or code-block end
 356                       (funcall
 357                        org-babel-process-comment-text
 358                        (buffer-substring
 359                         (max (condition-case nil
 360                                  (save-excursion
 361                                    (org-back-to-heading t)  ; sets match data
 362                                    (match-end 0))
 363                                (error (point-min)))
 364                              (save-excursion
 365                                (if (re-search-backward
 366                                     org-babel-src-block-regexp nil t)
 367                                    (match-end 0)
 368                                  (point-min))))
 369                         (point)))))
 370                    by-lang)
 371               ;; add the spec for this block to blocks under it's language
 372               (setq by-lang (cdr (assoc src-lang blocks)))
 373               (setq blocks (delq (assoc src-lang blocks) blocks))
 374               (setq blocks (cons
 375                             (cons src-lang
 376                                   (cons (list start-line file link
 377                                               source-name params body comment)
 378                                         by-lang)) blocks)))))))
 379     ;; ensure blocks in the correct order
 380     (setq blocks
 381           (mapcar
 382            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 383            blocks))
 384     blocks))
 385
 386 (defun org-babel-spec-to-string (spec)
 387   "Insert SPEC into the current file.
 388 Insert the source-code specified by SPEC into the current
 389 source code file.  This function uses `comment-region' which
 390 assumes that the appropriate major-mode is set.  SPEC has the
 391 form
 392
 393   (start-line file link source-name params body comment)"
 394   (let* ((start-line (nth 0 spec))
 395          (file (nth 1 spec))
 396          (link (org-link-escape (nth 2 spec)))
 397          (source-name (nth 3 spec))
 398          (body (nth 5 spec))
 399          (comment (nth 6 spec))
 400          (comments (cdr (assoc :comments (nth 4 spec))))
 401          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 402          (link-p (or (string= comments "both") (string= comments "link")
 403                      (string= comments "yes") (string= comments "noweb")))
 404          (link-data (mapcar (lambda (el)
 405                               (cons (symbol-name el)
 406                                     ((lambda (le)
 407                                        (if (stringp le) le (format "%S" le)))
 408                                      (eval el))))
 409                             '(start-line file link source-name))))
 410     (flet ((insert-comment (text)
 411             (when (and comments (not (string= comments "no"))
 412                        (> (length text) 0))
 413               (when padline (insert "\n"))
 414               (comment-region (point) (progn (insert text) (point)))
 415               (end-of-line nil) (insert "\n"))))
 416       (when comment (insert-comment comment))
 417       (when link-p
 418         (insert-comment
 419          (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 420       (when padline (insert "\n"))
 421       (insert
 422        (format
 423         "%s\n"
 424         (replace-regexp-in-string
 425          "^," ""
 426          (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 427       (when link-p
 428         (insert-comment
 429          (org-fill-template org-babel-tangle-comment-format-end link-data))))))
 430
 431 (defun org-babel-tangle-comment-links ( &optional info)
 432   "Return a list of begin and end link comments for the code block at point."
 433   (let* ((start-line (org-babel-where-is-src-block-head))
 434          (file (buffer-file-name))
 435          (link (org-link-escape (progn (call-interactively 'org-store-link)
 436                                        (org-babel-clean-text-properties
 437                                         (car (pop org-stored-links))))))
 438          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 439          (link-data (mapcar (lambda (el)
 440                               (cons (symbol-name el)
 441                                     ((lambda (le)
 442                                        (if (stringp le) le (format "%S" le)))
 443                                      (eval el))))
 444                             '(start-line file link source-name))))
 445     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 446           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 447
 448 ;; de-tangling functions
 449 (defvar org-bracket-link-analytic-regexp)
 450 (defun org-babel-detangle (&optional source-code-file)
 451   "Propagate changes in source file back original to Org-mode file.
 452 This requires that code blocks were tangled with link comments
 453 which enable the original code blocks to be found."
 454   (interactive)
 455   (save-excursion
 456     (when source-code-file (find-file source-code-file))
 457     (goto-char (point-min))
 458     (let ((counter 0) new-body end)
 459       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 460         (when (re-search-forward
 461                (concat " " (regexp-quote (match-string 5)) " ends here"))
 462           (setq end (match-end 0))
 463           (forward-line -1)
 464           (save-excursion
 465             (when (setq new-body (org-babel-tangle-jump-to-org))
 466               (org-babel-update-block-body new-body)))
 467           (setq counter (+ 1 counter)))
 468         (goto-char end))
 469       (prog1 counter (message "detangled %d code blocks" counter)))))
 470
 471 (defun org-babel-tangle-jump-to-org ()
 472   "Jump from a tangled code file to the related Org-mode file."
 473   (interactive)
 474   (let ((mid (point))
 475         start end done
 476         target-buffer target-char link path block-name body)
 477     (save-window-excursion
 478       (save-excursion
 479         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 480                     (not ; ever wider searches until matching block comments
 481                      (and (setq start (point-at-eol))
 482                           (setq link (match-string 0))
 483                           (setq path (match-string 3))
 484                           (setq block-name (match-string 5))
 485                           (save-excursion
 486                             (save-match-data
 487                               (re-search-forward
 488                                (concat " " (regexp-quote block-name)
 489                                        " ends here") nil t)
 490                               (setq end (point-at-bol))))))))
 491         (unless (and start (< start mid) (< mid end))
 492           (error "not in tangled code"))
 493         (setq body (org-babel-trim (buffer-substring start end))))
 494       (when (string-match "::" path)
 495         (setq path (substring path 0 (match-beginning 0))))
 496       (find-file path) (setq target-buffer (current-buffer))
 497       (goto-char start) (org-open-link-from-string link)
 498       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 499           (org-babel-next-src-block
 500            (string-to-number (match-string 1 block-name)))
 501         (org-babel-goto-named-src-block block-name))
 502       (setq target-char (point)))
 503     (pop-to-buffer target-buffer)
 504     (prog1 body (goto-char target-char))))
 505
 506 (provide 'ob-tangle)
 507
 508
 509
 510 ;;; ob-tangle.el ends here