lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, markdown
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library implements a Markdown back-end (vanilla flavor) for
  26 ;; Org exporter, based on `html' back-end.  See Org manual for more
  27 ;; information.
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (require 'ox-html)
  33 (require 'ox-publish)
  34
  35 \f
  36 ;;; User-Configurable Variables
  37
  38 (defgroup org-export-md nil
  39   "Options specific to Markdown export back-end."
  40   :tag "Org Markdown"
  41   :group 'org-export
  42   :version "24.4"
  43   :package-version '(Org . "8.0"))
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 \f
  55 ;;; Define Back-End
  56
  57 (org-export-define-derived-backend 'md 'html
  58   :export-block '("MD" "MARKDOWN")
  59   :filters-alist '((:filter-parse-tree . org-md-separate-elements))
  60   :menu-entry
  61   '(?m "Export to Markdown"
  62        ((?M "To temporary buffer"
  63             (lambda (a s v b) (org-md-export-as-markdown a s v)))
  64         (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  65         (?o "To file and open"
  66             (lambda (a s v b)
  67               (if a (org-md-export-to-markdown t s v)
  68                 (org-open-file (org-md-export-to-markdown nil s v)))))))
  69   :translate-alist '((bold . org-md-bold)
  70                      (code . org-md-verbatim)
  71                      (example-block . org-md-example-block)
  72                      (export-block . org-md-export-block)
  73                      (fixed-width . org-md-example-block)
  74                      (headline . org-md-headline)
  75                      (horizontal-rule . org-md-horizontal-rule)
  76                      (inline-src-block . org-md-verbatim)
  77                      (inner-template . org-md-inner-template)
  78                      (italic . org-md-italic)
  79                      (item . org-md-item)
  80                      (keyword . org-md-keyword)
  81                      (line-break . org-md-line-break)
  82                      (link . org-md-link)
  83                      (node-property . org-md-node-property)
  84                      (paragraph . org-md-paragraph)
  85                      (plain-list . org-md-plain-list)
  86                      (plain-text . org-md-plain-text)
  87                      (property-drawer . org-md-property-drawer)
  88                      (quote-block . org-md-quote-block)
  89                      (section . org-md-section)
  90                      (src-block . org-md-example-block)
  91                      (template . org-md-template)
  92                      (verbatim . org-md-verbatim))
  93   :options-alist '((:md-headline-style nil nil org-md-headline-style)))
  94
  95 \f
  96 ;;; Filters
  97
  98 (defun org-md-separate-elements (tree backend info)
  99   "Fix blank lines between elements.
 100
 101 TREE is the parse tree being exported.  BACKEND is the export
 102 back-end used.  INFO is a plist used as a communication channel.
 103
 104 Enforce a blank line between elements.  There are two exceptions
 105 to this rule:
 106
 107   1. Preserve blank lines between sibling items in a plain list,
 108
 109   2. In an item, remove any blank line before the very first
 110      paragraph and the next sub-list.
 111
 112 Assume BACKEND is `md'."
 113   (org-element-map tree (remq 'item org-element-all-elements)
 114     (lambda (e)
 115       (org-element-put-property
 116        e :post-blank
 117        (if (and (eq (org-element-type e) 'paragraph)
 118                 (eq (org-element-type (org-element-property :parent e)) 'item)
 119                 (eq (org-element-type (org-export-get-next-element e info))
 120                     'plain-list)
 121                 (not (org-export-get-previous-element e info)))
 122            0
 123          1))))
 124   ;; Return updated tree.
 125   tree)
 126
 127
 128 \f
 129 ;;; Transcode Functions
 130
 131 ;;;; Bold
 132
 133 (defun org-md-bold (bold contents info)
 134   "Transcode BOLD object into Markdown format.
 135 CONTENTS is the text within bold markup.  INFO is a plist used as
 136 a communication channel."
 137   (format "**%s**" contents))
 138
 139
 140 ;;;; Code and Verbatim
 141
 142 (defun org-md-verbatim (verbatim contents info)
 143   "Transcode VERBATIM object into Markdown format.
 144 CONTENTS is nil.  INFO is a plist used as a communication
 145 channel."
 146   (let ((value (org-element-property :value verbatim)))
 147     (format (cond ((not (string-match "`" value)) "`%s`")
 148                   ((or (string-match "\\``" value)
 149                        (string-match "`\\'" value))
 150                    "`` %s ``")
 151                   (t "``%s``"))
 152             value)))
 153
 154
 155 ;;;; Example Block, Src Block and export Block
 156
 157 (defun org-md-example-block (example-block contents info)
 158   "Transcode EXAMPLE-BLOCK element into Markdown format.
 159 CONTENTS is nil.  INFO is a plist used as a communication
 160 channel."
 161   (replace-regexp-in-string
 162    "^" "    "
 163    (org-remove-indentation
 164     (org-export-format-code-default example-block info))))
 165
 166 (defun org-md-export-block (export-block contents info)
 167   "Transcode a EXPORT-BLOCK element from Org to Markdown.
 168 CONTENTS is nil.  INFO is a plist holding contextual information."
 169   (if (member (org-element-property :type export-block) '("MARKDOWN" "MD"))
 170       (org-remove-indentation (org-element-property :value export-block))
 171     ;; Also include HTML export blocks.
 172     (org-export-with-backend 'html export-block contents info)))
 173
 174
 175 ;;;; Headline
 176
 177 (defun org-md-headline (headline contents info)
 178   "Transcode HEADLINE element into Markdown format.
 179 CONTENTS is the headline contents.  INFO is a plist used as
 180 a communication channel."
 181   (unless (org-element-property :footnote-section-p headline)
 182     (let* ((level (org-export-get-relative-level headline info))
 183            (title (org-export-data (org-element-property :title headline) info))
 184            (todo (and (plist-get info :with-todo-keywords)
 185                       (let ((todo (org-element-property :todo-keyword
 186                                                         headline)))
 187                         (and todo (concat (org-export-data todo info) " ")))))
 188            (tags (and (plist-get info :with-tags)
 189                       (let ((tag-list (org-export-get-tags headline info)))
 190                         (and tag-list
 191                              (format "     :%s:"
 192                                      (mapconcat 'identity tag-list ":"))))))
 193            (priority
 194             (and (plist-get info :with-priority)
 195                  (let ((char (org-element-property :priority headline)))
 196                    (and char (format "[#%c] " char)))))
 197            (anchor
 198             (when (plist-get info :with-toc)
 199               (org-html--anchor
 200                (or (org-element-property :CUSTOM_ID headline)
 201                    (org-export-get-headline-id headline info))
 202                nil nil info)))
 203            ;; Headline text without tags.
 204            (heading (concat todo priority title))
 205            (style (plist-get info :md-headline-style)))
 206       (cond
 207        ;; Cannot create a headline.  Fall-back to a list.
 208        ((or (org-export-low-level-p headline info)
 209             (not (memq style '(atx setext)))
 210             (and (eq style 'atx) (> level 6))
 211             (and (eq style 'setext) (> level 2)))
 212         (let ((bullet
 213                (if (not (org-export-numbered-headline-p headline info)) "-"
 214                  (concat (number-to-string
 215                           (car (last (org-export-get-headline-number
 216                                       headline info))))
 217                          "."))))
 218           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 219                   "\n\n"
 220                   (and contents
 221                        (replace-regexp-in-string "^" "    " contents)))))
 222        ;; Use "Setext" style.
 223        ((eq style 'setext)
 224         (concat heading tags anchor "\n"
 225                 (make-string (length heading) (if (= level 1) ?= ?-))
 226                 "\n\n"
 227                 contents))
 228        ;; Use "atx" style.
 229        (t (concat (make-string level ?#) " " heading tags anchor "\n\n" contents))))))
 230
 231
 232 ;;;; Horizontal Rule
 233
 234 (defun org-md-horizontal-rule (horizontal-rule contents info)
 235   "Transcode HORIZONTAL-RULE element into Markdown format.
 236 CONTENTS is the horizontal rule contents.  INFO is a plist used
 237 as a communication channel."
 238   "---")
 239
 240
 241 ;;;; Italic
 242
 243 (defun org-md-italic (italic contents info)
 244   "Transcode ITALIC object into Markdown format.
 245 CONTENTS is the text within italic markup.  INFO is a plist used
 246 as a communication channel."
 247   (format "*%s*" contents))
 248
 249
 250 ;;;; Item
 251
 252 (defun org-md-item (item contents info)
 253   "Transcode ITEM element into Markdown format.
 254 CONTENTS is the item contents.  INFO is a plist used as
 255 a communication channel."
 256   (let* ((type (org-element-property :type (org-export-get-parent item)))
 257          (struct (org-element-property :structure item))
 258          (bullet (if (not (eq type 'ordered)) "-"
 259                    (concat (number-to-string
 260                             (car (last (org-list-get-item-number
 261                                         (org-element-property :begin item)
 262                                         struct
 263                                         (org-list-prevs-alist struct)
 264                                         (org-list-parents-alist struct)))))
 265                            "."))))
 266     (concat bullet
 267             (make-string (- 4 (length bullet)) ? )
 268             (case (org-element-property :checkbox item)
 269               (on "[X] ")
 270               (trans "[-] ")
 271               (off "[ ] "))
 272             (let ((tag (org-element-property :tag item)))
 273               (and tag (format "**%s:** "(org-export-data tag info))))
 274             (and contents
 275                  (org-trim (replace-regexp-in-string "^" "    " contents))))))
 276
 277
 278
 279 ;;;; Keyword
 280
 281 (defun org-md-keyword (keyword contents info)
 282   "Transcode a KEYWORD element into Markdown format.
 283 CONTENTS is nil.  INFO is a plist used as a communication
 284 channel."
 285   (if (member (org-element-property :key keyword) '("MARKDOWN" "MD"))
 286       (org-element-property :value keyword)
 287     (org-export-with-backend 'html keyword contents info)))
 288
 289
 290 ;;;; Line Break
 291
 292 (defun org-md-line-break (line-break contents info)
 293   "Transcode LINE-BREAK object into Markdown format.
 294 CONTENTS is nil.  INFO is a plist used as a communication
 295 channel."
 296   "  \n")
 297
 298
 299 ;;;; Link
 300
 301 (defun org-md-link (link contents info)
 302   "Transcode LINE-BREAK object into Markdown format.
 303 CONTENTS is the link's description.  INFO is a plist used as
 304 a communication channel."
 305   (let ((link-org-files-as-md
 306          (function
 307           (lambda (raw-path)
 308             ;; Treat links to `file.org' as links to `file.md'.
 309             (if (string= ".org" (downcase (file-name-extension raw-path ".")))
 310                 (concat (file-name-sans-extension raw-path) ".md")
 311               raw-path))))
 312         (type (org-element-property :type link)))
 313     (cond
 314      ;; Link type is handled by a special function.
 315      ((org-export-custom-protocol-maybe link contents 'md))
 316      ((member type '("custom-id" "id"))
 317       (let ((destination (org-export-resolve-id-link link info)))
 318         (if (stringp destination)       ; External file.
 319             (let ((path (funcall link-org-files-as-md destination)))
 320               (if (not contents) (format "<%s>" path)
 321                 (format "[%s](%s)" contents path)))
 322           (concat
 323            (and contents (concat contents " "))
 324            (format "(%s)"
 325                    (format (org-export-translate "See section %s" :html info)
 326                            (if (org-export-numbered-headline-p destination info)
 327                                (mapconcat #'number-to-string
 328                                           (org-export-get-headline-number
 329                                            destination info)
 330                                           ".")
 331                              (org-export-data
 332                               (org-element-property :title destination) info))))))))
 333      ((org-export-inline-image-p link org-html-inline-image-rules)
 334       (let ((path (let ((raw-path (org-element-property :path link)))
 335                     (if (not (file-name-absolute-p raw-path)) raw-path
 336                       (expand-file-name raw-path))))
 337             (caption (org-export-data
 338                       (org-export-get-caption
 339                        (org-export-get-parent-element link)) info)))
 340         (format "![img](%s)"
 341                 (if (not (org-string-nw-p caption)) path
 342                   (format "%s \"%s\"" path caption)))))
 343      ((string= type "coderef")
 344       (let ((ref (org-element-property :path link)))
 345         (format (org-export-get-coderef-format ref contents)
 346                 (org-export-resolve-coderef ref info))))
 347      ((equal type "radio") contents)
 348      ((equal type "fuzzy")
 349       (let ((destination (org-export-resolve-fuzzy-link link info)))
 350         (if (org-string-nw-p contents) contents
 351           (when destination
 352             (let ((number (org-export-get-ordinal destination info)))
 353               (if number
 354                   (if (atom number) (number-to-string number)
 355                     (mapconcat #'number-to-string number "."))
 356                 ;; Unnumbered headline.
 357                 (and (eq 'headline (org-element-type destination))
 358                      ;; BUG: shouldn't headlines have a form like [ref](name) in md?
 359                      (org-export-data
 360                       (org-element-property :title destination) info))))))))
 361      (t (let* ((raw-path (org-element-property :path link))
 362                (path
 363                 (cond
 364                  ((member type '("http" "https" "ftp"))
 365                   (concat type ":" raw-path))
 366                  ((string= type "file")
 367                   (let ((path (funcall link-org-files-as-md raw-path)))
 368                     (if (not (file-name-absolute-p path)) path
 369                       ;; If file path is absolute, prepend it
 370                       ;; with "file:" component.
 371                       (concat "file:" path))))
 372                  (t raw-path))))
 373           (if (not contents) (format "<%s>" path)
 374             (format "[%s](%s)" contents path)))))))
 375
 376
 377 ;;;; Node Property
 378
 379 (defun org-md-node-property (node-property contents info)
 380   "Transcode a NODE-PROPERTY element into Markdown syntax.
 381 CONTENTS is nil.  INFO is a plist holding contextual
 382 information."
 383   (format "%s:%s"
 384           (org-element-property :key node-property)
 385           (let ((value (org-element-property :value node-property)))
 386             (if value (concat " " value) ""))))
 387
 388
 389 ;;;; Paragraph
 390
 391 (defun org-md-paragraph (paragraph contents info)
 392   "Transcode PARAGRAPH element into Markdown format.
 393 CONTENTS is the paragraph contents.  INFO is a plist used as
 394 a communication channel."
 395   (let ((first-object (car (org-element-contents paragraph))))
 396     ;; If paragraph starts with a #, protect it.
 397     (if (and (stringp first-object) (string-match "\\`#" first-object))
 398         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 399       contents)))
 400
 401
 402 ;;;; Plain List
 403
 404 (defun org-md-plain-list (plain-list contents info)
 405   "Transcode PLAIN-LIST element into Markdown format.
 406 CONTENTS is the plain-list contents.  INFO is a plist used as
 407 a communication channel."
 408   contents)
 409
 410
 411 ;;;; Plain Text
 412
 413 (defun org-md-plain-text (text info)
 414   "Transcode a TEXT string into Markdown format.
 415 TEXT is the string to transcode.  INFO is a plist holding
 416 contextual information."
 417   (when (plist-get info :with-smart-quotes)
 418     (setq text (org-export-activate-smart-quotes text :html info)))
 419   ;; Protect ambiguous #.  This will protect # at the beginning of
 420   ;; a line, but not at the beginning of a paragraph.  See
 421   ;; `org-md-paragraph'.
 422   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 423   ;; Protect ambiguous !
 424   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 425   ;; Protect `, *, _ and \
 426   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 427   ;; Handle special strings, if required.
 428   (when (plist-get info :with-special-strings)
 429     (setq text (org-html-convert-special-strings text)))
 430   ;; Handle break preservation, if required.
 431   (when (plist-get info :preserve-breaks)
 432     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 433   ;; Return value.
 434   text)
 435
 436
 437 ;;;; Property Drawer
 438
 439 (defun org-md-property-drawer (property-drawer contents info)
 440   "Transcode a PROPERTY-DRAWER element into Markdown format.
 441 CONTENTS holds the contents of the drawer.  INFO is a plist
 442 holding contextual information."
 443   (and (org-string-nw-p contents)
 444        (replace-regexp-in-string "^" "    " contents)))
 445
 446
 447 ;;;; Quote Block
 448
 449 (defun org-md-quote-block (quote-block contents info)
 450   "Transcode QUOTE-BLOCK element into Markdown format.
 451 CONTENTS is the quote-block contents.  INFO is a plist used as
 452 a communication channel."
 453   (replace-regexp-in-string
 454    "^" "> "
 455    (replace-regexp-in-string "\n\\'" "" contents)))
 456
 457
 458 ;;;; Section
 459
 460 (defun org-md-section (section contents info)
 461   "Transcode SECTION element into Markdown format.
 462 CONTENTS is the section contents.  INFO is a plist used as
 463 a communication channel."
 464   contents)
 465
 466
 467 ;;;; Template
 468
 469 (defun org-md-inner-template (contents info)
 470   "Return body of document after converting it to Markdown syntax.
 471 CONTENTS is the transcoded contents string.  INFO is a plist
 472 holding export options."
 473   ;; Make sure CONTENTS is separated from table of contents and
 474   ;; footnotes with at least a blank line.
 475   (org-trim (org-html-inner-template (concat "\n" contents "\n") info)))
 476
 477 (defun org-md-template (contents info)
 478   "Return complete document string after Markdown conversion.
 479 CONTENTS is the transcoded contents string.  INFO is a plist used
 480 as a communication channel."
 481   contents)
 482
 483
 484 \f
 485 ;;; Interactive function
 486
 487 ;;;###autoload
 488 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 489   "Export current buffer to a Markdown buffer.
 490
 491 If narrowing is active in the current buffer, only export its
 492 narrowed part.
 493
 494 If a region is active, export that region.
 495
 496 A non-nil optional argument ASYNC means the process should happen
 497 asynchronously.  The resulting buffer should be accessible
 498 through the `org-export-stack' interface.
 499
 500 When optional argument SUBTREEP is non-nil, export the sub-tree
 501 at point, extracting information from the headline properties
 502 first.
 503
 504 When optional argument VISIBLE-ONLY is non-nil, don't export
 505 contents of hidden elements.
 506
 507 Export is done in a buffer named \"*Org MD Export*\", which will
 508 be displayed when `org-export-show-temporary-export-buffer' is
 509 non-nil."
 510   (interactive)
 511   (org-export-to-buffer 'md "*Org MD Export*"
 512     async subtreep visible-only nil nil (lambda () (text-mode))))
 513
 514 ;;;###autoload
 515 (defun org-md-convert-region-to-md ()
 516   "Assume the current region has org-mode syntax, and convert it to Markdown.
 517 This can be used in any buffer.  For example, you can write an
 518 itemized list in org-mode syntax in a Markdown buffer and use
 519 this command to convert it."
 520   (interactive)
 521   (org-export-replace-region-by 'md))
 522
 523
 524 ;;;###autoload
 525 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 526   "Export current buffer to a Markdown file.
 527
 528 If narrowing is active in the current buffer, only export its
 529 narrowed part.
 530
 531 If a region is active, export that region.
 532
 533 A non-nil optional argument ASYNC means the process should happen
 534 asynchronously.  The resulting file should be accessible through
 535 the `org-export-stack' interface.
 536
 537 When optional argument SUBTREEP is non-nil, export the sub-tree
 538 at point, extracting information from the headline properties
 539 first.
 540
 541 When optional argument VISIBLE-ONLY is non-nil, don't export
 542 contents of hidden elements.
 543
 544 Return output file's name."
 545   (interactive)
 546   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 547     (org-export-to-file 'md outfile async subtreep visible-only)))
 548
 549 ;;;###autoload
 550 (defun org-md-publish-to-md (plist filename pub-dir)
 551   "Publish an org file to Markdown.
 552
 553 FILENAME is the filename of the Org file to be published.  PLIST
 554 is the property list for the given project.  PUB-DIR is the
 555 publishing directory.
 556
 557 Return output file name."
 558   (org-publish-org-to 'md filename ".md" plist pub-dir))
 559
 560 (provide 'ox-md)
 561
 562 ;; Local variables:
 563 ;; generated-autoload-file: "org-loaddefs.el"
 564 ;; End:
 565
 566 ;;; ox-md.el ends here