lisp/org-archive.el

   1 ;;; org-archive.el --- Archiving for Org             -*- lexical-binding: t; -*-
   2
   3 ;; Copyright (C) 2004-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file contains the face definitions for Org.
  28
  29 ;;; Code:
  30
  31 (require 'org)
  32
  33 (declare-function org-element-type "org-element" (element))
  34 (declare-function org-datetree-find-date-create "org-datetree" (date &optional keep-restriction))
  35 (declare-function org-inlinetask-remove-END-maybe "org-inlinetask" ())
  36
  37 (defcustom org-archive-default-command 'org-archive-subtree
  38   "The default archiving command."
  39   :group 'org-archive
  40   :type '(choice
  41           (const org-archive-subtree)
  42           (const org-archive-to-archive-sibling)
  43           (const org-archive-set-tag)))
  44
  45 (defcustom org-archive-reversed-order nil
  46   "Non-nil means make the tree first child under the archive heading, not last."
  47   :group 'org-archive
  48   :version "24.1"
  49   :type 'boolean)
  50
  51 (defcustom org-archive-sibling-heading "Archive"
  52   "Name of the local archive sibling that is used to archive entries locally.
  53 Locally means: in the tree, under a sibling.
  54 See `org-archive-to-archive-sibling' for more information."
  55   :group 'org-archive
  56   :type 'string)
  57
  58 (defcustom org-archive-mark-done nil
  59   "Non-nil means mark entries as DONE when they are moved to the archive file.
  60 This can be a string to set the keyword to use.  When non-nil, Org will
  61 use the first keyword in its list that means done."
  62   :group 'org-archive
  63   :type '(choice
  64           (const :tag "No" nil)
  65           (const :tag "Yes" t)
  66           (string :tag "Use this keyword")))
  67
  68 (defcustom org-archive-stamp-time t
  69   "Non-nil means add a time stamp to entries moved to an archive file.
  70 This variable is obsolete and has no effect anymore, instead add or remove
  71 `time' from the variable `org-archive-save-context-info'."
  72   :group 'org-archive
  73   :type 'boolean)
  74
  75 (defcustom org-archive-file-header-format "\nArchived entries from file %s\n\n"
  76   "The header format string for newly created archive files.
  77 When nil, no header will be inserted.
  78 When a string, a %s formatter will be replaced by the file name."
  79   :group 'org-archive
  80   :version "24.4"
  81   :package-version '(Org . "8.0")
  82   :type 'string)
  83
  84 (defcustom org-archive-subtree-add-inherited-tags 'infile
  85   "Non-nil means append inherited tags when archiving a subtree."
  86   :group 'org-archive
  87   :version "24.1"
  88   :type '(choice
  89           (const :tag "Never" nil)
  90           (const :tag "When archiving a subtree to the same file" infile)
  91           (const :tag "Always" t)))
  92
  93 (defcustom org-archive-save-context-info '(time file olpath category todo itags)
  94   "Parts of context info that should be stored as properties when archiving.
  95 When a subtree is moved to an archive file, it loses information given by
  96 context, like inherited tags, the category, and possibly also the TODO
  97 state (depending on the variable `org-archive-mark-done').
  98 This variable can be a list of any of the following symbols:
  99
 100 time       The time of archiving.
 101 file       The file where the entry originates.
 102 ltags      The local tags, in the headline of the subtree.
 103 itags      The tags the subtree inherits from further up the hierarchy.
 104 todo       The pre-archive TODO state.
 105 category   The category, taken from file name or #+CATEGORY lines.
 106 olpath     The outline path to the item.  These are all headlines above
 107            the current item, separated by /, like a file path.
 108
 109 For each symbol present in the list, a property will be created in
 110 the archived entry, with a prefix \"ARCHIVE_\", to remember this
 111 information."
 112   :group 'org-archive
 113   :type '(set :greedy t
 114               (const :tag "Time" time)
 115               (const :tag "File" file)
 116               (const :tag "Category" category)
 117               (const :tag "TODO state" todo)
 118               (const :tag "Priority" priority)
 119               (const :tag "Inherited tags" itags)
 120               (const :tag "Outline path" olpath)
 121               (const :tag "Local tags" ltags)))
 122
 123 (defvar org-archive-hook nil
 124   "Hook run after successfully archiving a subtree.
 125 Hook functions are called with point on the subtree in the
 126 original file.  At this stage, the subtree has been added to the
 127 archive location, but not yet deleted from the original file.")
 128
 129 (defun org-get-local-archive-location ()
 130   "Get the archive location applicable at point."
 131   (let ((re "^[ \t]*#\\+ARCHIVE:[ \t]+\\(\\S-.*\\S-\\)[ \t]*$")
 132         prop)
 133     (save-excursion
 134       (save-restriction
 135         (widen)
 136         (setq prop (org-entry-get nil "ARCHIVE" 'inherit))
 137         (cond
 138          ((and prop (string-match "\\S-" prop))
 139           prop)
 140          ((or (re-search-backward re nil t)
 141               (re-search-forward re nil t))
 142           (match-string 1))
 143          (t org-archive-location))))))
 144
 145 ;;;###autoload
 146 (defun org-add-archive-files (files)
 147   "Splice the archive files into the list of files.
 148 This implies visiting all these files and finding out what the
 149 archive file is."
 150   (org-uniquify
 151    (apply
 152     'append
 153     (mapcar
 154      (lambda (f)
 155        (if (not (file-exists-p f))
 156            nil
 157          (with-current-buffer (org-get-agenda-file-buffer f)
 158            (cons f (org-all-archive-files)))))
 159      files))))
 160
 161 (defun org-all-archive-files ()
 162   "Get a list of all archive files used in the current buffer."
 163   (let ((case-fold-search t)
 164         files)
 165     (org-with-wide-buffer
 166      (goto-char (point-min))
 167      (while (re-search-forward
 168              "^[ \t]*\\(#\\+\\|:\\)ARCHIVE:[ \t]+\\(.*\\)"
 169              nil t)
 170        (when (save-match-data
 171                (if (eq (match-string 1) ":") (org-at-property-p)
 172                  (eq (org-element-type (org-element-at-point)) 'keyword)))
 173          (let ((file (org-extract-archive-file
 174                       (match-string-no-properties 2))))
 175            (when (and (org-string-nw-p file) (file-exists-p file))
 176              (push file files))))))
 177     (setq files (nreverse files))
 178     (let ((file (org-extract-archive-file)))
 179       (when (and (org-string-nw-p file) (file-exists-p file))
 180         (push file files)))
 181     files))
 182
 183 (defun org-extract-archive-file (&optional location)
 184   "Extract and expand the file name from archive LOCATION.
 185 if LOCATION is not given, the value of `org-archive-location' is used."
 186   (setq location (or location org-archive-location))
 187   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 188       (if (= (match-beginning 1) (match-end 1))
 189           (buffer-file-name (buffer-base-buffer))
 190         (expand-file-name
 191          (format (match-string 1 location)
 192                  (file-name-nondirectory
 193                   (buffer-file-name (buffer-base-buffer))))))))
 194
 195 (defun org-extract-archive-heading (&optional location)
 196   "Extract the heading from archive LOCATION.
 197 if LOCATION is not given, the value of `org-archive-location' is used."
 198   (setq location (or location org-archive-location))
 199   (if (string-match "\\(.*\\)::\\(.*\\)" location)
 200       (format (match-string 2 location)
 201               (file-name-nondirectory
 202                (buffer-file-name (buffer-base-buffer))))))
 203
 204 ;;;###autoload
 205 (defun org-archive-subtree (&optional find-done)
 206   "Move the current subtree to the archive.
 207 The archive can be a certain top-level heading in the current file, or in
 208 a different file.  The tree will be moved to that location, the subtree
 209 heading be marked DONE, and the current time will be added.
 210
 211 When called with a single prefix argument FIND-DONE, find whole trees without any
 212 open TODO items and archive them (after getting confirmation from the user).
 213 When called with a double prefix argument, find whole trees with timestamps before
 214 today and archive them (after getting confirmation from the user).
 215 If the cursor is not at a headline when these commands are called, try all level
 216 1 trees.  If the cursor is on a headline, only try the direct children of
 217 this heading."
 218   (interactive "P")
 219   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 220       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 221                     'region-start-level 'region))
 222             org-loop-over-headlines-in-active-region)
 223         (org-map-entries
 224          `(progn (setq org-map-continue-from (progn (org-back-to-heading) (point)))
 225                  (org-archive-subtree ,find-done))
 226          org-loop-over-headlines-in-active-region
 227          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 228     (cond
 229      ((equal find-done '(4))  (org-archive-all-done))
 230      ((equal find-done '(16)) (org-archive-all-old))
 231      (t
 232       ;; Save all relevant TODO keyword-relatex variables
 233       (let* ((tr-org-todo-keywords-1 org-todo-keywords-1)
 234              (tr-org-todo-kwd-alist org-todo-kwd-alist)
 235              (tr-org-done-keywords org-done-keywords)
 236              (tr-org-todo-regexp org-todo-regexp)
 237              (tr-org-todo-line-regexp org-todo-line-regexp)
 238              (tr-org-odd-levels-only org-odd-levels-only)
 239              (this-buffer (current-buffer))
 240              (time (format-time-string
 241                     (substring (cdr org-time-stamp-formats) 1 -1)))
 242              (file (abbreviate-file-name
 243                     (or (buffer-file-name (buffer-base-buffer))
 244                         (error "No file associated to buffer"))))
 245              (location (org-get-local-archive-location))
 246              (afile (or (org-extract-archive-file location)
 247                         (error "Invalid `org-archive-location'")))
 248              (heading (org-extract-archive-heading location))
 249              (infile-p (equal file (abbreviate-file-name (or afile ""))))
 250              (newfile-p (and (org-string-nw-p afile)
 251                              (not (file-exists-p afile))))
 252              (buffer (cond ((not (org-string-nw-p afile)) this-buffer)
 253                            ((find-buffer-visiting afile))
 254                            ((find-file-noselect afile))
 255                            (t (error "Cannot access file \"%s\"" afile))))
 256              level datetree-date datetree-subheading-p)
 257         (when (string-match "\\`datetree/" heading)
 258           ;; Replace with ***, to represent the 3 levels of headings the
 259           ;; datetree has.
 260           (setq heading (replace-regexp-in-string "\\`datetree/" "***" heading))
 261           (setq datetree-subheading-p (> (length heading) 3))
 262           (setq datetree-date (org-date-to-gregorian
 263                                (or (org-entry-get nil "CLOSED" t) time))))
 264         (if (and (> (length heading) 0)
 265                  (string-match "^\\*+" heading))
 266             (setq level (match-end 0))
 267           (setq heading nil level 0))
 268         (save-excursion
 269           (org-back-to-heading t)
 270           ;; Get context information that will be lost by moving the
 271           ;; tree.  See `org-archive-save-context-info'.
 272           (let* ((all-tags (org-get-tags-at))
 273                  (local-tags (org-get-tags))
 274                  (inherited-tags (org-delete-all local-tags all-tags))
 275                  (context
 276                   `((category . ,(org-get-category nil 'force-refresh))
 277                     (file . ,file)
 278                     (itags . ,(mapconcat #'identity inherited-tags " "))
 279                     (ltags . ,(mapconcat #'identity local-tags " "))
 280                     (olpath . ,(mapconcat #'identity
 281                                           (org-get-outline-path)
 282                                           "/"))
 283                     (time . ,time)
 284                     (todo . ,(org-entry-get (point) "TODO")))))
 285             ;; We first only copy, in case something goes wrong
 286             ;; we need to protect `this-command', to avoid kill-region sets it,
 287             ;; which would lead to duplication of subtrees
 288             (let (this-command) (org-copy-subtree 1 nil t))
 289             (set-buffer buffer)
 290             ;; Enforce Org mode for the archive buffer
 291             (if (not (derived-mode-p 'org-mode))
 292                 ;; Force the mode for future visits.
 293                 (let ((org-insert-mode-line-in-empty-file t)
 294                       (org-inhibit-startup t))
 295                   (call-interactively 'org-mode)))
 296             (when (and newfile-p org-archive-file-header-format)
 297               (goto-char (point-max))
 298               (insert (format org-archive-file-header-format
 299                               (buffer-file-name this-buffer))))
 300             (when datetree-date
 301               (require 'org-datetree)
 302               (org-datetree-find-date-create datetree-date)
 303               (org-narrow-to-subtree))
 304             ;; Force the TODO keywords of the original buffer
 305             (let ((org-todo-line-regexp tr-org-todo-line-regexp)
 306                   (org-todo-keywords-1 tr-org-todo-keywords-1)
 307                   (org-todo-kwd-alist tr-org-todo-kwd-alist)
 308                   (org-done-keywords tr-org-done-keywords)
 309                   (org-todo-regexp tr-org-todo-regexp)
 310                   (org-todo-line-regexp tr-org-todo-line-regexp)
 311                   (org-odd-levels-only
 312                    (if (local-variable-p 'org-odd-levels-only (current-buffer))
 313                        org-odd-levels-only
 314                      tr-org-odd-levels-only)))
 315               (goto-char (point-min))
 316               (outline-show-all)
 317               (if (and heading (not (and datetree-date (not datetree-subheading-p))))
 318                   (progn
 319                     (if (re-search-forward
 320                          (concat "^" (regexp-quote heading)
 321                                  "[ \t]*\\(:[[:alnum:]_@#%:]+:\\)?[ \t]*\\($\\|\r\\)")
 322                          nil t)
 323                         (goto-char (match-end 0))
 324                       ;; Heading not found, just insert it at the end
 325                       (goto-char (point-max))
 326                       (or (bolp) (insert "\n"))
 327                       ;; datetrees don't need too much spacing
 328                       (insert (if datetree-date "" "\n") heading "\n")
 329                       (end-of-line 0))
 330                     ;; Make the subtree visible
 331                     (outline-show-subtree)
 332                     (if org-archive-reversed-order
 333                         (progn
 334                           (org-back-to-heading t)
 335                           (outline-next-heading))
 336                       (org-end-of-subtree t))
 337                     (skip-chars-backward " \t\r\n")
 338                     (and (looking-at "[ \t\r\n]*")
 339                          ;; datetree archives don't need so much spacing.
 340                          (replace-match (if datetree-date "\n" "\n\n"))))
 341                 ;; No specific heading, just go to end of file.
 342                 (goto-char (point-max))
 343                 ;; Subtree narrowing can let the buffer end on
 344                 ;; a headline.  `org-paste-subtree' then deletes it.
 345                 ;; To prevent this, make sure visible part of buffer
 346                 ;; always terminates on a new line, while limiting
 347                 ;; number of blank lines in a date tree.
 348                 (unless (and datetree-date (bolp)) (insert "\n")))
 349               ;; Paste
 350               (org-paste-subtree (org-get-valid-level level (and heading 1)))
 351               ;; Shall we append inherited tags?
 352               (and inherited-tags
 353                    (or (and (eq org-archive-subtree-add-inherited-tags 'infile)
 354                             infile-p)
 355                        (eq org-archive-subtree-add-inherited-tags t))
 356                    (org-set-tags-to all-tags))
 357               ;; Mark the entry as done
 358               (when (and org-archive-mark-done
 359                          (let ((case-fold-search nil))
 360                            (looking-at org-todo-line-regexp))
 361                          (or (not (match-end 2))
 362                              (not (member (match-string 2) org-done-keywords))))
 363                 (let (org-log-done org-todo-log-states)
 364                   (org-todo
 365                    (car (or (member org-archive-mark-done org-done-keywords)
 366                             org-done-keywords)))))
 367
 368               ;; Add the context info.
 369               (dolist (item org-archive-save-context-info)
 370                 (let ((value (cdr (assq item context))))
 371                   (when (org-string-nw-p value)
 372                     (org-entry-put
 373                      (point)
 374                      (concat "ARCHIVE_" (upcase (symbol-name item)))
 375                      value))))
 376               (widen)
 377               ;; Save and kill the buffer, if it is not the same
 378               ;; buffer.
 379               (unless (eq this-buffer buffer) (save-buffer)))))
 380         ;; Here we are back in the original buffer.  Everything seems
 381         ;; to have worked.  So now run hooks, cut the tree and finish
 382         ;; up.
 383         (run-hooks 'org-archive-hook)
 384         (let (this-command) (org-cut-subtree))
 385         (when (featurep 'org-inlinetask)
 386           (org-inlinetask-remove-END-maybe))
 387         (setq org-markers-to-move nil)
 388         (message "Subtree archived %s"
 389                  (if (eq this-buffer buffer)
 390                      (concat "under heading: " heading)
 391                    (concat "in file: " (abbreviate-file-name afile)))))))
 392     (org-reveal)
 393     (if (looking-at "^[ \t]*$")
 394         (outline-next-visible-heading 1))))
 395
 396 ;;;###autoload
 397 (defun org-archive-to-archive-sibling ()
 398   "Archive the current heading by moving it under the archive sibling.
 399
 400 The archive sibling is a sibling of the heading with the heading name
 401 `org-archive-sibling-heading' and an `org-archive-tag' tag.  If this
 402 sibling does not exist, it will be created at the end of the subtree.
 403
 404 Archiving time is retained in the ARCHIVE_TIME node property."
 405   (interactive)
 406   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 407       (let ((cl (when (eq org-loop-over-headlines-in-active-region 'start-level)
 408                   'region-start-level 'region))
 409             org-loop-over-headlines-in-active-region)
 410         (org-map-entries
 411          '(progn (setq org-map-continue-from
 412                        (progn (org-back-to-heading)
 413                               (if (looking-at (concat "^.*:" org-archive-tag ":.*$"))
 414                                   (org-end-of-subtree t)
 415                                 (point))))
 416                  (when (org-at-heading-p)
 417                    (org-archive-to-archive-sibling)))
 418          org-loop-over-headlines-in-active-region
 419          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 420     (save-restriction
 421       (widen)
 422       (let (b e pos leader level)
 423         (org-back-to-heading t)
 424         (looking-at org-outline-regexp)
 425         (setq leader (match-string 0)
 426               level (funcall outline-level))
 427         (setq pos (point))
 428         (condition-case nil
 429             (outline-up-heading 1 t)
 430           (error (setq e (point-max)) (goto-char (point-min))))
 431         (setq b (point))
 432         (unless e
 433           (condition-case nil
 434               (org-end-of-subtree t t)
 435             (error (goto-char (point-max))))
 436           (setq e (point)))
 437         (goto-char b)
 438         (unless (re-search-forward
 439                  (concat "^" (regexp-quote leader)
 440                          "[ \t]*"
 441                          org-archive-sibling-heading
 442                          "[ \t]*:"
 443                          org-archive-tag ":") e t)
 444           (goto-char e)
 445           (or (bolp) (newline))
 446           (insert leader org-archive-sibling-heading "\n")
 447           (beginning-of-line 0)
 448           (org-toggle-tag org-archive-tag 'on))
 449         (beginning-of-line 1)
 450         (if org-archive-reversed-order
 451             (outline-next-heading)
 452           (org-end-of-subtree t t))
 453         (save-excursion
 454           (goto-char pos)
 455           (let ((this-command this-command)) (org-cut-subtree)))
 456         (org-paste-subtree (org-get-valid-level level 1))
 457         (org-set-property
 458          "ARCHIVE_TIME"
 459          (format-time-string
 460           (substring (cdr org-time-stamp-formats) 1 -1)))
 461         (outline-up-heading 1 t)
 462         (outline-hide-subtree)
 463         (org-cycle-show-empty-lines 'folded)
 464         (goto-char pos)))
 465     (org-reveal)
 466     (if (looking-at "^[ \t]*$")
 467         (outline-next-visible-heading 1))))
 468
 469 (defun org-archive-all-done (&optional tag)
 470   "Archive sublevels of the current tree without open TODO items.
 471 If the cursor is not on a headline, try all level 1 trees.  If
 472 it is on a headline, try all direct children.
 473 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 474   (org-archive-all-matches
 475    (lambda (_beg end)
 476      (let ((case-fold-search nil))
 477        (unless (re-search-forward org-not-done-heading-regexp end t)
 478          "no open TODO items")))
 479    tag))
 480
 481 (defun org-archive-all-old (&optional tag)
 482   "Archive sublevels of the current tree with timestamps prior to today.
 483 If the cursor is not on a headline, try all level 1 trees.  If
 484 it is on a headline, try all direct children.
 485 When TAG is non-nil, don't move trees, but mark them with the ARCHIVE tag."
 486   (org-archive-all-matches
 487    (lambda (_beg end)
 488      (let (ts)
 489        (and (re-search-forward org-ts-regexp end t)
 490             (setq ts (match-string 0))
 491             (< (org-time-stamp-to-now ts) 0)
 492             (if (not (looking-at
 493                       (concat "--\\(" org-ts-regexp "\\)")))
 494                 (concat "old timestamp " ts)
 495               (setq ts (concat "old timestamp " ts (match-string 0)))
 496               (and (< (org-time-stamp-to-now (match-string 1)) 0)
 497                    ts)))))
 498    tag))
 499
 500 (defun org-archive-all-matches (predicate &optional tag)
 501   "Archive sublevels of the current tree that match PREDICATE.
 502
 503 PREDICATE is a function of two arguments, BEG and END, which
 504 specify the beginning and end of the headline being considered.
 505 It is called with point positioned at BEG.  The headline will be
 506 archived if PREDICATE returns non-nil.  If the return value of
 507 PREDICATE is a string, it should describe the reason for
 508 archiving the heading.
 509
 510 If the cursor is not on a headline, try all level 1 trees.  If it
 511 is on a headline, try all direct children.  When TAG is non-nil,
 512 don't move trees, but mark them with the ARCHIVE tag."
 513   (let ((rea (concat ".*:" org-archive-tag ":")) re1
 514         (begm (make-marker))
 515         (endm (make-marker))
 516         (question (if tag "Set ARCHIVE tag? "
 517                     "Move subtree to archive? "))
 518         reason beg end (cntarch 0))
 519     (if (org-at-heading-p)
 520         (progn
 521           (setq re1 (concat "^" (regexp-quote
 522                                  (make-string
 523                                   (+ (- (match-end 0) (match-beginning 0) 1)
 524                                      (if org-odd-levels-only 2 1))
 525                                   ?*))
 526                             " "))
 527           (move-marker begm (point))
 528           (move-marker endm (org-end-of-subtree t)))
 529       (setq re1 "^* ")
 530       (move-marker begm (point-min))
 531       (move-marker endm (point-max)))
 532     (save-excursion
 533       (goto-char begm)
 534       (while (re-search-forward re1 endm t)
 535         (setq beg (match-beginning 0)
 536               end (save-excursion (org-end-of-subtree t) (point)))
 537         (goto-char beg)
 538         (if (not (setq reason (funcall predicate beg end)))
 539             (goto-char end)
 540           (goto-char beg)
 541           (if (and (or (not tag) (not (looking-at rea)))
 542                    (y-or-n-p
 543                     (if (stringp reason)
 544                         (concat question "(" reason ")")
 545                       question)))
 546               (progn
 547                 (if tag
 548                     (org-toggle-tag org-archive-tag 'on)
 549                   (org-archive-subtree))
 550                 (setq cntarch (1+ cntarch)))
 551             (goto-char end)))))
 552     (message "%d trees archived" cntarch)))
 553
 554 ;;;###autoload
 555 (defun org-toggle-archive-tag (&optional find-done)
 556   "Toggle the archive tag for the current headline.
 557 With prefix ARG, check all children of current headline and offer tagging
 558 the children that do not contain any open TODO items."
 559   (interactive "P")
 560   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 561       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 562                     'region-start-level 'region))
 563             org-loop-over-headlines-in-active-region)
 564         (org-map-entries
 565          `(org-toggle-archive-tag ,find-done)
 566          org-loop-over-headlines-in-active-region
 567          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 568     (if find-done
 569         (org-archive-all-done 'tag)
 570       (let (set)
 571         (save-excursion
 572           (org-back-to-heading t)
 573           (setq set (org-toggle-tag org-archive-tag))
 574           (when set (org-flag-subtree t)))
 575         (and set (beginning-of-line 1))
 576         (message "Subtree %s" (if set "archived" "unarchived"))))))
 577
 578 (defun org-archive-set-tag ()
 579   "Set the ARCHIVE tag."
 580   (interactive)
 581   (if (and (org-region-active-p) org-loop-over-headlines-in-active-region)
 582       (let ((cl (if (eq org-loop-over-headlines-in-active-region 'start-level)
 583                     'region-start-level 'region))
 584             org-loop-over-headlines-in-active-region)
 585         (org-map-entries
 586          'org-archive-set-tag
 587          org-loop-over-headlines-in-active-region
 588          cl (if (outline-invisible-p) (org-end-of-subtree nil t))))
 589     (org-toggle-tag org-archive-tag 'on)))
 590
 591 ;;;###autoload
 592 (defun org-archive-subtree-default ()
 593   "Archive the current subtree with the default command.
 594 This command is set with the variable `org-archive-default-command'."
 595   (interactive)
 596   (call-interactively org-archive-default-command))
 597
 598 ;;;###autoload
 599 (defun org-archive-subtree-default-with-confirmation ()
 600   "Archive the current subtree with the default command.
 601 This command is set with the variable `org-archive-default-command'."
 602   (interactive)
 603   (if (y-or-n-p "Archive this subtree or entry? ")
 604       (call-interactively org-archive-default-command)
 605     (error "Abort")))
 606
 607 (provide 'org-archive)
 608
 609 ;; Local variables:
 610 ;; generated-autoload-file: "org-loaddefs.el"
 611 ;; End:
 612
 613 ;;; org-archive.el ends here