lisp/org-inlinetask.el

   1 ;;; org-inlinetask.el --- Tasks independent of outline hierarchy
   2
   3 ;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.35trans
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  27 ;;
  28 ;;; Commentary:
  29 ;;
  30 ;; This module implements inline tasks in Org-mode.  Inline tasks are
  31 ;; tasks that have all the properties of normal outline nodes, including
  32 ;; the ability to store meta data like scheduling dates, TODO state, tags
  33 ;; and properties.  However, these nodes are treated specially by the
  34 ;; visibility cycling and export commands.
  35 ;;
  36 ;; Visibility cycling exempts these nodes from cycling. So whenever their
  37 ;; parent is opened, so are these tasks.  This will only work with
  38 ;; `org-cycle', so if you are also using other commands to show/hide
  39 ;; entries, you will occasionally find these tasks to behave like
  40 ;; all other outline nodes, seemingly splitting the text of the parent
  41 ;; into children.
  42 ;;
  43 ;; Export commands do not treat these nodes as part of the sectioning
  44 ;; structure, but as a special inline text that is either removed, or
  45 ;; formatted in some special way.
  46 ;;
  47 ;; Special fontification of inline tasks, so that they can be immediately
  48 ;; recognized.  From the stars of the headline, only the first and the
  49 ;; last two will be visible, the others will be hidden using the
  50 ;; `org-hide' face.
  51 ;;
  52 ;; An inline task is identified solely by a minimum outline level, given
  53 ;; by the variable `org-inlinetask-min-level', default 15.
  54 ;;
  55 ;; Inline tasks are normally assumed to contain at most a time planning
  56 ;; line (DEADLINE etc) after it, and then any number of drawers, for
  57 ;; example LOGBOOK of PROPERTIES.  No empty lines are allowed.
  58 ;; If you need to have normal text as part of an inline task, you
  59 ;; can do so by adding an "END" headline with the same number of stars,
  60 ;; for example
  61 ;;
  62 ;;    **************** TODO some small task
  63 ;;                     DEADLINE: <2009-03-30 Mon>
  64 ;;                     :PROPERTIES:
  65 ;;                       :SOMETHING: or other
  66 ;;                     :END:
  67 ;;                     And here is some extra text
  68 ;;    **************** END
  69 ;;
  70 ;; Also, if you want to use refiling and archiving for inline tasks,
  71 ;; The END line must be present to make things work properly.
  72 ;;
  73 ;; This package installs one new command:
  74 ;;
  75 ;; C-c C-x t      Insert a new inline task with END line
  76
  77
  78 ;;; Code
  79
  80 (require 'org)
  81
  82 (defgroup org-inlinetask nil
  83   "Options concerning inline tasks in Org mode."
  84   :tag "Org Inline Tasks"
  85   :group 'org-structure)
  86
  87 (defcustom org-inlinetask-min-level 15
  88   "Minimum level a headline must have before it is treated as an inline task.
  89 It is strongly recommended that you set `org-cycle-max-level' not at all,
  90 or to a number smaller than this one.  In fact, when `org-cycle-max-level' is
  91 not set, it will be assumed to be one less than the value of smaller than
  92 the value of this variable."
  93   :group 'org-inlinetask
  94   :type 'boolean)
  95
  96 (defcustom org-inlinetask-export t
  97   "Non-nil means export inline tasks.
  98 When nil, they will not be exported."
  99   :group 'org-inlinetask
 100   :type 'boolean)
 101
 102 (defvar org-odd-levels-only)
 103 (defvar org-keyword-time-regexp)
 104 (defvar org-drawer-regexp)
 105 (defvar org-complex-heading-regexp)
 106 (defvar org-property-end-re)
 107
 108 (defcustom org-inlinetask-defaut-state nil
 109   "Non-nil means make inline tasks have a TODO keyword initially.
 110 This should be the state `org-inlinetask-insert-task' should use by
 111 default, or nil of no state should be assigned."
 112   :group 'org-inlinetask
 113   :type '(choice
 114           (const :tag "No state" nil)
 115           (string :tag "Specific state")))
 116
 117 (defun org-inlinetask-insert-task (&optional no-state)
 118   "Insert an inline task.
 119 If prefix arg NO-STATE is set, irgnore `org-inlinetask-defaut-state'."
 120   (interactive "P")
 121   (or (bolp) (newline))
 122   (let ((indent org-inlinetask-min-level))
 123     (if org-odd-levels-only
 124         (setq indent (- (* 2 indent) 1)))
 125     (insert (make-string indent ?*)
 126             (if (or no-state (not org-inlinetask-defaut-state))
 127                 " \n"
 128               (concat " " org-inlinetask-defaut-state " \n"))
 129             (make-string indent ?*) " END\n"))
 130   (end-of-line -1))
 131 (define-key org-mode-map "\C-c\C-xt" 'org-inlinetask-insert-task)
 132
 133 (defvar htmlp)  ; dynamically scoped into the next function
 134 (defvar latexp) ; dynamically scoped into the next function
 135 (defun org-inlinetask-export-handler ()
 136   "Handle headlines with level larger or equal to `org-inlinetask-min-level'.
 137 Either remove headline and meta data, or do special formatting."
 138   (goto-char (point-min))
 139   (let* ((nstars (if org-odd-levels-only
 140                      (1- (* 2 (or org-inlinetask-min-level 200)))
 141                    (or org-inlinetask-min-level 200)))
 142          (re1 (format "^\\(\\*\\{%d,\\}\\) .*\n" nstars))
 143          (re2 (concat "^[ \t]*" org-keyword-time-regexp))
 144          headline beg end stars content indent)
 145     (while (re-search-forward re1 nil t)
 146       (setq headline (match-string 0)
 147             stars (match-string 1)
 148             content nil)
 149       (replace-match "")
 150       (while (looking-at re2)
 151         (delete-region (point) (1+ (point-at-eol))))
 152       (while (looking-at org-drawer-regexp)
 153         (setq beg (point))
 154         (if (re-search-forward org-property-end-re nil t)
 155             (delete-region beg (1+ (match-end 0)))))
 156       (setq beg (point))
 157       (when (and (re-search-forward "^\\(\\*+\\) " nil t)
 158                  (= (length (match-string 1)) (length stars))
 159                  (progn (goto-char (match-end 0))
 160                         (looking-at "END[ \t]*$")))
 161         (setq content (buffer-substring beg (1- (point-at-bol))))
 162         (delete-region beg (1+ (match-end 0))))
 163       (goto-char beg)
 164       (when org-inlinetask-export
 165         (when (string-match org-complex-heading-regexp headline)
 166           (setq headline (concat
 167                           (if (match-end 2)
 168                               (concat
 169                                (org-add-props
 170                                    (format
 171                                     "@<span class=\"%s %s\"> %s@</span>"
 172                                     (if (member (match-string 2 headline)
 173                                                 org-done-keywords)
 174                                         "done" "todo")
 175                                     (match-string 2 headline)
 176                                     (match-string 2 headline))
 177                                    nil 'org-protected t)
 178                                " ") "")
 179                           (match-string 4 headline)))
 180           (when content
 181             (if (not (string-match "\\S-" content))
 182                 (setq content nil)
 183               (if (string-match "[ \t\n]+\\'" content)
 184                   (setq content (substring content 0 (match-beginning 0))))
 185               (setq content (org-remove-indentation content))
 186               (if latexp (setq content (concat "\\quad \\\\\n" content)))))
 187           (insert (make-string (org-inlinetask-get-current-indentation) ?\ )
 188                   "- ")
 189           (setq indent (make-string (current-column) ?\ ))
 190           (insert headline " ::")
 191           (if content
 192               (insert (if htmlp " " (concat "\n" indent))
 193                       (mapconcat 'identity (org-split-string content "\n")
 194                                  (concat "\n" indent)) "\n")
 195             (insert "\n"))
 196           (insert indent)
 197           (backward-delete-char 2)
 198           (insert "THISISTHEINLINELISTTEMINATOR\n"))))))
 199
 200 (defun org-inlinetask-get-current-indentation ()
 201   "Get the indentation of the last non-while line above this one."
 202   (save-excursion
 203     (beginning-of-line 1)
 204     (skip-chars-backward " \t\n")
 205     (beginning-of-line 1)
 206     (or (org-at-item-p)
 207         (looking-at "[ \t]*"))
 208     (goto-char (match-end 0))
 209     (current-column)))
 210
 211 (defun org-inlinetask-fontify (limit)
 212   "Fontify the inline tasks."
 213   (let* ((nstars (if org-odd-levels-only
 214                      (1- (* 2 (or org-inlinetask-min-level 200)))
 215                    (or org-inlinetask-min-level 200)))
 216          (re (concat "^\\(\\*\\)\\(\\*\\{"
 217                     (format "%d" (- nstars 3))
 218                     ",\\}\\)\\(\\*\\* .*\\)")))
 219     (while (re-search-forward re limit t)
 220       (add-text-properties (match-beginning 1) (match-end 1)
 221                            '(face org-warning font-lock-fontified t))
 222       (add-text-properties (match-beginning 2) (match-end 2)
 223                            '(face org-hide font-lock-fontified t))
 224       (add-text-properties (match-beginning 3) (match-end 3)
 225                            '(face shadow font-lock-fontified t)))))
 226
 227 (defun org-inlinetask-remove-END-maybe ()
 228   "Remove an END line when present."
 229   (when (looking-at (format "\\([ \t]*\n\\)*\\*\\{%d,\\}[ \t]+END[ \t]*$"
 230                             org-inlinetask-min-level))
 231     (replace-match "")))
 232
 233 (defun org-inlinetask-remove-terminator ()
 234   (let (beg end)
 235     (save-excursion
 236       (goto-char (point-min))
 237       (while (re-search-forward "THISISTHEINLINELISTTEMINATOR\n" nil t)
 238         (setq beg (match-beginning 0) end (match-end 0))
 239         (save-excursion
 240           (beginning-of-line 1)
 241           (and (looking-at "<p\\(ara\\)?>THISISTHEINLINELISTTEMINATOR[ \t\n]*</p\\(ara\\)?>")
 242                (setq beg (point) end (match-end 0))))
 243         (delete-region beg end)))))
 244
 245 (eval-after-load "org-exp"
 246   '(add-hook 'org-export-preprocess-after-tree-selection-hook
 247              'org-inlinetask-export-handler))
 248 (eval-after-load "org"
 249   '(add-hook 'org-font-lock-hook 'org-inlinetask-fontify))
 250 (eval-after-load "org-html"
 251   '(add-hook 'org-export-html-final-hook 'org-inlinetask-remove-terminator))
 252 (eval-after-load "org-latex"
 253   '(add-hook 'org-export-latex-final-hook 'org-inlinetask-remove-terminator))
 254 (eval-after-load "org-ascii"
 255   '(add-hook 'org-export-ascii-final-hook 'org-inlinetask-remove-terminator))
 256 (eval-after-load "org-docbook"
 257   '(add-hook 'org-export-docbook-final-hook 'org-inlinetask-remove-terminator))
 258
 259 (provide 'org-inlinetask)
 260
 261 ;;; org-inlinetask.el ends here