lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2014 Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg@gnu.org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, capture
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; capture templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a capture template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-capture-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to capture this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-capture' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/res/writing/latex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better capture template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114 (require 'org-compat)
 115
 116 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 117 (defvar org-id-locations)
 118
 119 (declare-function bibtex-beginning-of-entry "bibtex" ())
 120 (declare-function bibtex-generate-autokey "bibtex" ())
 121 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 122 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 123 (declare-function org-babel-trim "ob" (string &optional regexp))
 124
 125 \f
 126 ;;; Bibtex data
 127 (defvar org-bibtex-types
 128   '((:article
 129      (:description . "An article from a journal or magazine")
 130      (:required :author :title :journal :year)
 131      (:optional :volume :number :pages :month :note))
 132     (:book
 133      (:description . "A book with an explicit publisher")
 134      (:required (:editor :author) :title :publisher :year)
 135      (:optional (:volume :number) :series :address :edition :month :note))
 136     (:booklet
 137      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 138      (:required :title)
 139      (:optional :author :howpublished :address :month :year :note))
 140     (:conference
 141      (:description . "")
 142      (:required :author :title :booktitle :year)
 143      (:optional :editor :pages :organization :publisher :address :month :note))
 144     (:inbook
 145      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 146      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 147      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 148     (:incollection
 149      (:description . "A part of a book having its own title.")
 150      (:required :author :title :booktitle :publisher :year)
 151      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 152     (:inproceedings
 153      (:description . "An article in a conference proceedings")
 154      (:required :author :title :booktitle :year)
 155      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 156     (:manual
 157      (:description . "Technical documentation.")
 158      (:required :title)
 159      (:optional :author :organization :address :edition :month :year :note))
 160     (:mastersthesis
 161      (:description . "A Master’s thesis.")
 162      (:required :author :title :school :year)
 163      (:optional :type :address :month :note))
 164     (:misc
 165      (:description . "Use this type when nothing else fits.")
 166      (:required)
 167      (:optional :author :title :howpublished :month :year :note))
 168     (:phdthesis
 169      (:description . "A PhD thesis.")
 170      (:required :author :title :school :year)
 171      (:optional :type :address :month :note))
 172     (:proceedings
 173      (:description . "The proceedings of a conference.")
 174      (:required :title :year)
 175      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 176     (:techreport
 177      (:description . "A report published by a school or other institution.")
 178      (:required :author :title :institution :year)
 179      (:optional :type :address :month :note))
 180     (:unpublished
 181      (:description . "A document having an author and title, but not formally published.")
 182      (:required :author :title :note)
 183      (:optional :month :year)))
 184   "Bibtex entry types with required and optional parameters.")
 185
 186 (defvar org-bibtex-fields
 187   '((:address      . "Usually the address of the publisher or other type of institution.  For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 188     (:annote       . "An annotation.  It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 189     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 190     (:booktitle    . "Title of a book, part of which is being cited.  See the LaTeX book for how to type titles.  For book entries, use the title field instead.")
 191     (:chapter      . "A chapter (or section or whatever) number.")
 192     (:crossref     . "The database key of the entry being cross referenced.")
 193     (:edition      . "The edition of a book for example, 'Second'.  This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 194     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book.  If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 195     (:howpublished . "How something strange has been published.  The first word should be capitalized.")
 196     (:institution  . "The sponsoring institution of a technical report.")
 197     (:journal      . "A journal name.")
 198     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing.  This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 199     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written.  You should use the standard three-letter abbreviation,")
 200     (:note         . "Any additional information that can help the reader.  The first word should be capitalized.")
 201     (:number       . "Any additional information that can help the reader.  The first word should be capitalized.")
 202     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 203     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 204     (:publisher    . "The publisher’s name.")
 205     (:school       . "The name of the school where a thesis was written.")
 206     (:series       . "The name of a series or set of books.  When citing an entire book, the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 207     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 208     (:type         . "The type of a technical report for example, 'Research Note'.")
 209     (:volume       . "The volume of a journal or multi-volume book.")
 210     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 211   "Bibtex fields with descriptions.")
 212
 213 (defvar org-bibtex-entries nil
 214   "List to hold parsed bibtex entries.")
 215
 216 (defcustom org-bibtex-autogen-keys nil
 217   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 218   :group 'org-bibtex
 219   :version "24.1"
 220   :type  'boolean)
 221
 222 (defcustom org-bibtex-prefix nil
 223   "Optional prefix for all bibtex property names.
 224 For example setting to 'BIB_' would allow interoperability with fireforg."
 225   :group 'org-bibtex
 226   :version "24.1"
 227   :type  '(choice
 228            (const nil)
 229            (string)))
 230
 231 (defcustom org-bibtex-treat-headline-as-title t
 232   "Treat headline text as title if title property is absent.
 233 If an entry is missing a title property, use the headline text as
 234 the property.  If this value is t, `org-bibtex-check' will ignore
 235 a missing title field."
 236   :group 'org-bibtex
 237   :version "24.1"
 238   :type 'boolean)
 239
 240 (defcustom org-bibtex-export-arbitrary-fields nil
 241   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 242 This only has effect if `org-bibtex-prefix' is defined, so as to
 243 ensure that other org-properties, such as CATEGORY or LOGGING are
 244 not placed in the exported bibtex entry."
 245   :group 'org-bibtex
 246   :version "24.1"
 247   :type 'boolean)
 248
 249 (defcustom org-bibtex-key-property "CUSTOM_ID"
 250   "Property that holds the bibtex key.
 251 By default, this is CUSTOM_ID, which enables easy linking to
 252 bibtex headlines from within an org file.  This can be set to ID
 253 to enable global links, but only with great caution, as global
 254 IDs must be unique."
 255   :group 'org-bibtex
 256   :version "24.1"
 257   :type 'string)
 258
 259 (defcustom org-bibtex-tags nil
 260   "List of tag(s) that should be added to new bib entries."
 261   :group 'org-bibtex
 262   :version "24.1"
 263   :type '(repeat  :tag "Tag" (string)))
 264
 265 (defcustom org-bibtex-tags-are-keywords nil
 266   "Convert the value of the keywords field to tags and vice versa.
 267
 268 When non-nil, comma-separated entries in a bibtex entry's keywords
 269 field will be converted to Org tags.  Note: spaces will be escaped
 270 with underscores, and characters that are not permitted in Org
 271 tags will be removed.
 272
 273 When non-nil, local tags in an Org entry will be exported as
 274 a comma-separated string of keywords when exported to bibtex.
 275 If `org-bibtex-inherit-tags' is non-nil, inherited tags will also
 276 be exported as keywords.  Tags defined in `org-bibtex-tags' or
 277 `org-bibtex-no-export-tags' will not be exported."
 278   :group 'org-bibtex
 279   :version "24.1"
 280   :type 'boolean)
 281
 282 (defcustom org-bibtex-no-export-tags nil
 283   "List of tag(s) that should not be converted to keywords.
 284 This variable is relevant only if `org-bibtex-tags-are-keywords'
 285 is non-nil."
 286   :group 'org-bibtex
 287   :version "24.1"
 288   :type '(repeat :tag "Tag" (string)))
 289
 290 (defcustom org-bibtex-inherit-tags nil
 291   "Controls whether inherited tags are converted to bibtex keywords.
 292 It is relevant only if `org-bibtex-tags-are-keywords' is non-nil.
 293 Tag inheritence itself is controlled by `org-use-tag-inheritence'
 294 and `org-exclude-tags-from-inheritence'."
 295   :group 'org-bibtex
 296   :version "25.1"
 297   :package-version '(Org . "8.3")
 298   :type 'boolean)
 299
 300 (defcustom org-bibtex-type-property-name "btype"
 301   "Property in which to store bibtex entry type (e.g., article)."
 302   :group 'org-bibtex
 303   :version "24.1"
 304   :type 'string)
 305
 306 \f
 307 ;;; Utility functions
 308 (defun org-bibtex-get (property)
 309   (let ((it (let ((org-special-properties
 310                    (delete "FILE" (copy-sequence org-special-properties))))
 311               (or
 312                (org-entry-get (point) (upcase property))
 313                (org-entry-get (point) (concat org-bibtex-prefix
 314                                               (upcase property)))))))
 315     (when it (org-babel-trim it))))
 316
 317 (defun org-bibtex-put (property value)
 318   (let ((prop (upcase (if (keywordp property)
 319                           (substring (symbol-name property) 1)
 320                         property))))
 321     (org-set-property
 322      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 323              prop)
 324      value)))
 325
 326 (defun org-bibtex-headline ()
 327   "Return a bibtex entry of the given headline as a string."
 328   (let* ((val (lambda (key lst) (cdr (assoc key lst))))
 329          (to (lambda (string) (intern (concat ":" string))))
 330          (from (lambda (key) (substring (symbol-name key) 1)))
 331          flatten ; silent compiler warning
 332          (flatten (lambda (&rest lsts)
 333                     (apply #'append (mapcar
 334                                      (lambda (e)
 335                                        (if (listp e) (apply flatten e) (list e)))
 336                                      lsts))))
 337          (notes (buffer-string))
 338          (id (org-bibtex-get org-bibtex-key-property))
 339          (type (org-bibtex-get org-bibtex-type-property-name))
 340          (tags (when org-bibtex-tags-are-keywords
 341                  (delq nil
 342                        (mapcar
 343                         (lambda (tag)
 344                           (unless (member tag
 345                                           (append org-bibtex-tags
 346                                                   org-bibtex-no-export-tags))
 347                             tag))
 348                         (if org-bibtex-inherit-tags
 349                             (org-get-tags-at)
 350                           (org-get-local-tags-at)))))))
 351     (when type
 352       (let ((entry (format
 353                     "@%s{%s,\n%s\n}\n" type id
 354                     (mapconcat
 355                      (lambda (pair)
 356                        (format "  %s={%s}" (car pair) (cdr pair)))
 357                      (remove nil
 358                              (if (and org-bibtex-export-arbitrary-fields
 359                                       org-bibtex-prefix)
 360                                  (mapcar
 361                                   (lambda (kv)
 362                                     (let ((key (car kv)) (val0 (cdr kv)))
 363                                       (when (and
 364                                              (string-match org-bibtex-prefix key)
 365                                              (not (string=
 366                                                    (downcase (concat org-bibtex-prefix
 367                                                                      org-bibtex-type-property-name))
 368                                                    (downcase key))))
 369                                         (cons (downcase (replace-regexp-in-string
 370                                                          org-bibtex-prefix "" key))
 371                                               val0))))
 372                                   (org-entry-properties nil 'standard))
 373                                (mapcar
 374                                 (lambda (field)
 375                                   (let ((value (or (org-bibtex-get (funcall from field))
 376                                                    (and (equal :title field)
 377                                                         (nth 4 (org-heading-components))))))
 378                                     (when value (cons (funcall from field) value))))
 379                                 (funcall flatten
 380                                          (funcall val :required (funcall val (funcall to type) org-bibtex-types))
 381                                          (funcall val :optional (funcall val (funcall to type) org-bibtex-types))))))
 382                      ",\n"))))
 383         (with-temp-buffer
 384           (insert entry)
 385           (when tags
 386             (bibtex-beginning-of-entry)
 387             (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 388                 (progn (goto-char (match-end 1)) (insert ", "))
 389               (search-forward ",\n" nil t)
 390               (insert "  keywords={},\n")
 391               (search-backward "}," nil t))
 392             (insert (mapconcat #'identity tags ", ")))
 393           (buffer-string))))))
 394
 395 (defun org-bibtex-ask (field)
 396   (unless (assoc field org-bibtex-fields)
 397     (error "Field:%s is not known" field))
 398   (save-window-excursion
 399     (let* ((name (substring (symbol-name field) 1))
 400            (buf-name (format "*Bibtex Help %s*" name)))
 401       (with-output-to-temp-buffer buf-name
 402         (princ (cdr (assoc field org-bibtex-fields))))
 403       (with-current-buffer buf-name (visual-line-mode 1))
 404       (org-fit-window-to-buffer (get-buffer-window buf-name))
 405       (let ((result (read-from-minibuffer (format "%s: " name))))
 406         (when (> (length result) 0) result)))))
 407
 408 (defun org-bibtex-autokey ()
 409   "Generate an autokey for the current headline."
 410   (org-bibtex-put org-bibtex-key-property
 411                   (if org-bibtex-autogen-keys
 412                       (let* ((entry (org-bibtex-headline))
 413                              (key
 414                               (with-temp-buffer
 415                                 (insert entry)
 416                                 (bibtex-generate-autokey))))
 417                         ;; test for duplicate IDs if using global ID
 418                         (when (and
 419                                (equal org-bibtex-key-property "ID")
 420                                (featurep 'org-id)
 421                                (hash-table-p org-id-locations)
 422                                (gethash key org-id-locations))
 423                           (warn "Another entry has the same ID"))
 424                         key)
 425                     (read-from-minibuffer "id: "))))
 426
 427 (defun org-bibtex-fleshout (type &optional optional)
 428   "Fleshout current heading, ensuring all required fields are present.
 429 With optional argument OPTIONAL, also prompt for optional fields."
 430   (let ((val (lambda (key lst) (cdr (assoc key lst))))
 431         (keyword (lambda (name) (intern (concat ":" (downcase name)))))
 432         (name (lambda (keyword) (substring (symbol-name keyword) 1))))
 433     (dolist (field (append
 434                     (if org-bibtex-treat-headline-as-title
 435                         (remove :title (funcall val :required (funcall val type org-bibtex-types)))
 436                       (funcall val :required (funcall val type org-bibtex-types)))
 437                     (when optional (funcall val :optional (funcall val type org-bibtex-types)))))
 438       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 439         (let ((present (first (remove
 440                                nil
 441                                (mapcar
 442                                 (lambda (f) (when (org-bibtex-get (funcall name f)) f))
 443                                 field)))))
 444           (setf field (or present (funcall keyword
 445                                            (org-icompleting-read
 446                                             "Field: " (mapcar name field)))))))
 447       (let ((name (funcall name field)))
 448         (unless (org-bibtex-get name)
 449           (let ((prop (org-bibtex-ask field)))
 450             (when prop (org-bibtex-put name prop)))))))
 451   (when (and type (assoc type org-bibtex-types)
 452              (not (org-bibtex-get org-bibtex-key-property)))
 453     (org-bibtex-autokey)))
 454
 455 \f
 456 ;;; Bibtex link functions
 457 (org-add-link-type "bibtex" 'org-bibtex-open)
 458 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 459
 460 (defun org-bibtex-open (path)
 461   "Visit the bibliography entry on PATH."
 462   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 463                    (match-string 1 path)))
 464          (path (substring path 0 (match-beginning 0))))
 465     (org-open-file path t nil search)))
 466
 467 (defun org-bibtex-store-link ()
 468   "Store a link to a BibTeX entry."
 469   (when (eq major-mode 'bibtex-mode)
 470     (let* ((search (org-create-file-search-in-bibtex))
 471            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 472                          "::" search))
 473            (entry (mapcar ; repair strings enclosed in "..." or {...}
 474                    (lambda(c)
 475                      (if (string-match
 476                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 477                          (cons (car c) (match-string 1 (cdr c))) c))
 478                    (save-excursion
 479                      (bibtex-beginning-of-entry)
 480                      (bibtex-parse-entry)))))
 481       (org-store-link-props
 482        :key (cdr (assoc "=key=" entry))
 483        :author (or (cdr (assoc "author" entry)) "[no author]")
 484        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 485        :title (or (cdr (assoc "title" entry)) "[no title]")
 486        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 487        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 488        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 489        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 490        :url (or (cdr (assoc "url" entry)) "[no url]")
 491        :year (or (cdr (assoc "year" entry)) "[no year]")
 492        :month (or (cdr (assoc "month" entry)) "[no month]")
 493        :address (or (cdr (assoc "address" entry)) "[no address]")
 494        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 495        :number (or (cdr (assoc "number" entry)) "[no number]")
 496        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 497        :series (or (cdr (assoc "series" entry)) "[no series]")
 498        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 499        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 500        :type "bibtex"
 501        :link link
 502        :description org-bibtex-description))))
 503
 504 (defun org-create-file-search-in-bibtex ()
 505   "Create the search string and description for a BibTeX database entry."
 506   ;; Make a good description for this entry, using names, year and the title
 507   ;; Put it into the `description' variable which is dynamically scoped.
 508   (let ((bibtex-autokey-names 1)
 509         (bibtex-autokey-names-stretch 1)
 510         (bibtex-autokey-name-case-convert-function 'identity)
 511         (bibtex-autokey-name-separator " & ")
 512         (bibtex-autokey-additional-names " et al.")
 513         (bibtex-autokey-year-length 4)
 514         (bibtex-autokey-name-year-separator " ")
 515         (bibtex-autokey-titlewords 3)
 516         (bibtex-autokey-titleword-separator " ")
 517         (bibtex-autokey-titleword-case-convert-function 'identity)
 518         (bibtex-autokey-titleword-length 'infty)
 519         (bibtex-autokey-year-title-separator ": "))
 520     (setq org-bibtex-description (bibtex-generate-autokey)))
 521   ;; Now parse the entry, get the key and return it.
 522   (save-excursion
 523     (bibtex-beginning-of-entry)
 524     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 525
 526 (defun org-execute-file-search-in-bibtex (s)
 527   "Find the link search string S as a key for a database entry."
 528   (when (eq major-mode 'bibtex-mode)
 529     ;; Yes, we want to do the search in this file.
 530     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 531     (goto-char (point-min))
 532     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 533                                     (regexp-quote s) "[ \t\n]*,") nil t)
 534          (goto-char (match-beginning 0)))
 535     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 536         ;; Use double prefix to indicate that any web link should be browsed
 537         (let ((b (current-buffer)) (p (point)))
 538           ;; Restore the window configuration because we just use the web link
 539           (set-window-configuration org-window-config-before-follow-link)
 540           (with-current-buffer b
 541             (goto-char p)
 542             (bibtex-url)))
 543       (recenter 0))  ; Move entry start to beginning of window
 544     ;; return t to indicate that the search is done.
 545     t))
 546
 547 ;; Finally add the link search function to the right hook.
 548 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 549
 550 \f
 551 ;;; Bibtex <-> Org-mode headline translation functions
 552 (defun org-bibtex (&optional filename)
 553   "Export each headline in the current file to a bibtex entry.
 554 Headlines are exported using `org-bibtex-headline'."
 555   (interactive
 556    (list (read-file-name
 557           "Bibtex file: " nil nil nil
 558           (file-name-nondirectory
 559            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 560   (let ((error-point
 561          (catch 'bib
 562            (let ((bibtex-entries
 563                   (remove nil (org-map-entries
 564                                (lambda ()
 565                                  (condition-case foo
 566                                      (org-bibtex-headline)
 567                                    (error (throw 'bib (point)))))))))
 568              (with-temp-file filename
 569                (insert (mapconcat #'identity bibtex-entries "\n")))
 570              (message "Successfully exported %d BibTeX entries to %s"
 571                       (length bibtex-entries) filename) nil))))
 572     (when error-point
 573       (goto-char error-point)
 574       (message "Bibtex error at %S" (nth 4 (org-heading-components))))))
 575
 576 (defun org-bibtex-check (&optional optional)
 577   "Check the current headline for required fields.
 578 With prefix argument OPTIONAL also prompt for optional fields."
 579   (interactive "P")
 580   (save-restriction
 581     (org-narrow-to-subtree)
 582     (let ((type (let ((name (org-bibtex-get org-bibtex-type-property-name)))
 583                   (when name (intern (concat ":" name))))))
 584       (when type (org-bibtex-fleshout type optional)))))
 585
 586 (defun org-bibtex-check-all (&optional optional)
 587   "Check all headlines in the current file.
 588 With prefix argument OPTIONAL also prompt for optional fields."
 589   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 590
 591 (defun org-bibtex-create (&optional arg nonew)
 592   "Create a new entry at the given level.
 593 With a prefix arg, query for optional fields as well.
 594 If nonew is t, add data to the headline of the entry at point."
 595   (interactive "P")
 596   (let* ((type (org-icompleting-read
 597                 "Type: " (mapcar (lambda (type)
 598                                    (substring (symbol-name (car type)) 1))
 599                                  org-bibtex-types)
 600                 nil nil (when nonew
 601                           (org-bibtex-get org-bibtex-type-property-name))))
 602          (type (if (keywordp type) type (intern (concat ":" type))))
 603          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 604     (unless (assoc type org-bibtex-types)
 605       (error "Type:%s is not known" type))
 606     (if nonew
 607         (org-back-to-heading)
 608       (org-insert-heading)
 609       (let ((title (org-bibtex-ask :title)))
 610         (insert title)
 611         (org-bibtex-put "TITLE" title)))
 612     (org-bibtex-put org-bibtex-type-property-name
 613                     (substring (symbol-name type) 1))
 614     (org-bibtex-fleshout type arg)
 615     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 616
 617 (defun org-bibtex-create-in-current-entry (&optional arg)
 618   "Add bibliographical data to the current entry.
 619 With a prefix arg, query for optional fields."
 620   (interactive "P")
 621   (org-bibtex-create arg t))
 622
 623 (defun org-bibtex-read ()
 624   "Read a bibtex entry and save to `org-bibtex-entries'.
 625 This uses `bibtex-parse-entry'."
 626   (interactive)
 627   (let ((keyword (lambda (str) (intern (concat ":" (downcase str)))))
 628         (clean-space (lambda (str) (replace-regexp-in-string
 629                                     "[[:space:]\n\r]+" " " str)))
 630         (strip-delim
 631          (lambda (str)       ; strip enclosing "..." and {...}
 632            (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 633              (when (and (> (length str) 1)
 634                         (= (aref str 0) (car pair))
 635                         (= (aref str (1- (length str))) (cdr pair)))
 636                (setf str (substring str 1 (1- (length str)))))) str)))
 637     (push (mapcar
 638            (lambda (pair)
 639              (cons (let ((field (funcall keyword (car pair))))
 640                      (case field
 641                        (:=type= :type)
 642                        (:=key= :key)
 643                        (otherwise field)))
 644                    (funcall clean-space (funcall strip-delim (cdr pair)))))
 645            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 646           org-bibtex-entries)))
 647
 648 (defun org-bibtex-read-buffer (buffer)
 649   "Read all bibtex entries in BUFFER and save to `org-bibtex-entries'.
 650 Return the number of saved entries."
 651   (interactive "bBuffer: ")
 652   (let ((start-length (length org-bibtex-entries)))
 653     (with-current-buffer buffer
 654       (save-excursion
 655         (goto-char (point-max))
 656         (while (not (= (point) (point-min)))
 657           (backward-char 1)
 658           (org-bibtex-read)
 659           (bibtex-beginning-of-entry))))
 660     (let ((added (- (length org-bibtex-entries) start-length)))
 661       (message "Parsed %d entries" added)
 662       added)))
 663
 664 (defun org-bibtex-read-file (file)
 665   "Read FILE with `org-bibtex-read-buffer'."
 666   (interactive "fFile: ")
 667   (org-bibtex-read-buffer (find-file-noselect file 'nowarn 'rawfile)))
 668
 669 (defun org-bibtex-write ()
 670   "Insert a heading built from the first element of `org-bibtex-entries'."
 671   (interactive)
 672   (when (= (length org-bibtex-entries) 0)
 673     (error "No entries in `org-bibtex-entries'"))
 674   (let* ((entry (pop org-bibtex-entries))
 675          (org-special-properties nil) ; avoids errors with `org-entry-put'
 676          (val (lambda (field) (cdr (assoc field entry))))
 677          (togtag (lambda (tag) (org-toggle-tag tag 'on))))
 678     (org-insert-heading)
 679     (insert (funcall val :title))
 680     (org-bibtex-put "TITLE" (funcall val :title))
 681     (org-bibtex-put org-bibtex-type-property-name
 682                     (downcase (funcall val :type)))
 683     (dolist (pair entry)
 684       (case (car pair)
 685         (:title    nil)
 686         (:type     nil)
 687         (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 688         (:keywords (if org-bibtex-tags-are-keywords
 689                        (mapc
 690                         (lambda (kw)
 691                           (funcall
 692                            togtag
 693                            (replace-regexp-in-string
 694                             "[^[:alnum:]_@#%]" ""
 695                             (replace-regexp-in-string "[ \t]+" "_" kw))))
 696                         (split-string (cdr pair) ", *"))
 697                      (org-bibtex-put (car pair) (cdr pair))))
 698         (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 699     (mapc togtag org-bibtex-tags)))
 700
 701 (defun org-bibtex-yank ()
 702   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 703   (interactive)
 704   (let (entry)
 705     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 706     (if entry
 707         (org-bibtex-write)
 708       (error "Yanked text does not appear to contain a BibTeX entry"))))
 709
 710 (defun org-bibtex-import-from-file (file)
 711   "Read bibtex entries from FILE and insert as Org-mode headlines after point."
 712   (interactive "fFile: ")
 713   (dotimes (_ (org-bibtex-read-file file))
 714     (save-excursion (org-bibtex-write))
 715     (re-search-forward org-property-end-re)
 716     (open-line 1) (forward-char 1)))
 717
 718 (defun org-bibtex-export-to-kill-ring ()
 719   "Export current headline to kill ring as bibtex entry."
 720   (interactive)
 721   (let ((result (org-bibtex-headline)))
 722     (kill-new result) result))
 723
 724 (defun org-bibtex-search (string)
 725   "Search for bibliographical entries in agenda files.
 726 This function relies `org-search-view' to locate results."
 727   (interactive "sSearch string: ")
 728   (let ((org-agenda-overriding-header "Bib search results:")
 729         (org-agenda-search-view-always-boolean t))
 730     (org-search-view nil
 731                      (format "%s +{:%s%s:}"
 732                              string (or org-bibtex-prefix "")
 733                              org-bibtex-type-property-name))))
 734
 735 (provide 'org-bibtex)
 736
 737 ;;; org-bibtex.el ends here