lisp/ob-tangle.el

   1 ;;; ob-tangle.el --- extract source code from org-mode files
   2
   3 ;; Copyright (C) 2009, 2010  Free Software Foundation, Inc.
   4
   5 ;; Author: Eric Schulte
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Extract the code from source blocks out into raw source-code files.
  28
  29 ;;; Code:
  30 (require 'ob)
  31 (require 'org-src)
  32 (eval-when-compile
  33   (require 'cl))
  34
  35 (declare-function org-link-escape "org" (text &optional table))
  36 (declare-function org-heading-components "org" ())
  37 (declare-function org-back-to-heading "org" (invisible-ok))
  38 (declare-function org-fill-template "org" (template alist))
  39 (declare-function org-babel-update-block-body "org" (new-body))
  40 (declare-function make-directory "files" (dir &optional parents))
  41
  42 ;;;###autoload
  43 (defcustom org-babel-tangle-lang-exts
  44   '(("emacs-lisp" . "el"))
  45   "Alist mapping languages to their file extensions.
  46 The key is the language name, the value is the string that should
  47 be inserted as the extension commonly used to identify files
  48 written in this language.  If no entry is found in this list,
  49 then the name of the language is used."
  50   :group 'org-babel-tangle
  51   :type '(repeat
  52           (cons
  53            (string "Language name")
  54            (string "File Extension"))))
  55
  56 (defcustom org-babel-post-tangle-hook nil
  57   "Hook run in code files tangled by `org-babel-tangle'."
  58   :group 'org-babel
  59   :type 'hook)
  60
  61 (defcustom org-babel-pre-tangle-hook '(save-buffer)
  62   "Hook run at the beginning of `org-babel-tangle'."
  63   :group 'org-babel
  64   :type 'hook)
  65
  66 (defcustom org-babel-tangle-body-hook nil
  67   "Hook run over the contents of each code block body."
  68   :group 'org-babel
  69   :type 'hook)
  70
  71 (defcustom org-babel-tangle-comment-format-beg "[[%link][%source-name]]"
  72   "Format of inserted comments in tangled code files.
  73 The following format strings can be used to insert special
  74 information into the output using `org-fill-template'.
  75 %start-line --- the line number at the start of the code block
  76 %file --------- the file from which the code block was tangled
  77 %link --------- Org-mode style link to the code block
  78 %source-name -- name of the code block
  79
  80 Whether or not comments are inserted during tangling is
  81 controlled by the :comments header argument."
  82   :group 'org-babel
  83   :type 'string)
  84
  85 (defcustom org-babel-tangle-comment-format-end "%source-name ends here"
  86   "Format of inserted comments in tangled code files.
  87 The following format strings can be used to insert special
  88 information into the output using `org-fill-template'.
  89 %start-line --- the line number at the start of the code block
  90 %file --------- the file from which the code block was tangled
  91 %link --------- Org-mode style link to the code block
  92 %source-name -- name of the code block
  93
  94 Whether or not comments are inserted during tangling is
  95 controlled by the :comments header argument."
  96   :group 'org-babel
  97   :type 'string)
  98
  99 (defcustom org-babel-tangle-named-block-combination nil
 100   "Combine blocks of the same name during tangling."
 101   :group 'org-babel
 102   :type '(choice
 103           (const :tag "Default: no special handling" nil)
 104           (const :tag "Append all blocks of the same name" append)
 105           (const :tag "Only keep the first block of the same name" first)
 106           (const :tag "Only keep the last block of the same name" last)))
 107
 108 (defun org-babel-find-file-noselect-refresh (file)
 109   "Find file ensuring that the latest changes on disk are
 110 represented in the file."
 111   (find-file-noselect file)
 112   (with-current-buffer (get-file-buffer file)
 113     (revert-buffer t t t)))
 114
 115 (defmacro org-babel-with-temp-filebuffer (file &rest body)
 116   "Open FILE into a temporary buffer execute BODY there like
 117 `progn', then kill the FILE buffer returning the result of
 118 evaluating BODY."
 119   (declare (indent 1))
 120   (let ((temp-result (make-symbol "temp-result"))
 121         (temp-file (make-symbol "temp-file"))
 122         (visited-p (make-symbol "visited-p")))
 123     `(let (,temp-result ,temp-file
 124            (,visited-p (get-file-buffer ,file)))
 125        (org-babel-find-file-noselect-refresh ,file)
 126        (setf ,temp-file (get-file-buffer ,file))
 127        (with-current-buffer ,temp-file
 128          (setf ,temp-result (progn ,@body)))
 129        (unless ,visited-p (kill-buffer ,temp-file))
 130        ,temp-result)))
 131
 132 ;;;###autoload
 133 (defun org-babel-load-file (file)
 134   "Load Emacs Lisp source code blocks in the Org-mode FILE.
 135 This function exports the source code using
 136 `org-babel-tangle' and then loads the resulting file using
 137 `load-file'."
 138   (interactive "fFile to load: ")
 139   (flet ((age (file)
 140               (float-time
 141                (time-subtract (current-time)
 142                               (nth 5 (or (file-attributes (file-truename file))
 143                                          (file-attributes file)))))))
 144     (let* ((base-name (file-name-sans-extension file))
 145            (exported-file (concat base-name ".el")))
 146       ;; tangle if the org-mode file is newer than the elisp file
 147       (unless (and (file-exists-p exported-file)
 148                    (> (age file) (age exported-file)))
 149         (org-babel-tangle-file file exported-file "emacs-lisp"))
 150       (load-file exported-file)
 151       (message "loaded %s" exported-file))))
 152
 153 ;;;###autoload
 154 (defun org-babel-tangle-file (file &optional target-file lang)
 155   "Extract the bodies of source code blocks in FILE.
 156 Source code blocks are extracted with `org-babel-tangle'.
 157 Optional argument TARGET-FILE can be used to specify a default
 158 export file for all source blocks.  Optional argument LANG can be
 159 used to limit the exported source code blocks by language."
 160   (interactive "fFile to tangle: \nP")
 161   (let ((visited-p (get-file-buffer (expand-file-name file)))
 162         to-be-removed)
 163     (save-window-excursion
 164       (find-file file)
 165       (setq to-be-removed (current-buffer))
 166       (org-babel-tangle target-file lang))
 167     (unless visited-p
 168       (kill-buffer to-be-removed))))
 169
 170 (defun org-babel-tangle-publish (_ filename pub-dir)
 171   "Tangle FILENAME and place the results in PUB-DIR."
 172   (mapc (lambda (el) (copy-file el pub-dir t)) (org-babel-tangle-file filename)))
 173
 174 ;;;###autoload
 175 (defun org-babel-tangle (&optional target-file lang)
 176   "Write code blocks to source-specific files.
 177 Extract the bodies of all source code blocks from the current
 178 file into their own source-specific files.  Optional argument
 179 TARGET-FILE can be used to specify a default export file for all
 180 source blocks.  Optional argument LANG can be used to limit the
 181 exported source code blocks by language."
 182   (interactive)
 183   (run-hooks 'org-babel-pre-tangle-hook)
 184   (save-excursion
 185     (let ((block-counter 0)
 186           (org-babel-default-header-args
 187            (if target-file
 188                (org-babel-merge-params org-babel-default-header-args
 189                                        (list (cons :tangle target-file)))
 190              org-babel-default-header-args))
 191           path-collector)
 192       (mapc ;; map over all languages
 193        (lambda (by-lang)
 194          (let* ((lang (car by-lang))
 195                 (specs (cdr by-lang))
 196                 (ext (or (cdr (assoc lang org-babel-tangle-lang-exts)) lang))
 197                 (lang-f (intern
 198                          (concat
 199                           (or (and (cdr (assoc lang org-src-lang-modes))
 200                                    (symbol-name
 201                                     (cdr (assoc lang org-src-lang-modes))))
 202                               lang)
 203                           "-mode")))
 204                 she-banged)
 205            (mapc
 206             (lambda (spec)
 207               (flet ((get-spec (name)
 208                                (cdr (assoc name (nth 4 spec)))))
 209                 (let* ((tangle (get-spec :tangle))
 210                        (she-bang ((lambda (sheb) (when (> (length sheb) 0) sheb))
 211                                   (get-spec :shebang)))
 212                        (base-name (cond
 213                                    ((string= "yes" tangle)
 214                                     (file-name-sans-extension
 215                                      (buffer-file-name)))
 216                                    ((string= "no" tangle) nil)
 217                                    ((> (length tangle) 0) tangle)))
 218                        (file-name (when base-name
 219                                     ;; decide if we want to add ext to base-name
 220                                     (if (and ext (string= "yes" tangle))
 221                                         (concat base-name "." ext) base-name))))
 222                   (when file-name
 223                     ;; possibly create the parent directories for file
 224                     (when ((lambda (m) (and m (not (string= m "no"))))
 225                            (get-spec :mkdirp))
 226                       (make-directory (file-name-directory file-name) 'parents))
 227                     ;; delete any old versions of file
 228                     (when (and (file-exists-p file-name)
 229                                (not (member file-name path-collector)))
 230                       (delete-file file-name))
 231                     ;; drop source-block to file
 232                     (with-temp-buffer
 233                       (when (fboundp lang-f) (funcall lang-f))
 234                       (when (and she-bang (not (member file-name she-banged)))
 235                         (insert (concat she-bang "\n"))
 236                         (setq she-banged (cons file-name she-banged)))
 237                       (org-babel-spec-to-string spec)
 238                       ;; We avoid append-to-file as it does not work with tramp.
 239                       (let ((content (buffer-string)))
 240                         (with-temp-buffer
 241                           (if (file-exists-p file-name)
 242                               (insert-file-contents file-name))
 243                           (goto-char (point-max))
 244                           (insert content)
 245                           (write-region nil nil file-name))))
 246                     ;; if files contain she-bangs, then make the executable
 247                     (when she-bang (set-file-modes file-name #o755))
 248                     ;; update counter
 249                     (setq block-counter (+ 1 block-counter))
 250                     (add-to-list 'path-collector file-name)))))
 251             specs)))
 252        (org-babel-tangle-combine-named-blocks
 253         (org-babel-tangle-collect-blocks lang)))
 254       (message "tangled %d code block%s from %s" block-counter
 255                (if (= block-counter 1) "" "s")
 256                (file-name-nondirectory
 257                 (buffer-file-name (or (buffer-base-buffer) (current-buffer)))))
 258       ;; run `org-babel-post-tangle-hook' in all tangled files
 259       (when org-babel-post-tangle-hook
 260         (mapc
 261          (lambda (file)
 262            (org-babel-with-temp-filebuffer file
 263              (run-hooks 'org-babel-post-tangle-hook)))
 264          path-collector))
 265       path-collector)))
 266
 267 (defun org-babel-tangle-clean ()
 268   "Remove comments inserted by `org-babel-tangle'.
 269 Call this function inside of a source-code file generated by
 270 `org-babel-tangle' to remove all comments inserted automatically
 271 by `org-babel-tangle'.  Warning, this comment removes any lines
 272 containing constructs which resemble org-mode file links or noweb
 273 references."
 274   (interactive)
 275   (goto-char (point-min))
 276   (while (or (re-search-forward "\\[\\[file:.*\\]\\[.*\\]\\]" nil t)
 277              (re-search-forward "<<[^[:space:]]*>>" nil t))
 278     (delete-region (save-excursion (beginning-of-line 1) (point))
 279                    (save-excursion (end-of-line 1) (forward-char 1) (point)))))
 280
 281 (defvar org-stored-links)
 282 (defun org-babel-tangle-collect-blocks (&optional language)
 283   "Collect source blocks in the current Org-mode file.
 284 Return an association list of source-code block specifications of
 285 the form used by `org-babel-spec-to-string' grouped by language.
 286 Optional argument LANG can be used to limit the collected source
 287 code blocks by language."
 288   (let ((block-counter 1) (current-heading "") blocks)
 289     (org-babel-map-src-blocks (buffer-file-name)
 290       ((lambda (new-heading)
 291          (if (not (string= new-heading current-heading))
 292              (progn
 293                (setq block-counter 1)
 294                (setq current-heading new-heading))
 295            (setq block-counter (+ 1 block-counter))))
 296        (replace-regexp-in-string "[ \t]" "-"
 297                                  (condition-case nil
 298                                      (nth 4 (org-heading-components))
 299                                    (error (buffer-file-name)))))
 300       (let* ((start-line (save-restriction (widen)
 301                                            (+ 1 (line-number-at-pos (point)))))
 302              (file (buffer-file-name))
 303              (info (org-babel-get-src-block-info 'light))
 304              (src-lang (nth 0 info)))
 305         (unless (string= (cdr (assoc :tangle (nth 2 info))) "no")
 306           (unless (and language (not (string= language src-lang)))
 307             (let* ((info (org-babel-get-src-block-info))
 308                    (params (nth 2 info))
 309                    (link ((lambda (link)
 310                             (and (string-match org-bracket-link-regexp link)
 311                                  (match-string 1 link)))
 312                           (org-babel-clean-text-properties
 313                            (org-store-link nil))))
 314                    (source-name
 315                     (intern (or (nth 4 info)
 316                                 (format "%s:%d"
 317                                         current-heading block-counter))))
 318                    (expand-cmd
 319                     (intern (concat "org-babel-expand-body:" src-lang)))
 320                    (assignments-cmd
 321                     (intern (concat "org-babel-variable-assignments:" src-lang)))
 322                    (body
 323                     ((lambda (body) ;; run the tangle-body-hook
 324                        (with-temp-buffer
 325                          (insert body)
 326                          (run-hooks 'org-babel-tangle-body-hook)
 327                          (buffer-string)))
 328                      ((lambda (body) ;; expand the body in language specific manner
 329                         (if (assoc :no-expand params)
 330                             body
 331                           (if (fboundp expand-cmd)
 332                               (funcall expand-cmd body params)
 333                             (org-babel-expand-body:generic
 334                              body params
 335                              (and (fboundp assignments-cmd)
 336                                   (funcall assignments-cmd params))))))
 337                       (if (and (cdr (assoc :noweb params)) ;; expand noweb refs
 338                                (let ((nowebs (split-string
 339                                               (cdr (assoc :noweb params)))))
 340                                  (or (member "yes" nowebs)
 341                                      (member "tangle" nowebs))))
 342                           (org-babel-expand-noweb-references info)
 343                         (nth 1 info)))))
 344                    (comment
 345                     (when (or (string= "both" (cdr (assoc :comments params)))
 346                               (string= "org" (cdr (assoc :comments params))))
 347                       ;; from the previous heading or code-block end
 348                       (buffer-substring
 349                        (max (condition-case nil
 350                                 (save-excursion
 351                                   (org-back-to-heading t) (point))
 352                               (error 0))
 353                             (save-excursion
 354                               (re-search-backward
 355                                org-babel-src-block-regexp nil t)
 356                               (match-end 0)))
 357                        (point))))
 358                    by-lang)
 359               ;; add the spec for this block to blocks under it's language
 360               (setq by-lang (cdr (assoc src-lang blocks)))
 361               (setq blocks (delq (assoc src-lang blocks) blocks))
 362               (setq blocks (cons
 363                             (cons src-lang
 364                                   (cons (list start-line file link
 365                                               source-name params body comment)
 366                                         by-lang)) blocks)))))))
 367     ;; ensure blocks in the correct order
 368     (setq blocks
 369           (mapcar
 370            (lambda (by-lang) (cons (car by-lang) (reverse (cdr by-lang))))
 371            blocks))
 372     blocks))
 373
 374 (defun org-babel-tangle-combine-named-blocks (blocks)
 375   "Combine blocks of the same name.
 376 This function follows noweb behavior of appending blocks of the
 377 same name in the order they appear in the file."
 378   (if org-babel-tangle-named-block-combination
 379       (let (tangled-names)
 380         (mapcar
 381          (lambda (by-lang)
 382            (cons
 383             (car by-lang)
 384             (mapcar (lambda (spec)
 385                       (let ((name (nth 3 spec)))
 386                         (unless (member name tangled-names)
 387                           (when name
 388                             (setf
 389                              (nth 5 spec)
 390                              (let ((named (mapcar
 391                                            (lambda (el) (nth 5 el))
 392                                            (remove-if
 393                                             (lambda (el)
 394                                               (not (equal name (nth 3 el))))
 395                                             (cdr by-lang)))))
 396                                (case org-babel-tangle-named-block-combination
 397                                  (append (mapconcat #'identity
 398                                                     named ""))
 399                                  (first  (first named))
 400                                  (last   (car (last  named))))))
 401                             (add-to-list 'tangled-names name))
 402                           spec)))
 403                     (cdr by-lang))))
 404          blocks))
 405     blocks))
 406
 407 (defun org-babel-spec-to-string (spec)
 408   "Insert SPEC into the current file.
 409 Insert the source-code specified by SPEC into the current
 410 source code file.  This function uses `comment-region' which
 411 assumes that the appropriate major-mode is set.  SPEC has the
 412 form
 413
 414   (start-line file link source-name params body comment)"
 415   (let* ((start-line (nth 0 spec))
 416          (file (nth 1 spec))
 417          (link (org-link-escape (nth 2 spec)))
 418          (source-name (nth 3 spec))
 419          (body (nth 5 spec))
 420          (comment (nth 6 spec))
 421          (comments (cdr (assoc :comments (nth 4 spec))))
 422          (padline (not (string= "no" (cdr (assoc :padline (nth 4 spec))))))
 423          (link-p (or (string= comments "both") (string= comments "link")
 424                      (string= comments "yes") (string= comments "noweb")))
 425          (link-data (mapcar (lambda (el)
 426                               (cons (symbol-name el)
 427                                     ((lambda (le)
 428                                        (if (stringp le) le (format "%S" le)))
 429                                      (eval el))))
 430                             '(start-line file link source-name))))
 431     (flet ((insert-comment (text)
 432             (let ((text (org-babel-trim text)))
 433               (when (and comments (not (string= comments "no"))
 434                          (> (length text) 0))
 435                 (when padline (insert "\n"))
 436                 (comment-region (point) (progn (insert text) (point)))
 437                 (end-of-line nil) (insert "\n")))))
 438       (when comment (insert-comment comment))
 439       (when link-p
 440         (insert-comment
 441          (org-fill-template org-babel-tangle-comment-format-beg link-data)))
 442       (when padline (insert "\n"))
 443       (insert
 444        (format
 445         "%s\n"
 446         (replace-regexp-in-string
 447          "^," ""
 448          (org-babel-trim body (if org-src-preserve-indentation "[\f\n\r\v]")))))
 449       (when link-p
 450         (insert-comment
 451          (org-fill-template org-babel-tangle-comment-format-end link-data))))))
 452
 453 (defun org-babel-tangle-comment-links ( &optional info)
 454   "Return a list of begin and end link comments for the code block at point."
 455   (let* ((start-line (org-babel-where-is-src-block-head))
 456          (file (buffer-file-name))
 457          (link (org-link-escape (progn (call-interactively 'org-store-link)
 458                                        (org-babel-clean-text-properties
 459                                         (car (pop org-stored-links))))))
 460          (source-name (nth 4 (or info (org-babel-get-src-block-info 'light))))
 461          (link-data (mapcar (lambda (el)
 462                               (cons (symbol-name el)
 463                                     ((lambda (le)
 464                                        (if (stringp le) le (format "%S" le)))
 465                                      (eval el))))
 466                             '(start-line file link source-name))))
 467     (list (org-fill-template org-babel-tangle-comment-format-beg link-data)
 468           (org-fill-template org-babel-tangle-comment-format-end link-data))))
 469
 470 ;; de-tangling functions
 471 (defvar org-bracket-link-analytic-regexp)
 472 (defun org-babel-detangle (&optional source-code-file)
 473   "Propagate changes in source file back original to Org-mode file.
 474 This requires that code blocks were tangled with link comments
 475 which enable the original code blocks to be found."
 476   (interactive)
 477   (save-excursion
 478     (when source-code-file (find-file source-code-file))
 479     (goto-char (point-min))
 480     (let ((counter 0) new-body end)
 481       (while (re-search-forward org-bracket-link-analytic-regexp nil t)
 482         (when (re-search-forward
 483                (concat " " (regexp-quote (match-string 5)) " ends here"))
 484           (setq end (match-end 0))
 485           (forward-line -1)
 486           (save-excursion
 487             (when (setq new-body (org-babel-tangle-jump-to-org))
 488               (org-babel-update-block-body new-body)))
 489           (setq counter (+ 1 counter)))
 490         (goto-char end))
 491       (prog1 counter (message "detangled %d code blocks" counter)))))
 492
 493 (defun org-babel-tangle-jump-to-org ()
 494   "Jump from a tangled code file to the related Org-mode file."
 495   (interactive)
 496   (let ((mid (point))
 497         start end done
 498         target-buffer target-char link path block-name body)
 499     (save-window-excursion
 500       (save-excursion
 501         (while (and (re-search-backward org-bracket-link-analytic-regexp nil t)
 502                     (not ; ever wider searches until matching block comments
 503                      (and (setq start (point-at-eol))
 504                           (setq link (match-string 0))
 505                           (setq path (match-string 3))
 506                           (setq block-name (match-string 5))
 507                           (save-excursion
 508                             (save-match-data
 509                               (re-search-forward
 510                                (concat " " (regexp-quote block-name)
 511                                        " ends here") nil t)
 512                               (setq end (point-at-bol))))))))
 513         (unless (and start (< start mid) (< mid end))
 514           (error "not in tangled code"))
 515         (setq body (org-babel-trim (buffer-substring start end))))
 516       (when (string-match "::" path)
 517         (setq path (substring path 0 (match-beginning 0))))
 518       (find-file path) (setq target-buffer (current-buffer))
 519       (goto-char start) (org-open-link-from-string link)
 520       (if (string-match "[^ \t\n\r]:\\([[:digit:]]+\\)" block-name)
 521           (org-babel-next-src-block
 522            (string-to-number (match-string 1 block-name)))
 523         (org-babel-goto-named-src-block block-name))
 524       (setq target-char (point)))
 525     (pop-to-buffer target-buffer)
 526     (prog1 body (goto-char target-char))))
 527
 528 (provide 'ob-tangle)
 529
 530 ;; arch-tag: 413ced93-48f5-4216-86e4-3fc5df8c8f24
 531
 532 ;;; ob-tangle.el ends here