lisp/ob-haskell.el

   1 ;;; ob-haskell.el --- Babel Functions for Haskell    -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Org-Babel support for evaluating haskell source code.  This one will
  27 ;; be sort of tricky because haskell programs must be compiled before
  28 ;; they can be run, but haskell code can also be run through an
  29 ;; interactive interpreter.
  30 ;;
  31 ;; For now lets only allow evaluation using the haskell interpreter.
  32
  33 ;;; Requirements:
  34
  35 ;; - haskell-mode :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  36 ;;
  37 ;; - inf-haskell :: http://www.iro.umontreal.ca/~monnier/elisp/#haskell-mode
  38 ;;
  39 ;; - (optionally) lhs2tex :: http://people.cs.uu.nl/andres/lhs2tex/
  40
  41 ;;; Code:
  42 (require 'ob)
  43 (require 'comint)
  44 (eval-when-compile (require 'cl))
  45
  46 (declare-function org-remove-indentation "org" (code &optional n))
  47 (declare-function haskell-mode "ext:haskell-mode" ())
  48 (declare-function run-haskell "ext:inf-haskell" (&optional arg))
  49 (declare-function inferior-haskell-load-file
  50                   "ext:inf-haskell" (&optional reload))
  51
  52 (defvar org-babel-tangle-lang-exts)
  53 (add-to-list 'org-babel-tangle-lang-exts '("haskell" . "hs"))
  54
  55 (defvar org-babel-default-header-args:haskell
  56   '((:padlines . "no")))
  57
  58 (defvar org-babel-haskell-lhs2tex-command "lhs2tex")
  59
  60 (defvar org-babel-haskell-eoe "\"org-babel-haskell-eoe\"")
  61
  62 (defun org-babel-execute:haskell (body params)
  63   "Execute a block of Haskell code."
  64   (let* ((session (cdr (assoc :session params)))
  65          (result-type (cdr (assoc :result-type params)))
  66          (full-body (org-babel-expand-body:generic
  67                      body params
  68                      (org-babel-variable-assignments:haskell params)))
  69          (session (org-babel-haskell-initiate-session session params))
  70          (raw (org-babel-comint-with-output
  71                   (session org-babel-haskell-eoe t full-body)
  72                 (insert (org-babel-trim full-body))
  73                 (comint-send-input nil t)
  74                 (insert org-babel-haskell-eoe)
  75                 (comint-send-input nil t)))
  76          (results (mapcar
  77                    #'org-babel-haskell-read-string
  78                    (cdr (member org-babel-haskell-eoe
  79                                 (reverse (mapcar #'org-babel-trim raw)))))))
  80     (org-babel-reassemble-table
  81      (let ((result
  82             (case result-type
  83               (output (mapconcat #'identity (reverse (cdr results)) "\n"))
  84               (value (car results)))))
  85        (org-babel-result-cond (cdr (assoc :result-params params))
  86          result (org-babel-script-escape result)))
  87      (org-babel-pick-name (cdr (assoc :colname-names params))
  88                           (cdr (assoc :colname-names params)))
  89      (org-babel-pick-name (cdr (assoc :rowname-names params))
  90                           (cdr (assoc :rowname-names params))))))
  91
  92 (defun org-babel-haskell-read-string (string)
  93   "Strip \\\"s from around a haskell string."
  94   (if (string-match "^\"\\([^\000]+\\)\"$" string)
  95       (match-string 1 string)
  96     string))
  97
  98 (defun org-babel-haskell-initiate-session (&optional _session _params)
  99   "Initiate a haskell session.
 100 If there is not a current inferior-process-buffer in SESSION
 101 then create one.  Return the initialized session."
 102   (require 'inf-haskell)
 103   (or (get-buffer "*haskell*")
 104       (save-window-excursion (run-haskell) (sleep-for 0.25) (current-buffer))))
 105
 106 (defun org-babel-load-session:haskell (session body params)
 107   "Load BODY into SESSION."
 108   (save-window-excursion
 109     (let* ((buffer (org-babel-prep-session:haskell session params))
 110            (load-file (concat (org-babel-temp-file "haskell-load-") ".hs")))
 111       (with-temp-buffer
 112         (insert body) (write-file load-file)
 113         (haskell-mode) (inferior-haskell-load-file))
 114       buffer)))
 115
 116 (defun org-babel-prep-session:haskell (session params)
 117   "Prepare SESSION according to the header arguments in PARAMS."
 118   (save-window-excursion
 119     (let ((buffer (org-babel-haskell-initiate-session session)))
 120       (org-babel-comint-in-buffer buffer
 121         (mapc (lambda (line)
 122                 (insert line)
 123                 (comint-send-input nil t))
 124               (org-babel-variable-assignments:haskell params)))
 125       (current-buffer))))
 126
 127 (defun org-babel-variable-assignments:haskell (params)
 128   "Return list of haskell statements assigning the block's variables."
 129   (mapcar (lambda (pair)
 130             (format "let %s = %s"
 131                     (car pair)
 132                     (org-babel-haskell-var-to-haskell (cdr pair))))
 133           (mapcar #'cdr (org-babel-get-header params :var))))
 134
 135 (defun org-babel-haskell-var-to-haskell (var)
 136   "Convert an elisp value VAR into a haskell variable.
 137 The elisp VAR is converted to a string of haskell source code
 138 specifying a variable of the same value."
 139   (if (listp var)
 140       (concat "[" (mapconcat #'org-babel-haskell-var-to-haskell var ", ") "]")
 141     (format "%S" var)))
 142
 143 (defvar org-export-copy-to-kill-ring)
 144 (declare-function org-export-to-file "ox"
 145                   (backend file
 146                            &optional async subtreep visible-only body-only ext-plist))
 147 (defun org-babel-haskell-export-to-lhs (&optional arg)
 148   "Export to a .lhs file with all haskell code blocks escaped.
 149 When called with a prefix argument the resulting
 150 .lhs file will be exported to a .tex file.  This function will
 151 create two new files, base-name.lhs and base-name.tex where
 152 base-name is the name of the current org-mode file.
 153
 154 Note that all standard Babel literate programming
 155 constructs (header arguments, no-web syntax etc...) are ignored."
 156   (interactive "P")
 157   (let* ((contents (buffer-string))
 158          (haskell-regexp
 159           (concat "^\\([ \t]*\\)#\\+begin_src[ \t]haskell*\\(.*\\)?[\r\n]"
 160                   "\\([^\000]*?\\)[\r\n][ \t]*#\\+end_src.*"))
 161          (base-name (file-name-sans-extension (buffer-file-name)))
 162          (tmp-file (org-babel-temp-file "haskell-"))
 163          (tmp-org-file (concat tmp-file ".org"))
 164          (tmp-tex-file (concat tmp-file ".tex"))
 165          (lhs-file (concat base-name ".lhs"))
 166          (tex-file (concat base-name ".tex"))
 167          (command (concat org-babel-haskell-lhs2tex-command
 168                           " " (org-babel-process-file-name lhs-file)
 169                           " > " (org-babel-process-file-name tex-file)))
 170          (preserve-indentp org-src-preserve-indentation)
 171          indentation)
 172     ;; escape haskell source-code blocks
 173     (with-temp-file tmp-org-file
 174       (insert contents)
 175       (goto-char (point-min))
 176       (while (re-search-forward haskell-regexp nil t)
 177         (save-match-data (setq indentation (length (match-string 1))))
 178         (replace-match (save-match-data
 179                          (concat
 180                           "#+begin_latex\n\\begin{code}\n"
 181                           (if (or preserve-indentp
 182                                   (string-match "-i" (match-string 2)))
 183                               (match-string 3)
 184                             (org-remove-indentation (match-string 3)))
 185                           "\n\\end{code}\n#+end_latex\n"))
 186                        t t)
 187         (indent-code-rigidly (match-beginning 0) (match-end 0) indentation)))
 188     (save-excursion
 189       ;; export to latex w/org and save as .lhs
 190       (require 'ox-latex)
 191       (find-file tmp-org-file)
 192       ;; Ensure we do not clutter kill ring with incomplete results.
 193       (let (org-export-copy-to-kill-ring)
 194         (org-export-to-file 'latex tmp-tex-file))
 195       (kill-buffer nil)
 196       (delete-file tmp-org-file)
 197       (find-file tmp-tex-file)
 198       (goto-char (point-min)) (forward-line 2)
 199       (insert "%include polycode.fmt\n")
 200       ;; ensure all \begin/end{code} statements start at the first column
 201       (while (re-search-forward "^[ \t]+\\\\begin{code}[^\000]+\\\\end{code}" nil t)
 202         (replace-match (save-match-data (org-remove-indentation (match-string 0)))
 203                        t t))
 204       (setq contents (buffer-string))
 205       (save-buffer) (kill-buffer nil))
 206     (delete-file tmp-tex-file)
 207     ;; save org exported latex to a .lhs file
 208     (with-temp-file lhs-file (insert contents))
 209     (if (not arg)
 210         (find-file lhs-file)
 211       ;; process .lhs file with lhs2tex
 212       (message "running %s" command) (shell-command command) (find-file tex-file))))
 213
 214 (provide 'ob-haskell)
 215
 216
 217
 218 ;;; ob-haskell.el ends here