lisp/ox-org.el

   1 ;;; ox-org.el --- Org Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'ox)
  28 (declare-function htmlize-buffer "htmlize" (&optional buffer))
  29
  30 (defgroup org-export-org nil
  31   "Options for exporting Org mode files to Org."
  32   :tag "Org Export Org"
  33   :group 'org-export
  34   :version "24.4"
  35   :package-version '(Org . "8.0"))
  36
  37 (define-obsolete-variable-alias
  38   'org-export-htmlized-org-css-url 'org-org-htmlized-css-url "24.4")
  39 (defcustom org-org-htmlized-css-url nil
  40   "URL pointing to the CSS defining colors for htmlized Emacs buffers.
  41 Normally when creating an htmlized version of an Org buffer,
  42 htmlize will create the CSS to define the font colors.  However,
  43 this does not work when converting in batch mode, and it also can
  44 look bad if different people with different fontification setup
  45 work on the same website.  When this variable is non-nil,
  46 creating an htmlized version of an Org buffer using
  47 `org-org-export-as-org' will include a link to this URL if the
  48 setting of `org-html-htmlize-output-type' is 'css."
  49   :group 'org-export-org
  50   :type '(choice
  51           (const :tag "Don't include external stylesheet link" nil)
  52           (string :tag "URL or local href")))
  53
  54 (org-export-define-backend 'org
  55   '((babel-call . org-org-identity)
  56     (bold . org-org-identity)
  57     (center-block . org-org-identity)
  58     (clock . org-org-identity)
  59     (code . org-org-identity)
  60     (diary-sexp . org-org-identity)
  61     (drawer . org-org-identity)
  62     (dynamic-block . org-org-identity)
  63     (entity . org-org-identity)
  64     (example-block . org-org-identity)
  65     (fixed-width . org-org-identity)
  66     (footnote-definition . ignore)
  67     (footnote-reference . org-org-identity)
  68     (headline . org-org-headline)
  69     (horizontal-rule . org-org-identity)
  70     (inline-babel-call . org-org-identity)
  71     (inline-src-block . org-org-identity)
  72     (inlinetask . org-org-identity)
  73     (italic . org-org-identity)
  74     (item . org-org-identity)
  75     (keyword . org-org-keyword)
  76     (latex-environment . org-org-identity)
  77     (latex-fragment . org-org-identity)
  78     (line-break . org-org-identity)
  79     (link . org-org-link)
  80     (node-property . org-org-identity)
  81     (template . org-org-template)
  82     (paragraph . org-org-identity)
  83     (plain-list . org-org-identity)
  84     (planning . org-org-identity)
  85     (property-drawer . org-org-identity)
  86     (quote-block . org-org-identity)
  87     (radio-target . org-org-identity)
  88     (section . org-org-section)
  89     (special-block . org-org-identity)
  90     (src-block . org-org-identity)
  91     (statistics-cookie . org-org-identity)
  92     (strike-through . org-org-identity)
  93     (subscript . org-org-identity)
  94     (superscript . org-org-identity)
  95     (table . org-org-identity)
  96     (table-cell . org-org-identity)
  97     (table-row . org-org-identity)
  98     (target . org-org-identity)
  99     (timestamp . org-org-identity)
 100     (underline . org-org-identity)
 101     (verbatim . org-org-identity)
 102     (verse-block . org-org-identity))
 103   :menu-entry
 104   '(?O "Export to Org"
 105        ((?O "As Org buffer" org-org-export-as-org)
 106         (?o "As Org file" org-org-export-to-org)
 107         (?v "As Org file and open"
 108             (lambda (a s v b)
 109               (if a (org-org-export-to-org t s v b)
 110                 (org-open-file (org-org-export-to-org nil s v b))))))))
 111
 112 (defun org-org-identity (blob contents info)
 113   "Transcode BLOB element or object back into Org syntax.
 114 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 115   (let ((case-fold-search t))
 116     (replace-regexp-in-string
 117      "^[ \t]*#\\+ATTR_[-_A-Za-z0-9]+:\\(?: .*\\)?\n" ""
 118      (org-export-expand blob contents t))))
 119
 120 (defun org-org-headline (headline contents info)
 121   "Transcode HEADLINE element back into Org syntax.
 122 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 123   (unless (org-element-property :footnote-section-p headline)
 124     (unless (plist-get info :with-todo-keywords)
 125       (org-element-put-property headline :todo-keyword nil))
 126     (unless (plist-get info :with-tags)
 127       (org-element-put-property headline :tags nil))
 128     (unless (plist-get info :with-priority)
 129       (org-element-put-property headline :priority nil))
 130     (org-element-put-property headline :level
 131                               (org-export-get-relative-level headline info))
 132     (org-element-headline-interpreter headline contents)))
 133
 134 (defun org-org-keyword (keyword contents info)
 135   "Transcode KEYWORD element back into Org syntax.
 136 CONTENTS is nil.  INFO is ignored."
 137   (let ((key (org-element-property :key keyword)))
 138     (unless (member key
 139                     '("AUTHOR" "CREATOR" "DATE" "EMAIL" "OPTIONS" "TITLE"))
 140       (org-element-keyword-interpreter keyword nil))))
 141
 142 (defun org-org-link (link contents info)
 143   "Transcode LINK object back into Org syntax.
 144 CONTENTS is the description of the link, as a string, or nil.
 145 INFO is a plist containing current export state."
 146   (or (org-export-custom-protocol-maybe link contents 'org)
 147       (org-element-link-interpreter link contents)))
 148
 149 (defun org-org-template (contents info)
 150   "Return Org document template with document keywords.
 151 CONTENTS is the transcoded contents string.  INFO is a plist used
 152 as a communication channel."
 153   (concat
 154    (and (plist-get info :time-stamp-file)
 155         (format-time-string "# Created %Y-%m-%d %a %H:%M\n"))
 156    (org-element-normalize-string
 157     (mapconcat #'identity
 158                (org-element-map (plist-get info :parse-tree) 'keyword
 159                  (lambda (k)
 160                    (and (string-equal (org-element-property :key k) "OPTIONS")
 161                         (concat "#+OPTIONS: "
 162                                 (org-element-property :value k)))))
 163                "\n"))
 164    (and (plist-get info :with-title)
 165         (format "#+TITLE: %s\n" (org-export-data (plist-get info :title) info)))
 166    (and (plist-get info :with-date)
 167         (let ((date (org-export-data (org-export-get-date info) info)))
 168           (and (org-string-nw-p date)
 169                (format "#+DATE: %s\n" date))))
 170    (and (plist-get info :with-author)
 171         (let ((author (org-export-data (plist-get info :author) info)))
 172           (and (org-string-nw-p author)
 173                (format "#+AUTHOR: %s\n" author))))
 174    (and (plist-get info :with-email)
 175         (let ((email (org-export-data (plist-get info :email) info)))
 176           (and (org-string-nw-p email)
 177                (format "#+EMAIL: %s\n" email))))
 178    (and (plist-get info :with-creator)
 179         (org-string-nw-p (plist-get info :creator))
 180         (format "#+CREATOR: %s\n" (plist-get info :creator)))
 181    contents))
 182
 183 (defun org-org-section (section contents info)
 184   "Transcode SECTION element back into Org syntax.
 185 CONTENTS is the contents of the section.  INFO is a plist used as
 186 a communication channel."
 187   (concat
 188    (org-element-normalize-string contents)
 189    ;; Insert footnote definitions appearing for the first time in this
 190    ;; section.  Indeed, some of them may not be available to narrowing
 191    ;; so we make sure all of them are included in the result.
 192    (let ((footnotes-alist
 193           (org-element-map section 'footnote-reference
 194             (lambda (fn)
 195               (and (eq (org-element-property :type fn) 'standard)
 196                    (org-export-footnote-first-reference-p fn info)
 197                    (cons (org-element-property :label fn)
 198                          (org-export-get-footnote-definition fn info))))
 199             info)))
 200      (and footnotes-alist
 201           (concat "\n"
 202                   (mapconcat
 203                    (lambda (d)
 204                      (org-element-normalize-string
 205                       (concat (format "[%s] "(car d))
 206                               (org-export-data (cdr d) info))))
 207                    footnotes-alist "\n"))))
 208    (make-string (or (org-element-property :post-blank section) 0) ?\n)))
 209
 210 ;;;###autoload
 211 (defun org-org-export-as-org
 212   (&optional async subtreep visible-only body-only ext-plist)
 213   "Export current buffer to an Org buffer.
 214
 215 If narrowing is active in the current buffer, only export its
 216 narrowed part.
 217
 218 If a region is active, export that region.
 219
 220 A non-nil optional argument ASYNC means the process should happen
 221 asynchronously.  The resulting buffer should be accessible
 222 through the `org-export-stack' interface.
 223
 224 When optional argument SUBTREEP is non-nil, export the sub-tree
 225 at point, extracting information from the headline properties
 226 first.
 227
 228 When optional argument VISIBLE-ONLY is non-nil, don't export
 229 contents of hidden elements.
 230
 231 When optional argument BODY-ONLY is non-nil, strip document
 232 keywords from output.
 233
 234 EXT-PLIST, when provided, is a property list with external
 235 parameters overriding Org default settings, but still inferior to
 236 file-local settings.
 237
 238 Export is done in a buffer named \"*Org ORG Export*\", which will
 239 be displayed when `org-export-show-temporary-export-buffer' is
 240 non-nil."
 241   (interactive)
 242   (org-export-to-buffer 'org "*Org ORG Export*"
 243     async subtreep visible-only body-only ext-plist (lambda () (org-mode))))
 244
 245 ;;;###autoload
 246 (defun org-org-export-to-org
 247   (&optional async subtreep visible-only body-only ext-plist)
 248   "Export current buffer to an org file.
 249
 250 If narrowing is active in the current buffer, only export its
 251 narrowed part.
 252
 253 If a region is active, export that region.
 254
 255 A non-nil optional argument ASYNC means the process should happen
 256 asynchronously.  The resulting file should be accessible through
 257 the `org-export-stack' interface.
 258
 259 When optional argument SUBTREEP is non-nil, export the sub-tree
 260 at point, extracting information from the headline properties
 261 first.
 262
 263 When optional argument VISIBLE-ONLY is non-nil, don't export
 264 contents of hidden elements.
 265
 266 When optional argument BODY-ONLY is non-nil, strip document
 267 keywords from output.
 268
 269 EXT-PLIST, when provided, is a property list with external
 270 parameters overriding Org default settings, but still inferior to
 271 file-local settings.
 272
 273 Return output file name."
 274   (interactive)
 275   (let ((outfile (org-export-output-file-name ".org" subtreep)))
 276     (org-export-to-file 'org outfile
 277       async subtreep visible-only body-only ext-plist)))
 278
 279 ;;;###autoload
 280 (defun org-org-publish-to-org (plist filename pub-dir)
 281   "Publish an org file to org.
 282
 283 FILENAME is the filename of the Org file to be published.  PLIST
 284 is the property list for the given project.  PUB-DIR is the
 285 publishing directory.
 286
 287 Return output file name."
 288   (org-publish-org-to 'org filename ".org" plist pub-dir)
 289   (when (plist-get plist :htmlized-source)
 290     (require 'htmlize)
 291     (require 'ox-html)
 292     (let* ((org-inhibit-startup t)
 293            (htmlize-output-type 'css)
 294            (html-ext (concat "." (or (plist-get plist :html-extension)
 295                                      org-html-extension "html")))
 296            (visitingp (find-buffer-visiting filename))
 297            (work-buffer (or visitingp (find-file filename)))
 298            newbuf)
 299       (font-lock-ensure)
 300       (show-all)
 301       (org-show-block-all)
 302       (setq newbuf (htmlize-buffer))
 303       (with-current-buffer newbuf
 304         (when org-org-htmlized-css-url
 305           (goto-char (point-min))
 306           (and (re-search-forward
 307                 "<style type=\"text/css\">[^\000]*?\n[ \t]*</style>.*" nil t)
 308                (replace-match
 309                 (format
 310                  "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">"
 311                  org-org-htmlized-css-url) t t)))
 312         (write-file (concat pub-dir (file-name-nondirectory filename) html-ext)))
 313       (kill-buffer newbuf)
 314       (unless visitingp (kill-buffer work-buffer)))
 315     (set-buffer-modified-p nil)))
 316
 317
 318 (provide 'ox-org)
 319
 320 ;; Local variables:
 321 ;; generated-autoload-file: "org-loaddefs.el"
 322 ;; End:
 323
 324 ;;; ox-org.el ends here