lisp/org-clock.el

   1 ;;; org-clock.el --- The time clocking code for Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.31trans
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the time clocking code for Org-mode
  30
  31 (require 'org)
  32 (eval-when-compile
  33   (require 'cl)
  34   (require 'calendar))
  35
  36 (declare-function calendar-absolute-from-iso    "cal-iso"    (&optional date))
  37 (defvar org-time-stamp-formats)
  38
  39 (defgroup org-clock nil
  40   "Options concerning clocking working time in Org-mode."
  41   :tag "Org Clock"
  42   :group 'org-progress)
  43
  44 (defcustom org-clock-into-drawer org-log-into-drawer
  45   "Should clocking info be wrapped into a drawer?
  46 When t, clocking info will always be inserted into a :LOGBOOK: drawer.
  47 If necessary, the drawer will be created.
  48 When nil, the drawer will not be created, but used when present.
  49 When an integer and the number of clocking entries in an item
  50 reaches or exceeds this number, a drawer will be created.
  51 When a string, it names the drawer to be used.
  52
  53 The default for this variable is the value of `org-log-into-drawer',
  54 which see."
  55   :group 'org-todo
  56   :group 'org-clock
  57   :type '(choice
  58           (const :tag "Always" t)
  59           (const :tag "Only when drawer exists" nil)
  60           (integer :tag "When at least N clock entries")
  61           (const :tag "Into LOGBOOK drawer" "LOGBOOK")
  62           (string :tag "Into Drawer named...")))
  63
  64 (defcustom org-clock-out-when-done t
  65   "When non-nil, clock will be stopped when the clocked entry is marked DONE.
  66 A nil value means, clock will keep running until stopped explicitly with
  67 `C-c C-x C-o', or until the clock is started in a different item."
  68   :group 'org-clock
  69   :type 'boolean)
  70
  71 (defcustom org-clock-out-remove-zero-time-clocks nil
  72   "Non-nil means, remove the clock line when the resulting time is zero."
  73   :group 'org-clock
  74   :type 'boolean)
  75
  76 (defcustom org-clock-in-switch-to-state nil
  77   "Set task to a special todo state while clocking it.
  78 The value should be the state to which the entry should be
  79 switched. If the value is a function, it must take one
  80 parameter (the current TODO state of the item) and return the
  81 state to switch it to."
  82   :group 'org-clock
  83   :group 'org-todo
  84   :type '(choice
  85           (const :tag "Don't force a state" nil)
  86           (string :tag "State")
  87           (symbol :tag "Function")))
  88
  89 (defcustom org-clock-out-switch-to-state nil
  90   "Set task to a special todo state after clocking out.
  91 The value should be the state to which the entry should be
  92 switched. If the value is a function, it must take one
  93 parameter (the current TODO state of the item) and return the
  94 state to switch it to."
  95   :group 'org-clock
  96   :group 'org-todo
  97   :type '(choice
  98           (const :tag "Don't force a state" nil)
  99           (string :tag "State")
 100           (symbol :tag "Function")))
 101
 102 (defcustom org-clock-history-length 5
 103   "Number of clock tasks to remember in history."
 104   :group 'org-clock
 105   :type 'integer)
 106
 107 (defcustom org-clock-goto-may-find-recent-task t
 108   "Non-nil means, `org-clock-goto' can go to recent task if no active clock."
 109   :group 'org-clock
 110   :type 'boolean)
 111
 112 (defcustom org-clock-heading-function nil
 113   "When non-nil, should be a function to create `org-clock-heading'.
 114 This is the string shown in the mode line when a clock is running.
 115 The function is called with point at the beginning of the headline."
 116   :group 'org-clock
 117   :type 'function)
 118
 119 (defcustom org-clock-string-limit 0
 120   "Maximum length of clock strings in the modeline. 0 means no limit."
 121   :group 'org-clock
 122   :type 'integer)
 123
 124 (defcustom org-clock-in-resume nil
 125   "If non-nil, resume clock when clocking into task with open clock.
 126 When clocking into a task with a clock entry which has not been closed,
 127 the clock can be resumed from that point."
 128   :group 'org-clock
 129   :type 'boolean)
 130
 131 (defcustom org-clock-persist nil
 132   "When non-nil, save the running clock when emacs is closed.
 133 The clock is resumed when emacs restarts.
 134 When this is t, both the running clock, and the entire clock
 135 history are saved.  When this is the symbol `clock', only the
 136 running clock is saved.
 137
 138 When Emacs restarts with saved clock information, the file containing the
 139 running clock as well as all files mentioned in the clock history will
 140 be visited.
 141 All this depends on running `org-clock-persistence-insinuate' in .emacs"
 142   :group 'org-clock
 143   :type '(choice
 144           (const :tag "Just the running clock" clock)
 145           (const :tag "Clock and history" t)
 146           (const :tag "No persistence" nil)))
 147
 148 (defcustom org-clock-persist-file (convert-standard-filename
 149                                    "~/.emacs.d/org-clock-save.el")
 150   "File to save clock data to."
 151   :group 'org-clock
 152   :type 'string)
 153
 154 (defcustom org-clock-persist-query-save nil
 155   "When non-nil, ask before saving the current clock on exit."
 156   :group 'org-clock
 157   :type 'boolean)
 158
 159 (defcustom org-clock-persist-query-resume t
 160   "When non-nil, ask before resuming any stored clock during load."
 161   :group 'org-clock
 162   :type 'boolean)
 163
 164 (defcustom org-clock-sound nil
 165   "Sound that will used for notifications.
 166 Possible values:
 167
 168 nil        no sound played.
 169 t          standard Emacs beep
 170 file name  play this sound file.  If not possible, fall back to beep"
 171   :group 'org-clock
 172   :type '(choice
 173           (const :tag "No sound" nil)
 174           (const :tag "Standard beep" t)
 175           (file :tag "Play sound file")))
 176
 177 (defcustom org-clock-modeline-total 'auto
 178   "Default setting for the time included for the modeline clock.
 179 This can be overruled locally using the CLOCK_MODELINE_TOTAL property.
 180 Allowed values are:
 181
 182 current  Only the time in the current instance of the clock
 183 today    All time clocked inot this task today
 184 repeat   All time clocked into this task since last repeat
 185 all      All time ever recorded for this task
 186 auto     Automatically, either `all', or `repeat' for repeating tasks"
 187   :group 'org-clock
 188   :type '(choice
 189           (const :tag "Current clock" current)
 190           (const :tag "Today's task time" today)
 191           (const :tag "Since last repeat" repeat)
 192           (const :tag "All task time" all)
 193           (const :tag "Automatically, `all' or since `repeat'" auto)))
 194
 195 (defcustom org-show-notification-handler nil
 196   "Function or program to send notification with.
 197 The function or program will be called with the notification
 198 string as argument."
 199   :group 'org-clock
 200   :type '(choice
 201           (string :tag "Program")
 202           (function :tag "Function")))
 203
 204 (defcustom org-clock-clocktable-default-properties '(:maxlevel 2 :scope file)
 205   "Default properties for new clocktables."
 206   :group 'org-clock
 207   :type 'plist)
 208
 209
 210 (defvar org-clock-in-prepare-hook nil
 211   "Hook run when preparing the clock.
 212 This hook is run before anything happens to the task that
 213 you want to clock in.  For example, you can use this hook
 214 to add an effort property.")
 215 (defvar org-clock-in-hook nil
 216   "Hook run when starting the clock.")
 217 (defvar org-clock-out-hook nil
 218   "Hook run when stopping the current clock.")
 219
 220 (defvar org-clock-cancel-hook nil
 221   "Hook run when cancelling the current clock.")
 222 (defvar org-clock-goto-hook nil
 223   "Hook run when selecting the currently clocked-in entry.")
 224
 225 ;;; The clock for measuring work time.
 226
 227 (defvar org-mode-line-string "")
 228 (put 'org-mode-line-string 'risky-local-variable t)
 229
 230 (defvar org-clock-mode-line-timer nil)
 231 (defvar org-clock-heading "")
 232 (defvar org-clock-heading-for-remember "")
 233 (defvar org-clock-start-time "")
 234
 235 (defvar org-clock-effort ""
 236   "Effort estimate of the currently clocking task")
 237
 238 (defvar org-clock-total-time nil
 239   "Holds total time, spent previously on currently clocked item.
 240 This does not include the time in the currently running clock.")
 241
 242 (defvar org-clock-history nil
 243   "List of marker pointing to recent clocked tasks.")
 244
 245 (defvar org-clock-default-task (make-marker)
 246   "Marker pointing to the default task that should clock time.
 247 The clock can be made to switch to this task after clocking out
 248 of a different task.")
 249
 250 (defvar org-clock-interrupted-task (make-marker)
 251   "Marker pointing to the task that has been interrupted by the current clock.")
 252
 253 (defvar org-clock-mode-line-map (make-sparse-keymap))
 254 (define-key org-clock-mode-line-map [mode-line mouse-2] 'org-clock-goto)
 255 (define-key org-clock-mode-line-map [mode-line mouse-1] 'org-clock-menu)
 256
 257 (defun org-clock-menu ()
 258   (interactive)
 259   (popup-menu
 260    '("Clock"
 261      ["Clock out" org-clock-out t]
 262      ["Change effort estimate" org-clock-modify-effort-estimate t]
 263      ["Go to clock entry" org-clock-goto t]
 264      ["Switch task" (lambda () (interactive) (org-clock-in '(4))) :active t :keys "C-u C-c C-x C-i"])))
 265
 266 (defun org-clock-history-push (&optional pos buffer)
 267   "Push a marker to the clock history."
 268   (setq org-clock-history-length (max 1 (min 35 org-clock-history-length)))
 269   (let ((m (move-marker (make-marker) (or pos (point)) buffer)) n l)
 270     (while (setq n (member m org-clock-history))
 271       (move-marker (car n) nil))
 272     (setq org-clock-history
 273           (delq nil
 274                 (mapcar (lambda (x) (if (marker-buffer x) x nil))
 275                         org-clock-history)))
 276     (when (>= (setq l (length org-clock-history)) org-clock-history-length)
 277       (setq org-clock-history
 278             (nreverse
 279              (nthcdr (- l org-clock-history-length -1)
 280                      (nreverse org-clock-history)))))
 281     (push m org-clock-history)))
 282
 283 (defun org-clock-save-markers-for-cut-and-paste (beg end)
 284   "Save relative positions of markers in region."
 285   (org-check-and-save-marker org-clock-marker beg end)
 286   (org-check-and-save-marker org-clock-hd-marker beg end)
 287   (org-check-and-save-marker org-clock-default-task beg end)
 288   (org-check-and-save-marker org-clock-interrupted-task beg end)
 289   (mapc (lambda (m) (org-check-and-save-marker m beg end))
 290         org-clock-history))
 291
 292 (defun org-clock-select-task (&optional prompt)
 293   "Select a task that recently was associated with clocking."
 294   (interactive)
 295   (let (sel-list rpl (i 0) s)
 296     (save-window-excursion
 297       (org-switch-to-buffer-other-window
 298        (get-buffer-create "*Clock Task Select*"))
 299       (erase-buffer)
 300       (when (marker-buffer org-clock-default-task)
 301         (insert (org-add-props "Default Task\n" nil 'face 'bold))
 302         (setq s (org-clock-insert-selection-line ?d org-clock-default-task))
 303         (push s sel-list))
 304       (when (marker-buffer org-clock-interrupted-task)
 305         (insert (org-add-props "The task interrupted by starting the last one\n" nil 'face 'bold))
 306         (setq s (org-clock-insert-selection-line ?i org-clock-interrupted-task))
 307         (push s sel-list))
 308       (when (marker-buffer org-clock-marker)
 309         (insert (org-add-props "Current Clocking Task\n" nil 'face 'bold))
 310         (setq s (org-clock-insert-selection-line ?c org-clock-marker))
 311         (push s sel-list))
 312       (insert (org-add-props "Recent Tasks\n" nil 'face 'bold))
 313       (mapc
 314        (lambda (m)
 315          (when (marker-buffer m)
 316            (setq i (1+ i)
 317                  s (org-clock-insert-selection-line
 318                     (if (< i 10)
 319                         (+ i ?0)
 320                       (+ i (- ?A 10))) m))
 321            (push s sel-list)))
 322        org-clock-history)
 323       (org-fit-window-to-buffer)
 324       (message (or prompt "Select task for clocking:"))
 325       (setq rpl (read-char-exclusive))
 326       (cond
 327        ((eq rpl ?q) nil)
 328        ((eq rpl ?x) nil)
 329        ((assoc rpl sel-list) (cdr (assoc rpl sel-list)))
 330        (t (error "Invalid task choice %c" rpl))))))
 331
 332 (defun org-clock-insert-selection-line (i marker)
 333   "Insert a line for the clock selection menu.
 334 And return a cons cell with the selection character integer and the marker
 335 pointing to it."
 336   (when (marker-buffer marker)
 337     (let (file cat task heading prefix)
 338       (with-current-buffer (org-base-buffer (marker-buffer marker))
 339         (save-excursion
 340           (save-restriction
 341             (widen)
 342             (goto-char marker)
 343             (setq file (buffer-file-name (marker-buffer marker))
 344                   cat (or (org-get-category)
 345                           (progn (org-refresh-category-properties)
 346                                  (org-get-category)))
 347                   heading (org-get-heading 'notags)
 348                   prefix (save-excursion
 349                            (org-back-to-heading t)
 350                            (looking-at "\\*+ ")
 351                            (match-string 0))
 352                   task (substring
 353                         (org-fontify-like-in-org-mode
 354                          (concat prefix heading)
 355                          org-odd-levels-only)
 356                         (length prefix))))))
 357       (when (and cat task)
 358         (insert (format "[%c] %-15s %s\n" i cat task))
 359         (cons i marker)))))
 360
 361 (defun org-clock-get-clock-string ()
 362   "Form a clock-string, that will be show in the mode line.
 363 If an effort estimate was defined for current item, use
 364 01:30/01:50 format (clocked/estimated).
 365 If not, show simply the clocked time like 01:50."
 366   (let* ((clocked-time (org-clock-get-clocked-time))
 367          (h (floor clocked-time 60))
 368          (m (- clocked-time (* 60 h))))
 369     (if (and org-clock-effort)
 370         (let* ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 371                (effort-h (floor effort-in-minutes 60))
 372                (effort-m (- effort-in-minutes (* effort-h 60))))
 373           (format (concat "-[" org-time-clocksum-format "/" org-time-clocksum-format " (%s)]")
 374                   h m effort-h effort-m  org-clock-heading))
 375       (format (concat "-[" org-time-clocksum-format " (%s)]")
 376               h m org-clock-heading))))
 377
 378 (defun org-clock-update-mode-line ()
 379   (setq org-mode-line-string
 380         (org-propertize
 381          (let ((clock-string (org-clock-get-clock-string))
 382                (help-text "Org-mode clock is running.\nmouse-1 shows a menu\nmouse-2 will jump to task"))
 383            (if (and (> org-clock-string-limit 0)
 384                     (> (length clock-string) org-clock-string-limit))
 385                (org-propertize (substring clock-string 0 org-clock-string-limit)
 386                                'help-echo (concat help-text ": " org-clock-heading))
 387              (org-propertize clock-string 'help-echo help-text)))
 388          'local-map org-clock-mode-line-map
 389          'mouse-face (if (featurep 'xemacs) 'highlight 'mode-line-highlight)
 390          'face 'org-mode-line-clock))
 391   (if org-clock-effort (org-clock-notify-once-if-expired))
 392   (force-mode-line-update))
 393
 394 (defun org-clock-get-clocked-time ()
 395   "Get the clocked time for the current item in minutes.
 396 The time returned includes the the time spent on this task in
 397 previous clocking intervals."
 398   (let ((currently-clocked-time
 399          (floor (- (org-float-time)
 400                    (org-float-time org-clock-start-time)) 60)))
 401     (+ currently-clocked-time (or org-clock-total-time 0))))
 402
 403 (defun org-clock-modify-effort-estimate (&optional value)
 404  "Add to or set the effort estimate of the item currently being clocked.
 405 VALUE can be a number of minutes, or a string with forat hh:mm or mm.
 406 WHen the strig starts with a + or a - sign, the current value of the effort
 407 property will be changed by that amount.
 408 This will update the \"Effort\" property of currently clocked item, and
 409 the mode line."
 410  (interactive)
 411  (when (org-clock-is-active)
 412    (let ((current org-clock-effort) sign)
 413      (unless value
 414        ;; Prompt user for a value or a change
 415        (setq value
 416              (read-string
 417               (format "Set effort (hh:mm or mm%s): "
 418                       (if current
 419                           (format ", prefix + to add to %s" org-clock-effort)
 420                         "")))))
 421      (when (stringp value)
 422        ;; A string.  See if it is a delta
 423        (setq sign (string-to-char value))
 424        (if (member sign '(?- ?+))
 425            (setq current (org-hh:mm-string-to-minutes (substring current 1)))
 426          (setq current 0))
 427        (setq value (org-hh:mm-string-to-minutes value))
 428        (if (equal ?- sign)
 429            (setq value (- current value))
 430          (if (equal ?+ sign) (setq value (+ current value)))))
 431      (setq value (max 0 value)
 432            org-clock-effort (org-minutes-to-hh:mm-string value))
 433      (org-entry-put org-clock-marker "Effort" org-clock-effort)
 434      (org-clock-update-mode-line)
 435      (message "Effort is now %s" org-clock-effort))))
 436
 437 (defvar org-clock-notification-was-shown nil
 438   "Shows if we have shown notification already.")
 439
 440 (defun org-clock-notify-once-if-expired ()
 441   "Show notification if we spent more time than we estimated before.
 442 Notification is shown only once."
 443   (when (marker-buffer org-clock-marker)
 444     (let ((effort-in-minutes (org-hh:mm-string-to-minutes org-clock-effort))
 445           (clocked-time (org-clock-get-clocked-time)))
 446       (if (>= clocked-time effort-in-minutes)
 447           (unless org-clock-notification-was-shown
 448             (setq org-clock-notification-was-shown t)
 449             (org-notify
 450              (format "Task '%s' should be finished by now. (%s)"
 451                      org-clock-heading org-clock-effort) t))
 452         (setq org-clock-notification-was-shown nil)))))
 453
 454 (defun org-notify (notification &optional play-sound)
 455   "Send a NOTIFICATION and maybe PLAY-SOUND."
 456   (org-show-notification notification)
 457   (if play-sound (org-clock-play-sound)))
 458
 459 (defun org-show-notification (notification)
 460   "Show notification.
 461 Use `org-show-notification-handler' if defined,
 462 use libnotify if available, or fall back on a message."
 463   (cond ((functionp org-show-notification-handler)
 464          (funcall org-show-notification-handler notification))
 465         ((stringp org-show-notification-handler)
 466          (start-process "emacs-timer-notification" nil
 467                         org-show-notification-handler notification))
 468         ((org-program-exists "notify-send")
 469          (start-process "emacs-timer-notification" nil
 470                         "notify-send" notification))
 471         ;; Maybe the handler will send a message, so only use message as
 472         ;; a fall back option
 473         (t (message notification))))
 474
 475 (defun org-clock-play-sound ()
 476   "Play sound as configured by `org-clock-sound'.
 477 Use alsa's aplay tool if available."
 478   (cond
 479    ((not org-clock-sound))
 480    ((eq org-clock-sound t) (beep t) (beep t))
 481    ((stringp org-clock-sound)
 482     (if (file-exists-p org-clock-sound)
 483         (if (org-program-exists "aplay")
 484             (start-process "org-clock-play-notification" nil
 485                            "aplay" org-clock-sound)
 486           (condition-case nil
 487               (play-sound-file org-clock-sound)
 488             (error (beep t) (beep t))))))))
 489
 490 (defun org-program-exists (program-name)
 491   "Checks whenever we can locate program and launch it."
 492   (if (eq system-type 'gnu/linux)
 493       (= 0 (call-process "which" nil nil nil program-name))))
 494
 495 (defvar org-clock-mode-line-entry nil
 496   "Information for the modeline about the running clock.")
 497
 498 (defun org-clock-in (&optional select)
 499   "Start the clock on the current item.
 500 If necessary, clock-out of the currently active clock.
 501 With prefix arg SELECT, offer a list of recently clocked tasks to
 502 clock into.  When SELECT is `C-u C-u', clock into the current task and mark
 503 is as the default task, a special task that will always be offered in
 504 the clocking selection, associated with the letter `d'."
 505   (interactive "P")
 506   (setq org-clock-notification-was-shown nil)
 507   (catch 'abort
 508     (let ((interrupting (marker-buffer org-clock-marker))
 509           ts selected-task target-pos (msg-extra ""))
 510       (when (equal select '(4))
 511         (setq selected-task (org-clock-select-task "Clock-in on task: "))
 512         (if selected-task
 513             (setq selected-task (copy-marker selected-task))
 514           (error "Abort")))
 515       (when interrupting
 516         ;; We are interrupting the clocking of a different task.
 517         ;; Save a marker to this task, so that we can go back.
 518         (move-marker org-clock-interrupted-task
 519                      (marker-position org-clock-marker)
 520                      (marker-buffer org-clock-marker))
 521         (org-clock-out t))
 522
 523       (when (equal select '(16))
 524         ;; Mark as default clocking task
 525         (org-clock-mark-default-task))
 526
 527       (setq target-pos (point))  ;; we want to clock in at this location
 528       (run-hooks 'org-clock-in-prepare-hook)
 529       (save-excursion
 530         (when (and selected-task (marker-buffer selected-task))
 531           ;; There is a selected task, move to the correct buffer
 532           ;; and set the new target position.
 533           (set-buffer (org-base-buffer (marker-buffer selected-task)))
 534           (setq target-pos (marker-position selected-task))
 535           (move-marker selected-task nil))
 536         (save-excursion
 537           (save-restriction
 538             (widen)
 539             (goto-char target-pos)
 540             (org-back-to-heading t)
 541             (or interrupting (move-marker org-clock-interrupted-task nil))
 542             (org-clock-history-push)
 543             (cond ((functionp org-clock-in-switch-to-state)
 544                    (looking-at org-complex-heading-regexp)
 545                    (let ((newstate (funcall org-clock-in-switch-to-state
 546                                             (match-string 2))))
 547                      (if newstate (org-todo newstate))))
 548                   ((and org-clock-in-switch-to-state
 549                         (not (looking-at (concat outline-regexp "[ \t]*"
 550                                                  org-clock-in-switch-to-state
 551                                                  "\\>"))))
 552                    (org-todo org-clock-in-switch-to-state)))
 553             (setq org-clock-heading-for-remember
 554                   (and (looking-at org-complex-heading-regexp)
 555                        (match-end 4)
 556                        (org-trim (buffer-substring (match-end 1)
 557                                                    (match-end 4)))))
 558             (setq org-clock-heading
 559                   (cond ((and org-clock-heading-function
 560                               (functionp org-clock-heading-function))
 561                          (funcall org-clock-heading-function))
 562                         ((looking-at org-complex-heading-regexp)
 563                          (match-string 4))
 564                         (t "???")))
 565             (setq org-clock-heading (org-propertize org-clock-heading
 566                                                     'face nil))
 567             (org-clock-find-position org-clock-in-resume)
 568             (cond
 569              ((and org-clock-in-resume
 570                    (looking-at
 571                     (concat "^[ \t]* " org-clock-string
 572                             " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 573                             " +\\sw+\.? +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")))
 574               (message "Matched %s" (match-string 1))
 575               (setq ts (concat "[" (match-string 1) "]"))
 576               (goto-char (match-end 1))
 577               (setq org-clock-start-time
 578                     (apply 'encode-time
 579                            (org-parse-time-string (match-string 1))))
 580               (setq org-clock-effort (org-get-effort))
 581               (setq org-clock-total-time (org-clock-sum-current-item
 582                                           (org-clock-get-sum-start))))
 583              ((eq org-clock-in-resume 'auto-restart)
 584               ;; called from org-clock-load during startup,
 585               ;; do not interrupt, but warn!
 586               (message "Cannot restart clock because task does not contain unfinished clock")
 587               (ding)
 588               (sit-for 2)
 589               (throw 'abort nil))
 590              (t
 591               (insert-before-markers "\n")
 592               (backward-char 1)
 593               (org-indent-line-function)
 594               (when (and (save-excursion
 595                            (end-of-line 0)
 596                            (org-in-item-p)))
 597                 (beginning-of-line 1)
 598                 (org-indent-line-to (- (org-get-indentation) 2)))
 599               (insert org-clock-string " ")
 600               (setq org-clock-effort (org-get-effort))
 601               (setq org-clock-total-time (org-clock-sum-current-item
 602                                           (org-clock-get-sum-start)))
 603               (setq org-clock-start-time (current-time))
 604               (setq ts (org-insert-time-stamp org-clock-start-time
 605                                               'with-hm 'inactive))))
 606             (move-marker org-clock-marker (point) (buffer-base-buffer))
 607             (move-marker org-clock-hd-marker
 608                          (save-excursion (org-back-to-heading t) (point))
 609                          (buffer-base-buffer))
 610             (or global-mode-string (setq global-mode-string '("")))
 611             (or (memq 'org-mode-line-string global-mode-string)
 612                 (setq global-mode-string
 613                       (append global-mode-string '(org-mode-line-string))))
 614             (org-clock-update-mode-line)
 615             (setq org-clock-mode-line-timer
 616                   (run-with-timer 60 60 'org-clock-update-mode-line))
 617             (message "Clock starts at %s - %s" ts msg-extra)
 618             (run-hooks 'org-clock-in-hook)))))))
 619
 620 (defun org-clock-mark-default-task ()
 621   "Mark current task as default task."
 622   (interactive)
 623   (save-excursion
 624     (org-back-to-heading t)
 625     (move-marker org-clock-default-task (point))))
 626
 627 (defvar msg-extra)
 628 (defun org-clock-get-sum-start ()
 629   "Return the time from which clock times should be counted.
 630 This is for the currently running clock as it is displayed
 631 in the mode line.  This function looks at the properties
 632 LAST_REPEAT and in particular CLOCK_MODELINE_TOTAL and the
 633 corresponding variable `org-clock-modeline-total' and then
 634 decides which time to use."
 635   (let ((cmt (or (org-entry-get nil "CLOCK_MODELINE_TOTAL")
 636                  (symbol-name org-clock-modeline-total)))
 637         (lr (org-entry-get nil "LAST_REPEAT")))
 638     (cond
 639      ((equal cmt "current")
 640       (setq msg-extra "showing time in current clock instance")
 641       (current-time))
 642      ((equal cmt "today")
 643       (setq msg-extra "showing today's task time.")
 644       (let* ((dt (decode-time (current-time))))
 645         (setq dt (append (list 0 0 0) (nthcdr 3 dt)))
 646         (if org-extend-today-until
 647             (setf (nth 2 dt) org-extend-today-until))
 648         (apply 'encode-time dt)))
 649      ((or (equal cmt "all")
 650           (and (or (not cmt) (equal cmt "auto"))
 651                (not lr)))
 652       (setq msg-extra "showing entire task time.")
 653       nil)
 654      ((or (equal cmt "repeat")
 655           (and (or (not cmt) (equal cmt "auto"))
 656                lr))
 657       (setq msg-extra "showing task time since last repeat.")
 658       (if (not lr)
 659           nil
 660         (org-time-string-to-time lr)))
 661      (t nil))))
 662
 663 (defun org-clock-find-position (find-unclosed)
 664   "Find the location where the next clock line should be inserted.
 665 When FIND-UNCLOSED is non-nil, first check if there is an unclosed clock
 666 line and position cursor in that line."
 667   (org-back-to-heading t)
 668   (catch 'exit
 669     (let ((beg (save-excursion
 670                  (beginning-of-line 2)
 671                  (or (bolp) (newline))
 672                  (point)))
 673           (end (progn (outline-next-heading) (point)))
 674           (re (concat "^[ \t]*" org-clock-string))
 675           (cnt 0)
 676           (drawer (if (stringp org-clock-into-drawer)
 677                       org-clock-into-drawer "LOGBOOK"))
 678           first last ind-last)
 679       (goto-char beg)
 680       (when (and find-unclosed
 681                  (re-search-forward
 682                   (concat "^[ \t]* " org-clock-string
 683                           " \\[\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}"
 684                           " +\\sw+ +[012][0-9]:[0-5][0-9]\\)\\][ \t]*$")
 685                   end t))
 686         (beginning-of-line 1)
 687         (throw 'exit t))
 688       (when (eobp) (newline) (setq end (max (point) end)))
 689       (when (re-search-forward (concat "^[ \t]*:" drawer ":") end t)
 690         ;; we seem to have a CLOCK drawer, so go there.
 691         (beginning-of-line 2)
 692         (or org-log-states-order-reversed
 693             (and (re-search-forward org-property-end-re nil t)
 694                  (goto-char (match-beginning 0))))
 695         (throw 'exit t))
 696       ;; Lets count the CLOCK lines
 697       (goto-char beg)
 698       (while (re-search-forward re end t)
 699         (setq first (or first (match-beginning 0))
 700               last (match-beginning 0)
 701               cnt (1+ cnt)))
 702       (when (and (integerp org-clock-into-drawer)
 703                  last
 704                  (>= (1+ cnt) org-clock-into-drawer))
 705         ;; Wrap current entries into a new drawer
 706         (goto-char last)
 707         (setq ind-last (org-get-indentation))
 708         (beginning-of-line 2)
 709         (if (and (>= (org-get-indentation) ind-last)
 710                  (org-at-item-p))
 711             (org-end-of-item))
 712         (insert ":END:\n")
 713         (beginning-of-line 0)
 714         (org-indent-line-to ind-last)
 715         (goto-char first)
 716         (insert ":" drawer ":\n")
 717         (beginning-of-line 0)
 718         (org-indent-line-function)
 719         (org-flag-drawer t)
 720         (beginning-of-line 2)
 721         (or org-log-states-order-reversed
 722             (and (re-search-forward org-property-end-re nil t)
 723                  (goto-char (match-beginning 0))))
 724         (throw 'exit nil))
 725
 726       (goto-char beg)
 727       (while (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 728                   (not (equal (match-string 1) org-clock-string)))
 729         ;; Planning info, skip to after it
 730         (beginning-of-line 2)
 731         (or (bolp) (newline)))
 732       (when (or (eq org-clock-into-drawer t)
 733                 (stringp org-clock-into-drawer)
 734                 (and (integerp org-clock-into-drawer)
 735                      (< org-clock-into-drawer 2)))
 736         (insert ":" drawer ":\n:END:\n")
 737         (beginning-of-line -1)
 738         (org-indent-line-function)
 739         (org-flag-drawer t)
 740         (beginning-of-line 2)
 741         (org-indent-line-function)
 742         (beginning-of-line)
 743         (or org-log-states-order-reversed
 744             (and (re-search-forward org-property-end-re nil t)
 745                  (goto-char (match-beginning 0))))))))
 746
 747 (defun org-clock-out (&optional fail-quietly)
 748   "Stop the currently running clock.
 749 If there is no running clock, throw an error, unless FAIL-QUIETLY is set."
 750   (interactive)
 751   (catch 'exit
 752     (if (not (marker-buffer org-clock-marker))
 753         (if fail-quietly (throw 'exit t) (error "No active clock")))
 754     (let (ts te s h m remove)
 755       (save-excursion
 756         (set-buffer (marker-buffer org-clock-marker))
 757         (save-restriction
 758           (widen)
 759           (goto-char org-clock-marker)
 760           (beginning-of-line 1)
 761           (if (and (looking-at (concat "[ \t]*" org-keyword-time-regexp))
 762                    (equal (match-string 1) org-clock-string))
 763               (setq ts (match-string 2))
 764             (if fail-quietly (throw 'exit nil) (error "Clock start time is gone")))
 765           (goto-char (match-end 0))
 766           (delete-region (point) (point-at-eol))
 767           (insert "--")
 768           (setq te (org-insert-time-stamp (current-time) 'with-hm 'inactive))
 769           (setq s (- (org-float-time (apply 'encode-time (org-parse-time-string te)))
 770                      (org-float-time (apply 'encode-time (org-parse-time-string ts))))
 771                 h (floor (/ s 3600))
 772                 s (- s (* 3600 h))
 773                 m (floor (/ s 60))
 774                 s (- s (* 60 s)))
 775           (insert " => " (format "%2d:%02d" h m))
 776           (when (setq remove (and org-clock-out-remove-zero-time-clocks
 777                                   (= (+ h m) 0)))
 778             (beginning-of-line 1)
 779             (delete-region (point) (point-at-eol))
 780             (and (looking-at "\n") (> (point-max) (1+ (point)))
 781                  (delete-char 1)))
 782           (move-marker org-clock-marker nil)
 783           (move-marker org-clock-hd-marker nil)
 784           (when org-log-note-clock-out
 785             (org-add-log-setup 'clock-out nil nil nil nil
 786                                (concat "# Task: " (org-get-heading t) "\n\n")))
 787           (when org-clock-mode-line-timer
 788             (cancel-timer org-clock-mode-line-timer)
 789             (setq org-clock-mode-line-timer nil))
 790           (setq global-mode-string
 791                 (delq 'org-mode-line-string global-mode-string))
 792           (when org-clock-out-switch-to-state
 793             (save-excursion
 794               (org-back-to-heading t)
 795               (let ((org-inhibit-logging t))
 796                 (cond
 797                  ((functionp org-clock-out-switch-to-state)
 798                   (looking-at org-complex-heading-regexp)
 799                   (let ((newstate (funcall org-clock-out-switch-to-state
 800                                            (match-string 2))))
 801                     (if newstate (org-todo newstate))))
 802                  ((and org-clock-out-switch-to-state
 803                        (not (looking-at (concat outline-regexp "[ \t]*"
 804                                                 org-clock-out-switch-to-state
 805                                                 "\\>"))))
 806                   (org-todo org-clock-out-switch-to-state))))))
 807           (force-mode-line-update)
 808           (message (concat "Clock stopped at %s after HH:MM = " org-time-clocksum-format "%s") te h m
 809                    (if remove " => LINE REMOVED" ""))
 810           (run-hooks 'org-clock-out-hook))))))
 811
 812 (defun org-clock-cancel ()
 813   "Cancel the running clock be removing the start timestamp."
 814   (interactive)
 815   (if (not (marker-buffer org-clock-marker))
 816       (error "No active clock"))
 817   (save-excursion
 818     (set-buffer (marker-buffer org-clock-marker))
 819     (goto-char org-clock-marker)
 820     (delete-region (1- (point-at-bol)) (point-at-eol)))
 821   (move-marker org-clock-marker nil)
 822   (move-marker org-clock-hd-marker nil)
 823   (setq global-mode-string
 824         (delq 'org-mode-line-string global-mode-string))
 825   (force-mode-line-update)
 826   (message "Clock canceled")
 827   (run-hooks 'org-clock-cancel-hook))
 828
 829 (defun org-clock-goto (&optional select)
 830   "Go to the currently clocked-in entry, or to the most recently clocked one.
 831 With prefix arg SELECT, offer recently clocked tasks for selection."
 832   (interactive "@P")
 833   (let* ((recent nil)
 834          (m (cond
 835              (select
 836               (or (org-clock-select-task "Select task to go to: ")
 837                   (error "No task selected")))
 838              ((marker-buffer org-clock-marker) org-clock-marker)
 839              ((and org-clock-goto-may-find-recent-task
 840                    (car org-clock-history)
 841                    (marker-buffer (car org-clock-history)))
 842               (setq recent t)
 843               (car org-clock-history))
 844              (t (error "No active or recent clock task")))))
 845     (switch-to-buffer (marker-buffer m))
 846     (if (or (< m (point-min)) (> m (point-max))) (widen))
 847     (goto-char m)
 848     (org-show-entry)
 849     (org-back-to-heading t)
 850     (org-cycle-hide-drawers 'children)
 851     (recenter)
 852     (if recent
 853         (message "No running clock, this is the most recently clocked task"))
 854     (run-hooks 'org-clock-goto-hook)))
 855
 856 (defvar org-clock-file-total-minutes nil
 857   "Holds the file total time in minutes, after a call to `org-clock-sum'.")
 858 (make-variable-buffer-local 'org-clock-file-total-minutes)
 859
 860 (defun org-clock-sum (&optional tstart tend)
 861   "Sum the times for each subtree.
 862 Puts the resulting times in minutes as a text property on each headline.
 863 TSTART and TEND can mark a time range to be considered."
 864   (interactive)
 865   (let* ((bmp (buffer-modified-p))
 866          (re (concat "^\\(\\*+\\)[ \t]\\|^[ \t]*"
 867                      org-clock-string
 868                      "[ \t]*\\(?:\\(\\[.*?\\]\\)-+\\(\\[.*?\\]\\)\\|=>[ \t]+\\([0-9]+\\):\\([0-9]+\\)\\)"))
 869          (lmax 30)
 870          (ltimes (make-vector lmax 0))
 871          (t1 0)
 872          (level 0)
 873          ts te dt
 874          time)
 875     (if (stringp tstart) (setq tstart (org-time-string-to-seconds tstart)))
 876     (if (stringp tend) (setq tend (org-time-string-to-seconds tend)))
 877     (if (consp tstart) (setq tstart (org-float-time tstart)))
 878     (if (consp tend) (setq tend (org-float-time tend)))
 879     (remove-text-properties (point-min) (point-max) '(:org-clock-minutes t))
 880     (save-excursion
 881       (goto-char (point-max))
 882       (while (re-search-backward re nil t)
 883         (cond
 884          ((match-end 2)
 885           ;; Two time stamps
 886           (setq ts (match-string 2)
 887                 te (match-string 3)
 888                 ts (org-float-time
 889                     (apply 'encode-time (org-parse-time-string ts)))
 890                 te (org-float-time
 891                     (apply 'encode-time (org-parse-time-string te)))
 892                 ts (if tstart (max ts tstart) ts)
 893                 te (if tend (min te tend) te)
 894                 dt (- te ts)
 895                 t1 (if (> dt 0) (+ t1 (floor (/ dt 60))) t1)))
 896          ((match-end 4)
 897           ;; A naked time
 898           (setq t1 (+ t1 (string-to-number (match-string 5))
 899                       (* 60 (string-to-number (match-string 4))))))
 900          (t ;; A headline
 901           (setq level (- (match-end 1) (match-beginning 1)))
 902           (when (or (> t1 0) (> (aref ltimes level) 0))
 903             (loop for l from 0 to level do
 904                   (aset ltimes l (+ (aref ltimes l) t1)))
 905             (setq t1 0 time (aref ltimes level))
 906             (loop for l from level to (1- lmax) do
 907                   (aset ltimes l 0))
 908             (goto-char (match-beginning 0))
 909             (put-text-property (point) (point-at-eol) :org-clock-minutes time)))))
 910       (setq org-clock-file-total-minutes (aref ltimes 0)))
 911     (set-buffer-modified-p bmp)))
 912
 913 (defun org-clock-sum-current-item (&optional tstart)
 914   "Returns time, clocked on current item in total"
 915   (save-excursion
 916     (save-restriction
 917       (org-narrow-to-subtree)
 918       (org-clock-sum tstart)
 919       org-clock-file-total-minutes)))
 920
 921 (defun org-clock-display (&optional total-only)
 922   "Show subtree times in the entire buffer.
 923 If TOTAL-ONLY is non-nil, only show the total time for the entire file
 924 in the echo area."
 925   (interactive)
 926   (org-clock-remove-overlays)
 927   (let (time h m p)
 928     (org-clock-sum)
 929     (unless total-only
 930       (save-excursion
 931         (goto-char (point-min))
 932         (while (or (and (equal (setq p (point)) (point-min))
 933                         (get-text-property p :org-clock-minutes))
 934                    (setq p (next-single-property-change
 935                             (point) :org-clock-minutes)))
 936           (goto-char p)
 937           (when (setq time (get-text-property p :org-clock-minutes))
 938             (org-clock-put-overlay time (funcall outline-level))))
 939         (setq h (/ org-clock-file-total-minutes 60)
 940               m (- org-clock-file-total-minutes (* 60 h)))
 941         ;; Arrange to remove the overlays upon next change.
 942         (when org-remove-highlights-with-change
 943           (org-add-hook 'before-change-functions 'org-clock-remove-overlays
 944                         nil 'local))))
 945     (message (concat "Total file time: " org-time-clocksum-format " (%d hours and %d minutes)") h m h m)))
 946
 947 (defvar org-clock-overlays nil)
 948 (make-variable-buffer-local 'org-clock-overlays)
 949
 950 (defun org-clock-put-overlay (time &optional level)
 951   "Put an overlays on the current line, displaying TIME.
 952 If LEVEL is given, prefix time with a corresponding number of stars.
 953 This creates a new overlay and stores it in `org-clock-overlays', so that it
 954 will be easy to remove."
 955   (let* ((c 60) (h (floor (/ time 60))) (m (- time (* 60 h)))
 956          (l (if level (org-get-valid-level level 0) 0))
 957          (fmt (concat "%s " org-time-clocksum-format "%s"))
 958          (off 0)
 959          ov tx)
 960     (org-move-to-column c)
 961     (unless (eolp) (skip-chars-backward "^ \t"))
 962     (skip-chars-backward " \t")
 963     (setq ov (org-make-overlay (1- (point)) (point-at-eol))
 964           tx (concat (buffer-substring (1- (point)) (point))
 965                      (make-string (+ off (max 0 (- c (current-column)))) ?.)
 966                      (org-add-props (format fmt
 967                                             (make-string l ?*) h m
 968                                             (make-string (- 16 l) ?\ ))
 969                          (list 'face 'org-clock-overlay))
 970                      ""))
 971     (if (not (featurep 'xemacs))
 972         (org-overlay-put ov 'display tx)
 973       (org-overlay-put ov 'invisible t)
 974       (org-overlay-put ov 'end-glyph (make-glyph tx)))
 975     (push ov org-clock-overlays)))
 976
 977 (defun org-clock-remove-overlays (&optional beg end noremove)
 978   "Remove the occur highlights from the buffer.
 979 BEG and END are ignored.  If NOREMOVE is nil, remove this function
 980 from the `before-change-functions' in the current buffer."
 981   (interactive)
 982   (unless org-inhibit-highlight-removal
 983     (mapc 'org-delete-overlay org-clock-overlays)
 984     (setq org-clock-overlays nil)
 985     (unless noremove
 986       (remove-hook 'before-change-functions
 987                    'org-clock-remove-overlays 'local))))
 988
 989 (defvar state) ;; dynamically scoped into this function
 990 (defun org-clock-out-if-current ()
 991   "Clock out if the current entry contains the running clock.
 992 This is used to stop the clock after a TODO entry is marked DONE,
 993 and is only done if the variable `org-clock-out-when-done' is not nil."
 994   (when (and org-clock-out-when-done
 995              (member state org-done-keywords)
 996              (equal (or (buffer-base-buffer (marker-buffer org-clock-marker))
 997                         (marker-buffer org-clock-marker))
 998                     (or (buffer-base-buffer (current-buffer))
 999                         (current-buffer)))
1000              (< (point) org-clock-marker)
1001              (> (save-excursion (outline-next-heading) (point))
1002                 org-clock-marker))
1003     ;; Clock out, but don't accept a logging message for this.
1004     (let ((org-log-note-clock-out nil))
1005       (org-clock-out))))
1006
1007 (add-hook 'org-after-todo-state-change-hook
1008           'org-clock-out-if-current)
1009
1010 ;;;###autoload
1011 (defun org-get-clocktable (&rest props)
1012   "Get a formatted clocktable with parameters according to PROPS.
1013 The table is created in a temporary buffer, fully formatted and
1014 fontified, and then returned."
1015   ;; Set the defaults
1016   (setq props (plist-put props :name "clocktable"))
1017   (unless (plist-member props :maxlevel)
1018     (setq props (plist-put props :maxlevel 2)))
1019   (unless (plist-member props :scope)
1020     (setq props (plist-put props :scope 'agenda)))
1021   (with-temp-buffer
1022     (org-mode)
1023     (org-create-dblock props)
1024     (org-update-dblock)
1025     (font-lock-fontify-buffer)
1026     (forward-line 2)
1027     (buffer-substring (point) (progn
1028                                 (re-search-forward "^#\\+END" nil t)
1029                                 (point-at-bol)))))
1030
1031 (defun org-clock-report (&optional arg)
1032   "Create a table containing a report about clocked time.
1033 If the cursor is inside an existing clocktable block, then the table
1034 will be updated.  If not, a new clocktable will be inserted.
1035 When called with a prefix argument, move to the first clock table in the
1036 buffer and update it."
1037   (interactive "P")
1038   (org-clock-remove-overlays)
1039   (when arg
1040     (org-find-dblock "clocktable")
1041     (org-show-entry))
1042   (if (org-in-clocktable-p)
1043       (goto-char (org-in-clocktable-p))
1044     (org-create-dblock (append (list :name "clocktable")
1045                                org-clock-clocktable-default-properties)))
1046   (org-update-dblock))
1047
1048 (defun org-in-clocktable-p ()
1049   "Check if the cursor is in a clocktable."
1050   (let ((pos (point)) start)
1051     (save-excursion
1052       (end-of-line 1)
1053       (and (re-search-backward "^#\\+BEGIN:[ \t]+clocktable" nil t)
1054            (setq start (match-beginning 0))
1055            (re-search-forward "^#\\+END:.*" nil t)
1056            (>= (match-end 0) pos)
1057            start))))
1058
1059 (defun org-clock-special-range (key &optional time as-strings)
1060   "Return two times bordering a special time range.
1061 Key is a symbol specifying the range and can be one of `today', `yesterday',
1062 `thisweek', `lastweek', `thismonth', `lastmonth', `thisyear', `lastyear'.
1063 A week starts Monday 0:00 and ends Sunday 24:00.
1064 The range is determined relative to TIME.  TIME defaults to the current time.
1065 The return value is a cons cell with two internal times like the ones
1066 returned by `current time' or `encode-time'. if AS-STRINGS is non-nil,
1067 the returned times will be formatted strings."
1068   (if (integerp key) (setq key (intern (number-to-string key))))
1069   (let* ((tm (decode-time (or time (current-time))))
1070          (s 0) (m (nth 1 tm)) (h (nth 2 tm))
1071          (d (nth 3 tm)) (month (nth 4 tm)) (y (nth 5 tm))
1072          (dow (nth 6 tm))
1073          (skey (symbol-name key))
1074          (shift 0)
1075          s1 m1 h1 d1 month1 y1 diff ts te fm txt w date)
1076     (cond
1077      ((string-match "^[0-9]+$" skey)
1078       (setq y (string-to-number skey) m 1 d 1 key 'year))
1079      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1080       (setq y (string-to-number (match-string 1 skey))
1081             month (string-to-number (match-string 2 skey))
1082             d 1 key 'month))
1083      ((string-match "^\\([0-9]+\\)-[wW]\\([0-9]\\{1,2\\}\\)$" skey)
1084       (require 'cal-iso)
1085       (setq y (string-to-number (match-string 1 skey))
1086             w (string-to-number (match-string 2 skey)))
1087       (setq date (calendar-gregorian-from-absolute
1088                   (calendar-absolute-from-iso (list w 1 y))))
1089       (setq d (nth 1 date) month (car date) y (nth 2 date)
1090             dow 1
1091             key 'week))
1092      ((string-match "^\\([0-9]+\\)-\\([0-9]\\{1,2\\}\\)-\\([0-9]\\{1,2\\}\\)$" skey)
1093       (setq y (string-to-number (match-string 1 skey))
1094             month (string-to-number (match-string 2 skey))
1095             d (string-to-number (match-string 3 skey))
1096             key 'day))
1097      ((string-match "\\([-+][0-9]+\\)$" skey)
1098       (setq shift (string-to-number (match-string 1 skey))
1099             key (intern (substring skey 0 (match-beginning 1))))))
1100     (when (= shift 0)
1101       (cond ((eq key 'yesterday) (setq key 'today shift -1))
1102             ((eq key 'lastweek)  (setq key 'week  shift -1))
1103             ((eq key 'lastmonth) (setq key 'month shift -1))
1104             ((eq key 'lastyear)  (setq key 'year  shift -1))))
1105     (cond
1106      ((memq key '(day today))
1107       (setq d (+ d shift) h 0 m 0 h1 24 m1 0))
1108      ((memq key '(week thisweek))
1109       (setq diff (+ (* -7 shift) (if (= dow 0) 6 (1- dow)))
1110             m 0 h 0 d (- d diff) d1 (+ 7 d)))
1111      ((memq key '(month thismonth))
1112       (setq d 1 h 0 m 0 d1 1 month (+ month shift) month1 (1+ month) h1 0 m1 0))
1113      ((memq key '(year thisyear))
1114       (setq m 0 h 0 d 1 month 1 y (+ y shift) y1 (1+ y)))
1115      (t (error "No such time block %s" key)))
1116     (setq ts (encode-time s m h d month y)
1117           te (encode-time (or s1 s) (or m1 m) (or h1 h)
1118                           (or d1 d) (or month1 month) (or y1 y)))
1119     (setq fm (cdr org-time-stamp-formats))
1120     (cond
1121      ((memq key '(day today))
1122       (setq txt (format-time-string "%A, %B %d, %Y" ts)))
1123      ((memq key '(week thisweek))
1124       (setq txt (format-time-string "week %G-W%V" ts)))
1125      ((memq key '(month thismonth))
1126       (setq txt (format-time-string "%B %Y" ts)))
1127      ((memq key '(year thisyear))
1128       (setq txt (format-time-string "the year %Y" ts))))
1129     (if as-strings
1130         (list (format-time-string fm ts) (format-time-string fm te) txt)
1131       (list ts te txt))))
1132
1133 (defun org-clocktable-shift (dir n)
1134   "Try to shift the :block date of the clocktable at point.
1135 Point must be in the #+BEGIN: line of a clocktable, or this function
1136 will throw an error.
1137 DIR is a direction, a symbol `left', `right', `up', or `down'.
1138 Both `left' and `down' shift the block toward the past, `up' and `right'
1139 push it toward the future.
1140 N is the number of shift steps to take.  The size of the step depends on
1141 the currently selected interval size."
1142   (setq n (prefix-numeric-value n))
1143   (and (memq dir '(left down)) (setq n (- n)))
1144   (save-excursion
1145     (goto-char (point-at-bol))
1146     (if (not (looking-at "#\\+BEGIN: clocktable\\>.*?:block[ \t]+\\(\\S-+\\)"))
1147         (error "Line needs a :block definition before this command works")
1148       (let* ((b (match-beginning 1)) (e (match-end 1))
1149              (s (match-string 1))
1150              block shift ins y mw d date wp m)
1151         (cond
1152          ((equal s "yesterday") (setq s "today-1"))
1153          ((equal s "lastweek") (setq s "thisweek-1"))
1154          ((equal s "lastmonth") (setq s "thismonth-1"))
1155          ((equal s "lastyear") (setq s "thisyear-1")))
1156         (cond
1157          ((string-match "^\\(today\\|thisweek\\|thismonth\\|thisyear\\)\\([-+][0-9]+\\)?$" s)
1158           (setq block (match-string 1 s)
1159                 shift (if (match-end 2)
1160                           (string-to-number (match-string 2 s))
1161                         0))
1162           (setq shift (+ shift n))
1163           (setq ins (if (= shift 0) block (format "%s%+d" block shift))))
1164          ((string-match "\\([0-9]+\\)\\(-\\([wW]?\\)\\([0-9]\\{1,2\\}\\)\\(-\\([0-9]\\{1,2\\}\\)\\)?\\)?" s)
1165           ;;               1        1  2   3       3  4                4  5   6                6  5   2
1166           (setq y (string-to-number (match-string 1 s))
1167                 wp (and (match-end 3) (match-string 3 s))
1168                 mw (and (match-end 4) (string-to-number (match-string 4 s)))
1169                 d (and (match-end 6) (string-to-number (match-string 6 s))))
1170           (cond
1171            (d (setq ins (format-time-string
1172                          "%Y-%m-%d"
1173                          (encode-time 0 0 0 (+ d n) m y))))
1174            ((and wp mw (> (length wp) 0))
1175             (require 'cal-iso)
1176             (setq date (calendar-gregorian-from-absolute (calendar-absolute-from-iso (list (+ mw n) 1 y))))
1177             (setq ins (format-time-string
1178                        "%G-W%V"
1179                        (encode-time 0 0 0 (nth 1 date) (car date) (nth 2 date)))))
1180            (mw
1181             (setq ins (format-time-string
1182                        "%Y-%m"
1183                        (encode-time 0 0 0 1 (+ mw n) y))))
1184            (y
1185             (setq ins (number-to-string (+ y n))))))
1186          (t (error "Cannot shift clocktable block")))
1187         (when ins
1188           (goto-char b)
1189           (insert ins)
1190           (delete-region (point) (+ (point) (- e b)))
1191           (beginning-of-line 1)
1192           (org-update-dblock)
1193           t)))))
1194
1195 (defun org-dblock-write:clocktable (params)
1196   "Write the standard clocktable."
1197   (catch 'exit
1198     (let* ((hlchars '((1 . "*") (2 . "/")))
1199            (ins (make-marker))
1200            (total-time nil)
1201            (scope (plist-get params :scope))
1202            (tostring (plist-get  params :tostring))
1203            (multifile (plist-get  params :multifile))
1204            (header (plist-get  params :header))
1205            (maxlevel (or (plist-get params :maxlevel) 3))
1206            (step (plist-get params :step))
1207            (emph (plist-get params :emphasize))
1208            (timestamp (plist-get params :timestamp))
1209            (ts (plist-get params :tstart))
1210            (te (plist-get params :tend))
1211            (block (plist-get params :block))
1212            (link (plist-get params :link))
1213            ipos time p level hlc hdl tsp props content recalc formula pcol
1214            cc beg end pos tbl tbl1 range-text rm-file-column scope-is-list st)
1215       (setq org-clock-file-total-minutes nil)
1216       (when step
1217         (unless (or block (and ts te))
1218           (error "Clocktable `:step' can only be used with `:block' or `:tstart,:end'"))
1219         (org-clocktable-steps params)
1220         (throw 'exit nil))
1221       (when block
1222         (setq cc (org-clock-special-range block nil t)
1223               ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1224       (when (integerp ts) (setq ts (calendar-gregorian-from-absolute ts)))
1225       (when (integerp te) (setq te (calendar-gregorian-from-absolute te)))
1226       (when (and ts (listp ts))
1227         (setq ts (format "%4d-%02d-%02d" (nth 2 ts) (car ts) (nth 1 ts))))
1228       (when (and te (listp te))
1229         (setq te (format "%4d-%02d-%02d" (nth 2 te) (car te) (nth 1 te))))
1230       ;; Now the times are strings we can parse.
1231       (if ts (setq ts (org-float-time
1232                        (apply 'encode-time (org-parse-time-string ts)))))
1233       (if te (setq te (org-float-time
1234                        (apply 'encode-time (org-parse-time-string te)))))
1235       (move-marker ins (point))
1236       (setq ipos (point))
1237
1238       ;; Get the right scope
1239       (setq pos (point))
1240       (cond
1241        ((and scope (listp scope) (symbolp (car scope)))
1242         (setq scope (eval scope)))
1243        ((eq scope 'agenda)
1244         (setq scope (org-agenda-files t)))
1245        ((eq scope 'agenda-with-archives)
1246         (setq scope (org-agenda-files t))
1247         (setq scope (org-add-archive-files scope)))
1248        ((eq scope 'file-with-archives)
1249         (setq scope (org-add-archive-files (list (buffer-file-name)))
1250               rm-file-column t)))
1251       (setq scope-is-list (and scope (listp scope)))
1252       (save-restriction
1253         (cond
1254          ((not scope))
1255          ((eq scope 'file) (widen))
1256          ((eq scope 'subtree) (org-narrow-to-subtree))
1257          ((eq scope 'tree)
1258           (while (org-up-heading-safe))
1259           (org-narrow-to-subtree))
1260          ((and (symbolp scope) (string-match "^tree\\([0-9]+\\)$"
1261                                              (symbol-name scope)))
1262           (setq level (string-to-number (match-string 1 (symbol-name scope))))
1263           (catch 'exit
1264             (while (org-up-heading-safe)
1265               (looking-at outline-regexp)
1266               (if (<= (org-reduced-level (funcall outline-level)) level)
1267                   (throw 'exit nil))))
1268           (org-narrow-to-subtree))
1269          (scope-is-list
1270           (let* ((files scope)
1271                  (scope 'agenda)
1272                  (p1 (copy-sequence params))
1273                  file)
1274             (setq p1 (plist-put p1 :tostring t))
1275             (setq p1 (plist-put p1 :multifile t))
1276             (setq p1 (plist-put p1 :scope 'file))
1277             (org-prepare-agenda-buffers files)
1278             (while (setq file (pop files))
1279               (with-current-buffer (find-buffer-visiting file)
1280                 (setq tbl1 (org-dblock-write:clocktable p1))
1281                 (when tbl1
1282                   (push (org-clocktable-add-file
1283                          file
1284                          (concat "| |*File time*|*"
1285                                  (org-minutes-to-hh:mm-string
1286                                   org-clock-file-total-minutes)
1287                                  "*|\n"
1288                                  tbl1)) tbl)
1289                   (setq total-time (+ (or total-time 0)
1290                                       org-clock-file-total-minutes))))))))
1291         (goto-char pos)
1292
1293         (unless scope-is-list
1294           (org-clock-sum ts te)
1295           (goto-char (point-min))
1296           (setq st t)
1297           (while (or (and (bobp) (prog1 st (setq st nil))
1298                           (get-text-property (point) :org-clock-minutes)
1299                           (setq p (point-min)))
1300                      (setq p (next-single-property-change (point) :org-clock-minutes)))
1301             (goto-char p)
1302             (when (setq time (get-text-property p :org-clock-minutes))
1303               (save-excursion
1304                 (beginning-of-line 1)
1305                 (when (and (looking-at (org-re "\\(\\*+\\)[ \t]+\\(.*?\\)\\([ \t]+:[[:alnum:]_@:]+:\\)?[ \t]*$"))
1306                            (setq level (org-reduced-level
1307                                         (- (match-end 1) (match-beginning 1))))
1308                            (<= level maxlevel))
1309                   (setq hlc (if emph (or (cdr (assoc level hlchars)) "") "")
1310                         hdl (if (not link)
1311                                 (match-string 2)
1312                               (org-make-link-string
1313                                (format "file:%s::%s"
1314                                        (buffer-file-name)
1315                                        (save-match-data
1316                                          (org-make-org-heading-search-string
1317                                           (match-string 2))))
1318                                (match-string 2)))
1319                         tsp (when timestamp
1320                               (setq props (org-entry-properties (point)))
1321                               (or (cdr (assoc "SCHEDULED" props))
1322                                   (cdr (assoc "TIMESTAMP" props))
1323                                   (cdr (assoc "DEADLINE" props))
1324                                   (cdr (assoc "TIMESTAMP_IA" props)))))
1325                   (if (and (not multifile) (= level 1)) (push "|-" tbl))
1326                   (push (concat
1327                          "| " (int-to-string level) "|"
1328                          (if timestamp (concat tsp "|") "")
1329                          hlc hdl hlc " |"
1330                          (make-string (1- level) ?|)
1331                          hlc (org-minutes-to-hh:mm-string time) hlc
1332                          " |") tbl))))))
1333         (setq tbl (nreverse tbl))
1334         (if tostring
1335             (if tbl (mapconcat 'identity tbl "\n") nil)
1336           (goto-char ins)
1337           (insert-before-markers
1338            (or header
1339                (concat
1340                 "Clock summary at ["
1341                 (substring
1342                  (format-time-string (cdr org-time-stamp-formats))
1343                  1 -1)
1344                 "]"
1345                 (if block (concat ", for " range-text ".") "")
1346                 "\n\n"))
1347            (if scope-is-list "|File" "")
1348            "|L|" (if timestamp "Timestamp|" "") "Headline|Time|\n")
1349           (setq total-time (or total-time org-clock-file-total-minutes))
1350           (insert-before-markers
1351            "|-\n|"
1352            (if scope-is-list "|" "")
1353            (if timestamp "|Timestamp|" "|")
1354            "*Total time*| *"
1355            (org-minutes-to-hh:mm-string (or total-time 0))
1356            "*|\n|-\n")
1357           (setq tbl (delq nil tbl))
1358           (if (and (stringp (car tbl)) (> (length (car tbl)) 1)
1359                    (equal (substring (car tbl) 0 2) "|-"))
1360               (pop tbl))
1361           (insert-before-markers (mapconcat
1362                                   'identity (delq nil tbl)
1363                                   (if scope-is-list "\n|-\n" "\n")))
1364           (backward-delete-char 1)
1365           (if (setq formula (plist-get params :formula))
1366               (cond
1367                ((eq formula '%)
1368                 (setq pcol (+ (if scope-is-list 1 0) maxlevel 3))
1369                 (insert
1370                  (format
1371                   "\n#+TBLFM: $%d='(org-clock-time%% @%d$%d $%d..$%d);%%.1f"
1372                   pcol
1373                   2
1374                   (+ 3 (if scope-is-list 1 0))
1375                   (+ (if scope-is-list 1 0) 3)
1376                   (1- pcol)))
1377                 (setq recalc t))
1378                ((stringp formula)
1379                 (insert "\n#+TBLFM: " formula)
1380                 (setq recalc t))
1381                (t (error "invalid formula in clocktable")))
1382             ;; Should we rescue an old formula?
1383             (when (stringp (setq content (plist-get params :content)))
1384               (when (string-match "^\\([ \t]*#\\+TBLFM:.*\\)" content)
1385                 (setq recalc t)
1386                 (insert "\n" (match-string 1 (plist-get params :content)))
1387                 (beginning-of-line 0))))
1388           (goto-char ipos)
1389           (skip-chars-forward "^|")
1390           (org-table-align)
1391           (when recalc
1392             (if (eq formula '%)
1393                 (save-excursion (org-table-goto-column pcol nil 'force)
1394                                 (insert "%")))
1395             (org-table-recalculate 'all))
1396           (when rm-file-column
1397             (forward-char 1)
1398             (org-table-delete-column)))))))
1399
1400 (defun org-clocktable-steps (params)
1401   (let* ((p1 (copy-sequence params))
1402          (ts (plist-get p1 :tstart))
1403          (te (plist-get p1 :tend))
1404          (step0 (plist-get p1 :step))
1405          (step (cdr (assoc step0 '((day . 86400) (week . 604800)))))
1406          (block (plist-get p1 :block))
1407          cc range-text)
1408     (when block
1409       (setq cc (org-clock-special-range block nil t)
1410             ts (car cc) te (nth 1 cc) range-text (nth 2 cc)))
1411     (if ts (setq ts (org-float-time
1412                      (apply 'encode-time (org-parse-time-string ts)))))
1413     (if te (setq te (org-float-time
1414                      (apply 'encode-time (org-parse-time-string te)))))
1415     (setq p1 (plist-put p1 :header ""))
1416     (setq p1 (plist-put p1 :step nil))
1417     (setq p1 (plist-put p1 :block nil))
1418     (while (< ts te)
1419       (or (bolp) (insert "\n"))
1420       (setq p1 (plist-put p1 :tstart (format-time-string
1421                                       (org-time-stamp-format nil t)
1422                                       (seconds-to-time ts))))
1423       (setq p1 (plist-put p1 :tend (format-time-string
1424                                     (org-time-stamp-format nil t)
1425                                     (seconds-to-time (setq ts (+ ts step))))))
1426       (insert "\n" (if (eq step0 'day) "Daily report: " "Weekly report starting on: ")
1427               (plist-get p1 :tstart) "\n")
1428       (org-dblock-write:clocktable p1)
1429       (re-search-forward "#\\+END:")
1430       (end-of-line 0))))
1431
1432 (defun org-clocktable-add-file (file table)
1433   (if table
1434       (let ((lines (org-split-string table "\n"))
1435             (ff (file-name-nondirectory file)))
1436         (mapconcat 'identity
1437                    (mapcar (lambda (x)
1438                              (if (string-match org-table-dataline-regexp x)
1439                                  (concat "|" ff x)
1440                                x))
1441                            lines)
1442                    "\n"))))
1443
1444 (defun org-clock-time% (total &rest strings)
1445   "Compute a time fraction in percent.
1446 TOTAL s a time string like 10:21 specifying the total times.
1447 STRINGS is a list of strings that should be checked for a time.
1448 The first string that does have a time will be used.
1449 This function is made for clock tables."
1450   (let ((re "\\([0-9]+\\):\\([0-9]+\\)")
1451         tot s)
1452     (save-match-data
1453       (catch 'exit
1454         (if (not (string-match re total))
1455             (throw 'exit 0.)
1456           (setq tot (+ (string-to-number (match-string 2 total))
1457                        (* 60 (string-to-number (match-string 1 total)))))
1458           (if (= tot 0.) (throw 'exit 0.)))
1459         (while (setq s (pop strings))
1460           (if (string-match "\\([0-9]+\\):\\([0-9]+\\)" s)
1461               (throw 'exit
1462                      (/ (* 100.0 (+ (string-to-number (match-string 2 s))
1463                                     (* 60 (string-to-number (match-string 1 s)))))
1464                         tot))))
1465         0))))
1466
1467 (defun org-clock-save ()
1468   "Persist various clock-related data to disk.
1469 The details of what will be saved are regulated by the variable
1470 `org-clock-persist'."
1471   (when org-clock-persist
1472     (let (b)
1473       (with-current-buffer (find-file (expand-file-name org-clock-persist-file))
1474         (progn
1475           (delete-region (point-min) (point-max))
1476           ;;Store clock
1477           (insert (format ";; org-persist.el - %s at %s\n"
1478                           system-name (format-time-string
1479                                        (cdr org-time-stamp-formats))))
1480           (if (and (setq b (marker-buffer org-clock-marker))
1481                    (setq b (or (buffer-base-buffer b) b))
1482                    (buffer-live-p b)
1483                    (buffer-file-name b)
1484                    (or (not org-clock-persist-query-save)
1485                        (y-or-n-p (concat "Save current clock ("
1486                                          (substring-no-properties org-clock-heading)
1487                                          ") "))))
1488               (insert "(setq resume-clock '(\""
1489                       (buffer-file-name (marker-buffer org-clock-marker))
1490                       "\" . " (int-to-string (marker-position org-clock-marker))
1491                       "))\n"))
1492           ;; Store clocked task history. Tasks are stored reversed to make
1493           ;; reading simpler
1494           (when (and org-clock-history (eq org-clock-persist t))
1495             (insert
1496              "(setq stored-clock-history '("
1497              (mapconcat
1498               (lambda (m)
1499                 (when (and (setq b (marker-buffer m))
1500                            (setq b (or (buffer-base-buffer b) b))
1501                            (buffer-live-p b)
1502                            (buffer-file-name b))
1503                   (concat "(\"" (buffer-file-name b)
1504                           "\" . " (int-to-string (marker-position m))
1505                           ")")))
1506               (reverse org-clock-history) " ") "))\n"))
1507           (save-buffer)
1508           (kill-buffer (current-buffer)))))))
1509
1510 (defvar org-clock-loaded nil
1511   "Was the clock file loaded?")
1512
1513 (defun org-clock-load ()
1514   "Load clock-related data from disk, maybe resuming a stored clock."
1515   (when (and org-clock-persist (not org-clock-loaded))
1516     (let ((filename (expand-file-name org-clock-persist-file))
1517           (org-clock-in-resume 'auto-restart)
1518           resume-clock stored-clock-history)
1519       (if (not (file-readable-p filename))
1520           (message "Not restoring clock data; %s not found"
1521                    org-clock-persist-file)
1522         (message "%s" "Restoring clock data")
1523         (setq org-clock-loaded t)
1524         (load-file filename)
1525         ;; load history
1526         (when stored-clock-history
1527           (save-window-excursion
1528             (mapc (lambda (task)
1529                     (if (file-exists-p (car task))
1530                         (org-clock-history-push (cdr task)
1531                                                 (find-file (car task)))))
1532                   stored-clock-history)))
1533         ;; resume clock
1534         (when (and resume-clock org-clock-persist
1535                    (file-exists-p (car resume-clock))
1536                    (or (not org-clock-persist-query-resume)
1537                        (y-or-n-p
1538                         (concat
1539                          "Resume clock ("
1540                          (with-current-buffer (find-file (car resume-clock))
1541                            (save-excursion
1542                              (goto-char (cdr resume-clock))
1543                              (org-back-to-heading t)
1544                              (and (looking-at org-complex-heading-regexp)
1545                                   (match-string 4))))
1546                          ") "))))
1547           (when (file-exists-p (car resume-clock))
1548             (with-current-buffer (find-file (car resume-clock))
1549               (goto-char (cdr resume-clock))
1550               (org-clock-in)
1551               (if (org-invisible-p)
1552                   (org-show-context)))))))))
1553
1554 ;;;###autoload
1555 (defun org-clock-persistence-insinuate ()
1556   "Set up hooks for clock persistence"
1557   (add-hook 'org-mode-hook 'org-clock-load)
1558   (add-hook 'kill-emacs-hook 'org-clock-save))
1559
1560 ;; Suggested bindings
1561 (org-defkey org-mode-map "\C-c\C-x\C-e" 'org-clock-modify-effort-estimate)
1562
1563 (provide 'org-clock)
1564
1565 ;; arch-tag: 7b42c5d4-9b36-48be-97c0-66a869daed4c
1566
1567 ;;; org-clock.el ends here