lisp/ox-org.el

   1 ;;; ox-org.el --- Org Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2013-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'ox)
  28 (declare-function htmlize-buffer "htmlize" (&optional buffer))
  29
  30 (defgroup org-export-org nil
  31   "Options for exporting Org mode files to Org."
  32   :tag "Org Export Org"
  33   :group 'org-export
  34   :version "24.4"
  35   :package-version '(Org . "8.0"))
  36
  37 (define-obsolete-variable-alias
  38   'org-export-htmlized-org-css-url 'org-org-htmlized-css-url "24.4")
  39 (defcustom org-org-htmlized-css-url nil
  40   "URL pointing to the CSS defining colors for htmlized Emacs buffers.
  41 Normally when creating an htmlized version of an Org buffer,
  42 htmlize will create the CSS to define the font colors.  However,
  43 this does not work when converting in batch mode, and it also can
  44 look bad if different people with different fontification setup
  45 work on the same website.  When this variable is non-nil,
  46 creating an htmlized version of an Org buffer using
  47 `org-org-export-as-org' will include a link to this URL if the
  48 setting of `org-html-htmlize-output-type' is 'css."
  49   :group 'org-export-org
  50   :type '(choice
  51           (const :tag "Don't include external stylesheet link" nil)
  52           (string :tag "URL or local href")))
  53
  54 (org-export-define-backend 'org
  55   '((babel-call . org-org-identity)
  56     (bold . org-org-identity)
  57     (center-block . org-org-identity)
  58     (clock . org-org-identity)
  59     (code . org-org-identity)
  60     (comment . (lambda (&rest args) ""))
  61     (comment-block . (lambda (&rest args) ""))
  62     (diary-sexp . org-org-identity)
  63     (drawer . org-org-identity)
  64     (dynamic-block . org-org-identity)
  65     (entity . org-org-identity)
  66     (example-block . org-org-identity)
  67     (fixed-width . org-org-identity)
  68     (footnote-definition . org-org-identity)
  69     (footnote-reference . org-org-identity)
  70     (headline . org-org-headline)
  71     (horizontal-rule . org-org-identity)
  72     (inline-babel-call . org-org-identity)
  73     (inline-src-block . org-org-identity)
  74     (inlinetask . org-org-identity)
  75     (italic . org-org-identity)
  76     (item . org-org-identity)
  77     (keyword . org-org-keyword)
  78     (latex-environment . org-org-identity)
  79     (latex-fragment . org-org-identity)
  80     (line-break . org-org-identity)
  81     (link . org-org-identity)
  82     (node-property . org-org-identity)
  83     (template . org-org-template)
  84     (paragraph . org-org-identity)
  85     (plain-list . org-org-identity)
  86     (planning . org-org-identity)
  87     (property-drawer . org-org-identity)
  88     (quote-block . org-org-identity)
  89     (radio-target . org-org-identity)
  90     (section . org-org-identity)
  91     (special-block . org-org-identity)
  92     (src-block . org-org-identity)
  93     (statistics-cookie . org-org-identity)
  94     (strike-through . org-org-identity)
  95     (subscript . org-org-identity)
  96     (superscript . org-org-identity)
  97     (table . org-org-identity)
  98     (table-cell . org-org-identity)
  99     (table-row . org-org-identity)
 100     (target . org-org-identity)
 101     (timestamp . org-org-identity)
 102     (underline . org-org-identity)
 103     (verbatim . org-org-identity)
 104     (verse-block . org-org-identity))
 105   :menu-entry
 106   '(?O "Export to Org"
 107        ((?O "As Org buffer" org-org-export-as-org)
 108         (?o "As Org file" org-org-export-to-org)
 109         (?v "As Org file and open"
 110             (lambda (a s v b)
 111               (if a (org-org-export-to-org t s v b)
 112                 (org-open-file (org-org-export-to-org nil s v b))))))))
 113
 114 (defun org-org-identity (blob contents info)
 115   "Transcode BLOB element or object back into Org syntax.
 116 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 117   (let ((case-fold-search t))
 118     (replace-regexp-in-string
 119      "^[ \t]*#\\+ATTR_[-_A-Za-z0-9]+:\\(?: .*\\)?\n" ""
 120      (org-export-expand blob contents t))))
 121
 122 (defun org-org-headline (headline contents info)
 123   "Transcode HEADLINE element back into Org syntax.
 124 CONTENTS is its contents, as a string or nil.  INFO is ignored."
 125   (unless (plist-get info :with-todo-keywords)
 126     (org-element-put-property headline :todo-keyword nil))
 127   (unless (plist-get info :with-tags)
 128     (org-element-put-property headline :tags nil))
 129   (unless (plist-get info :with-priority)
 130     (org-element-put-property headline :priority nil))
 131   (org-element-put-property headline :level
 132                             (org-export-get-relative-level headline info))
 133   (org-element-headline-interpreter headline contents))
 134
 135 (defun org-org-keyword (keyword contents info)
 136   "Transcode KEYWORD element back into Org syntax.
 137 CONTENTS is nil.  INFO is ignored.  This function ignores
 138 keywords targeted at other export back-ends."
 139   (let ((key (org-element-property :key keyword)))
 140     (unless (or (member key
 141                         (mapcar
 142                          (lambda (block-cons)
 143                            (and (eq (cdr block-cons)
 144                                     'org-element-export-block-parser)
 145                                 (car block-cons)))
 146                          org-element-block-name-alist))
 147                 (member key
 148                         '("AUTHOR" "CREATOR" "DATE" "DESCRIPTION" "EMAIL"
 149                           "KEYWORDS" "TITLE")))
 150       (org-element-keyword-interpreter keyword nil))))
 151
 152 (defun org-org-template (contents info)
 153   "Return Org document template with document keywords.
 154 CONTENTS is the transcoded contents string.  INFO is a plist used
 155 as a communication channel."
 156   (concat
 157    (and (plist-get info :time-stamp-file)
 158         (format-time-string "# Created %Y-%m-%d %a %H:%M\n"))
 159    (format "#+TITLE: %s\n" (org-export-data (plist-get info :title) info))
 160    (and (plist-get info :with-date)
 161         (let ((date (org-export-data (org-export-get-date info) info)))
 162           (and (org-string-nw-p date)
 163                (format "#+DATE: %s\n" date))))
 164    (and (plist-get info :with-author)
 165         (let ((author (org-export-data (plist-get info :author) info)))
 166           (and (org-string-nw-p author)
 167                (format "#+AUTHOR: %s\n" author))))
 168    (and (plist-get info :with-email)
 169         (let ((email (org-export-data (plist-get info :email) info)))
 170           (and (org-string-nw-p email)
 171                (format "#+EMAIL: %s\n" email))))
 172    (and (eq (plist-get info :with-creator) t)
 173         (org-string-nw-p (plist-get info :creator))
 174         (format "#+CREATOR: %s\n" (plist-get info :creator)))
 175    (and (org-string-nw-p (plist-get info :keywords))
 176         (format "#+KEYWORDS: %s\n" (plist-get info :keywords)))
 177    (and (org-string-nw-p (plist-get info :description))
 178         (format "#+DESCRIPTION: %s\n" (plist-get info :description)))
 179    contents
 180    (and (eq (plist-get info :with-creator) 'comment)
 181         (org-string-nw-p (plist-get info :creator))
 182         (format "\n# %s\n" (plist-get info :creator)))))
 183
 184 ;;;###autoload
 185 (defun org-org-export-as-org
 186   (&optional async subtreep visible-only body-only ext-plist)
 187   "Export current buffer to an Org buffer.
 188
 189 If narrowing is active in the current buffer, only export its
 190 narrowed part.
 191
 192 If a region is active, export that region.
 193
 194 A non-nil optional argument ASYNC means the process should happen
 195 asynchronously.  The resulting buffer should be accessible
 196 through the `org-export-stack' interface.
 197
 198 When optional argument SUBTREEP is non-nil, export the sub-tree
 199 at point, extracting information from the headline properties
 200 first.
 201
 202 When optional argument VISIBLE-ONLY is non-nil, don't export
 203 contents of hidden elements.
 204
 205 When optional argument BODY-ONLY is non-nil, strip document
 206 keywords from output.
 207
 208 EXT-PLIST, when provided, is a property list with external
 209 parameters overriding Org default settings, but still inferior to
 210 file-local settings.
 211
 212 Export is done in a buffer named \"*Org ORG Export*\", which will
 213 be displayed when `org-export-show-temporary-export-buffer' is
 214 non-nil."
 215   (interactive)
 216   (org-export-to-buffer 'org "*Org ORG Export*"
 217     async subtreep visible-only body-only ext-plist (lambda () (org-mode))))
 218
 219 ;;;###autoload
 220 (defun org-org-export-to-org
 221   (&optional async subtreep visible-only body-only ext-plist)
 222   "Export current buffer to an org file.
 223
 224 If narrowing is active in the current buffer, only export its
 225 narrowed part.
 226
 227 If a region is active, export that region.
 228
 229 A non-nil optional argument ASYNC means the process should happen
 230 asynchronously.  The resulting file should be accessible through
 231 the `org-export-stack' interface.
 232
 233 When optional argument SUBTREEP is non-nil, export the sub-tree
 234 at point, extracting information from the headline properties
 235 first.
 236
 237 When optional argument VISIBLE-ONLY is non-nil, don't export
 238 contents of hidden elements.
 239
 240 When optional argument BODY-ONLY is non-nil, strip document
 241 keywords from output.
 242
 243 EXT-PLIST, when provided, is a property list with external
 244 parameters overriding Org default settings, but still inferior to
 245 file-local settings.
 246
 247 Return output file name."
 248   (interactive)
 249   (let ((outfile (org-export-output-file-name ".org" subtreep)))
 250     (org-export-to-file 'org outfile
 251       async subtreep visible-only body-only ext-plist)))
 252
 253 ;;;###autoload
 254 (defun org-org-publish-to-org (plist filename pub-dir)
 255   "Publish an org file to org.
 256
 257 FILENAME is the filename of the Org file to be published.  PLIST
 258 is the property list for the given project.  PUB-DIR is the
 259 publishing directory.
 260
 261 Return output file name."
 262   (org-publish-org-to 'org filename ".org" plist pub-dir)
 263   (when (plist-get plist :htmlized-source)
 264     (require 'htmlize)
 265     (require 'ox-html)
 266     (let* ((org-inhibit-startup t)
 267            (htmlize-output-type 'css)
 268            (html-ext (concat "." (or (plist-get plist :html-extension)
 269                                      org-html-extension "html")))
 270            (visitingp (find-buffer-visiting filename))
 271            (work-buffer (or visitingp (find-file filename)))
 272            newbuf)
 273       (font-lock-fontify-buffer)
 274       (show-all)
 275       (org-show-block-all)
 276       (setq newbuf (htmlize-buffer))
 277       (with-current-buffer newbuf
 278         (when org-org-htmlized-css-url
 279           (goto-char (point-min))
 280           (and (re-search-forward
 281                 "<style type=\"text/css\">[^\000]*?\n[ \t]*</style>.*" nil t)
 282                (replace-match
 283                 (format
 284                  "<link rel=\"stylesheet\" type=\"text/css\" href=\"%s\">"
 285                  org-org-htmlized-css-url) t t)))
 286         (write-file (concat pub-dir (file-name-nondirectory filename) html-ext)))
 287       (kill-buffer newbuf)
 288       (unless visitingp (kill-buffer work-buffer)))
 289     (set-buffer-modified-p nil)))
 290
 291
 292 (provide 'ox-org)
 293
 294 ;; Local variables:
 295 ;; generated-autoload-file: "org-loaddefs.el"
 296 ;; End:
 297
 298 ;;; ox-org.el ends here