lisp/ob-lisp.el

   1 ;;; ob-lisp.el --- org-babel functions for common lisp evaluation
   2
   3 ;; Copyright (C) 2009, 2010, 2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Joel Boehland, Eric Schulte, David T. O'Toole <dto@gnu.org>
   6 ;; Keywords: literate programming, reproducible research
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.5
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; support for evaluating common lisp code, relies on slime for all eval
  28
  29 ;;; Requirements:
  30
  31 ;; Requires SLIME (Superior Lisp Interaction Mode for Emacs.)
  32 ;; See http://common-lisp.net/project/slime/
  33
  34 ;;; Code:
  35 (require 'ob)
  36
  37 (declare-function slime-eval "ext:slime" (sexp &optional package))
  38
  39 (add-to-list 'org-babel-tangle-lang-exts '("lisp" . "lisp"))
  40
  41 (defvar org-babel-default-header-args:lisp '())
  42 (defvar org-babel-header-arg-names:lisp '(package))
  43
  44 (defcustom org-babel-lisp-dir-fmt
  45   "(let ((*default-pathname-defaults* #P%S)) %%s)"
  46   "Format string used to wrap code bodies to set the current directory.
  47 For example a value of \"(progn ;; %s\\n   %%s)\" would ignore the
  48 current directory string.")
  49
  50 (defun org-babel-expand-body:lisp (body params)
  51   "Expand BODY according to PARAMS, return the expanded body."
  52   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  53          (result-params (cdr (assoc :result-params params)))
  54          (print-level nil) (print-length nil)
  55          (body (org-babel-trim
  56                 (if (> (length vars) 0)
  57                     (concat "(let ("
  58                             (mapconcat
  59                              (lambda (var)
  60                                (format "(%S (quote %S))" (car var) (cdr var)))
  61                              vars "\n      ")
  62                             ")\n" body ")")
  63                   body))))
  64     (if (or (member "code" result-params)
  65             (member "pp" result-params))
  66         (format "(pprint %s)" body)
  67       body)))
  68
  69 (defun org-babel-execute:lisp (body params)
  70   "Execute a block of Common Lisp code with Babel."
  71   (require 'slime)
  72   (org-babel-reassemble-table
  73    ((lambda (result)
  74       (if (member "output" (cdr (assoc :result-params params)))
  75           (car result)
  76         (condition-case nil
  77             (read (org-bable-lisp-vector-to-list (cadr result)))
  78           (error (cadr result)))))
  79     (with-temp-buffer
  80       (insert (org-babel-expand-body:lisp body params))
  81       (slime-eval `(swank:eval-and-grab-output
  82                     ,(let ((dir (if (assoc :dir params)
  83                                             (cdr (assoc :dir params))
  84                                           default-directory)))
  85                        (format
  86                         (if dir (format org-babel-lisp-dir-fmt dir) "(progn %s)")
  87                         (buffer-substring-no-properties
  88                          (point-min) (point-max)))))
  89                   (cdr (assoc :package params)))))
  90    (org-babel-pick-name (cdr (assoc :colname-names params))
  91                         (cdr (assoc :colnames params)))
  92    (org-babel-pick-name (cdr (assoc :rowname-names params))
  93                         (cdr (assoc :rownames params)))))
  94
  95 (defun org-bable-lisp-vector-to-list (results)
  96   ;; TODO: better would be to replace #(...) with [...]
  97   (replace-regexp-in-string "#(" "(" results))
  98
  99 (provide 'ob-lisp)
 100
 101 ;; arch-tag: 18086168-009f-4947-bbb5-3532375d851d
 102
 103 ;;; ob-lisp.el ends here