lisp/ob-ref.el

   1 ;;; ob-ref.el --- org-babel functions for referencing external data
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for referencing data from the header arguments of a
  28 ;; org-babel block.  The syntax of such a reference should be
  29
  30 ;;   #+VAR: variable-name=file:resource-id
  31
  32 ;; - variable-name :: the name of the variable to which the value
  33 ;;                    will be assigned
  34
  35 ;; - file :: path to the file containing the resource, or omitted if
  36 ;;           resource is in the current file
  37
  38 ;; - resource-id :: the id or name of the resource
  39
  40 ;; So an example of a simple src block referencing table data in the
  41 ;; same file would be
  42
  43 ;;  #+TBLNAME: sandbox
  44 ;;  | 1 |         2 | 3 |
  45 ;;  | 4 | org-babel | 6 |
  46 ;;
  47 ;;  #+begin_src emacs-lisp :var table=sandbox
  48 ;;    (message table)
  49 ;;  #+end_src
  50
  51 ;;; Code:
  52 (require 'ob)
  53 (eval-when-compile
  54   (require 'cl))
  55
  56 (declare-function org-remove-if-not "org" (predicate seq))
  57 (declare-function org-at-table-p "org" (&optional table-type))
  58 (declare-function org-count "org" (CL-ITEM CL-SEQ))
  59 (declare-function org-in-item-p "org-list" ())
  60
  61 (defvar org-babel-ref-split-regexp
  62   "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  63
  64 (defun org-babel-ref-parse (assignment)
  65   "Parse a variable ASSIGNMENT in a header argument.
  66 If the right hand side of the assignment has a literal value
  67 return that value, otherwise interpret as a reference to an
  68 external resource and find it's value using
  69 `org-babel-ref-resolve'.  Return a list with two elements.  The
  70 first element of the list will be the name of the variable, and
  71 the second will be an emacs-lisp representation of the value of
  72 the variable."
  73   (when (string-match org-babel-ref-split-regexp assignment)
  74     (let ((var (match-string 1 assignment))
  75           (ref (match-string 2 assignment)))
  76       (cons (intern var)
  77             (let ((out (org-babel-read ref)))
  78               (if (equal out ref)
  79                   (if (string-match "^\".+\"$" ref)
  80                       (read ref)
  81                     (org-babel-ref-resolve ref))
  82                 out))))))
  83
  84 (defvar org-babel-library-of-babel)
  85 (defun org-babel-ref-resolve (ref)
  86   "Resolve the reference REF and return its value."
  87   (save-excursion
  88     (let ((case-fold-search t)
  89           type args new-refere new-header-args new-referent result
  90           lob-info split-file split-ref index index-row index-col)
  91       ;; if ref is indexed grab the indices -- beware nested indices
  92       (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
  93                  (let ((str (substring ref 0 (match-beginning 0))))
  94                    (= (org-count ?( str) (org-count ?) str))))
  95         (setq index (match-string 1 ref))
  96         (setq ref (substring ref 0 (match-beginning 0))))
  97       ;; assign any arguments to pass to source block
  98       (when (string-match
  99              "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)\(\\(.*\\)\)$" ref)
 100         (setq new-refere      (match-string 1 ref))
 101         (setq new-header-args (match-string 3 ref))
 102         (setq new-referent    (match-string 5 ref))
 103         (when (> (length new-refere) 0)
 104           (when (> (length new-referent) 0)
 105             (setq args (mapcar (lambda (ref) (cons :var ref))
 106                                (org-babel-ref-split-args new-referent))))
 107           (when (> (length new-header-args) 0)
 108             (setq args (append (org-babel-parse-header-arguments new-header-args)
 109                                args)))
 110           (setq ref new-refere)))
 111       (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
 112         (setq split-file (match-string 1 ref))
 113         (setq split-ref (match-string 2 ref))
 114         (find-file split-file) (setq ref split-ref))
 115       (save-restriction
 116         (widen)
 117         (goto-char (point-min))
 118         (if (let ((result_regexp (concat "^[ \t]*#\\+\\(TBLNAME\\|RESNAME"
 119                                          "\\|RESULTS\\):[ \t]*"
 120                                          (regexp-quote ref) "[ \t]*$"))
 121                   (regexp (concat org-babel-src-name-regexp
 122                                   (regexp-quote ref) "\\(\(.*\)\\)?" "[ \t]*$")))
 123               ;; goto ref in the current buffer
 124               (or (and (not args)
 125                        (or (re-search-forward result_regexp nil t)
 126                            (re-search-backward result_regexp nil t)))
 127                   (re-search-forward regexp nil t)
 128                   (re-search-backward regexp nil t)
 129                   ;; check the Library of Babel
 130                   (setq lob-info (cdr (assoc (intern ref)
 131                                              org-babel-library-of-babel)))))
 132             (unless lob-info (goto-char (match-beginning 0)))
 133           ;; ;; TODO: allow searching for names in other buffers
 134           ;; (setq id-loc (org-id-find ref 'marker)
 135           ;;       buffer (marker-buffer id-loc)
 136           ;;       loc (marker-position id-loc))
 137           ;; (move-marker id-loc nil)
 138           (error "reference '%s' not found in this buffer" ref))
 139         (if lob-info
 140             (setq type 'lob)
 141           (while (not (setq type (org-babel-ref-at-ref-p)))
 142             (forward-line 1)
 143             (beginning-of-line)
 144             (if (or (= (point) (point-min)) (= (point) (point-max)))
 145                 (error "reference not found"))))
 146         (let ((params (append args '((:results . "silent")))))
 147           (setq result
 148                 (case type
 149                   ('results-line (org-babel-read-result))
 150                   ('table (org-babel-read-table))
 151                   ('list (org-babel-read-list))
 152                   ('file (org-babel-read-link))
 153                   ('source-block (org-babel-execute-src-block nil nil params))
 154                   ('lob (org-babel-execute-src-block nil lob-info params)))))
 155         (if (symbolp result)
 156             (format "%S" result)
 157           (if (and index (listp result))
 158               (org-babel-ref-index-list index result)
 159             result))))))
 160
 161 (defun org-babel-ref-index-list (index lis)
 162   "Return the subset of LIS indexed by INDEX.
 163
 164 Indices are 0 based and negative indices count from the end of
 165 LIS, so 0 references the first element of LIS and -1 references
 166 the last.  If INDEX is separated by \",\"s then each \"portion\"
 167 is assumed to index into the next deepest nesting or dimension.
 168
 169 A valid \"portion\" can consist of either an integer index, two
 170 integers separated by a \":\" in which case the entire range is
 171 returned, or an empty string or \"*\" both of which are
 172 interpreted to mean the entire range and as such are equivalent
 173 to \"0:-1\"."
 174   (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
 175       (let ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\*\\)")
 176             (length (length lis))
 177             (portion (match-string 1 index))
 178             (remainder (substring index (match-end 0))))
 179         (flet ((wrap (num) (if (< num 0) (+ length num) num))
 180                (open (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls)))
 181           (open
 182            (mapcar
 183             (lambda (sub-lis) (org-babel-ref-index-list remainder sub-lis))
 184             (if (or (= 0 (length portion)) (string-match ind-re portion))
 185                 (mapcar
 186                  (lambda (n) (nth n lis))
 187                  (apply 'org-number-sequence
 188                         (if (and (> (length portion) 0) (match-string 2 portion))
 189                             (list
 190                              (wrap (string-to-number (match-string 2 portion)))
 191                              (wrap (string-to-number (match-string 3 portion))))
 192                           (list (wrap 0) (wrap -1)))))
 193               (list (nth (wrap (string-to-number portion)) lis)))))))
 194     lis))
 195
 196 (defun org-babel-ref-split-args (arg-string)
 197   "Split ARG-STRING into top-level arguments of balanced parenthesis."
 198   (let ((index 0) (depth 0) (buffer "") holder return)
 199     ;; crawl along string, splitting at any ","s which are on the top level
 200     (while (< index (length arg-string))
 201       (setq holder (substring arg-string index (+ 1 index)))
 202       (setq buffer (concat buffer holder))
 203       (setq index (+ 1 index))
 204       (cond
 205        ((string= holder ",")
 206         (when (= depth 0)
 207           (setq return (reverse (cons (substring buffer 0 -1) return)))
 208           (setq buffer "")))
 209        ((or (string= holder "(") (string= holder "[")) (setq depth (+ depth 1)))
 210        ((or (string= holder ")") (string= holder "]")) (setq depth (- depth 1)))))
 211     (mapcar #'org-babel-trim (reverse (cons buffer return)))))
 212
 213 (defvar org-bracket-link-regexp)
 214 (defun org-babel-ref-at-ref-p ()
 215   "Return the type of reference located at point.
 216 Return nil if none of the supported reference types are found.
 217 Supported reference types are tables and source blocks."
 218   (cond ((org-at-table-p) 'table)
 219         ((org-in-item-p) 'list)
 220         ((looking-at "^[ \t]*#\\+BEGIN_SRC") 'source-block)
 221         ((looking-at org-bracket-link-regexp) 'file)
 222         ((looking-at org-babel-result-regexp) 'results-line)))
 223
 224 (provide 'ob-ref)
 225
 226 ;; arch-tag: ace4a4f4-ea38-4dac-8fe6-6f52fcc43b6d
 227
 228 ;;; ob-ref.el ends here