lisp/ob-R.el

   1 ;;; ob-R.el --- org-babel functions for R code evaluation
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte, Dan Davison
   6 ;; Keywords: literate programming, reproducible research, R, statistics
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.4
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Org-Babel support for evaluating R code
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'ob-ref)
  32 (require 'ob-comint)
  33 (require 'ob-eval)
  34 (eval-when-compile (require 'cl))
  35
  36 (declare-function orgtbl-to-tsv "org-table" (table params))
  37 (declare-function R "ext:essd-r" (&optional start-args))
  38 (declare-function inferior-ess-send-input "ext:ess-inf" ())
  39 (declare-function ess-make-buffer-current "ext:ess-inf" ())
  40 (declare-function ess-eval-buffer "ext:ess-inf" (vis))
  41 (declare-function org-number-sequence "org-compat" (from &optional to inc))
  42
  43 (defconst org-babel-header-arg-names:R
  44   '(width height bg units pointsize antialias quality compression
  45           res type family title fonts version paper encoding
  46           pagecentre colormodel useDingbats horizontal)
  47   "R-specific header arguments.")
  48
  49 (defvar org-babel-default-header-args:R '())
  50
  51 (defvar org-babel-R-command "R --slave --no-save"
  52   "Name of command to use for executing R code.")
  53
  54 (defun org-babel-expand-body:R (body params &optional graphics-file)
  55   "Expand BODY according to PARAMS, return the expanded body."
  56   (let ((graphics-file
  57          (or graphics-file (org-babel-R-graphical-output-file params))))
  58     (mapconcat
  59      #'identity
  60      ((lambda (inside)
  61         (if graphics-file
  62             (append
  63              (list (org-babel-R-construct-graphics-device-call
  64                     graphics-file params))
  65              inside
  66              (list "dev.off()"))
  67           inside))
  68       (append (org-babel-variable-assignments:R params)
  69               (list body))) "\n")))
  70
  71 (defun org-babel-execute:R (body params)
  72   "Execute a block of R code.
  73 This function is called by `org-babel-execute-src-block'."
  74   (save-excursion
  75     (let* ((result-type (cdr (assoc :result-type params)))
  76            (session (org-babel-R-initiate-session
  77                      (cdr (assoc :session params)) params))
  78            (colnames-p (cdr (assoc :colnames params)))
  79            (rownames-p (cdr (assoc :rownames params)))
  80            (graphics-file (org-babel-R-graphical-output-file params))
  81            (full-body (org-babel-expand-body:R body params graphics-file))
  82            (result
  83             (org-babel-R-evaluate
  84              session full-body result-type
  85              (or (equal "yes" colnames-p)
  86                  (org-babel-pick-name
  87                   (cdr (assoc :colname-names params)) colnames-p))
  88              (or (equal "yes" rownames-p)
  89                  (org-babel-pick-name
  90                   (cdr (assoc :rowname-names params)) rownames-p)))))
  91       (message "result is %S" result)
  92       (if graphics-file nil result))))
  93
  94 (defun org-babel-prep-session:R (session params)
  95   "Prepare SESSION according to the header arguments specified in PARAMS."
  96   (let* ((session (org-babel-R-initiate-session session params))
  97          (var-lines (org-babel-variable-assignments:R params)))
  98     (org-babel-comint-in-buffer session
  99       (mapc (lambda (var)
 100               (end-of-line 1) (insert var) (comint-send-input nil t)
 101               (org-babel-comint-wait-for-output session)) var-lines))
 102     session))
 103
 104 (defun org-babel-load-session:R (session body params)
 105   "Load BODY into SESSION."
 106   (save-window-excursion
 107     (let ((buffer (org-babel-prep-session:R session params)))
 108       (with-current-buffer buffer
 109         (goto-char (process-mark (get-buffer-process (current-buffer))))
 110         (insert (org-babel-chomp body)))
 111       buffer)))
 112
 113 ;; helper functions
 114
 115 (defun org-babel-variable-assignments:R (params)
 116   "Return list of R statements assigning the block's variables"
 117   (let ((vars (mapcar #'cdr (org-babel-get-header params :var))))
 118     (mapcar
 119      (lambda (pair)
 120        (org-babel-R-assign-elisp
 121         (car pair) (cdr pair)
 122         (equal "yes" (cdr (assoc :colnames params)))
 123         (equal "yes" (cdr (assoc :rownames params)))))
 124      (mapcar
 125       (lambda (i)
 126         (cons (car (nth i vars))
 127               (org-babel-reassemble-table
 128                (cdr (nth i vars))
 129                (cdr (nth i (cdr (assoc :colname-names params))))
 130                (cdr (nth i (cdr (assoc :rowname-names params)))))))
 131       (org-number-sequence 0 (1- (length vars)))))))
 132
 133 (defun org-babel-R-quote-tsv-field (s)
 134   "Quote field S for export to R."
 135   (if (stringp s)
 136       (concat "\"" (mapconcat 'identity (split-string s "\"") "\"\"") "\"")
 137     (format "%S" s)))
 138
 139 (defun org-babel-R-assign-elisp (name value colnames-p rownames-p)
 140   "Construct R code assigning the elisp VALUE to a variable named NAME."
 141   (if (listp value)
 142       (let ((transition-file (org-babel-temp-file "R-import-")))
 143         ;; ensure VALUE has an orgtbl structure (depth of at least 2)
 144         (unless (listp (car value)) (setq value (list value)))
 145         (with-temp-file transition-file
 146           (insert (orgtbl-to-tsv value '(:fmt org-babel-R-quote-tsv-field)))
 147           (insert "\n"))
 148         (format "%s <- read.table(\"%s\", header=%s, row.names=%s, sep=\"\\t\", as.is=TRUE)"
 149                 name (org-babel-process-file-name transition-file 'noquote)
 150                 (if (or (eq (nth 1 value) 'hline) colnames-p) "TRUE" "FALSE")
 151                 (if rownames-p "1" "NULL")))
 152     (format "%s <- %s" name (org-babel-R-quote-tsv-field value))))
 153
 154 (defvar ess-ask-for-ess-directory nil)
 155 (defun org-babel-R-initiate-session (session params)
 156   "If there is not a current R process then create one."
 157   (unless (string= session "none")
 158     (let ((session (or session "*R*"))
 159           (ess-ask-for-ess-directory
 160            (and ess-ask-for-ess-directory (not (cdr (assoc :dir params))))))
 161       (if (org-babel-comint-buffer-livep session)
 162           session
 163         (save-window-excursion
 164           (require 'ess) (R)
 165           (rename-buffer
 166            (if (bufferp session)
 167                (buffer-name session)
 168              (if (stringp session)
 169                  session
 170                (buffer-name))))
 171           (current-buffer))))))
 172
 173 (defvar ess-local-process-name nil)
 174 (defun org-babel-R-associate-session (session)
 175   "Associate R code buffer with an R session.
 176 Make SESSION be the inferior ESS process associated with the
 177 current code buffer."
 178   (setq ess-local-process-name
 179         (process-name (get-buffer-process session)))
 180   (ess-make-buffer-current))
 181
 182 (defun org-babel-R-graphical-output-file (params)
 183   "Name of file to which R should send graphical output."
 184   (and (member "graphics" (cdr (assq :result-params params)))
 185        (cdr (assq :file params))))
 186
 187 (defun org-babel-R-construct-graphics-device-call (out-file params)
 188   "Construct the call to the graphics device."
 189   (let ((devices
 190          '((:bmp . "bmp")
 191            (:jpg . "jpeg")
 192            (:jpeg . "jpeg")
 193            (:tiff . "tiff")
 194            (:png . "png")
 195            (:svg . "svg")
 196            (:pdf . "pdf")
 197            (:ps . "postscript")
 198            (:postscript . "postscript")))
 199         (allowed-args '(:width :height :bg :units :pointsize
 200                                :antialias :quality :compression :res
 201                                :type :family :title :fonts :version
 202                                :paper :encoding :pagecentre :colormodel
 203                                :useDingbats :horizontal))
 204         (device (and (string-match ".+\\.\\([^.]+\\)" out-file)
 205                      (match-string 1 out-file)))
 206         (extra-args (cdr (assq :R-dev-args params))) filearg args)
 207     (setq device (or (and device (cdr (assq (intern (concat ":" device))
 208                                             devices))) "png"))
 209     (setq filearg
 210           (if (member device '("pdf" "postscript" "svg")) "file" "filename"))
 211     (setq args (mapconcat
 212                 (lambda (pair)
 213                   (if (member (car pair) allowed-args)
 214                       (format ",%s=%s"
 215                               (substring (symbol-name (car pair)) 1)
 216                               (cdr pair)) ""))
 217                 params ""))
 218     (format "%s(%s=\"%s\"%s%s%s)"
 219             device filearg out-file args
 220             (if extra-args "," "") (or extra-args ""))))
 221
 222 (defvar org-babel-R-eoe-indicator "'org_babel_R_eoe'")
 223 (defvar org-babel-R-eoe-output "[1] \"org_babel_R_eoe\"")
 224
 225 (defvar org-babel-R-write-object-command "{function(object, transfer.file) {object;invisible(if(inherits(try(write.table(object, file=transfer.file, sep=\"\\t\", na=\"nil\",row.names=%s, col.names=%s, quote=FALSE), silent=TRUE),\"try-error\")) {if(!file.exists(transfer.file)) file.create(transfer.file)})}}(object=%s, transfer.file=\"%s\")")
 226
 227 (defun org-babel-R-evaluate
 228   (session body result-type column-names-p row-names-p)
 229   "Evaluate R code in BODY."
 230   (if session
 231       (org-babel-R-evaluate-session
 232        session body result-type column-names-p row-names-p)
 233     (org-babel-R-evaluate-external-process
 234      body result-type column-names-p row-names-p)))
 235
 236 (defun org-babel-R-evaluate-external-process
 237   (body result-type column-names-p row-names-p)
 238   "Evaluate BODY in external R process.
 239 If RESULT-TYPE equals 'output then return standard output as a
 240 string. If RESULT-TYPE equals 'value then return the value of the
 241 last statement in BODY, as elisp."
 242   (case result-type
 243     (value
 244      (let ((tmp-file (org-babel-temp-file "R-")))
 245        (org-babel-eval org-babel-R-command
 246                        (format org-babel-R-write-object-command
 247                                (if row-names-p "TRUE" "FALSE")
 248                                (if column-names-p
 249                                    (if row-names-p "NA" "TRUE")
 250                                  "FALSE")
 251                                (format "{function ()\n{\n%s\n}}()" body)
 252                                (org-babel-process-file-name tmp-file 'noquote)))
 253        (org-babel-R-process-value-result
 254         (org-babel-import-elisp-from-file tmp-file '(16)) column-names-p)))
 255     (output (org-babel-eval org-babel-R-command body))))
 256
 257 (defun org-babel-R-evaluate-session
 258   (session body result-type column-names-p row-names-p)
 259   "Evaluate BODY in SESSION.
 260 If RESULT-TYPE equals 'output then return standard output as a
 261 string. If RESULT-TYPE equals 'value then return the value of the
 262 last statement in BODY, as elisp."
 263   (case result-type
 264     (value
 265      (with-temp-buffer
 266        (insert (org-babel-chomp body))
 267        (let ((ess-local-process-name
 268               (process-name (get-buffer-process session))))
 269          (ess-eval-buffer nil)))
 270      (let ((tmp-file (org-babel-temp-file "R-")))
 271        (org-babel-comint-eval-invisibly-and-wait-for-file
 272         session tmp-file
 273         (format org-babel-R-write-object-command
 274                 (if row-names-p "TRUE" "FALSE")
 275                 (if column-names-p
 276                     (if row-names-p "NA" "TRUE")
 277                   "FALSE")
 278                 ".Last.value" (org-babel-process-file-name tmp-file 'noquote)))
 279        (org-babel-R-process-value-result
 280         (org-babel-import-elisp-from-file tmp-file '(16))  column-names-p)))
 281     (output
 282      (mapconcat
 283       #'org-babel-chomp
 284       (butlast
 285        (delq nil
 286              (mapcar
 287               (lambda (line) (when (> (length line) 0) line))
 288               (mapcar
 289                (lambda (line) ;; cleanup extra prompts left in output
 290                  (if (string-match
 291                       "^\\([ ]*[>+][ ]?\\)+\\([[0-9]+\\|[ ]\\)" line)
 292                      (substring line (match-end 1))
 293                    line))
 294                (org-babel-comint-with-output (session org-babel-R-eoe-output)
 295                  (insert (mapconcat #'org-babel-chomp
 296                                     (list body org-babel-R-eoe-indicator)
 297                                     "\n"))
 298                  (inferior-ess-send-input)))))) "\n"))))
 299
 300 (defun org-babel-R-process-value-result (result column-names-p)
 301   "R-specific processing of return value.
 302 Insert hline if column names in output have been requested."
 303   (if column-names-p
 304       (cons (car result) (cons 'hline (cdr result)))
 305     result))
 306
 307 (provide 'ob-R)
 308
 309 ;; arch-tag: cd4c7298-503b-450f-a3c2-f3e74b630237
 310
 311 ;;; ob-R.el ends here