lisp/ob-dot.el

   1 ;;; ob-dot.el --- org-babel functions for dot evaluation
   2
   3 ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating dot source code.
  27 ;;
  28 ;; For information on dot see http://www.graphviz.org/
  29 ;;
  30 ;; This differs from most standard languages in that
  31 ;;
  32 ;; 1) there is no such thing as a "session" in dot
  33 ;;
  34 ;; 2) we are generally only going to return results of type "file"
  35 ;;
  36 ;; 3) we are adding the "file" and "cmdline" header arguments
  37 ;;
  38 ;; 4) there are no variables (at least for now)
  39
  40 ;;; Code:
  41 (require 'ob)
  42
  43 (defvar org-babel-default-header-args:dot
  44   '((:results . "file") (:exports . "results"))
  45   "Default arguments to use when evaluating a dot source block.")
  46
  47 (defun org-babel-expand-body:dot (body params)
  48   "Expand BODY according to PARAMS, return the expanded body."
  49   (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
  50     (mapc
  51      (lambda (pair)
  52        (let ((name (symbol-name (car pair)))
  53              (value (cdr pair)))
  54          (setq body
  55                (replace-regexp-in-string
  56                 (concat "\$" (regexp-quote name))
  57                 (if (stringp value) value (format "%S" value))
  58                 body
  59                 t
  60                 t))))
  61      vars)
  62     body))
  63
  64 (defun org-babel-execute:dot (body params)
  65   "Execute a block of Dot code with org-babel.
  66 This function is called by `org-babel-execute-src-block'."
  67   (let* ((result-params (cdr (assoc :result-params params)))
  68          (out-file (cdr (or (assoc :file params)
  69                             (error "You need to specify a :file parameter"))))
  70          (cmdline (or (cdr (assoc :cmdline params))
  71                       (format "-T%s" (file-name-extension out-file))))
  72          (cmd (or (cdr (assoc :cmd params)) "dot"))
  73          (in-file (org-babel-temp-file "dot-")))
  74     (with-temp-file in-file
  75       (insert (org-babel-expand-body:dot body params)))
  76     (org-babel-eval
  77      (concat cmd
  78              " " (org-babel-process-file-name in-file)
  79              " " cmdline
  80              " -o " (org-babel-process-file-name out-file)) "")
  81     nil)) ;; signal that output has already been written to file
  82
  83 (defun org-babel-prep-session:dot (session params)
  84   "Return an error because Dot does not support sessions."
  85   (error "Dot does not support sessions"))
  86
  87 (provide 'ob-dot)
  88
  89
  90
  91 ;;; ob-dot.el ends here