lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extract the code from source blocks out into raw source-code files.
  27
  28 ;;; Code:
  29 (require 'org-src)
  30 (eval-when-compile
  31   (require 'cl))
  32
  33 (declare-function org-edit-special "org" (&optional arg))
  34 (declare-function org-link-escape "org" (text &optional table))
  35 (declare-function org-store-link "org" (arg))
  36 (declare-function org-open-link-from-string "org" (s &optional arg reference-buffer))
  37 (declare-function org-heading-components "org" ())
  38 (declare-function org-back-to-heading "org" (invisible-ok))
  39 (declare-function org-fill-template "org" (template alist))
  40 (declare-function org-babel-update-block-body "org" (new-body))
  41 (declare-function make-directory "files" (dir &optional parents))
  42
  43 (defcustom org-babel-tangle-lang-exts
  44   '(("emacs-lisp" . "el"))
  45   "Alist mapping languages to their file extensions.
  46 The key is the language name, the value is the string that should
  47 be inserted as the extension commonly used to identify files
  48 written in this language.  If no entry is found in this list,
  49 then the name of the language is used."
  50   :group 'org-babel-tangle
  51   :version "24.1"
  52   :type '(repeat
  53           (cons
  54            (string "Language name")
  55            (string "File Extension"))))
  56
  57 (defcustom org-babel-post-tangle-hook nil
  58   "Hook run in code files tangled by `org-babel-tangle'."
  59   :group 'org-babel
  60   :version "24.1"
  61   :type 'hook)
  62
  63 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  64   "Hook run at the beginning of `org-babel-tangle'."
  65   :group 'org-babel
  66   :version "24.1"
  67   :type 'hook)
  68
  69 (defcustom org-babel-tangle-body-hook nil
  70   "Hook run over the contents of each code block body."
  71   :group 'org-babel
  72   :version "24.1"
  73   :type 'hook)
  74
  75 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  76   "Format of inserted comments in tangled code files.
  77 The following format strings can be used to insert special
  78 information into the output using `org-fill-template'.
  79 %start-line --- the line number at the start of the code block
  80 %file --------- the file from which the code block was tangled
  81 %link --------- Org-mode style link to the code block
  82 %source-name -- name of the code block
  83
  84 Whether or not comments are inserted during tangling is
  85 controlled by the :comments header argument."
  86   :group 'org-babel
  87   :version "24.1"
  88   :type 'string)
  89
  90 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  91   "Format of inserted comments in tangled code files.
  92 The following format strings can be used to insert special
  93 information into the output using `org-fill-template'.
  94 %start-line --- the line number at the start of the code block
  95 %file --------- the file from which the code block was tangled
  96 %link --------- Org-mode style link to the code block
  97 %source-name -- name of the code block
  98
  99 Whether or not comments are inserted during tangling is
 100 controlled by the :comments header argument."
 101   :group 'org-babel
 102   :version "24.1"
 103   :type 'string)
 104
 105 (defcustom org-babel-process-comment-text #'org-babel-trim
 106   "Function called to process raw Org-mode text collected to be
 107 inserted as comments in tangled source-code files.  The function
 108 should take a single string argument and return a string
 109 result.  The default value is `org-babel-trim'."
 110   :group 'org-babel
 111   :version "24.1"
 112   :type 'function)
 113
 114 (defun org-babel-find-file-noselect-refresh (file)
 115   "Find file ensuring that the latest changes on disk are
 116 represented in the file."
 117   (find-file-noselect file 'nowarn)
 118   (with-current-buffer (get-file-buffer file)
 119     (revert-buffer t t t)))
 120
 121 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 122   "Open FILE into a temporary buffer execute BODY there like
 123 `progn', then kill the FILE buffer returning the result of
 124 evaluating BODY."
 125   (declare (indent 1))
 126   (let ((temp-path (make-symbol "temp-path"))
 127         (temp-result (make-symbol "temp-result"))
 128         (temp-file (make-symbol "temp-file"))
 129         (visited-p (make-symbol "visited-p")))
 130     `(let* ((,temp-path ,file)
 131             (,visited-p (get-file-buffer ,temp-path))
 132             ,temp-result ,temp-file)
 133        (org-babel-find-file-noselect-refresh ,temp-path)
 134        (setf ,temp-file (get-file-buffer ,temp-path))
 135        (with-current-buffer ,temp-file
 136          (setf ,temp-result (progn ,@body)))
 137        (unless ,visited-p (kill-buffer ,temp-file))
 138        ,temp-result)))
 139 (def-edebug-spec org-babel-with-temp-filebuffer (form body))
 140
 141 ;;;###autoload
 142 (defun org-babel-tangle-file (file &optional target-file lang)
 143   "Extract the bodies of source code blocks in FILE.
 144 Source code blocks are extracted with `org-babel-tangle'.
 145 Optional argument TARGET-FILE can be used to specify a default
 146 export file for all source blocks.  Optional argument LANG can be
 147 used to limit the exported source code blocks by language."
 148   (interactive "fFile to tangle: \nP")
 149   (let ((visited-p (get-file-buffer (expand-file-name file)))
 150         to-be-removed)
 151     (save-window-excursion
 152       (find-file file)
 153       (setq to-be-removed (current-buffer))
 154       (org-babel-tangle nil target-file lang))
 155     (unless visited-p
 156       (kill-buffer to-be-removed))))
 157
 158 (defun org-babel-tangle-publish (_ filename pub-dir)
 159   "Tangle FILENAME and place the results in PUB-DIR."
 160   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 161
 162 ;;;###autoload
 163 (defun org-babel-tangle (&optional arg target-file lang)
 164   "Write code blocks to source-specific files.
 165 Extract the bodies of all source code blocks from the current
 166 file into their own source-specific files.
 167 With one universal prefix argument, only tangle the block at point.
 168 When two universal prefix arguments, only tangle blocks for the
 169 tangle file of the block at point.
 170 Optional argument TARGET-FILE can be used to specify a default
 171 export file for all source blocks.  Optional argument LANG can be
 172 used to limit the exported source code blocks by language."
 173   (interactive "P")
 174   (run-hooks 'org-babel-pre-tangle-hook)
 175   ;; Possibly Restrict the buffer to the current code block
 176   (save-restriction
 177     (when (equal arg '(4))
 178       (let ((head (org-babel-where-is-src-block-head)))
 179           (if head
 180               (goto-char head)
 181             (user-error "Point is not in a source code block"))))
 182     (save-excursion
 183       (let ((block-counter 0)
 184             (org-babel-default-header-args
 185              (if target-file
 186                  (org-babel-merge-params org-babel-default-header-args
 187                                          (list (cons :tangle target-file)))
 188                org-babel-default-header-args))
 189             (tangle-file
 190              (when (equal arg '(16))
 191                (or (cdr (assoc :tangle (nth 2 (org-babel-get-src-block-info 'light))))
 192                    (user-error "Point is not in a source code block"))))
 193             path-collector)
 194         (mapc ;; map over all languages
 195          (lambda (by-lang)
 196            (let* ((lang (car by-lang))
 197                   (specs (cdr by-lang))
 198                   (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 199                   (lang-f (intern
 200                            (concat
 201                             (or (and (cdr (assoc lang org-src-lang-modes))
 202                                      (symbol-name
 203                                       (cdr (assoc lang org-src-lang-modes))))
 204                                 lang)
 205                             "-mode")))
 206                   she-banged)
 207              (mapc
 208               (lambda (spec)
 209                 (let ((get-spec (lambda (name) (cdr (assoc name (nth 4 spec))))))
 210                   (let* ((tangle (funcall get-spec :tangle))
 211                          (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 212                                     (funcall get-spec :shebang)))
 213                          (tangle-mode (funcall get-spec :tangle-mode))
 214                          (base-name (cond
 215                                      ((string= "yes" tangle)
 216                                       (file-name-sans-extension
 217                                        (buffer-file-name)))
 218                                      ((string= "no" tangle) nil)
 219                                      ((> (length tangle) 0) tangle)))
 220                          (file-name (when base-name
 221                                       ;; decide if we want to add ext to base-name
 222                                       (if (and ext (string= "yes" tangle))
 223                                           (concat base-name "." ext) base-name))))
 224                     (when file-name
 225                       ;; possibly create the parent directories for file
 226                       (when ((lambda (m) (and m (not (string= m "no"))))
 227                              (funcall get-spec :mkdirp))
 228                         (make-directory (file-name-directory file-name) 'parents))
 229                       ;; delete any old versions of file
 230                       (when (and (file-exists-p file-name)
 231                                  (not (member file-name (mapcar #'car path-collector))))
 232                         (delete-file file-name))
 233                       ;; drop source-block to file
 234                       (with-temp-buffer
 235                         (when (fboundp lang-f) (ignore-errors (funcall lang-f)))
 236                         (when (and she-bang (not (member file-name she-banged)))
 237                           (insert (concat she-bang "\n"))
 238                           (setq she-banged (cons file-name she-banged)))
 239                         (org-babel-spec-to-string spec)
 240                         ;; We avoid append-to-file as it does not work with tramp.
 241                         (let ((content (buffer-string)))
 242                           (with-temp-buffer
 243                             (if (file-exists-p file-name)
 244                                 (insert-file-contents file-name))
 245                             (goto-char (point-max))
 246                             ;; Handle :padlines unless first line in file
 247                             (unless (or (string= "no" (cdr (assoc :padline (nth 4 spec))))
 248                                         (= (point) (point-min)))
 249                               (insert "\n"))
 250                             (insert content)
 251                             (write-region nil nil file-name))))
 252                       ;; if files contain she-bangs, then make the executable
 253                       (when she-bang
 254                         (unless tangle-mode (setq tangle-mode #o755)))
 255                       ;; update counter
 256                       (setq block-counter (+ 1 block-counter))
 257                       (add-to-list 'path-collector
 258                                    (cons file-name tangle-mode)
 259                                    nil
 260                                    (lambda (a b) (equal (car a) (car b))))))))
 261               specs)))
 262          (if (equal arg '(4))
 263              (org-babel-tangle-single-block 1 t)
 264            (org-babel-tangle-collect-blocks lang tangle-file)))
 265         (message "Tangled %d code block%s from %s" block-counter
 266                  (if (= block-counter 1) "" "s")
 267                  (file-name-nondirectory
 268                   (buffer-file-name
 269                    (or (buffer-base-buffer) (current-buffer)))))
 270         ;; run `org-babel-post-tangle-hook' in all tangled files
 271         (when org-babel-post-tangle-hook
 272           (mapc
 273            (lambda (file)
 274              (org-babel-with-temp-filebuffer file
 275                (run-hooks 'org-babel-post-tangle-hook)))
 276            (mapcar #'car path-collector)))
 277         ;; set permissions on tangled files
 278         (mapc (lambda (pair)
 279                 (when (cdr pair) (set-file-modes (car pair) (cdr pair))))
 280               path-collector)
 281         (mapcar #'car path-collector)))))
 282
 283 (defun org-babel-tangle-clean ()
 284   "Remove comments inserted by `org-babel-tangle'.
 285 Call this function inside of a source-code file generated by
 286 `org-babel-tangle' to remove all comments inserted automatically
 287 by `org-babel-tangle'.  Warning, this comment removes any lines
 288 containing constructs which resemble org-mode file links or noweb
 289 references."
 290   (interactive)
 291   (goto-char (point-min))
 292   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 293              (re-search-forward (org-babel-noweb-wrap) nil t))
 294     (delete-region (save-excursion (beginning-of-line 1) (point))
 295                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 296
 297 (defvar org-stored-links)
 298 (defvar org-bracket-link-regexp)
 299 (defun org-babel-spec-to-string (spec)
 300   "Insert SPEC into the current file.
 301
 302 Insert the source-code specified by SPEC into the current source
 303 code file.  This function uses `comment-region' which assumes
 304 that the appropriate major-mode is set.  SPEC has the form:
 305
 306   \(start-line file link source-name params body comment)"
 307   (let* ((start-line (nth 0 spec))
 308          (file (nth 1 spec))
 309          (link (nth 2 spec))
 310          (source-name (nth 3 spec))
 311          (body (nth 5 spec))
 312          (comment (nth 6 spec))
 313          (comments (cdr (assoc :comments (nth 4 spec))))
 314          (link-p (or (string= comments "both") (string= comments "link")
 315                      (string= comments "yes") (string= comments "noweb")))
 316          (link-data (mapcar (lambda (el)
 317                               (cons (symbol-name el)
 318                                     ((lambda (le)
 319                                        (if (stringp le) le (format "%S" le)))
 320                                      (eval el))))
 321                             '(start-line file link source-name)))
 322          (insert-comment (lambda (text)
 323                            (when (and comments (not (string= comments "no"))
 324                                       (> (length text) 0))
 325                              (comment-region (point) (progn (insert text) (point)))
 326                              (end-of-line nil) (insert "\n")))))
 327     (when comment (funcall insert-comment comment))
 328     (when link-p
 329       (funcall
 330        insert-comment
 331        (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 332     (insert
 333      (format
 334       "%s\n"
 335       (org-unescape-code-in-string
 336        (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 337     (when link-p
 338       (funcall
 339        insert-comment
 340        (org-fill-template org-babel-tangle-comment-format-end link-data)))))
 341
 342 (defvar org-comment-string) ;; Defined in org.el
 343 (defun org-babel-tangle-collect-blocks (&optional language tangle-file)
 344   "Collect source blocks in the current Org-mode file.
 345 Return an association list of source-code block specifications of
 346 the form used by `org-babel-spec-to-string' grouped by language.
 347 Optional argument LANGUAGE can be used to limit the collected
 348 source code blocks by language.  Optional argument TANGLE-FILE
 349 can be used to limit the collected code blocks by target file."
 350   (let ((block-counter 1) (current-heading "") blocks by-lang)
 351     (org-babel-map-src-blocks (buffer-file-name)
 352       (lambda (new-heading)
 353         (if (not (string= new-heading current-heading))
 354             (progn
 355               (setq block-counter 1)
 356               (setq current-heading new-heading))
 357           (setq block-counter (+ 1 block-counter))))
 358       (replace-regexp-in-string "[ \t]" "-"
 359                                 (condition-case nil
 360                                     (or (nth 4 (org-heading-components))
 361                                         "(dummy for heading without text)")
 362                                   (error (buffer-file-name))))
 363       (let* ((info (org-babel-get-src-block-info 'light))
 364              (src-lang (nth 0 info))
 365              (src-tfile (cdr (assoc :tangle (nth 2 info)))))
 366         (unless (or (string-match (concat "^" org-comment-string) current-heading)
 367                     (string= (cdr (assoc :tangle (nth 2 info))) "no")
 368                     (and tangle-file (not (equal tangle-file src-tfile))))
 369           (unless (and language (not (string= language src-lang)))
 370             ;; Add the spec for this block to blocks under it's language
 371             (setq by-lang (cdr (assoc src-lang blocks)))
 372             (setq blocks (delq (assoc src-lang blocks) blocks))
 373             (setq blocks (cons
 374                           (cons src-lang
 375                                 (cons
 376                                  (org-babel-tangle-single-block
 377                                   block-counter)
 378                                  by-lang)) blocks))))))
 379     ;; Ensure blocks are in the correct order
 380     (setq blocks
 381           (mapcar
 382            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 383            blocks))
 384     blocks))
 385
 386 (defun org-babel-tangle-single-block
 387   (block-counter &optional only-this-block)
 388   "Collect the tangled source for current block.
 389 Return the list of block attributes needed by
 390 `org-babel-tangle-collect-blocks'.
 391 When ONLY-THIS-BLOCK is non-nil, return the full association
 392 list to be used by `org-babel-tangle' directly."
 393   (let* ((info (org-babel-get-src-block-info))
 394          (start-line
 395           (save-restriction (widen)
 396                             (+ 1 (line-number-at-pos (point)))))
 397          (file (buffer-file-name))
 398          (src-lang (nth 0 info))
 399          (params (nth 2 info))
 400          (extra (nth 3 info))
 401          (cref-fmt (or (and (string-match "-l \"\\(.+\\)\"" extra)
 402                             (match-string 1 extra))
 403                        org-coderef-label-format))
 404          (link ((lambda (link)
 405                   (and (string-match org-bracket-link-regexp link)
 406                        (match-string 1 link)))
 407                 (org-no-properties
 408                  (org-store-link nil))))
 409          (source-name
 410           (intern (or (nth 4 info)
 411                       (format "%s:%d"
 412                               (or (ignore-errors (nth 4 (org-heading-components)))
 413                                   "No heading")
 414                               block-counter))))
 415          (expand-cmd
 416           (intern (concat "org-babel-expand-body:" src-lang)))
 417          (assignments-cmd
 418           (intern (concat "org-babel-variable-assignments:" src-lang)))
 419          (body
 420           ((lambda (body) ;; Run the tangle-body-hook
 421              (with-temp-buffer
 422                (insert body)
 423                (when (string-match "-r" extra)
 424                  (goto-char (point-min))
 425                  (while (re-search-forward
 426                          (replace-regexp-in-string "%s" ".+" cref-fmt) nil t)
 427                    (replace-match "")))
 428                (run-hooks 'org-babel-tangle-body-hook)
 429                (buffer-string)))
 430            ((lambda (body) ;; Expand the body in language specific manner
 431               (if (assoc :no-expand params)
 432                   body
 433                 (if (fboundp expand-cmd)
 434                     (funcall expand-cmd body params)
 435                   (org-babel-expand-body:generic
 436                    body params
 437                    (and (fboundp assignments-cmd)
 438                         (funcall assignments-cmd params))))))
 439             (if (org-babel-noweb-p params :tangle)
 440                 (org-babel-expand-noweb-references info)
 441               (nth 1 info)))))
 442          (comment
 443           (when (or (string= "both" (cdr (assoc :comments params)))
 444                     (string= "org" (cdr (assoc :comments params))))
 445             ;; From the previous heading or code-block end
 446             (funcall
 447              org-babel-process-comment-text
 448              (buffer-substring
 449               (max (condition-case nil
 450                        (save-excursion
 451                          (org-back-to-heading t)  ; Sets match data
 452                          (match-end 0))
 453                      (error (point-min)))
 454                    (save-excursion
 455                      (if (re-search-backward
 456                           org-babel-src-block-regexp nil t)
 457                          (match-end 0)
 458                        (point-min))))
 459               (point)))))
 460          (result
 461           (list start-line file link source-name params body comment)))
 462     (if only-this-block
 463         (list (cons src-lang (list result)))
 464       result)))
 465
 466 (defun org-babel-tangle-comment-links ( &optional info)
 467   "Return a list of begin and end link comments for the code block at point."
 468   (let* ((start-line (org-babel-where-is-src-block-head))
 469          (file (buffer-file-name))
 470          (link (org-link-escape (progn (call-interactively 'org-store-link)
 471                                        (org-no-properties
 472                                         (car (pop org-stored-links))))))
 473          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 474          (link-data (mapcar (lambda (el)
 475                               (cons (symbol-name el)
 476                                     ((lambda (le)
 477                                        (if (stringp le) le (format "%S" le)))
 478                                      (eval el))))
 479                             '(start-line file link source-name))))
 480     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 481           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 482
 483 ;; de-tangling functions
 484 (defvar org-bracket-link-analytic-regexp)
 485 (defun org-babel-detangle (&optional source-code-file)
 486   "Propagate changes in source file back original to Org-mode file.
 487 This requires that code blocks were tangled with link comments
 488 which enable the original code blocks to be found."
 489   (interactive)
 490   (save-excursion
 491     (when source-code-file (find-file source-code-file))
 492     (goto-char (point-min))
 493     (let ((counter 0) new-body end)
 494       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 495         (when (re-search-forward
 496                (concat " " (regexp-quote (match-string 5)) " ends here"))
 497           (setq end (match-end 0))
 498           (forward-line -1)
 499           (save-excursion
 500             (when (setq new-body (org-babel-tangle-jump-to-org))
 501               (org-babel-update-block-body new-body)))
 502           (setq counter (+ 1 counter)))
 503         (goto-char end))
 504       (prog1 counter (message "Detangled %d code blocks" counter)))))
 505
 506 (defun org-babel-tangle-jump-to-org ()
 507   "Jump from a tangled code file to the related Org-mode file."
 508   (interactive)
 509   (let ((mid (point))
 510         start body-start end done
 511         target-buffer target-char link path block-name body)
 512     (save-window-excursion
 513       (save-excursion
 514         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 515                     (not ; ever wider searches until matching block comments
 516                      (and (setq start (point-at-eol))
 517                           (setq body-start (save-excursion
 518                                              (forward-line 2) (point-at-bol)))
 519                           (setq link (match-string 0))
 520                           (setq path (match-string 3))
 521                           (setq block-name (match-string 5))
 522                           (save-excursion
 523                             (save-match-data
 524                               (re-search-forward
 525                                (concat " " (regexp-quote block-name)
 526                                        " ends here") nil t)
 527                               (setq end (point-at-bol))))))))
 528         (unless (and start (< start mid) (< mid end))
 529           (error "Not in tangled code"))
 530         (setq body (org-babel-trim (buffer-substring start end))))
 531       (when (string-match "::" path)
 532         (setq path (substring path 0 (match-beginning 0))))
 533       (find-file path) (setq target-buffer (current-buffer))
 534       (goto-char start) (org-open-link-from-string link)
 535       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 536           (org-babel-next-src-block
 537            (string-to-number (match-string 1 block-name)))
 538         (org-babel-goto-named-src-block block-name))
 539       ;; position at the beginning of the code block body
 540       (goto-char (org-babel-where-is-src-block-head))
 541       (forward-line 1)
 542       ;; Use org-edit-special to isolate the code.
 543       (org-edit-special)
 544       ;; Then move forward the correct number of characters in the
 545       ;; code buffer.
 546       (forward-char (- mid body-start))
 547       ;; And return to the Org-mode buffer with the point in the right
 548       ;; place.
 549       (org-edit-src-exit)
 550       (setq target-char (point)))
 551     (org-src-switch-to-buffer target-buffer t)
 552     (prog1 body (goto-char target-char))))
 553
 554 (provide 'ob-tangle)
 555
 556 ;; Local variables:
 557 ;; generated-autoload-file: "org-loaddefs.el"
 558 ;; End:
 559
 560 ;;; ob-tangle.el ends here