lisp/babel/langs/ob-haskell.el

   1 ;;; ob-haskell.el --- org-babel functions for haskell evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 0.01
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating haskell source code.  This one will
  28 ;; be sort of tricky because haskell programs must be compiled before
  29 ;; they can be run, but haskell code can also be run through an
  30 ;; interactive interpreter.
  31 ;;
  32 ;; For now lets only allow evaluation using the haskell interpreter.
  33
  34 ;;; Requirements:
  35
  36 ;; - haskell-mode :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  37 ;;
  38 ;; - inf-haskell :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  39 ;;
  40 ;; - (optionally) lhs2tex :: http://people.cs.uu.nl/andres/lhs2tex/
  41
  42 ;;; Code:
  43 (require 'ob)
  44 (require 'haskell-mode)
  45 (require 'inf-haskell)
  46
  47 (add-to-list 'org-babel-tangle-lang-exts '("haskell" . "hs"))
  48
  49 (defvar org-babel-default-header-args:haskell '())
  50
  51 (defvar org-babel-haskell-lhs2tex-command "lhs2tex")
  52
  53 (defvar org-babel-haskell-eoe "\"org-babel-haskell-eoe\"")
  54
  55 (defun org-babel-expand-body:haskell (body params &optional processed-params)
  56   "Expand BODY according to PARAMS, return the expanded body."
  57   (let (vars (nth 1 (or processed-params (org-babel-process-params params))))
  58     (concat
  59      (mapconcat
  60       (lambda (pair) (format "let %s = %s;" (car pair) (cdr pair)))
  61       vars "\n") "\n" body "\n")))
  62
  63 (defun org-babel-execute:haskell (body params)
  64   "Execute a block of Haskell code with org-babel."
  65   (message "executing haskell source code block")
  66   (let* ((processed-params (org-babel-process-params params))
  67          (session (first processed-params))
  68          (vars (nth 1 processed-params))
  69          (result-type (nth 3 processed-params))
  70          (full-body (org-babel-expand-body:haskell body params processed-params))
  71          (session (org-babel-prep-session:haskell session params))
  72          (raw (org-babel-comint-with-output
  73                   (session org-babel-haskell-eoe t full-body)
  74                 (insert (org-babel-trim full-body))
  75                 (comint-send-input nil t)
  76                 (insert org-babel-haskell-eoe)
  77                 (comint-send-input nil t)))
  78          (results (mapcar
  79                    #'org-babel-haskell-read-string
  80                    (cdr (member org-babel-haskell-eoe
  81                                 (reverse (mapcar #'org-babel-trim raw)))))))
  82     (org-babel-reassemble-table
  83      (case result-type
  84        (output (mapconcat #'identity (reverse (cdr results)) "\n"))
  85        (value (org-babel-haskell-table-or-string (car results))))
  86      (org-babel-pick-name (nth 4 processed-params) (cdr (assoc :colnames params)))
  87      (org-babel-pick-name (nth 5 processed-params) (cdr (assoc :rownames params))))))
  88
  89 (defun org-babel-haskell-read-string (string)
  90   "Strip \\\"s from around a haskell string."
  91   (if (string-match "^\"\\([^\000]+\\)\"$" string)
  92       (match-string 1 string)
  93     string))
  94
  95 (defun org-babel-haskell-initiate-session (&optional session params)
  96   "If there is not a current inferior-process-buffer in SESSION
  97 then create one.  Return the initialized session."
  98   ;; TODO: make it possible to have multiple sessions
  99   (run-haskell) (current-buffer))
 100
 101 (defun org-babel-load-session:haskell (session body params)
 102   "Load BODY into SESSION."
 103   (save-window-excursion
 104     (let* ((buffer (org-babel-prep-session:haskell session params))
 105            (load-file (concat (make-temp-file "org-babel-haskell-load") ".hs")))
 106       (with-temp-buffer
 107         (insert body) (write-file load-file)
 108         (haskell-mode) (inferior-haskell-load-file))
 109       buffer)))
 110
 111 (defun org-babel-prep-session:haskell (session params)
 112   "Prepare SESSION according to the header arguments specified in PARAMS."
 113   (save-window-excursion
 114     (org-babel-haskell-initiate-session session)
 115     (let* ((vars (org-babel-ref-variables params))
 116            (var-lines (mapconcat ;; define any variables
 117                        (lambda (pair)
 118                          (format "%s=%s"
 119                                  (car pair)
 120                                  (org-babel-ruby-var-to-ruby (cdr pair))))
 121                        vars "\n"))
 122            (vars-file (concat (make-temp-file "org-babel-haskell-vars") ".hs")))
 123       (when vars
 124         (with-temp-buffer
 125           (insert var-lines) (write-file vars-file)
 126           (haskell-mode) (inferior-haskell-load-file)))
 127       (current-buffer))))
 128
 129 (defun org-babel-haskell-table-or-string (results)
 130   "If the results look like a table, then convert them into an
 131 Emacs-lisp table, otherwise return the results as a string."
 132   (org-babel-read
 133    (if (and (stringp results) (string-match "^\\[.+\\]$" results))
 134        (org-babel-read
 135         (concat "'"
 136                 (replace-regexp-in-string
 137                  "\\[" "(" (replace-regexp-in-string
 138                             "\\]" ")" (replace-regexp-in-string
 139                                        "," " " (replace-regexp-in-string
 140                                                 "'" "\"" results))))))
 141      results)))
 142
 143 (defun org-babel-haskell-export-to-lhs (&optional arg)
 144   "Export to a .lhs file with all haskell code blocks escaped
 145 appropriately.  When called with a prefix argument the resulting
 146 .lhs file will be exported to a .tex file.  This function will
 147 create two new files, base-name.lhs and base-name.tex where
 148 base-name is the name of the current org-mode file.
 149
 150 Note that all standard org-babel literate programming
 151 constructs (header arguments, no-web syntax etc...) are ignored."
 152   (interactive "P")
 153   (let* ((contents (buffer-string))
 154          (haskell-regexp
 155           (concat "^\\([ \t]*\\)#\\+begin_src[ \t]haskell*\\(.*\\)?[\r\n]"
 156                   "\\([^\000]*?\\)[\r\n][ \t]*#\\+end_src.*"))
 157          (base-name (file-name-sans-extension (buffer-file-name)))
 158          (tmp-file (make-temp-file "ob-haskell"))
 159          (tmp-org-file (concat tmp-file ".org"))
 160          (tmp-tex-file (concat tmp-file ".tex"))
 161          (lhs-file (concat base-name ".lhs"))
 162          (tex-file (concat base-name ".tex"))
 163          (command (concat org-babel-haskell-lhs2tex-command " " lhs-file " > " tex-file))
 164          (preserve-indentp org-src-preserve-indentation)
 165          indentation)
 166     ;; escape haskell source-code blocks
 167     (with-temp-file tmp-org-file
 168       (insert contents)
 169       (goto-char (point-min))
 170       (while (re-search-forward haskell-regexp nil t)
 171         (save-match-data (setq indentation (length (match-string 1))))
 172         (replace-match (save-match-data
 173                          (concat
 174                           "#+begin_latex\n\\begin{code}\n"
 175                           (if (or preserve-indentp
 176                                   (string-match "-i" (match-string 2)))
 177                               (match-string 3)
 178                             (org-remove-indentation (match-string 3)))
 179                           "\n\\end{code}\n#+end_latex\n"))
 180                        t t)
 181         (indent-code-rigidly (match-beginning 0) (match-end 0) indentation)))
 182     (save-excursion
 183       ;; export to latex w/org and save as .lhs
 184       (find-file tmp-org-file) (funcall 'org-export-as-latex nil)
 185       (kill-buffer)
 186       (delete-file tmp-org-file)
 187       (find-file tmp-tex-file)
 188       (goto-char (point-min)) (forward-line 2)
 189       (insert "%include polycode.fmt\n")
 190       ;; ensure all \begin/end{code} statements start at the first column
 191       (while (re-search-forward "^[ \t]+\\\\begin{code}[^\000]+\\\\end{code}" nil t)
 192         (replace-match (save-match-data (org-remove-indentation (match-string 0)))
 193                        t t))
 194       (setq contents (buffer-string))
 195       (save-buffer) (kill-buffer))
 196     (delete-file tmp-tex-file)
 197     ;; save org exported latex to a .lhs file
 198     (with-temp-file lhs-file (insert contents))
 199     (if (not arg)
 200         (find-file lhs-file)
 201       ;; process .lhs file with lhs2tex
 202       (message "running %s" command) (shell-command command) (find-file tex-file))))
 203
 204 (provide 'ob-haskell)
 205
 206 ;; arch-tag: b53f75f3-ba1a-4b05-82d9-a2a0d4e70804
 207
 208 ;;; ob-haskell.el ends here