lisp/org-indent.el

   1 ;;; org-indent.el --- Dynamic indentation for  Org-mode
   2 ;; Copyright (C) 2009 Free Software Foundation, Inc.
   3 ;;
   4 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   5 ;; Keywords: outlines, hypermedia, calendar, wp
   6 ;; Homepage: http://orgmode.org
   7 ;; Version: 6.30trans
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This is an implementation of dynamic virtual indentation.  It works
  29 ;; by adding text properties to a buffer to make sure lines are
  30 ;; indented according to outline structure.
  31
  32 (require 'org-macs)
  33 (require 'org-compat)
  34 (require 'org)
  35 (eval-when-compile
  36   (require 'cl))
  37
  38
  39 (defgroup org-indent nil
  40   "Options concerning dynamic virtual outline indentation."
  41   :tag "Org Structure"
  42   :group 'org)
  43
  44 (defconst org-indent-max 40
  45   "Maximum indentation in characters")
  46 (defconst org-indent-max-levels 40
  47   "Maximum indentation in characters")
  48
  49 (defvar org-indent-strings nil
  50   "Vector with all indentation strings.
  51 It will be set in `org-indent-initialize'.")
  52 (defvar org-indent-stars nil
  53   "Vector with all indentation star strings.
  54 It will be set in `org-indent-initialize'.")
  55 (defvar org-hide-leading-stars-before-indent-mode nil
  56   "Used locally")
  57
  58 (defcustom org-indent-boundary-char ?\   ; comment to protect space char
  59   "The end of the virtual indentation strings, a single-character string.
  60 The default is just a space, but if you wish, you can use \"|\" or so.
  61 This can be useful on a terminal window - under a windowing system,
  62 it may be prettier to customize the org-indent face."
  63   :group 'org-indent
  64   :set (lambda (var val)
  65          (set var val)
  66          (and org-indent-strings (org-indent-initialize)))
  67   :type 'character)
  68
  69 (defcustom org-indent-mode-turns-off-org-adapt-indentation t
  70   "Non-nil means, turning on org-indent-mode turns off indentation adaptation.
  71 For details see the variable `org-adapt-indentation'."
  72   :group 'org-indent
  73   :type 'boolean)
  74
  75 (defcustom org-indent-mode-turns-on-hiding-stars t
  76   "Non-nil means, turning on org-indent-mode turns on `org-hide-leading-stars'."
  77   :group 'org-indent
  78   :type 'boolean)
  79
  80 (defcustom org-indent-indentation-per-level 2
  81   "Indentation per level in number of characters."
  82   :group 'org-indent
  83   :type 'integer)
  84
  85 (defcustom org-indent-fix-section-after-idle-time 0.2
  86   "Seconds of idle time before fixing virtual indentation of section.
  87 The hooking-in of virtual indentation is not yet perfect.  Occasionally,
  88 a change does not trigger to proper change of indentation.  For this we
  89 have a timer action that fixes indentation in the current section after
  90 a short amount idle time.  If we ever get the integration to work perfectly,
  91 this variable can be set to nil to get rid of the timer."
  92   :group 'org-indent
  93   :type '(choice
  94           (const "Do not install idle timer" nil)
  95           (number :tag "Idle time")))
  96
  97 (defun org-indent-initialize ()
  98   "Initialize the indentation strings and set the idle timer."
  99   ;; We use an idle timer to "repair" the current section, because the
 100   ;; redisplay seems to have some problems.
 101   (unless org-indent-strings
 102     (when org-indent-fix-section-after-idle-time
 103       (run-with-idle-timer
 104        org-indent-fix-section-after-idle-time
 105        t 'org-indent-refresh-section)))
 106   ;; Initialize the indentation and star vectors
 107   (setq org-indent-strings (make-vector (1+ org-indent-max) nil))
 108   (setq org-indent-stars (make-vector (1+ org-indent-max) nil))
 109   (aset org-indent-strings 0 "")
 110   (aset org-indent-stars 0 "")
 111   (loop for i from 1 to org-indent-max do
 112         (aset org-indent-strings i
 113               (org-add-props
 114                   (concat (make-string (1- i) ?\ )
 115                           (char-to-string org-indent-boundary-char))
 116                   nil 'face 'org-indent)))
 117   (loop for i from 1 to org-indent-max-levels do
 118         (aset org-indent-stars i
 119               (org-add-props (make-string i ?*)
 120                   nil 'face 'org-hide))))
 121
 122 ;;;###autoload
 123 (define-minor-mode org-indent-mode
 124   "When active, indent text according to outline structure.
 125
 126 Internally this works by adding `line-prefix' properties to all non-headlines.
 127 These properties are updated locally in idle time.
 128 FIXME:  How to update when broken?"
 129   nil " Ind" nil
 130   (if (org-bound-and-true-p org-inhibit-startup)
 131       (setq org-indent-mode nil)
 132     (if org-indent-mode
 133         (progn
 134           (or org-indent-strings (org-indent-initialize))
 135           (when org-indent-mode-turns-off-org-adapt-indentation
 136             (org-set-local 'org-adapt-indentation nil))
 137           (when org-indent-mode-turns-on-hiding-stars
 138             (org-set-local 'org-hide-leading-stars-before-indent-mode
 139                            org-hide-leading-stars)
 140             (org-set-local 'org-hide-leading-stars t))
 141           (make-local-variable 'buffer-substring-filters)
 142           (add-to-list 'buffer-substring-filters
 143                        'org-indent-remove-properties-from-string)
 144           (org-add-hook 'org-after-demote-entry-hook
 145                         'org-indent-refresh-section nil 'local)
 146           (org-add-hook 'org-after-promote-entry-hook
 147                         'org-indent-refresh-section nil 'local)
 148           (org-add-hook 'org-font-lock-hook
 149                         'org-indent-refresh-to nil 'local)
 150           (and font-lock-mode (org-restart-font-lock))
 151           )
 152       (save-excursion
 153         (save-restriction
 154           (org-indent-remove-properties (point-min) (point-max))
 155           (kill-local-variable 'org-adapt-indentation)
 156           (when (boundp 'org-hide-leading-stars-before-indent-mode)
 157             (org-set-local 'org-hide-leading-stars
 158                            org-hide-leading-stars-before-indent-mode))
 159           (setq buffer-substring-filters
 160                 (delq 'org-indent-remove-properties-from-string
 161                       buffer-substring-filters))
 162           (remove-hook 'org-after-promote-entry-hook
 163                        'org-indent-refresh-section 'local)
 164           (remove-hook 'org-after-demote-entry-hook
 165                        'org-indent-refresh-section 'local)
 166           (and font-lock-mode (org-restart-font-lock))
 167           (redraw-display))))))
 168
 169
 170 (defface org-indent
 171   (org-compatible-face nil nil)
 172   "Face for outline indentation.
 173 The default is to make it look like whitespace.  But you may find it
 174 useful to make it evver so slightly different."
 175   :group 'org-faces)
 176
 177 (defun org-indent-indent-buffer ()
 178   "Add indentation properties for the whole buffer."
 179   (interactive)
 180   (when org-indent-mode
 181     (save-excursion
 182       (save-restriction
 183         (widen)
 184         (org-indent-remove-properties (point-min) (point-max))
 185         (org-indent-add-properties (point-min) (point-max))))))
 186
 187 (defun org-indent-remove-properties (beg end)
 188   "Remove indentations between BEG and END."
 189   (org-unmodified
 190    (remove-text-properties beg end '(line-prefix nil wrap-prefix nil))))
 191
 192 (defun org-indent-remove-properties-from-string (string)
 193   "Remove indentations between BEG and END."
 194   (remove-text-properties 0 (length string)
 195                           '(line-prefix nil wrap-prefix nil) string)
 196   string)
 197
 198 (defvar org-indent-outline-re (concat "^" org-outline-regexp)
 199   "Outline heading regexp.")
 200
 201 (defun org-indent-add-properties (beg end)
 202   "Add indentation properties between BEG and END.
 203 Assumes that BEG is at the beginning of a line."
 204   (when (or t org-indent-mode)
 205     (let (ov b e n level exit nstars)
 206       (org-unmodified
 207        (save-excursion
 208          (goto-char beg)
 209          (while (not exit)
 210            (setq e end)
 211            (if (not (re-search-forward org-indent-outline-re nil t))
 212                (setq e (point-max) exit t)
 213              (setq e (match-beginning 0))
 214              (if (>= e end) (setq exit t))
 215              (setq level (- (match-end 0) (match-beginning 0) 1))
 216              (setq nstars (- (* (1- level) org-indent-indentation-per-level)
 217                              (1- level)))
 218              (add-text-properties
 219               (point-at-bol) (point-at-eol)
 220               (list 'line-prefix
 221                     (aref org-indent-stars nstars)
 222                     'wrap-prefix
 223                     (aref org-indent-strings
 224                           (* level org-indent-indentation-per-level)))))
 225            (when (and b (> e b))
 226              (add-text-properties
 227               b  e (list 'line-prefix (aref org-indent-strings n)
 228                          'wrap-prefix (aref org-indent-strings n))))
 229            (setq b (1+ (point-at-eol))
 230                  n (* level org-indent-indentation-per-level))))))))
 231
 232 (defun org-indent-refresh-section ()
 233   "Refresh indentation properties in the current outline section.
 234 Point is assumed to be at the beginning of a headline."
 235   (interactive)
 236   (when org-indent-mode
 237     (let (beg end)
 238       (save-excursion
 239         (when (ignore-errors (org-back-to-heading))
 240           (setq beg (point))
 241           (setq end (or (save-excursion (or (outline-next-heading) (point)))))
 242           (org-indent-remove-properties beg end)
 243           (org-indent-add-properties beg end))))))
 244
 245 (defun org-indent-refresh-to (limit)
 246   "Refresh indentation properties in the current outline section.
 247 Point is assumed to be at the beginning of a headline."
 248   (interactive)
 249   (when org-indent-mode
 250     (let ((beg (point)) (end limit))
 251       (save-excursion
 252         (and (ignore-errors (org-back-to-heading t))
 253              (setq beg (point))))
 254       (org-indent-remove-properties beg end)
 255       (org-indent-add-properties beg end)))
 256   (goto-char limit))
 257
 258 (defun org-indent-refresh-subtree ()
 259   "Refresh indentation properties in the current outline subtree.
 260 Point is assumed to be at the beginning of a headline."
 261   (interactive)
 262   (when org-indent-mode
 263     (save-excursion
 264       (let (beg end)
 265         (setq beg (point))
 266         (setq end (save-excursion (org-end-of-subtree t t)))
 267         (org-indent-remove-properties beg end)
 268         (org-indent-add-properties beg end)))))
 269
 270 (defun org-indent-refresh-buffer ()
 271   "Refresh indentation properties in the current outline subtree.
 272 Point is assumed to be at the beginning of a headline."
 273   (interactive)
 274   (when org-indent-mode
 275     (org-indent-mode -1)
 276     (org-indent-mode 1)))
 277
 278 (provide 'org-indent)
 279
 280 ;;; org-indent.el ends here